lib/DBIx/Class/Admin.pm

   1 package DBIx::Class::Admin;
   2
   3 use warnings;
   4 use strict;
   5
   6 # check deps
   7 BEGIN {
   8   require DBIx::Class::Optional::Dependencies;
   9   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('admin') ) {
  10     die "The following extra modules are required for DBIx::Class::Admin: $missing\n";
  11   }
  12 }
  13
  14 use JSON::Any qw(DWIW PP JSON CPANEL XS);
  15 use Moose;
  16 use MooseX::Types::Moose qw/Int Str Any Bool/;
  17 use DBIx::Class::Admin::Types qw/DBICConnectInfo DBICHashRef/;
  18 use MooseX::Types::JSON qw(JSON);
  19 use MooseX::Types::Path::Class qw(Dir File);
  20 use MooseX::Types::LoadableClass qw(LoadableClass);
  21 use Try::Tiny;
  22 use namespace::clean;
  23
  24 =head1 NAME
  25
  26 DBIx::Class::Admin - Administration object for schemas
  27
  28 =head1 SYNOPSIS
  29
  30   $ dbicadmin --help
  31
  32   $ dbicadmin --schema=MyApp::Schema \
  33     --connect='["dbi:SQLite:my.db", "", ""]' \
  34     --deploy
  35
  36   $ dbicadmin --schema=MyApp::Schema --class=Employee \
  37     --connect='["dbi:SQLite:my.db", "", ""]' \
  38     --op=update --set='{ "name": "New_Employee" }'
  39
  40   use DBIx::Class::Admin;
  41
  42   # ddl manipulation
  43   my $admin = DBIx::Class::Admin->new(
  44     schema_class=> 'MY::Schema',
  45     sql_dir=> $sql_dir,
  46     connect_info => { dsn => $dsn, user => $user, password => $pass },
  47   );
  48
  49   # create SQLite sql
  50   $admin->create('SQLite');
  51
  52   # create SQL diff for an upgrade
  53   $admin->create('SQLite', {} , "1.0");
  54
  55   # upgrade a database
  56   $admin->upgrade();
  57
  58   # install a version for an unversioned schema
  59   $admin->install("3.0");
  60
  61 =head1 REQUIREMENTS
  62
  63 The Admin interface has additional requirements not currently part of
  64 L<DBIx::Class>. See L<DBIx::Class::Optional::Dependencies> for more details.
  65
  66 =head1 ATTRIBUTES
  67
  68 =head2 schema_class
  69
  70 the class of the schema to load
  71
  72 =cut
  73
  74 has 'schema_class' => (
  75   is  => 'ro',
  76   isa => LoadableClass,
  77 );
  78
  79
  80 =head2 schema
  81
  82 A pre-connected schema object can be provided for manipulation
  83
  84 =cut
  85
  86 has 'schema' => (
  87   is          => 'ro',
  88   isa         => 'DBIx::Class::Schema',
  89   lazy_build  => 1,
  90 );
  91
  92 sub _build_schema {
  93   my ($self)  = @_;
  94
  95   $self->connect_info->[3]{ignore_version} = 1;
  96   return $self->schema_class->connect(@{$self->connect_info});
  97 }
  98
  99 =head2 resultset
 100
 101 a resultset from the schema to operate on
 102
 103 =cut
 104
 105 has 'resultset' => (
 106   is  => 'rw',
 107   isa => Str,
 108 );
 109
 110
 111 =head2 where
 112
 113 a hash ref or json string to be used for identifying data to manipulate
 114
 115 =cut
 116
 117 has 'where' => (
 118   is      => 'rw',
 119   isa     => DBICHashRef,
 120   coerce  => 1,
 121 );
 122
 123
 124 =head2 set
 125
 126 a hash ref or json string to be used for inserting or updating data
 127
 128 =cut
 129
 130 has 'set' => (
 131   is      => 'rw',
 132   isa     => DBICHashRef,
 133   coerce  => 1,
 134 );
 135
 136
 137 =head2 attrs
 138
 139 a hash ref or json string to be used for passing additional info to the ->search call
 140
 141 =cut
 142
 143 has 'attrs' => (
 144   is      => 'rw',
 145   isa     => DBICHashRef,
 146   coerce  => 1,
 147 );
 148
 149
 150 =head2 connect_info
 151
 152 connect_info the arguments to provide to the connect call of the schema_class
 153
 154 =cut
 155
 156 has 'connect_info' => (
 157   is          => 'ro',
 158   isa         => DBICConnectInfo,
 159   lazy_build  => 1,
 160   coerce      => 1,
 161 );
 162
 163 sub _build_connect_info {
 164   my ($self) = @_;
 165   return $self->_find_stanza($self->config, $self->config_stanza);
 166 }
 167
 168
 169 =head2 config_file
 170
 171 config_file provide a config_file to read connect_info from, if this is provided
 172 config_stanze should also be provided to locate where the connect_info is in the config
 173 The config file should be in a format readable by Config::Any.
 174
 175 =cut
 176
 177 has config_file => (
 178   is      => 'ro',
 179   isa     => File,
 180   coerce  => 1,
 181 );
 182
 183
 184 =head2 config_stanza
 185
 186 config_stanza for use with config_file should be a '::' delimited 'path' to the connection information
 187 designed for use with catalyst config files
 188
 189 =cut
 190
 191 has 'config_stanza' => (
 192   is  => 'ro',
 193   isa => Str,
 194 );
 195
 196
 197 =head2 config
 198
 199 Instead of loading from a file the configuration can be provided directly as a hash ref.  Please note
 200 config_stanza will still be required.
 201
 202 =cut
 203
 204 has config => (
 205   is          => 'ro',
 206   isa         => DBICHashRef,
 207   lazy_build  => 1,
 208 );
 209
 210 sub _build_config {
 211   my ($self) = @_;
 212
 213   try { require Config::Any }
 214     catch { die ("Config::Any is required to parse the config file.\n") };
 215
 216   my $cfg = Config::Any->load_files ( {files => [$self->config_file], use_ext =>1, flatten_to_hash=>1});
 217
 218   # just grab the config from the config file
 219   $cfg = $cfg->{$self->config_file};
 220   return $cfg;
 221 }
 222
 223
 224 =head2 sql_dir
 225
 226 The location where sql ddl files should be created or found for an upgrade.
 227
 228 =cut
 229
 230 has 'sql_dir' => (
 231   is      => 'ro',
 232   isa     => Dir,
 233   coerce  => 1,
 234 );
 235
 236
 237 =head2 sql_type
 238
 239 The type of sql dialect to use for creating sql files from schema
 240
 241 =cut
 242
 243 has 'sql_type' => (
 244   is     => 'ro',
 245   isa    => Str,
 246 );
 247
 248 =head2 version
 249
 250 Used for install, the version which will be 'installed' in the schema
 251
 252 =cut
 253
 254 has version => (
 255   is  => 'rw',
 256   isa => Str,
 257 );
 258
 259
 260 =head2 preversion
 261
 262 Previous version of the schema to create an upgrade diff for, the full sql for that version of the sql must be in the sql_dir
 263
 264 =cut
 265
 266 has preversion => (
 267   is  => 'rw',
 268   isa => Str,
 269 );
 270
 271
 272 =head2 force
 273
 274 Try and force certain operations.
 275
 276 =cut
 277
 278 has force => (
 279   is  => 'rw',
 280   isa => Bool,
 281 );
 282
 283
 284 =head2 quiet
 285
 286 Be less verbose about actions
 287
 288 =cut
 289
 290 has quiet => (
 291   is  => 'rw',
 292   isa => Bool,
 293 );
 294
 295 has '_confirm' => (
 296   is  => 'bare',
 297   isa => Bool,
 298 );
 299
 300
 301 =head2 trace
 302
 303 Toggle DBIx::Class debug output
 304
 305 =cut
 306
 307 has trace => (
 308     is => 'rw',
 309     isa => Bool,
 310     trigger => \&_trigger_trace,
 311 );
 312
 313 sub _trigger_trace {
 314     my ($self, $new, $old) = @_;
 315     $self->schema->storage->debug($new);
 316 }
 317
 318
 319 =head1 METHODS
 320
 321 =head2 create
 322
 323 =over 4
 324
 325 =item Arguments: $sqlt_type, \%sqlt_args, $preversion
 326
 327 =back
 328
 329 C<create> will generate sql for the supplied schema_class in sql_dir. The
 330 flavour of sql to generate can be controlled by supplying a sqlt_type which
 331 should be a L<SQL::Translator> name.
 332
 333 Arguments for L<SQL::Translator> can be supplied in the sqlt_args hashref.
 334
 335 Optional preversion can be supplied to generate a diff to be used by upgrade.
 336
 337 =cut
 338
 339 sub create {
 340   my ($self, $sqlt_type, $sqlt_args, $preversion) = @_;
 341
 342   $preversion ||= $self->preversion();
 343   $sqlt_type ||= $self->sql_type();
 344
 345   my $schema = $self->schema();
 346   # create the dir if does not exist
 347   $self->sql_dir->mkpath() if ( ! -d $self->sql_dir);
 348
 349   $schema->create_ddl_dir( $sqlt_type, (defined $schema->schema_version ? $schema->schema_version : ""), $self->sql_dir->stringify, $preversion, $sqlt_args );
 350 }
 351
 352
 353 =head2 upgrade
 354
 355 =over 4
 356
 357 =item Arguments: <none>
 358
 359 =back
 360
 361 upgrade will attempt to upgrade the connected database to the same version as the schema_class.
 362 B<MAKE SURE YOU BACKUP YOUR DB FIRST>
 363
 364 =cut
 365
 366 sub upgrade {
 367   my ($self) = @_;
 368   my $schema = $self->schema();
 369
 370   if (!$schema->get_db_version()) {
 371     # schema is unversioned
 372     $schema->throw_exception ("Could not determin current schema version, please either install() or deploy().\n");
 373   } else {
 374     $schema->upgrade_directory ($self->sql_dir) if $self->sql_dir;  # this will override whatever default the schema has
 375     my $ret = $schema->upgrade();
 376     return $ret;
 377   }
 378 }
 379
 380
 381 =head2 install
 382
 383 =over 4
 384
 385 =item Arguments: $version
 386
 387 =back
 388
 389 install is here to help when you want to move to L<DBIx::Class::Schema::Versioned> and have an existing
 390 database.  install will take a version and add the version tracking tables and 'install' the version.  No
 391 further ddl modification takes place.  Setting the force attribute to a true value will allow overriding of
 392 already versioned databases.
 393
 394 =cut
 395
 396 sub install {
 397   my ($self, $version) = @_;
 398
 399   my $schema = $self->schema();
 400   $version ||= $self->version();
 401   if (!$schema->get_db_version() ) {
 402     # schema is unversioned
 403     print "Going to install schema version\n" if (!$self->quiet);
 404     my $ret = $schema->install($version);
 405     print "return is $ret\n" if (!$self->quiet);
 406   }
 407   elsif ($schema->get_db_version() and $self->force ) {
 408     warn "Forcing install may not be a good idea\n";
 409     if($self->_confirm() ) {
 410       $self->schema->_set_db_version({ version => $version});
 411     }
 412   }
 413   else {
 414     $schema->throw_exception ("Schema already has a version. Try upgrade instead.\n");
 415   }
 416
 417 }
 418
 419
 420 =head2 deploy
 421
 422 =over 4
 423
 424 =item Arguments: $args
 425
 426 =back
 427
 428 deploy will create the schema at the connected database.  C<$args> are passed straight to
 429 L<DBIx::Class::Schema/deploy>.
 430
 431 =cut
 432
 433 sub deploy {
 434   my ($self, $args) = @_;
 435   my $schema = $self->schema();
 436   $schema->deploy( $args, $self->sql_dir );
 437 }
 438
 439 =head2 insert
 440
 441 =over 4
 442
 443 =item Arguments: $rs, $set
 444
 445 =back
 446
 447 insert takes the name of a resultset from the schema_class and a hashref of data to insert
 448 into that resultset
 449
 450 =cut
 451
 452 sub insert {
 453   my ($self, $rs, $set) = @_;
 454
 455   $rs ||= $self->resultset();
 456   $set ||= $self->set();
 457   my $resultset = $self->schema->resultset($rs);
 458   my $obj = $resultset->new_result($set)->insert;
 459   print ''.ref($resultset).' ID: '.join(',',$obj->id())."\n" if (!$self->quiet);
 460 }
 461
 462
 463 =head2 update
 464
 465 =over 4
 466
 467 =item Arguments: $rs, $set, $where
 468
 469 =back
 470
 471 update takes the name of a resultset from the schema_class, a hashref of data to update and
 472 a where hash used to form the search for the rows to update.
 473
 474 =cut
 475
 476 sub update {
 477   my ($self, $rs, $set, $where) = @_;
 478
 479   $rs ||= $self->resultset();
 480   $where ||= $self->where();
 481   $set ||= $self->set();
 482   my $resultset = $self->schema->resultset($rs);
 483   $resultset = $resultset->search( ($where||{}) );
 484
 485   my $count = $resultset->count();
 486   print "This action will modify $count ".ref($resultset)." records.\n" if (!$self->quiet);
 487
 488   if ( $self->force || $self->_confirm() ) {
 489     $resultset->update_all( $set );
 490   }
 491 }
 492
 493
 494 =head2 delete
 495
 496 =over 4
 497
 498 =item Arguments: $rs, $where, $attrs
 499
 500 =back
 501
 502 delete takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 503 The found data is deleted and cannot be recovered.
 504
 505 =cut
 506
 507 sub delete {
 508   my ($self, $rs, $where, $attrs) = @_;
 509
 510   $rs ||= $self->resultset();
 511   $where ||= $self->where();
 512   $attrs ||= $self->attrs();
 513   my $resultset = $self->schema->resultset($rs);
 514   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 515
 516   my $count = $resultset->count();
 517   print "This action will delete $count ".ref($resultset)." records.\n" if (!$self->quiet);
 518
 519   if ( $self->force || $self->_confirm() ) {
 520     $resultset->delete_all();
 521   }
 522 }
 523
 524
 525 =head2 select
 526
 527 =over 4
 528
 529 =item Arguments: $rs, $where, $attrs
 530
 531 =back
 532
 533 select takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 534 The found data is returned in a array ref where the first row will be the columns list.
 535
 536 =cut
 537
 538 sub select {
 539   my ($self, $rs, $where, $attrs) = @_;
 540
 541   $rs ||= $self->resultset();
 542   $where ||= $self->where();
 543   $attrs ||= $self->attrs();
 544   my $resultset = $self->schema->resultset($rs);
 545   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 546
 547   my @data;
 548   my @columns = $resultset->result_source->columns();
 549   push @data, [@columns];#
 550
 551   while (my $row = $resultset->next()) {
 552     my @fields;
 553     foreach my $column (@columns) {
 554       push( @fields, $row->get_column($column) );
 555     }
 556     push @data, [@fields];
 557   }
 558
 559   return \@data;
 560 }
 561
 562 sub _confirm {
 563   my ($self) = @_;
 564
 565   # mainly here for testing
 566   return 1 if ($self->meta->get_attribute('_confirm')->get_value($self));
 567
 568   print "Are you sure you want to do this? (type YES to confirm) \n";
 569   my $response = <STDIN>;
 570
 571   return ($response=~/^YES/);
 572 }
 573
 574 sub _find_stanza {
 575   my ($self, $cfg, $stanza) = @_;
 576   my @path = split /::/, $stanza;
 577   while (my $path = shift @path) {
 578     if (exists $cfg->{$path}) {
 579       $cfg = $cfg->{$path};
 580     }
 581     else {
 582       die ("Could not find $stanza in config, $path does not seem to exist.\n");
 583     }
 584   }
 585   $cfg = $cfg->{connect_info} if exists $cfg->{connect_info};
 586   return $cfg;
 587 }
 588
 589 =head1 FURTHER QUESTIONS?
 590
 591 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
 592
 593 =head1 COPYRIGHT AND LICENSE
 594
 595 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
 596 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
 597 redistribute it and/or modify it under the same terms as the
 598 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
 599
 600 =cut
 601
 602 1;