lib/Cwd.pm

   1 package Cwd;
   2 require 5.000;
   3
   4 =head1 NAME
   5
   6 Cwd - get pathname of current working directory
   7
   8 =head1 SYNOPSIS
   9
  10     use Cwd;
  11     $dir = cwd;
  12
  13     use Cwd;
  14     $dir = getcwd;
  15
  16     use Cwd;
  17     $dir = fastcwd;
  18
  19     use Cwd;
  20     $dir = fastgetcwd;
  21
  22     use Cwd 'chdir';
  23     chdir "/tmp";
  24     print $ENV{'PWD'};
  25
  26     use Cwd 'abs_path';     # aka realpath()
  27     print abs_path($ENV{'PWD'});
  28
  29     use Cwd 'fast_abs_path';
  30     print fast_abs_path($ENV{'PWD'});
  31
  32 =head1 DESCRIPTION
  33
  34 This module provides functions for determining the pathname of the
  35 current working directory.  By default, it exports the functions
  36 cwd(), getcwd(), fastcwd(), and fastgetcwd() into the caller's
  37 namespace.  Each of these functions are called without arguments and
  38 return the absolute path of the current working directory.  It is
  39 recommended that cwd (or another *cwd() function) be used in I<all>
  40 code to ensure portability.
  41
  42 The cwd() is the most natural and safe form for the current
  43 architecture. For most systems it is identical to `pwd` (but without
  44 the trailing line terminator).
  45
  46 The getcwd() function re-implements the getcwd(3) (or getwd(3)) functions
  47 in Perl.
  48
  49 The fastcwd() function looks the same as getcwd(), but runs faster.
  50 It's also more dangerous because it might conceivably chdir() you out
  51 of a directory that it can't chdir() you back into.  If fastcwd
  52 encounters a problem it will return undef but will probably leave you
  53 in a different directory.  For a measure of extra security, if
  54 everything appears to have worked, the fastcwd() function will check
  55 that it leaves you in the same directory that it started in. If it has
  56 changed it will C<die> with the message "Unstable directory path,
  57 current directory changed unexpectedly". That should never happen.
  58
  59 The fastgetcwd() function is provided as a synonym for cwd().
  60
  61 The abs_path() function takes a single argument and returns the
  62 absolute pathname for that argument.  It uses the same algorithm as
  63 getcwd().  (Actually, getcwd() is abs_path("."))  Symbolic links and
  64 relative-path components ("." and "..") are resolved to return the
  65 canonical pathname, just like realpath(3).  This function is also
  66 callable as realpath().
  67
  68 The fast_abs_path() function looks the same as abs_path() but runs
  69 faster and, like fastcwd(), is more dangerous.
  70
  71 If you ask to override your chdir() built-in function, then your PWD
  72 environment variable will be kept up to date.  (See
  73 L<perlsub/Overriding Builtin Functions>.) Note that it will only be
  74 kept up to date if all packages which use chdir import it from Cwd.
  75
  76 =cut
  77
  78 use strict;
  79
  80 use Carp;
  81
  82 our $VERSION = '2.04';
  83
  84 use base qw/ Exporter /;
  85 our @EXPORT = qw(cwd getcwd fastcwd fastgetcwd);
  86 our @EXPORT_OK = qw(chdir abs_path fast_abs_path realpath fast_realpath);
  87
  88
  89 # The 'natural and safe form' for UNIX (pwd may be setuid root)
  90
  91 sub _backtick_pwd {
  92     my $cwd = `pwd`;
  93     # `pwd` may fail e.g. if the disk is full
  94     chomp($cwd) if defined $cwd;
  95     $cwd;
  96 }
  97
  98 # Since some ports may predefine cwd internally (e.g., NT)
  99 # we take care not to override an existing definition for cwd().
 100
 101 unless(defined &cwd) {
 102     # The pwd command is not available in some chroot(2)'ed environments
 103     if($^O eq 'MacOS' || grep { -x "$_/pwd" } split(':', $ENV{PATH})) {
 104         *cwd = \&_backtick_pwd;
 105     }
 106     else {
 107         *cwd = \&getcwd;
 108     }
 109 }
 110
 111 # set a reasonable (and very safe) default for fastgetcwd, in case it
 112 # isn't redefined later (20001212 rspier)
 113 *fastgetcwd = \&cwd;
 114
 115 # By Brandon S. Allbery
 116 #
 117 # Usage: $cwd = getcwd();
 118
 119 sub getcwd
 120 {
 121     abs_path('.');
 122 }
 123
 124 # Now a callout to an XSUB.  We have to delay booting of the XSUB
 125 # until the first time fastcwd is called since Cwd::cwd is needed in the
 126 # building of perl when dynamic loading may be unavailable
 127 my $booted = 0;
 128 sub fastcwd {
 129     unless ($booted) {
 130         require XSLoader;
 131         XSLoader::load("Cwd");
 132         ++$booted;
 133     }
 134     return &Cwd::_fastcwd;
 135 }
 136
 137
 138 # Keeps track of current working directory in PWD environment var
 139 # Usage:
 140 #       use Cwd 'chdir';
 141 #       chdir $newdir;
 142
 143 my $chdir_init = 0;
 144
 145 sub chdir_init {
 146     if ($ENV{'PWD'} and $^O ne 'os2' and $^O ne 'dos' and $^O ne 'MSWin32') {
 147         my($dd,$di) = stat('.');
 148         my($pd,$pi) = stat($ENV{'PWD'});
 149         if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
 150             $ENV{'PWD'} = cwd();
 151         }
 152     }
 153     else {
 154         my $wd = cwd();
 155         $wd = Win32::GetFullPathName($wd) if $^O eq 'MSWin32';
 156         $ENV{'PWD'} = $wd;
 157     }
 158     # Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
 159     if ($^O ne 'MSWin32' and $ENV{'PWD'} =~ m|(/[^/]+(/[^/]+/[^/]+))(.*)|s) {
 160         my($pd,$pi) = stat($2);
 161         my($dd,$di) = stat($1);
 162         if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
 163             $ENV{'PWD'}="$2$3";
 164         }
 165     }
 166     $chdir_init = 1;
 167 }
 168
 169 sub chdir {
 170     my $newdir = @_ ? shift : '';       # allow for no arg (chdir to HOME dir)
 171     $newdir =~ s|///*|/|g unless $^O eq 'MSWin32';
 172     chdir_init() unless $chdir_init;
 173     my $newpwd;
 174     if ($^O eq 'MSWin32') {
 175         # get the full path name *before* the chdir()
 176         $newpwd = Win32::GetFullPathName($newdir);
 177     }
 178
 179     return 0 unless CORE::chdir $newdir;
 180
 181     if ($^O eq 'VMS') {
 182         return $ENV{'PWD'} = $ENV{'DEFAULT'}
 183     }
 184     elsif ($^O eq 'MacOS') {
 185         return $ENV{'PWD'} = cwd();
 186     }
 187     elsif ($^O eq 'MSWin32') {
 188         $ENV{'PWD'} = $newpwd;
 189         return 1;
 190     }
 191
 192     if ($newdir =~ m#^/#s) {
 193         $ENV{'PWD'} = $newdir;
 194     } else {
 195         my @curdir = split(m#/#,$ENV{'PWD'});
 196         @curdir = ('') unless @curdir;
 197         my $component;
 198         foreach $component (split(m#/#, $newdir)) {
 199             next if $component eq '.';
 200             pop(@curdir),next if $component eq '..';
 201             push(@curdir,$component);
 202         }
 203         $ENV{'PWD'} = join('/',@curdir) || '/';
 204     }
 205     1;
 206 }
 207
 208 # Taken from Cwd.pm It is really getcwd with an optional
 209 # parameter instead of '.'
 210 #
 211
 212 sub abs_path
 213 {
 214     my $start = @_ ? shift : '.';
 215     my($dotdots, $cwd, @pst, @cst, $dir, @tst);
 216
 217     unless (@cst = stat( $start ))
 218     {
 219         carp "stat($start): $!";
 220         return '';
 221     }
 222     $cwd = '';
 223     $dotdots = $start;
 224     do
 225     {
 226         $dotdots .= '/..';
 227         @pst = @cst;
 228         unless (opendir(PARENT, $dotdots))
 229         {
 230             carp "opendir($dotdots): $!";
 231             return '';
 232         }
 233         unless (@cst = stat($dotdots))
 234         {
 235             carp "stat($dotdots): $!";
 236             closedir(PARENT);
 237             return '';
 238         }
 239         if ($pst[0] == $cst[0] && $pst[1] == $cst[1])
 240         {
 241             $dir = undef;
 242         }
 243         else
 244         {
 245             do
 246             {
 247                 unless (defined ($dir = readdir(PARENT)))
 248                 {
 249                     carp "readdir($dotdots): $!";
 250                     closedir(PARENT);
 251                     return '';
 252                 }
 253                 $tst[0] = $pst[0]+1 unless (@tst = lstat("$dotdots/$dir"))
 254             }
 255             while ($dir eq '.' || $dir eq '..' || $tst[0] != $pst[0] ||
 256                    $tst[1] != $pst[1]);
 257         }
 258         $cwd = (defined $dir ? "$dir" : "" ) . "/$cwd" ;
 259         closedir(PARENT);
 260     } while (defined $dir);
 261     chop($cwd) unless $cwd eq '/'; # drop the trailing /
 262     $cwd;
 263 }
 264
 265 # added function alias for those of us more
 266 # used to the libc function.  --tchrist 27-Jan-00
 267 *realpath = \&abs_path;
 268
 269 sub fast_abs_path {
 270     my $cwd = getcwd();
 271     my $path = @_ ? shift : '.';
 272     CORE::chdir($path) || croak "Cannot chdir to $path:$!";
 273     my $realpath = getcwd();
 274     CORE::chdir($cwd)  || croak "Cannot chdir back to $cwd:$!";
 275     $realpath;
 276 }
 277
 278 # added function alias to follow principle of least surprise
 279 # based on previous aliasing.  --tchrist 27-Jan-00
 280 *fast_realpath = \&fast_abs_path;
 281
 282
 283 # --- PORTING SECTION ---
 284
 285 # VMS: $ENV{'DEFAULT'} points to default directory at all times
 286 # 06-Mar-1996  Charles Bailey  bailey@newman.upenn.edu
 287 # Note: Use of Cwd::chdir() causes the logical name PWD to be defined
 288 #   in the process logical name table as the default device and directory
 289 #   seen by Perl. This may not be the same as the default device
 290 #   and directory seen by DCL after Perl exits, since the effects
 291 #   the CRTL chdir() function persist only until Perl exits.
 292
 293 sub _vms_cwd {
 294     return $ENV{'DEFAULT'};
 295 }
 296
 297 sub _vms_abs_path {
 298     return $ENV{'DEFAULT'} unless @_;
 299     my $path = VMS::Filespec::pathify($_[0]);
 300     croak("Invalid path name $_[0]") unless defined $path;
 301     return VMS::Filespec::rmsexpand($path);
 302 }
 303
 304 sub _os2_cwd {
 305     $ENV{'PWD'} = `cmd /c cd`;
 306     chop $ENV{'PWD'};
 307     $ENV{'PWD'} =~ s:\\:/:g ;
 308     return $ENV{'PWD'};
 309 }
 310
 311 sub _win32_cwd {
 312     $ENV{'PWD'} = Win32::GetCwd();
 313     $ENV{'PWD'} =~ s:\\:/:g ;
 314     return $ENV{'PWD'};
 315 }
 316
 317 *_NT_cwd = \&_win32_cwd if (!defined &_NT_cwd &&
 318                             defined &Win32::GetCwd);
 319
 320 *_NT_cwd = \&_os2_cwd unless defined &_NT_cwd;
 321
 322 sub _dos_cwd {
 323     if (!defined &Dos::GetCwd) {
 324         $ENV{'PWD'} = `command /c cd`;
 325         chop $ENV{'PWD'};
 326         $ENV{'PWD'} =~ s:\\:/:g ;
 327     } else {
 328         $ENV{'PWD'} = Dos::GetCwd();
 329     }
 330     return $ENV{'PWD'};
 331 }
 332
 333 sub _qnx_cwd {
 334     $ENV{'PWD'} = `/usr/bin/fullpath -t`;
 335     chop $ENV{'PWD'};
 336     return $ENV{'PWD'};
 337 }
 338
 339 sub _qnx_abs_path {
 340     my $path = @_ ? shift : '.';
 341     my $realpath=`/usr/bin/fullpath -t $path`;
 342     chop $realpath;
 343     return $realpath;
 344 }
 345
 346 sub _epoc_cwd {
 347     $ENV{'PWD'} = EPOC::getcwd();
 348     return $ENV{'PWD'};
 349 }
 350
 351 {
 352     no warnings;        # assignments trigger 'subroutine redefined' warning
 353
 354     if ($^O eq 'VMS') {
 355         *cwd            = \&_vms_cwd;
 356         *getcwd         = \&_vms_cwd;
 357         *fastcwd        = \&_vms_cwd;
 358         *fastgetcwd     = \&_vms_cwd;
 359         *abs_path       = \&_vms_abs_path;
 360         *fast_abs_path  = \&_vms_abs_path;
 361     }
 362     elsif ($^O eq 'NT' or $^O eq 'MSWin32') {
 363         # We assume that &_NT_cwd is defined as an XSUB or in the core.
 364         *cwd            = \&_NT_cwd;
 365         *getcwd         = \&_NT_cwd;
 366         *fastcwd        = \&_NT_cwd;
 367         *fastgetcwd     = \&_NT_cwd;
 368         *abs_path       = \&fast_abs_path;
 369     }
 370     elsif ($^O eq 'os2') {
 371         # sys_cwd may keep the builtin command
 372         *cwd            = defined &sys_cwd ? \&sys_cwd : \&_os2_cwd;
 373         *getcwd         = \&cwd;
 374         *fastgetcwd     = \&cwd;
 375         *fastcwd        = \&cwd;
 376         *abs_path       = \&fast_abs_path;
 377     }
 378     elsif ($^O eq 'dos') {
 379         *cwd            = \&_dos_cwd;
 380         *getcwd         = \&_dos_cwd;
 381         *fastgetcwd     = \&_dos_cwd;
 382         *fastcwd        = \&_dos_cwd;
 383         *abs_path       = \&fast_abs_path;
 384     }
 385     elsif ($^O eq 'qnx') {
 386         *cwd            = \&_qnx_cwd;
 387         *getcwd         = \&_qnx_cwd;
 388         *fastgetcwd     = \&_qnx_cwd;
 389         *fastcwd        = \&_qnx_cwd;
 390         *abs_path       = \&_qnx_abs_path;
 391         *fast_abs_path  = \&_qnx_abs_path;
 392     }
 393     elsif ($^O eq 'cygwin') {
 394         *getcwd = \&cwd;
 395         *fastgetcwd     = \&cwd;
 396         *fastcwd        = \&cwd;
 397         *abs_path       = \&fast_abs_path;
 398     }
 399     elsif ($^O eq 'epoc') {
 400         *cwd            = \&_epoc_cwd;
 401         *getcwd         = \&_epoc_cwd;
 402         *fastgetcwd     = \&_epoc_cwd;
 403         *fastcwd        = \&_epoc_cwd;
 404         *abs_path       = \&fast_abs_path;
 405     }
 406     elsif ($^O eq 'MacOS') {
 407         *getcwd     = \&cwd;
 408         *fastgetcwd = \&cwd;
 409         *fastcwd    = \&cwd;
 410         *abs_path   = \&fast_abs_path;
 411     }
 412 }
 413
 414 # package main; eval join('',<DATA>) || die $@; # quick test
 415
 416 1;
 417
 418 __END__
 419 BEGIN { import Cwd qw(:DEFAULT chdir); }
 420 print join("\n", cwd, getcwd, fastcwd, "");
 421 chdir('..');
 422 print join("\n", cwd, getcwd, fastcwd, "");
 423 print "$ENV{PWD}\n";