lib/DBIx/Class/Admin.pm

   1 package DBIx::Class::Admin;
   2
   3 use warnings;
   4 use strict;
   5
   6 # check deps
   7 BEGIN {
   8   require DBIx::Class::Optional::Dependencies;
   9   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('admin') ) {
  10     die "The following extra modules are required for DBIx::Class::Admin: $missing\n";
  11   }
  12 }
  13
  14 use JSON::Any qw(DWIW PP JSON CPANEL XS);
  15 use Moose;
  16 use MooseX::Types::Moose qw/Int Str Any Bool/;
  17 use DBIx::Class::Admin::Types qw/DBICConnectInfo DBICHashRef/;
  18 use MooseX::Types::JSON qw(JSON);
  19 use MooseX::Types::Path::Class qw(Dir File);
  20 use MooseX::Types::LoadableClass qw(LoadableClass);
  21 use namespace::clean;
  22
  23 =head1 NAME
  24
  25 DBIx::Class::Admin - Administration object for schemas
  26
  27 =head1 SYNOPSIS
  28
  29   $ dbicadmin --help
  30
  31   $ dbicadmin --schema=MyApp::Schema \
  32     --connect='["dbi:SQLite:my.db", "", ""]' \
  33     --deploy
  34
  35   $ dbicadmin --schema=MyApp::Schema --class=Employee \
  36     --connect='["dbi:SQLite:my.db", "", ""]' \
  37     --op=update --set='{ "name": "New_Employee" }'
  38
  39   use DBIx::Class::Admin;
  40
  41   # ddl manipulation
  42   my $admin = DBIx::Class::Admin->new(
  43     schema_class=> 'MY::Schema',
  44     sql_dir=> $sql_dir,
  45     connect_info => { dsn => $dsn, user => $user, password => $pass },
  46   );
  47
  48   # create SQLite sql
  49   $admin->create('SQLite');
  50
  51   # create SQL diff for an upgrade
  52   $admin->create('SQLite', {} , "1.0");
  53
  54   # upgrade a database
  55   $admin->upgrade();
  56
  57   # install a version for an unversioned schema
  58   $admin->install("3.0");
  59
  60 =head1 REQUIREMENTS
  61
  62 The Admin interface has additional requirements not currently part of
  63 L<DBIx::Class>. See L<DBIx::Class::Optional::Dependencies> for more details.
  64
  65 =head1 ATTRIBUTES
  66
  67 =head2 schema_class
  68
  69 the class of the schema to load
  70
  71 =cut
  72
  73 has 'schema_class' => (
  74   is  => 'ro',
  75   isa => LoadableClass,
  76 );
  77
  78
  79 =head2 schema
  80
  81 A pre-connected schema object can be provided for manipulation
  82
  83 =cut
  84
  85 has 'schema' => (
  86   is          => 'ro',
  87   isa         => 'DBIx::Class::Schema',
  88   lazy_build  => 1,
  89 );
  90
  91 sub _build_schema {
  92   my ($self)  = @_;
  93
  94   $self->connect_info->[3]{ignore_version} = 1;
  95   return $self->schema_class->clone->connection(@{$self->connect_info});
  96 }
  97
  98 =head2 resultset
  99
 100 a resultset from the schema to operate on
 101
 102 =cut
 103
 104 has 'resultset' => (
 105   is  => 'rw',
 106   isa => Str,
 107 );
 108
 109
 110 =head2 where
 111
 112 a hash ref or json string to be used for identifying data to manipulate
 113
 114 =cut
 115
 116 has 'where' => (
 117   is      => 'rw',
 118   isa     => DBICHashRef,
 119   coerce  => 1,
 120 );
 121
 122
 123 =head2 set
 124
 125 a hash ref or json string to be used for inserting or updating data
 126
 127 =cut
 128
 129 has 'set' => (
 130   is      => 'rw',
 131   isa     => DBICHashRef,
 132   coerce  => 1,
 133 );
 134
 135
 136 =head2 attrs
 137
 138 a hash ref or json string to be used for passing additional info to the ->search call
 139
 140 =cut
 141
 142 has 'attrs' => (
 143   is      => 'rw',
 144   isa     => DBICHashRef,
 145   coerce  => 1,
 146 );
 147
 148
 149 =head2 connect_info
 150
 151 connect_info the arguments to provide to the connect call of the schema_class
 152
 153 =cut
 154
 155 has 'connect_info' => (
 156   is          => 'ro',
 157   isa         => DBICConnectInfo,
 158   lazy_build  => 1,
 159   coerce      => 1,
 160 );
 161
 162 sub _build_connect_info {
 163   my ($self) = @_;
 164   return $self->_find_stanza($self->config, $self->config_stanza);
 165 }
 166
 167
 168 =head2 config_file
 169
 170 config_file provide a config_file to read connect_info from, if this is provided
 171 config_stanze should also be provided to locate where the connect_info is in the config
 172 The config file should be in a format readable by Config::Any.
 173
 174 =cut
 175
 176 has config_file => (
 177   is      => 'ro',
 178   isa     => File,
 179   coerce  => 1,
 180 );
 181
 182
 183 =head2 config_stanza
 184
 185 config_stanza for use with config_file should be a '::' delimited 'path' to the connection information
 186 designed for use with catalyst config files
 187
 188 =cut
 189
 190 has 'config_stanza' => (
 191   is  => 'ro',
 192   isa => Str,
 193 );
 194
 195
 196 =head2 config
 197
 198 Instead of loading from a file the configuration can be provided directly as a hash ref.  Please note
 199 config_stanza will still be required.
 200
 201 =cut
 202
 203 has config => (
 204   is          => 'ro',
 205   isa         => DBICHashRef,
 206   lazy_build  => 1,
 207 );
 208
 209 sub _build_config {
 210   my ($self) = @_;
 211
 212   my $cfg = Config::Any->load_files ( {files => [$self->config_file], use_ext =>1, flatten_to_hash=>1});
 213
 214   # just grab the config from the config file
 215   $cfg = $cfg->{$self->config_file};
 216   return $cfg;
 217 }
 218
 219
 220 =head2 sql_dir
 221
 222 The location where sql ddl files should be created or found for an upgrade.
 223
 224 =cut
 225
 226 has 'sql_dir' => (
 227   is      => 'ro',
 228   isa     => Dir,
 229   coerce  => 1,
 230 );
 231
 232
 233 =head2 sql_type
 234
 235 The type of sql dialect to use for creating sql files from schema
 236
 237 =cut
 238
 239 has 'sql_type' => (
 240   is     => 'ro',
 241   isa    => Str,
 242 );
 243
 244 =head2 version
 245
 246 Used for install, the version which will be 'installed' in the schema
 247
 248 =cut
 249
 250 has version => (
 251   is  => 'rw',
 252   isa => Str,
 253 );
 254
 255
 256 =head2 preversion
 257
 258 Previous version of the schema to create an upgrade diff for, the full sql for that version of the sql must be in the sql_dir
 259
 260 =cut
 261
 262 has preversion => (
 263   is  => 'rw',
 264   isa => Str,
 265 );
 266
 267
 268 =head2 force
 269
 270 Try and force certain operations.
 271
 272 =cut
 273
 274 has force => (
 275   is  => 'rw',
 276   isa => Bool,
 277 );
 278
 279
 280 =head2 quiet
 281
 282 Be less verbose about actions
 283
 284 =cut
 285
 286 has quiet => (
 287   is  => 'rw',
 288   isa => Bool,
 289 );
 290
 291 has '_confirm' => (
 292   is  => 'bare',
 293   isa => Bool,
 294 );
 295
 296
 297 =head2 trace
 298
 299 Toggle DBIx::Class debug output
 300
 301 =cut
 302
 303 has trace => (
 304     is => 'rw',
 305     isa => Bool,
 306     trigger => \&_trigger_trace,
 307 );
 308
 309 sub _trigger_trace {
 310     my ($self, $new, $old) = @_;
 311     $self->schema->storage->debug($new);
 312 }
 313
 314
 315 =head1 METHODS
 316
 317 =head2 create
 318
 319 =over 4
 320
 321 =item Arguments: $sqlt_type, \%sqlt_args, $preversion
 322
 323 =back
 324
 325 C<create> will generate sql for the supplied schema_class in sql_dir. The
 326 flavour of sql to generate can be controlled by supplying a sqlt_type which
 327 should be a L<SQL::Translator> name.
 328
 329 Arguments for L<SQL::Translator> can be supplied in the sqlt_args hashref.
 330
 331 Optional preversion can be supplied to generate a diff to be used by upgrade.
 332
 333 =cut
 334
 335 sub create {
 336   my ($self, $sqlt_type, $sqlt_args, $preversion) = @_;
 337
 338   $preversion ||= $self->preversion();
 339   $sqlt_type ||= $self->sql_type();
 340
 341   my $schema = $self->schema();
 342
 343   $schema->create_ddl_dir(
 344     $sqlt_type,
 345     (defined $schema->schema_version ? $schema->schema_version : ""),
 346     $self->sql_dir,
 347     $preversion,
 348     $sqlt_args,
 349   );
 350 }
 351
 352
 353 =head2 upgrade
 354
 355 =over 4
 356
 357 =item Arguments: <none>
 358
 359 =back
 360
 361 upgrade will attempt to upgrade the connected database to the same version as the schema_class.
 362 B<MAKE SURE YOU BACKUP YOUR DB FIRST>
 363
 364 =cut
 365
 366 sub upgrade {
 367   my ($self) = @_;
 368   my $schema = $self->schema();
 369
 370   if (!$schema->get_db_version()) {
 371     # schema is unversioned
 372     $schema->throw_exception ("Could not determin current schema version, please either install() or deploy().\n");
 373   } else {
 374     $schema->upgrade_directory ($self->sql_dir) if $self->sql_dir;  # this will override whatever default the schema has
 375     my $ret = $schema->upgrade();
 376     return $ret;
 377   }
 378 }
 379
 380
 381 =head2 install
 382
 383 =over 4
 384
 385 =item Arguments: $version
 386
 387 =back
 388
 389 install is here to help when you want to move to L<DBIx::Class::Schema::Versioned> and have an existing
 390 database.  install will take a version and add the version tracking tables and 'install' the version.  No
 391 further ddl modification takes place.  Setting the force attribute to a true value will allow overriding of
 392 already versioned databases.
 393
 394 =cut
 395
 396 sub install {
 397   my ($self, $version) = @_;
 398
 399   my $schema = $self->schema();
 400   $version ||= $self->version();
 401   if (!$schema->get_db_version() ) {
 402     # schema is unversioned
 403     print "Going to install schema version\n" if (!$self->quiet);
 404     my $ret = $schema->install($version);
 405     print "return is $ret\n" if (!$self->quiet);
 406   }
 407   elsif ($schema->get_db_version() and $self->force ) {
 408     warn "Forcing install may not be a good idea\n";
 409     if($self->_confirm() ) {
 410       $self->schema->_set_db_version({ version => $version});
 411     }
 412   }
 413   else {
 414     $schema->throw_exception ("Schema already has a version. Try upgrade instead.\n");
 415   }
 416
 417 }
 418
 419
 420 =head2 deploy
 421
 422 =over 4
 423
 424 =item Arguments: $args
 425
 426 =back
 427
 428 deploy will create the schema at the connected database.  C<$args> are passed straight to
 429 L<DBIx::Class::Schema/deploy>.
 430
 431 =cut
 432
 433 sub deploy {
 434   my ($self, $args) = @_;
 435   my $schema = $self->schema();
 436   $schema->deploy( $args, $self->sql_dir );
 437 }
 438
 439 =head2 insert
 440
 441 =over 4
 442
 443 =item Arguments: $rs, $set
 444
 445 =back
 446
 447 insert takes the name of a resultset from the schema_class and a hashref of data to insert
 448 into that resultset
 449
 450 =cut
 451
 452 sub insert {
 453   my ($self, $rs, $set) = @_;
 454
 455   $rs ||= $self->resultset();
 456   $set ||= $self->set();
 457   my $resultset = $self->schema->resultset($rs);
 458   my $obj = $resultset->new_result($set)->insert;
 459   print ''.ref($resultset).' ID: '.join(',',$obj->id())."\n" if (!$self->quiet);
 460 }
 461
 462
 463 =head2 update
 464
 465 =over 4
 466
 467 =item Arguments: $rs, $set, $where
 468
 469 =back
 470
 471 update takes the name of a resultset from the schema_class, a hashref of data to update and
 472 a where hash used to form the search for the rows to update.
 473
 474 =cut
 475
 476 sub update {
 477   my ($self, $rs, $set, $where) = @_;
 478
 479   $rs ||= $self->resultset();
 480   $where ||= $self->where();
 481   $set ||= $self->set();
 482   my $resultset = $self->schema->resultset($rs);
 483   $resultset = $resultset->search( ($where||{}) );
 484
 485   my $count = $resultset->count();
 486   print "This action will modify $count ".ref($resultset)." records.\n" if (!$self->quiet);
 487
 488   if ( $self->force || $self->_confirm() ) {
 489     $resultset->update_all( $set );
 490   }
 491 }
 492
 493
 494 =head2 delete
 495
 496 =over 4
 497
 498 =item Arguments: $rs, $where, $attrs
 499
 500 =back
 501
 502 delete takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 503 The found data is deleted and cannot be recovered.
 504
 505 =cut
 506
 507 sub delete {
 508   my ($self, $rs, $where, $attrs) = @_;
 509
 510   $rs ||= $self->resultset();
 511   $where ||= $self->where();
 512   $attrs ||= $self->attrs();
 513   my $resultset = $self->schema->resultset($rs);
 514   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 515
 516   my $count = $resultset->count();
 517   print "This action will delete $count ".ref($resultset)." records.\n" if (!$self->quiet);
 518
 519   if ( $self->force || $self->_confirm() ) {
 520     $resultset->delete_all();
 521   }
 522 }
 523
 524
 525 =head2 select
 526
 527 =over 4
 528
 529 =item Arguments: $rs, $where, $attrs
 530
 531 =back
 532
 533 select takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 534 The found data is returned in a array ref where the first row will be the columns list.
 535
 536 =cut
 537
 538 sub select {
 539   my ($self, $rs, $where, $attrs) = @_;
 540
 541   $rs ||= $self->resultset();
 542   $where ||= $self->where();
 543   $attrs ||= $self->attrs();
 544   my $resultset = $self->schema->resultset($rs);
 545   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 546
 547   my @data;
 548   my @columns = $resultset->result_source->columns();
 549   push @data, [@columns];#
 550
 551   while (my $row = $resultset->next()) {
 552     my @fields;
 553     foreach my $column (@columns) {
 554       push( @fields, $row->get_column($column) );
 555     }
 556     push @data, [@fields];
 557   }
 558
 559   return \@data;
 560 }
 561
 562 sub _confirm {
 563   my ($self) = @_;
 564
 565   # mainly here for testing
 566   return 1 if ($self->meta->get_attribute('_confirm')->get_value($self));
 567
 568   print "Are you sure you want to do this? (type YES to confirm) \n";
 569   my $response = <STDIN>;
 570
 571   return ($response=~/^YES/);
 572 }
 573
 574 sub _find_stanza {
 575   my ($self, $cfg, $stanza) = @_;
 576   my @path = split /::/, $stanza;
 577   while (my $path = shift @path) {
 578     if (exists $cfg->{$path}) {
 579       $cfg = $cfg->{$path};
 580     }
 581     else {
 582       die ("Could not find $stanza in config, $path does not seem to exist.\n");
 583     }
 584   }
 585   $cfg = $cfg->{connect_info} if exists $cfg->{connect_info};
 586   return $cfg;
 587 }
 588
 589 =head1 FURTHER QUESTIONS?
 590
 591 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
 592
 593 =head1 COPYRIGHT AND LICENSE
 594
 595 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
 596 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
 597 redistribute it and/or modify it under the same terms as the
 598 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
 599
 600 =cut
 601
 602 1;