lib/Cwd.pm

   1 package Cwd;
   2 require 5.000;
   3
   4 =head1 NAME
   5
   6 getcwd - get pathname of current working directory
   7
   8 =head1 SYNOPSIS
   9
  10     use Cwd;
  11     $dir = cwd;
  12
  13     use Cwd;
  14     $dir = getcwd;
  15
  16     use Cwd;
  17     $dir = fastgetcwd;
  18
  19     use Cwd 'chdir';
  20     chdir "/tmp";
  21     print $ENV{'PWD'};
  22
  23     use Cwd 'abs_path';     # aka realpath()
  24     print abs_path($ENV{'PWD'});
  25
  26     use Cwd 'fast_abs_path';
  27     print fast_abs_path($ENV{'PWD'});
  28
  29 =head1 DESCRIPTION
  30
  31 The getcwd() function re-implements the getcwd(3) (or getwd(3)) functions
  32 in Perl.
  33
  34 The abs_path() function takes a single argument and returns the
  35 absolute pathname for that argument.  It uses the same algorithm
  36 as getcwd().  (Actually, getcwd() is abs_path("."))  Symbolic links
  37 and relative-path components ("." and "..") are resolved to return
  38 the canonical pathname, just like realpath(3).  Also callable as
  39 realpath().
  40
  41 The fastcwd() function looks the same as getcwd(), but runs faster.
  42 It's also more dangerous because it might conceivably chdir() you out
  43 of a directory that it can't chdir() you back into.  If fastcwd
  44 encounters a problem it will return undef but will probably leave you
  45 in a different directory.  For a measure of extra security, if
  46 everything appears to have worked, the fastcwd() function will check
  47 that it leaves you in the same directory that it started in. If it has
  48 changed it will C<die> with the message "Unstable directory path,
  49 current directory changed unexpectedly". That should never happen.
  50
  51 The fast_abs_path() function looks the same as abs_path(), but runs faster.
  52 And like fastcwd() is more dangerous.
  53
  54 The cwd() function looks the same as getcwd and fastgetcwd but is
  55 implemented using the most natural and safe form for the current
  56 architecture. For most systems it is identical to `pwd` (but without
  57 the trailing line terminator).
  58
  59 It is recommended that cwd (or another *cwd() function) is used in
  60 I<all> code to ensure portability.
  61
  62 If you ask to override your chdir() built-in function, then your PWD
  63 environment variable will be kept up to date.  (See
  64 L<perlsub/Overriding Builtin Functions>.) Note that it will only be
  65 kept up to date if all packages which use chdir import it from Cwd.
  66
  67 =cut
  68
  69 ## use strict;
  70
  71 use Carp;
  72
  73 $VERSION = '2.02';
  74
  75 require Exporter;
  76 @ISA = qw(Exporter);
  77 @EXPORT = qw(cwd getcwd fastcwd fastgetcwd);
  78 @EXPORT_OK = qw(chdir abs_path fast_abs_path realpath fast_realpath);
  79
  80
  81 # The 'natural and safe form' for UNIX (pwd may be setuid root)
  82
  83 sub _backtick_pwd {
  84     my $cwd = `pwd`;
  85     # `pwd` may fail e.g. if the disk is full
  86     chomp($cwd) if defined $cwd;
  87     $cwd;
  88 }
  89
  90 # Since some ports may predefine cwd internally (e.g., NT)
  91 # we take care not to override an existing definition for cwd().
  92
  93 *cwd = \&_backtick_pwd unless defined &cwd;
  94
  95
  96 # By Brandon S. Allbery
  97 #
  98 # Usage: $cwd = getcwd();
  99
 100 sub getcwd
 101 {
 102     abs_path('.');
 103 }
 104
 105 # By John Bazik
 106 #
 107 # Usage: $cwd = &fastcwd;
 108 #
 109 # This is a faster version of getcwd.  It's also more dangerous because
 110 # you might chdir out of a directory that you can't chdir back into.
 111
 112 sub fastcwd {
 113     my($odev, $oino, $cdev, $cino, $tdev, $tino);
 114     my(@path, $path);
 115     local(*DIR);
 116
 117     my($orig_cdev, $orig_cino) = stat('.');
 118     ($cdev, $cino) = ($orig_cdev, $orig_cino);
 119     for (;;) {
 120         my $direntry;
 121         ($odev, $oino) = ($cdev, $cino);
 122         CORE::chdir('..') || return undef;
 123         ($cdev, $cino) = stat('.');
 124         last if $odev == $cdev && $oino == $cino;
 125         opendir(DIR, '.') || return undef;
 126         for (;;) {
 127             $direntry = readdir(DIR);
 128             last unless defined $direntry;
 129             next if $direntry eq '.';
 130             next if $direntry eq '..';
 131
 132             ($tdev, $tino) = lstat($direntry);
 133             last unless $tdev != $odev || $tino != $oino;
 134         }
 135         closedir(DIR);
 136         return undef unless defined $direntry; # should never happen
 137         unshift(@path, $direntry);
 138     }
 139     $path = '/' . join('/', @path);
 140     if ($^O eq 'apollo') { $path = "/".$path; }
 141     # At this point $path may be tainted (if tainting) and chdir would fail.
 142     # To be more useful we untaint it then check that we landed where we started.
 143     $path = $1 if $path =~ /^(.*)\z/s;  # untaint
 144     CORE::chdir($path) || return undef;
 145     ($cdev, $cino) = stat('.');
 146     die "Unstable directory path, current directory changed unexpectedly"
 147         if $cdev != $orig_cdev || $cino != $orig_cino;
 148     $path;
 149 }
 150
 151
 152 # Keeps track of current working directory in PWD environment var
 153 # Usage:
 154 #       use Cwd 'chdir';
 155 #       chdir $newdir;
 156
 157 my $chdir_init = 0;
 158
 159 sub chdir_init {
 160     if ($ENV{'PWD'} and $^O ne 'os2' and $^O ne 'dos') {
 161         my($dd,$di) = stat('.');
 162         my($pd,$pi) = stat($ENV{'PWD'});
 163         if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
 164             $ENV{'PWD'} = cwd();
 165         }
 166     }
 167     else {
 168         $ENV{'PWD'} = cwd();
 169     }
 170     # Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
 171     if ($ENV{'PWD'} =~ m|(/[^/]+(/[^/]+/[^/]+))(.*)|s) {
 172         my($pd,$pi) = stat($2);
 173         my($dd,$di) = stat($1);
 174         if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
 175             $ENV{'PWD'}="$2$3";
 176         }
 177     }
 178     $chdir_init = 1;
 179 }
 180
 181 sub chdir {
 182     my $newdir = shift || '';   # allow for no arg (chdir to HOME dir)
 183     $newdir =~ s|///*|/|g;
 184     chdir_init() unless $chdir_init;
 185     return 0 unless CORE::chdir $newdir;
 186     if ($^O eq 'VMS') { return $ENV{'PWD'} = $ENV{'DEFAULT'} }
 187
 188     if ($newdir =~ m#^/#s) {
 189         $ENV{'PWD'} = $newdir;
 190     } else {
 191         my @curdir = split(m#/#,$ENV{'PWD'});
 192         @curdir = ('') unless @curdir;
 193         my $component;
 194         foreach $component (split(m#/#, $newdir)) {
 195             next if $component eq '.';
 196             pop(@curdir),next if $component eq '..';
 197             push(@curdir,$component);
 198         }
 199         $ENV{'PWD'} = join('/',@curdir) || '/';
 200     }
 201     1;
 202 }
 203
 204 # Taken from Cwd.pm It is really getcwd with an optional
 205 # parameter instead of '.'
 206 #
 207
 208 sub abs_path
 209 {
 210     my $start = @_ ? shift : '.';
 211     my($dotdots, $cwd, @pst, @cst, $dir, @tst);
 212
 213     unless (@cst = stat( $start ))
 214     {
 215         carp "stat($start): $!";
 216         return '';
 217     }
 218     $cwd = '';
 219     $dotdots = $start;
 220     do
 221     {
 222         $dotdots .= '/..';
 223         @pst = @cst;
 224         unless (opendir(PARENT, $dotdots))
 225         {
 226             carp "opendir($dotdots): $!";
 227             return '';
 228         }
 229         unless (@cst = stat($dotdots))
 230         {
 231             carp "stat($dotdots): $!";
 232             closedir(PARENT);
 233             return '';
 234         }
 235         if ($pst[0] == $cst[0] && $pst[1] == $cst[1])
 236         {
 237             $dir = undef;
 238         }
 239         else
 240         {
 241             do
 242             {
 243                 unless (defined ($dir = readdir(PARENT)))
 244                 {
 245                     carp "readdir($dotdots): $!";
 246                     closedir(PARENT);
 247                     return '';
 248                 }
 249                 $tst[0] = $pst[0]+1 unless (@tst = lstat("$dotdots/$dir"))
 250             }
 251             while ($dir eq '.' || $dir eq '..' || $tst[0] != $pst[0] ||
 252                    $tst[1] != $pst[1]);
 253         }
 254         $cwd = (defined $dir ? "$dir" : "" ) . "/$cwd" ;
 255         closedir(PARENT);
 256     } while (defined $dir);
 257     chop($cwd) unless $cwd eq '/'; # drop the trailing /
 258     $cwd;
 259 }
 260
 261 # added function alias for those of us more
 262 # used to the libc function.  --tchrist 27-Jan-00
 263 *realpath = \&abs_path;
 264
 265 sub fast_abs_path {
 266     my $cwd = getcwd();
 267     my $path = shift || '.';
 268     CORE::chdir($path) || croak "Cannot chdir to $path:$!";
 269     my $realpath = getcwd();
 270     CORE::chdir($cwd)  || croak "Cannot chdir back to $cwd:$!";
 271     $realpath;
 272 }
 273
 274 # added function alias to follow principle of least surprise
 275 # based on previous aliasing.  --tchrist 27-Jan-00
 276 *fast_realpath = \&fast_abs_path;
 277
 278
 279 # --- PORTING SECTION ---
 280
 281 # VMS: $ENV{'DEFAULT'} points to default directory at all times
 282 # 06-Mar-1996  Charles Bailey  bailey@newman.upenn.edu
 283 # Note: Use of Cwd::chdir() causes the logical name PWD to be defined
 284 #   in the process logical name table as the default device and directory
 285 #   seen by Perl. This may not be the same as the default device
 286 #   and directory seen by DCL after Perl exits, since the effects
 287 #   the CRTL chdir() function persist only until Perl exits.
 288
 289 sub _vms_cwd {
 290     return $ENV{'DEFAULT'};
 291 }
 292
 293 sub _vms_abs_path {
 294     return $ENV{'DEFAULT'} unless @_;
 295     my $path = VMS::Filespec::pathify($_[0]);
 296     croak("Invalid path name $_[0]") unless defined $path;
 297     return VMS::Filespec::rmsexpand($path);
 298 }
 299
 300 sub _os2_cwd {
 301     $ENV{'PWD'} = `cmd /c cd`;
 302     chop $ENV{'PWD'};
 303     $ENV{'PWD'} =~ s:\\:/:g ;
 304     return $ENV{'PWD'};
 305 }
 306
 307 sub _win32_cwd {
 308     $ENV{'PWD'} = Win32::GetCwd();
 309     $ENV{'PWD'} =~ s:\\:/:g ;
 310     return $ENV{'PWD'};
 311 }
 312
 313 *_NT_cwd = \&_win32_cwd if (!defined &_NT_cwd &&
 314                             defined &Win32::GetCwd);
 315
 316 *_NT_cwd = \&_os2_cwd unless defined &_NT_cwd;
 317
 318 sub _dos_cwd {
 319     if (!defined &Dos::GetCwd) {
 320         $ENV{'PWD'} = `command /c cd`;
 321         chop $ENV{'PWD'};
 322         $ENV{'PWD'} =~ s:\\:/:g ;
 323     } else {
 324         $ENV{'PWD'} = Dos::GetCwd();
 325     }
 326     return $ENV{'PWD'};
 327 }
 328
 329 sub _qnx_cwd {
 330     $ENV{'PWD'} = `/usr/bin/fullpath -t`;
 331     chop $ENV{'PWD'};
 332     return $ENV{'PWD'};
 333 }
 334
 335 sub _qnx_abs_path {
 336     my $path = shift || '.';
 337     my $realpath=`/usr/bin/fullpath -t $path`;
 338     chop $realpath;
 339     return $realpath;
 340 }
 341
 342 {
 343     no warnings;        # assignments trigger 'subroutine redefined' warning
 344
 345     if ($^O eq 'VMS') {
 346         *cwd            = \&_vms_cwd;
 347         *getcwd         = \&_vms_cwd;
 348         *fastcwd        = \&_vms_cwd;
 349         *fastgetcwd     = \&_vms_cwd;
 350         *abs_path       = \&_vms_abs_path;
 351         *fast_abs_path  = \&_vms_abs_path;
 352     }
 353     elsif ($^O eq 'NT' or $^O eq 'MSWin32') {
 354         # We assume that &_NT_cwd is defined as an XSUB or in the core.
 355         *cwd            = \&_NT_cwd;
 356         *getcwd         = \&_NT_cwd;
 357         *fastcwd        = \&_NT_cwd;
 358         *fastgetcwd     = \&_NT_cwd;
 359         *abs_path       = \&fast_abs_path;
 360     }
 361     elsif ($^O eq 'os2') {
 362         # sys_cwd may keep the builtin command
 363         *cwd            = defined &sys_cwd ? \&sys_cwd : \&_os2_cwd;
 364         *getcwd         = \&cwd;
 365         *fastgetcwd     = \&cwd;
 366         *fastcwd        = \&cwd;
 367         *abs_path       = \&fast_abs_path;
 368     }
 369     elsif ($^O eq 'dos') {
 370         *cwd            = \&_dos_cwd;
 371         *getcwd         = \&_dos_cwd;
 372         *fastgetcwd     = \&_dos_cwd;
 373         *fastcwd        = \&_dos_cwd;
 374         *abs_path       = \&fast_abs_path;
 375     }
 376     elsif ($^O eq 'qnx') {
 377         *cwd            = \&_qnx_cwd;
 378         *getcwd         = \&_qnx_cwd;
 379         *fastgetcwd     = \&_qnx_cwd;
 380         *fastcwd        = \&_qnx_cwd;
 381         *abs_path       = \&_qnx_abs_path;
 382         *fast_abs_path  = \&_qnx_abs_path;
 383     }
 384     elsif ($^O eq 'cygwin') {
 385         *getcwd = \&cwd;
 386         *fastgetcwd     = \&cwd;
 387         *fastcwd        = \&cwd;
 388         *abs_path       = \&fast_abs_path;
 389     }
 390 }
 391
 392 # package main; eval join('',<DATA>) || die $@; # quick test
 393
 394 1;
 395
 396 __END__
 397 BEGIN { import Cwd qw(:DEFAULT chdir); }
 398 print join("\n", cwd, getcwd, fastcwd, "");
 399 chdir('..');
 400 print join("\n", cwd, getcwd, fastcwd, "");
 401 print "$ENV{PWD}\n";