lib/DBIx/Class/DeploymentHandler/SqltDeployMethod.pm

   1 package DBIx::Class::DeploymentHandler::SqltDeployMethod;
   2 use Moose;
   3 use Method::Signatures::Simple;
   4 use Try::Tiny;
   5 use SQL::Translator;
   6 require SQL::Translator::Diff;
   7 require DBIx::Class::Storage;   # loaded for type constraint
   8
   9 use Carp 'carp';
  10
  11 has storage => (
  12   isa        => 'DBIx::Class::Storage',
  13   is         => 'ro',
  14   lazy_build => 1,
  15 );
  16
  17 method _build_storage {
  18   my $s = $self->schema->storage;
  19   $s->_determine_driver;
  20   $s
  21 }
  22
  23 has backup_directory => (
  24   isa => 'Str',
  25   is  => 'ro',
  26 );
  27
  28 has do_backup => (
  29   isa     => 'Bool',
  30   is      => 'ro',
  31   default => undef,
  32 );
  33
  34 has sqltargs => (
  35   isa => 'HashRef',
  36   is  => 'ro',
  37   default => sub { {} },
  38 );
  39 has upgrade_directory => (
  40   isa      => 'Str',
  41   is       => 'ro',
  42   required => 1,
  43   default  => 'sql',
  44 );
  45
  46 has version_rs => (
  47   isa        => 'DBIx::Class::ResultSet',
  48   is         => 'ro',
  49   lazy_build => 1,
  50   handles    => [qw( is_installed db_version )],
  51 );
  52
  53 method _build_version_rs {
  54    $self->schema->set_us_up_the_bomb;
  55    $self->schema->resultset('__VERSION')
  56 }
  57
  58 has databases => (
  59   coerce  => 1,
  60   isa     => 'DBIx::Class::DeploymentHandler::Databases',
  61   is      => 'ro',
  62   default => sub { [qw( MySQL SQLite PostgreSQL )] },
  63 );
  64
  65 has schema => (
  66   isa      => 'DBIx::Class::Schema',
  67   is       => 'ro',
  68   required => 1,
  69   handles => [qw( ddl_filename schema_version )],
  70 );
  71
  72 has _filedata => (
  73   isa => 'ArrayRef[Str]',
  74   is  => 'rw',
  75 );
  76
  77 method deployment_statements {
  78   my $dir      = $self->upgrade_directory;
  79   my $schema   = $self->schema;
  80   my $type     = $self->storage->sqlt_type;
  81   my $sqltargs = $self->sqltargs;
  82   my $version  = $self->schema_version || '1.x';
  83
  84   my $filename = $self->ddl_filename($type, $version, $dir);
  85   if(-f $filename) {
  86       my $file;
  87       open $file, q(<), $filename
  88         or carp "Can't open $filename ($!)";
  89       my @rows = <$file>;
  90       close $file;
  91       return join '', @rows;
  92   }
  93
  94   # sources needs to be a parser arg, but for simplicty allow at top level
  95   # coming in
  96   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
  97       if exists $sqltargs->{sources};
  98
  99   my $tr = SQL::Translator->new(
 100     producer => "SQL::Translator::Producer::${type}",
 101     %$sqltargs,
 102     parser => 'SQL::Translator::Parser::DBIx::Class',
 103     data => $schema,
 104   );
 105
 106   my @ret;
 107   my $wa = wantarray;
 108   if ($wa) {
 109     @ret = $tr->translate;
 110   }
 111   else {
 112     $ret[0] = $tr->translate;
 113   }
 114
 115   $schema->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
 116     unless (@ret && defined $ret[0]);
 117
 118   return $wa ? @ret : $ret[0];
 119 }
 120
 121 method deploy {
 122   my $storage  = $self->storage;
 123
 124   my $deploy = sub {
 125     my $line = shift;
 126     return if(!$line || $line =~ /^--|^BEGIN TRANSACTION|^COMMIT|^\s+$/);
 127     $storage->_query_start($line);
 128     try {
 129       # do a dbh_do cycle here, as we need some error checking in
 130       # place (even though we will ignore errors)
 131       $storage->dbh_do (sub { $_[1]->do($line) });
 132     }
 133     catch {
 134       carp "$_ (running '${line}')"
 135     }
 136     $storage->_query_end($line);
 137   };
 138   my @statements = $self->deployment_statements();
 139   if (@statements > 1) {
 140     foreach my $statement (@statements) {
 141       $deploy->( $statement );
 142     }
 143   }
 144   elsif (@statements == 1) {
 145     foreach my $line ( split(";\n", $statements[0])) {
 146       $deploy->( $line );
 147     }
 148   }
 149 }
 150
 151 method create_install_ddl {
 152   my $schema    = $self->schema;
 153   my $databases = $self->databases;
 154   my $dir       = $self->upgrade_directory;
 155   my $sqltargs  = $self->sqltargs;
 156   unless( -d $dir ) {
 157     carp "Upgrade directory $dir does not exist, using ./\n";
 158     $dir = "./";
 159   }
 160
 161   my $version = $schema->schema_version || '1.x';
 162   my $schema_version = $schema->schema_version || '1.x';
 163   $version ||= $schema_version;
 164
 165   $sqltargs = {
 166     add_drop_table => 1,
 167     ignore_constraint_names => 1,
 168     ignore_index_names => 1,
 169     %{$sqltargs || {}}
 170   };
 171
 172   my $sqlt = SQL::Translator->new( $sqltargs );
 173
 174   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
 175   my $sqlt_schema = $sqlt->translate({ data => $schema })
 176     or $self->throw_exception ($sqlt->error);
 177
 178   foreach my $db (@$databases) {
 179     $sqlt->reset;
 180     $sqlt->{schema} = $sqlt_schema;
 181     $sqlt->producer($db);
 182
 183     my $filename = $self->ddl_filename($db, $version, $dir);
 184     if (-e $filename && ($version eq $schema_version )) {
 185       # if we are dumping the current version, overwrite the DDL
 186       carp "Overwriting existing DDL file - $filename";
 187       unlink $filename;
 188     }
 189
 190     my $output = $sqlt->translate;
 191     if(!$output) {
 192       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
 193       next;
 194     }
 195     my $file;
 196     unless( open $file, q(>), $filename ) {
 197       $self->throw_exception("Can't open $filename for writing ($!)");
 198       next;
 199     }
 200     print {$file} $output;
 201     close $file;
 202   }
 203 }
 204
 205 method create_update_ddl($version, $preversion) {
 206   my $schema    = $self->schema;
 207   my $databases = $self->databases;
 208   my $dir       = $self->upgrade_directory;
 209   my $sqltargs  = $self->sqltargs;
 210
 211   unless( -d $dir ) {
 212     carp "Upgrade directory $dir does not exist, using ./\n";
 213     $dir = "./";
 214   }
 215
 216   my $schema_version = $schema->schema_version || '1.x';
 217   $version ||= $schema_version;
 218
 219   $sqltargs = {
 220     add_drop_table => 1,
 221     ignore_constraint_names => 1,
 222     ignore_index_names => 1,
 223     %{$sqltargs}
 224   };
 225
 226   my $sqlt = SQL::Translator->new( $sqltargs );
 227
 228   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
 229   my $sqlt_schema = $sqlt->translate({ data => $schema })
 230     or $self->throw_exception ($sqlt->error);
 231
 232   foreach my $db (@$databases) {
 233     $sqlt->reset;
 234     $sqlt->{schema} = $sqlt_schema;
 235     $sqlt->producer($db);
 236
 237     my $prefilename = $self->ddl_filename($db, $preversion, $dir);
 238     unless(-e $prefilename) {
 239       carp("No previous schema file found ($prefilename)");
 240       next;
 241     }
 242
 243     my $diff_file = $self->ddl_filename($db, $version, $dir, $preversion);
 244     if(-e $diff_file) {
 245       carp("Overwriting existing diff file - $diff_file");
 246       unlink $diff_file;
 247     }
 248
 249     my $source_schema;
 250     {
 251       my $t = SQL::Translator->new({
 252          %{$sqltargs},
 253          debug => 0,
 254          trace => 0,
 255       });
 256
 257       $t->parser( $db ) # could this really throw an exception?
 258         or $self->throw_exception ($t->error);
 259
 260       my $out = $t->translate( $prefilename )
 261         or $self->throw_exception ($t->error);
 262
 263       $source_schema = $t->schema;
 264
 265       $source_schema->name( $prefilename )
 266         unless  $source_schema->name;
 267     }
 268
 269     # The "new" style of producers have sane normalization and can support
 270     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
 271     # And we have to diff parsed SQL against parsed SQL.
 272     my $dest_schema = $sqlt_schema;
 273
 274     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
 275       my $t = SQL::Translator->new({
 276          %{$sqltargs},
 277          debug => 0,
 278          trace => 0,
 279       });
 280
 281       $t->parser( $db ) # could this really throw an exception?
 282         or $self->throw_exception ($t->error);
 283
 284       my $filename = $self->ddl_filename($db, $version, $dir);
 285       my $out = $t->translate( $filename )
 286         or $self->throw_exception ($t->error);
 287
 288       $dest_schema = $t->schema;
 289
 290       $dest_schema->name( $filename )
 291         unless $dest_schema->name;
 292     }
 293
 294     my $diff = SQL::Translator::Diff::schema_diff(
 295        $source_schema, $db,
 296        $dest_schema,   $db,
 297        $sqltargs
 298     );
 299     my $file;
 300     unless(open $file, q(>), $diff_file) {
 301       $self->throw_exception("Can't write to $diff_file ($!)");
 302       next;
 303     }
 304     print {$file} $diff;
 305     close $file;
 306   }
 307 }
 308
 309 method create_ddl_dir($version, $preversion) {
 310   $self->create_install_ddl;
 311   $self->create_update_ddl($version, $preversion) if $preversion;
 312 }
 313
 314 method _read_sql_file($file) {
 315   return unless $file;
 316
 317   open my $fh, '<', $file or carp("Can't open upgrade file, $file ($!)");
 318   my @data = split /\n/, join '', <$fh>;
 319   close $fh;
 320
 321   @data = grep {
 322     $_ &&
 323     !/^--/ &&
 324     !/^(BEGIN|BEGIN TRANSACTION|COMMIT)/m
 325   } split /;/,
 326     join '', @data;
 327
 328   return \@data;
 329 }
 330
 331 method create_upgrade_path { }
 332
 333 method upgrade_single_step($db_version, $target_version) {
 334   if ($db_version eq $target_version) {
 335     # croak?
 336     carp "Upgrade not necessary\n";
 337     return;
 338   }
 339
 340   my $upgrade_file = $self->ddl_filename(
 341     $self->storage->sqlt_type,
 342     $target_version,
 343     $self->upgrade_directory,
 344     $db_version,
 345   );
 346
 347   $self->create_upgrade_path({ upgrade_file => $upgrade_file });
 348
 349   unless (-f $upgrade_file) {
 350     # croak?
 351     carp "Upgrade not possible, no upgrade file found ($upgrade_file), please create one\n";
 352     return;
 353   }
 354
 355   carp "DB version ($db_version) is lower than the schema version (".$self->schema_version."). Attempting upgrade.\n";
 356
 357   $self->_filedata($self->_read_sql_file($upgrade_file)); # I don't like this --fREW 2010-02-22
 358   $self->backup if $self->do_backup;
 359   $self->schema->txn_do(sub { $self->do_upgrade });
 360
 361   $self->version_rs->create({
 362     version     => $target_version,
 363     # ddl         => $ddl,
 364     # upgrade_sql => $upgrade_sql,
 365   });
 366 }
 367
 368 method do_upgrade { $self->run_upgrade(qr/.*?/) }
 369
 370 method run_upgrade($stm) {
 371   return unless $self->_filedata;
 372   my @statements = grep { $_ =~ $stm } @{$self->_filedata};
 373
 374   for (@statements) {
 375     $self->storage->debugobj->query_start($_) if $self->storage->debug;
 376     $self->apply_statement($_);
 377     $self->storage->debugobj->query_end($_) if $self->storage->debug;
 378   }
 379 }
 380
 381 method apply_statement($statement) {
 382   # croak?
 383   $self->storage->dbh->do($_) or carp "SQL was: $_"
 384 }
 385
 386 method backup { $self->storage->backup($self->backup_directory) }
 387
 388 __PACKAGE__->meta->make_immutable;
 389
 390 1;
 391
 392 __END__
 393
 394 vim: ts=2 sw=2 expandtab