lib/Cwd.pm

   1 package Cwd;
   2 require 5.000;
   3
   4 =head1 NAME
   5
   6 getcwd - get pathname of current working directory
   7
   8 =head1 SYNOPSIS
   9
  10     use Cwd;
  11     $dir = cwd;
  12
  13     use Cwd;
  14     $dir = getcwd;
  15
  16     use Cwd;
  17     $dir = fastgetcwd;
  18
  19     use Cwd 'chdir';
  20     chdir "/tmp";
  21     print $ENV{'PWD'};
  22
  23     use Cwd 'abs_path';     # aka realpath()
  24     print abs_path($ENV{'PWD'});
  25
  26     use Cwd 'fast_abs_path';
  27     print fast_abs_path($ENV{'PWD'});
  28
  29 =head1 DESCRIPTION
  30
  31 The getcwd() function re-implements the getcwd(3) (or getwd(3)) functions
  32 in Perl.
  33
  34 The abs_path() function takes a single argument and returns the
  35 absolute pathname for that argument.  It uses the same algorithm
  36 as getcwd().  (Actually, getcwd() is abs_path("."))  Symbolic links
  37 and relative-path components ("." and "..") are resolved to return
  38 the canonical pathname, just like realpath(3).  Also callable as
  39 realpath().
  40
  41 The fastcwd() function looks the same as getcwd(), but runs faster.
  42 It's also more dangerous because it might conceivably chdir() you out
  43 of a directory that it can't chdir() you back into.  If fastcwd
  44 encounters a problem it will return undef but will probably leave you
  45 in a different directory.  For a measure of extra security, if
  46 everything appears to have worked, the fastcwd() function will check
  47 that it leaves you in the same directory that it started in. If it has
  48 changed it will C<die> with the message "Unstable directory path,
  49 current directory changed unexpectedly". That should never happen.
  50
  51 The fast_abs_path() function looks the same as abs_path(), but runs faster.
  52 And like fastcwd() is more dangerous.
  53
  54 The cwd() function looks the same as getcwd and fastgetcwd but is
  55 implemented using the most natural and safe form for the current
  56 architecture. For most systems it is identical to `pwd` (but without
  57 the trailing line terminator).
  58
  59 It is recommended that cwd (or another *cwd() function) is used in
  60 I<all> code to ensure portability.
  61
  62 If you ask to override your chdir() built-in function, then your PWD
  63 environment variable will be kept up to date.  (See
  64 L<perlsub/Overriding Builtin Functions>.) Note that it will only be
  65 kept up to date if all packages which use chdir import it from Cwd.
  66
  67 =cut
  68
  69 use strict;
  70
  71 use Carp;
  72
  73 our $VERSION = '2.03';
  74
  75 use base qw/ Exporter /;
  76 our @EXPORT = qw(cwd getcwd fastcwd fastgetcwd);
  77 our @EXPORT_OK = qw(chdir abs_path fast_abs_path realpath fast_realpath);
  78
  79
  80 # The 'natural and safe form' for UNIX (pwd may be setuid root)
  81
  82 sub _backtick_pwd {
  83     my $cwd = `pwd`;
  84     # `pwd` may fail e.g. if the disk is full
  85     chomp($cwd) if defined $cwd;
  86     $cwd;
  87 }
  88
  89 # Since some ports may predefine cwd internally (e.g., NT)
  90 # we take care not to override an existing definition for cwd().
  91
  92 *cwd = \&_backtick_pwd unless defined &cwd;
  93
  94
  95 # By Brandon S. Allbery
  96 #
  97 # Usage: $cwd = getcwd();
  98
  99 sub getcwd
 100 {
 101     abs_path('.');
 102 }
 103
 104 # By John Bazik
 105 #
 106 # Usage: $cwd = &fastcwd;
 107 #
 108 # This is a faster version of getcwd.  It's also more dangerous because
 109 # you might chdir out of a directory that you can't chdir back into.
 110
 111 sub fastcwd {
 112     my($odev, $oino, $cdev, $cino, $tdev, $tino);
 113     my(@path, $path);
 114     local(*DIR);
 115
 116     my($orig_cdev, $orig_cino) = stat('.');
 117     ($cdev, $cino) = ($orig_cdev, $orig_cino);
 118     for (;;) {
 119         my $direntry;
 120         ($odev, $oino) = ($cdev, $cino);
 121         CORE::chdir('..') || return undef;
 122         ($cdev, $cino) = stat('.');
 123         last if $odev == $cdev && $oino == $cino;
 124         opendir(DIR, '.') || return undef;
 125         for (;;) {
 126             $direntry = readdir(DIR);
 127             last unless defined $direntry;
 128             next if $direntry eq '.';
 129             next if $direntry eq '..';
 130
 131             ($tdev, $tino) = lstat($direntry);
 132             last unless $tdev != $odev || $tino != $oino;
 133         }
 134         closedir(DIR);
 135         return undef unless defined $direntry; # should never happen
 136         unshift(@path, $direntry);
 137     }
 138     $path = '/' . join('/', @path);
 139     if ($^O eq 'apollo') { $path = "/".$path; }
 140     # At this point $path may be tainted (if tainting) and chdir would fail.
 141     # To be more useful we untaint it then check that we landed where we started.
 142     $path = $1 if $path =~ /^(.*)\z/s;  # untaint
 143     CORE::chdir($path) || return undef;
 144     ($cdev, $cino) = stat('.');
 145     die "Unstable directory path, current directory changed unexpectedly"
 146         if $cdev != $orig_cdev || $cino != $orig_cino;
 147     $path;
 148 }
 149
 150
 151 # Keeps track of current working directory in PWD environment var
 152 # Usage:
 153 #       use Cwd 'chdir';
 154 #       chdir $newdir;
 155
 156 my $chdir_init = 0;
 157
 158 sub chdir_init {
 159     if ($ENV{'PWD'} and $^O ne 'os2' and $^O ne 'dos') {
 160         my($dd,$di) = stat('.');
 161         my($pd,$pi) = stat($ENV{'PWD'});
 162         if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
 163             $ENV{'PWD'} = cwd();
 164         }
 165     }
 166     else {
 167         $ENV{'PWD'} = cwd();
 168     }
 169     # Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
 170     if ($ENV{'PWD'} =~ m|(/[^/]+(/[^/]+/[^/]+))(.*)|s) {
 171         my($pd,$pi) = stat($2);
 172         my($dd,$di) = stat($1);
 173         if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
 174             $ENV{'PWD'}="$2$3";
 175         }
 176     }
 177     $chdir_init = 1;
 178 }
 179
 180 sub chdir {
 181     my $newdir = shift || '';   # allow for no arg (chdir to HOME dir)
 182     $newdir =~ s|///*|/|g;
 183     chdir_init() unless $chdir_init;
 184     return 0 unless CORE::chdir $newdir;
 185     if ($^O eq 'VMS') { return $ENV{'PWD'} = $ENV{'DEFAULT'} }
 186
 187     if ($newdir =~ m#^/#s) {
 188         $ENV{'PWD'} = $newdir;
 189     } else {
 190         my @curdir = split(m#/#,$ENV{'PWD'});
 191         @curdir = ('') unless @curdir;
 192         my $component;
 193         foreach $component (split(m#/#, $newdir)) {
 194             next if $component eq '.';
 195             pop(@curdir),next if $component eq '..';
 196             push(@curdir,$component);
 197         }
 198         $ENV{'PWD'} = join('/',@curdir) || '/';
 199     }
 200     1;
 201 }
 202
 203 # Taken from Cwd.pm It is really getcwd with an optional
 204 # parameter instead of '.'
 205 #
 206
 207 sub abs_path
 208 {
 209     my $start = @_ ? shift : '.';
 210     my($dotdots, $cwd, @pst, @cst, $dir, @tst);
 211
 212     unless (@cst = stat( $start ))
 213     {
 214         carp "stat($start): $!";
 215         return '';
 216     }
 217     $cwd = '';
 218     $dotdots = $start;
 219     do
 220     {
 221         $dotdots .= '/..';
 222         @pst = @cst;
 223         unless (opendir(PARENT, $dotdots))
 224         {
 225             carp "opendir($dotdots): $!";
 226             return '';
 227         }
 228         unless (@cst = stat($dotdots))
 229         {
 230             carp "stat($dotdots): $!";
 231             closedir(PARENT);
 232             return '';
 233         }
 234         if ($pst[0] == $cst[0] && $pst[1] == $cst[1])
 235         {
 236             $dir = undef;
 237         }
 238         else
 239         {
 240             do
 241             {
 242                 unless (defined ($dir = readdir(PARENT)))
 243                 {
 244                     carp "readdir($dotdots): $!";
 245                     closedir(PARENT);
 246                     return '';
 247                 }
 248                 $tst[0] = $pst[0]+1 unless (@tst = lstat("$dotdots/$dir"))
 249             }
 250             while ($dir eq '.' || $dir eq '..' || $tst[0] != $pst[0] ||
 251                    $tst[1] != $pst[1]);
 252         }
 253         $cwd = (defined $dir ? "$dir" : "" ) . "/$cwd" ;
 254         closedir(PARENT);
 255     } while (defined $dir);
 256     chop($cwd) unless $cwd eq '/'; # drop the trailing /
 257     $cwd;
 258 }
 259
 260 # added function alias for those of us more
 261 # used to the libc function.  --tchrist 27-Jan-00
 262 *realpath = \&abs_path;
 263
 264 sub fast_abs_path {
 265     my $cwd = getcwd();
 266     my $path = shift || '.';
 267     CORE::chdir($path) || croak "Cannot chdir to $path:$!";
 268     my $realpath = getcwd();
 269     CORE::chdir($cwd)  || croak "Cannot chdir back to $cwd:$!";
 270     $realpath;
 271 }
 272
 273 # added function alias to follow principle of least surprise
 274 # based on previous aliasing.  --tchrist 27-Jan-00
 275 *fast_realpath = \&fast_abs_path;
 276
 277
 278 # --- PORTING SECTION ---
 279
 280 # VMS: $ENV{'DEFAULT'} points to default directory at all times
 281 # 06-Mar-1996  Charles Bailey  bailey@newman.upenn.edu
 282 # Note: Use of Cwd::chdir() causes the logical name PWD to be defined
 283 #   in the process logical name table as the default device and directory
 284 #   seen by Perl. This may not be the same as the default device
 285 #   and directory seen by DCL after Perl exits, since the effects
 286 #   the CRTL chdir() function persist only until Perl exits.
 287
 288 sub _vms_cwd {
 289     return $ENV{'DEFAULT'};
 290 }
 291
 292 sub _vms_abs_path {
 293     return $ENV{'DEFAULT'} unless @_;
 294     my $path = VMS::Filespec::pathify($_[0]);
 295     croak("Invalid path name $_[0]") unless defined $path;
 296     return VMS::Filespec::rmsexpand($path);
 297 }
 298
 299 sub _os2_cwd {
 300     $ENV{'PWD'} = `cmd /c cd`;
 301     chop $ENV{'PWD'};
 302     $ENV{'PWD'} =~ s:\\:/:g ;
 303     return $ENV{'PWD'};
 304 }
 305
 306 sub _win32_cwd {
 307     $ENV{'PWD'} = Win32::GetCwd();
 308     $ENV{'PWD'} =~ s:\\:/:g ;
 309     return $ENV{'PWD'};
 310 }
 311
 312 *_NT_cwd = \&_win32_cwd if (!defined &_NT_cwd &&
 313                             defined &Win32::GetCwd);
 314
 315 *_NT_cwd = \&_os2_cwd unless defined &_NT_cwd;
 316
 317 sub _dos_cwd {
 318     if (!defined &Dos::GetCwd) {
 319         $ENV{'PWD'} = `command /c cd`;
 320         chop $ENV{'PWD'};
 321         $ENV{'PWD'} =~ s:\\:/:g ;
 322     } else {
 323         $ENV{'PWD'} = Dos::GetCwd();
 324     }
 325     return $ENV{'PWD'};
 326 }
 327
 328 sub _qnx_cwd {
 329     $ENV{'PWD'} = `/usr/bin/fullpath -t`;
 330     chop $ENV{'PWD'};
 331     return $ENV{'PWD'};
 332 }
 333
 334 sub _qnx_abs_path {
 335     my $path = shift || '.';
 336     my $realpath=`/usr/bin/fullpath -t $path`;
 337     chop $realpath;
 338     return $realpath;
 339 }
 340
 341 {
 342     no warnings;        # assignments trigger 'subroutine redefined' warning
 343
 344     if ($^O eq 'VMS') {
 345         *cwd            = \&_vms_cwd;
 346         *getcwd         = \&_vms_cwd;
 347         *fastcwd        = \&_vms_cwd;
 348         *fastgetcwd     = \&_vms_cwd;
 349         *abs_path       = \&_vms_abs_path;
 350         *fast_abs_path  = \&_vms_abs_path;
 351     }
 352     elsif ($^O eq 'NT' or $^O eq 'MSWin32') {
 353         # We assume that &_NT_cwd is defined as an XSUB or in the core.
 354         *cwd            = \&_NT_cwd;
 355         *getcwd         = \&_NT_cwd;
 356         *fastcwd        = \&_NT_cwd;
 357         *fastgetcwd     = \&_NT_cwd;
 358         *abs_path       = \&fast_abs_path;
 359     }
 360     elsif ($^O eq 'os2') {
 361         # sys_cwd may keep the builtin command
 362         *cwd            = defined &sys_cwd ? \&sys_cwd : \&_os2_cwd;
 363         *getcwd         = \&cwd;
 364         *fastgetcwd     = \&cwd;
 365         *fastcwd        = \&cwd;
 366         *abs_path       = \&fast_abs_path;
 367     }
 368     elsif ($^O eq 'dos') {
 369         *cwd            = \&_dos_cwd;
 370         *getcwd         = \&_dos_cwd;
 371         *fastgetcwd     = \&_dos_cwd;
 372         *fastcwd        = \&_dos_cwd;
 373         *abs_path       = \&fast_abs_path;
 374     }
 375     elsif ($^O eq 'qnx') {
 376         *cwd            = \&_qnx_cwd;
 377         *getcwd         = \&_qnx_cwd;
 378         *fastgetcwd     = \&_qnx_cwd;
 379         *fastcwd        = \&_qnx_cwd;
 380         *abs_path       = \&_qnx_abs_path;
 381         *fast_abs_path  = \&_qnx_abs_path;
 382     }
 383     elsif ($^O eq 'cygwin') {
 384         *getcwd = \&cwd;
 385         *fastgetcwd     = \&cwd;
 386         *fastcwd        = \&cwd;
 387         *abs_path       = \&fast_abs_path;
 388     }
 389 }
 390
 391 # package main; eval join('',<DATA>) || die $@; # quick test
 392
 393 1;
 394
 395 __END__
 396 BEGIN { import Cwd qw(:DEFAULT chdir); }
 397 print join("\n", cwd, getcwd, fastcwd, "");
 398 chdir('..');
 399 print join("\n", cwd, getcwd, fastcwd, "");
 400 print "$ENV{PWD}\n";