lib/DBIx/Class/CDBICompat/ImaDBI.pm

   1 package # hide from PAUSE
   2     DBIx::Class::CDBICompat::ImaDBI;
   3
   4 use strict;
   5 use warnings;
   6 use DBIx::ContextualFetch;
   7 use Sub::Name ();
   8
   9 use base qw(Class::Data::Inheritable);
  10
  11 __PACKAGE__->mk_classdata('sql_transformer_class' =>
  12                           'DBIx::Class::CDBICompat::SQLTransformer');
  13
  14 __PACKAGE__->mk_classdata('_transform_sql_handler_order'
  15                             => [ qw/TABLE ESSENTIAL JOIN IDENTIFIER/ ] );
  16
  17 __PACKAGE__->mk_classdata('_transform_sql_handlers' =>
  18   {
  19     'TABLE' =>
  20       sub {
  21         my ($self, $class, $data) = @_;
  22         return $class->result_source_instance->name unless $data;
  23         my ($f_class, $alias) = split(/=/, $data);
  24         $f_class ||= $class;
  25         $self->{_classes}{$alias} = $f_class;
  26         return $f_class->result_source_instance->name." ${alias}";
  27       },
  28     'ESSENTIAL' =>
  29       sub {
  30         my ($self, $class, $data) = @_;
  31         $class = $data ? $self->{_classes}{$data} : $class;
  32         return join(', ', $class->columns('Essential'));
  33       },
  34     'IDENTIFIER' =>
  35       sub {
  36         my ($self, $class, $data) = @_;
  37         $class = $data ? $self->{_classes}{$data} : $class;
  38         return join ' AND ', map  "$_ = ?", $class->primary_columns;
  39       },
  40     'JOIN' =>
  41       sub {
  42         my ($self, $class, $data) = @_;
  43         my ($from, $to) = split(/ /, $data);
  44         my ($from_class, $to_class) = @{$self->{_classes}}{$from, $to};
  45         my ($rel_obj) = grep { $_->{class} && $_->{class} eq $to_class }
  46                           map { $from_class->relationship_info($_) }
  47                             $from_class->relationships;
  48         unless ($rel_obj) {
  49           ($from, $to) = ($to, $from);
  50           ($from_class, $to_class) = ($to_class, $from_class);
  51           ($rel_obj) = grep { $_->{class} && $_->{class} eq $to_class }
  52                           map { $from_class->relationship_info($_) }
  53                             $from_class->relationships;
  54         }
  55         $self->throw_exception( "No relationship to JOIN from ${from_class} to ${to_class}" )
  56           unless $rel_obj;
  57         my $join = $from_class->storage->sql_maker->_join_condition(
  58           $from_class->result_source_instance->resolve_condition(
  59             $rel_obj->{cond}, $to, $from) );
  60         return $join;
  61       }
  62
  63   } );
  64
  65 sub db_Main {
  66   return $_[0]->storage->dbh;
  67 }
  68
  69 sub connection {
  70   my ($class, @info) = @_;
  71   $info[3] = { %{ $info[3] || {}} };
  72   $info[3]->{RootClass} = 'DBIx::ContextualFetch';
  73   return $class->next::method(@info);
  74 }
  75
  76 sub __driver {
  77   return $_[0]->storage->dbh->{Driver}->{Name};
  78 }
  79
  80 sub set_sql {
  81   my ($class, $name, $sql) = @_;
  82   no strict 'refs';
  83   my $sql_name = "sql_${name}";
  84   my $full_sql_name = join '::', $class, $sql_name;
  85   *$full_sql_name = Sub::Name::subname $full_sql_name,
  86     sub {
  87       my $sql = $sql;
  88       my $class = shift;
  89       return $class->storage->sth($class->transform_sql($sql, @_));
  90     };
  91   if ($sql =~ /select/i) {
  92     my $search_name = "search_${name}";
  93     my $full_search_name = join '::', $class, $search_name;
  94     *$full_search_name = Sub::Name::subname $full_search_name,
  95       sub {
  96         my ($class, @args) = @_;
  97         my $sth = $class->$sql_name;
  98         return $class->sth_to_objects($sth, \@args);
  99       };
 100   }
 101 }
 102
 103 sub sth_to_objects {
 104   my ($class, $sth, $execute_args) = @_;
 105
 106   $sth->execute(@$execute_args);
 107
 108   my @ret;
 109   while (my $row = $sth->fetchrow_hashref) {
 110     push(@ret, $class->inflate_result($class->result_source_instance, $row));
 111   }
 112
 113   return @ret;
 114 }
 115
 116 sub transform_sql {
 117   my ($class, $sql, @args) = @_;
 118
 119   my $tclass = $class->sql_transformer_class;
 120   $class->ensure_class_loaded($tclass);
 121   my $t = $tclass->new($class, $sql, @args);
 122
 123   return sprintf($t->sql, $t->args);
 124 }
 125
 126 package
 127   DBIx::ContextualFetch::st; # HIDE FROM PAUSE THIS IS NOT OUR CLASS
 128
 129 no warnings 'redefine';
 130
 131 sub _untaint_execute {
 132   my $sth = shift;
 133   my $old_value = $sth->{Taint};
 134   $sth->{Taint} = 0;
 135   my $ret;
 136   {
 137     no warnings 'uninitialized';
 138     $ret = $sth->SUPER::execute(@_);
 139   }
 140   $sth->{Taint} = $old_value;
 141   return $ret;
 142 }
 143
 144 1;