lib/Cwd.pm

   1 package Cwd;
   2 require 5.000;
   3
   4 =head1 NAME
   5
   6 getcwd - get pathname of current working directory
   7
   8 =head1 SYNOPSIS
   9
  10     use Cwd;
  11     $dir = cwd;
  12
  13     use Cwd;
  14     $dir = getcwd;
  15
  16     use Cwd;
  17     $dir = fastgetcwd;
  18
  19     use Cwd 'chdir';
  20     chdir "/tmp";
  21     print $ENV{'PWD'};
  22
  23     use Cwd 'abs_path';     # aka realpath()
  24     print abs_path($ENV{'PWD'});
  25
  26     use Cwd 'fast_abs_path';
  27     print fast_abs_path($ENV{'PWD'});
  28
  29 =head1 DESCRIPTION
  30
  31 The getcwd() function re-implements the getcwd(3) (or getwd(3)) functions
  32 in Perl.
  33
  34 The abs_path() function takes a single argument and returns the
  35 absolute pathname for that argument.  It uses the same algorithm
  36 as getcwd().  (Actually, getcwd() is abs_path("."))  Symbolic links
  37 and relative-path components ("." and "..") are resolved to return
  38 the canonical pathname, just like realpath(3).  Also callable as
  39 realpath().
  40
  41 The fastcwd() function looks the same as getcwd(), but runs faster.
  42 It's also more dangerous because it might conceivably chdir() you out
  43 of a directory that it can't chdir() you back into.  If fastcwd
  44 encounters a problem it will return undef but will probably leave you
  45 in a different directory.  For a measure of extra security, if
  46 everything appears to have worked, the fastcwd() function will check
  47 that it leaves you in the same directory that it started in. If it has
  48 changed it will C<die> with the message "Unstable directory path,
  49 current directory changed unexpectedly". That should never happen.
  50
  51 The fast_abs_path() function looks the same as abs_path(), but runs faster.
  52 And like fastcwd() is more dangerous.
  53
  54 The cwd() function looks the same as getcwd and fastgetcwd but is
  55 implemented using the most natural and safe form for the current
  56 architecture. For most systems it is identical to `pwd` (but without
  57 the trailing line terminator).
  58
  59 It is recommended that cwd (or another *cwd() function) is used in
  60 I<all> code to ensure portability.
  61
  62 If you ask to override your chdir() built-in function, then your PWD
  63 environment variable will be kept up to date.  (See
  64 L<perlsub/Overriding Builtin Functions>.) Note that it will only be
  65 kept up to date if all packages which use chdir import it from Cwd.
  66
  67 =cut
  68
  69 ## use strict;
  70
  71 use Carp;
  72
  73 $VERSION = '2.03';
  74
  75 require Exporter;
  76 @ISA = qw(Exporter);
  77 @EXPORT = qw(cwd getcwd fastcwd fastgetcwd);
  78 @EXPORT_OK = qw(chdir abs_path fast_abs_path realpath fast_realpath);
  79
  80
  81 # The 'natural and safe form' for UNIX (pwd may be setuid root)
  82
  83 sub _backtick_pwd {
  84     my $cwd;
  85     chop($cwd = `pwd`);
  86     $cwd;
  87 }
  88
  89 # Since some ports may predefine cwd internally (e.g., NT)
  90 # we take care not to override an existing definition for cwd().
  91
  92 *cwd = \&_backtick_pwd unless defined &cwd;
  93
  94
  95 # By Brandon S. Allbery
  96 #
  97 # Usage: $cwd = getcwd();
  98
  99 sub getcwd
 100 {
 101     abs_path('.');
 102 }
 103
 104 # By John Bazik
 105 #
 106 # Usage: $cwd = &fastcwd;
 107 #
 108 # This is a faster version of getcwd.  It's also more dangerous because
 109 # you might chdir out of a directory that you can't chdir back into.
 110
 111 sub fastcwd {
 112     my($odev, $oino, $cdev, $cino, $tdev, $tino);
 113     my(@path, $path);
 114     local(*DIR);
 115
 116     my($orig_cdev, $orig_cino) = stat('.');
 117     ($cdev, $cino) = ($orig_cdev, $orig_cino);
 118     for (;;) {
 119         my $direntry;
 120         ($odev, $oino) = ($cdev, $cino);
 121         CORE::chdir('..') || return undef;
 122         ($cdev, $cino) = stat('.');
 123         last if $odev == $cdev && $oino == $cino;
 124         opendir(DIR, '.') || return undef;
 125         for (;;) {
 126             $direntry = readdir(DIR);
 127             last unless defined $direntry;
 128             next if $direntry eq '.';
 129             next if $direntry eq '..';
 130
 131             ($tdev, $tino) = lstat($direntry);
 132             last unless $tdev != $odev || $tino != $oino;
 133         }
 134         closedir(DIR);
 135         return undef unless defined $direntry; # should never happen
 136         unshift(@path, $direntry);
 137     }
 138     $path = '/' . join('/', @path);
 139     if ($^O eq 'apollo') { $path = "/".$path; }
 140     # At this point $path may be tainted (if tainting) and chdir would fail.
 141     # To be more useful we untaint it then check that we landed where we started.
 142     $path = $1 if $path =~ /^(.*)\z/s;  # untaint
 143     CORE::chdir($path) || return undef;
 144     ($cdev, $cino) = stat('.');
 145     die "Unstable directory path, current directory changed unexpectedly"
 146         if $cdev != $orig_cdev || $cino != $orig_cino;
 147     $path;
 148 }
 149
 150
 151 # Keeps track of current working directory in PWD environment var
 152 # Usage:
 153 #       use Cwd 'chdir';
 154 #       chdir $newdir;
 155
 156 my $chdir_init = 0;
 157
 158 sub chdir_init {
 159     if ($ENV{'PWD'} and $^O ne 'os2' and $^O ne 'dos') {
 160         my($dd,$di) = stat('.');
 161         my($pd,$pi) = stat($ENV{'PWD'});
 162         if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
 163             $ENV{'PWD'} = cwd();
 164         }
 165     }
 166     else {
 167         $ENV{'PWD'} = cwd();
 168     }
 169     # Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
 170     if ($ENV{'PWD'} =~ m|(/[^/]+(/[^/]+/[^/]+))(.*)|s) {
 171         my($pd,$pi) = stat($2);
 172         my($dd,$di) = stat($1);
 173         if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
 174             $ENV{'PWD'}="$2$3";
 175         }
 176     }
 177     $chdir_init = 1;
 178 }
 179
 180 sub chdir {
 181     my $newdir = shift || '';   # allow for no arg (chdir to HOME dir)
 182     $newdir =~ s|///*|/|g;
 183     chdir_init() unless $chdir_init;
 184     return 0 unless CORE::chdir $newdir;
 185     if ($^O eq 'VMS') { return $ENV{'PWD'} = $ENV{'DEFAULT'} }
 186
 187     if ($newdir =~ m#^/#s) {
 188         $ENV{'PWD'} = $newdir;
 189     } else {
 190         my @curdir = split(m#/#,$ENV{'PWD'});
 191         @curdir = ('') unless @curdir;
 192         my $component;
 193         foreach $component (split(m#/#, $newdir)) {
 194             next if $component eq '.';
 195             pop(@curdir),next if $component eq '..';
 196             push(@curdir,$component);
 197         }
 198         $ENV{'PWD'} = join('/',@curdir) || '/';
 199     }
 200     1;
 201 }
 202
 203
 204 # By Jeff "japhy" Pinyan (07/23/2000)
 205 #   usage:  abs_path(PATHNAME)
 206 # see the docs
 207
 208 sub abs_path {
 209   my $base = @_ ? $_[0] : ".";
 210   my $path = "";
 211   my $file;
 212
 213   do {
 214     my @devino = (stat($base))[0,1] or
 215       carp("stat($base): $!"), return;
 216
 217     $base .= "/..";
 218
 219     opendir PREV, $base or carp("opendir($base): $!"), return;
 220     while (defined($file = readdir PREV)) {
 221       next if $file eq "." or $file eq "..";
 222       my @entry = (lstat("$base/$file"))[0,1] or
 223         carp("lstat($base/$file): $!"), return;
 224       last if $devino[0] == $entry[0] and $devino[1] == $entry[1];
 225     }
 226     closedir PREV;
 227
 228     $path = (defined $file and $file) . "/$path";
 229   } while defined $file;
 230
 231   length($path) > 1 and chop $path;
 232   return $path;
 233 }
 234
 235
 236 # added function alias for those of us more
 237 # used to the libc function.  --tchrist 27-Jan-00
 238 *realpath = \&abs_path;
 239
 240 sub fast_abs_path {
 241     my $cwd = getcwd();
 242     my $path = shift || '.';
 243     CORE::chdir($path) || croak "Cannot chdir to $path:$!";
 244     my $realpath = getcwd();
 245     CORE::chdir($cwd)  || croak "Cannot chdir back to $cwd:$!";
 246     $realpath;
 247 }
 248
 249 # added function alias to follow principle of least surprise
 250 # based on previous aliasing.  --tchrist 27-Jan-00
 251 *fast_realpath = \&fast_abs_path;
 252
 253
 254 # --- PORTING SECTION ---
 255
 256 # VMS: $ENV{'DEFAULT'} points to default directory at all times
 257 # 06-Mar-1996  Charles Bailey  bailey@newman.upenn.edu
 258 # Note: Use of Cwd::chdir() causes the logical name PWD to be defined
 259 #   in the process logical name table as the default device and directory
 260 #   seen by Perl. This may not be the same as the default device
 261 #   and directory seen by DCL after Perl exits, since the effects
 262 #   the CRTL chdir() function persist only until Perl exits.
 263
 264 sub _vms_cwd {
 265     return $ENV{'DEFAULT'};
 266 }
 267
 268 sub _vms_abs_path {
 269     return $ENV{'DEFAULT'} unless @_;
 270     my $path = VMS::Filespec::pathify($_[0]);
 271     croak("Invalid path name $_[0]") unless defined $path;
 272     return VMS::Filespec::rmsexpand($path);
 273 }
 274
 275 sub _os2_cwd {
 276     $ENV{'PWD'} = `cmd /c cd`;
 277     chop $ENV{'PWD'};
 278     $ENV{'PWD'} =~ s:\\:/:g ;
 279     return $ENV{'PWD'};
 280 }
 281
 282 sub _win32_cwd {
 283     $ENV{'PWD'} = Win32::GetCwd();
 284     $ENV{'PWD'} =~ s:\\:/:g ;
 285     return $ENV{'PWD'};
 286 }
 287
 288 *_NT_cwd = \&_win32_cwd if (!defined &_NT_cwd &&
 289                             defined &Win32::GetCwd);
 290
 291 *_NT_cwd = \&_os2_cwd unless defined &_NT_cwd;
 292
 293 sub _dos_cwd {
 294     if (!defined &Dos::GetCwd) {
 295         $ENV{'PWD'} = `command /c cd`;
 296         chop $ENV{'PWD'};
 297         $ENV{'PWD'} =~ s:\\:/:g ;
 298     } else {
 299         $ENV{'PWD'} = Dos::GetCwd();
 300     }
 301     return $ENV{'PWD'};
 302 }
 303
 304 sub _qnx_cwd {
 305     $ENV{'PWD'} = `/usr/bin/fullpath -t`;
 306     chop $ENV{'PWD'};
 307     return $ENV{'PWD'};
 308 }
 309
 310 sub _qnx_abs_path {
 311     my $path = shift || '.';
 312     my $realpath=`/usr/bin/fullpath -t $path`;
 313     chop $realpath;
 314     return $realpath;
 315 }
 316
 317 {
 318     no warnings;        # assignments trigger 'subroutine redefined' warning
 319
 320     if ($^O eq 'VMS') {
 321         *cwd            = \&_vms_cwd;
 322         *getcwd         = \&_vms_cwd;
 323         *fastcwd        = \&_vms_cwd;
 324         *fastgetcwd     = \&_vms_cwd;
 325         *abs_path       = \&_vms_abs_path;
 326         *fast_abs_path  = \&_vms_abs_path;
 327     }
 328     elsif ($^O eq 'NT' or $^O eq 'MSWin32') {
 329         # We assume that &_NT_cwd is defined as an XSUB or in the core.
 330         *cwd            = \&_NT_cwd;
 331         *getcwd         = \&_NT_cwd;
 332         *fastcwd        = \&_NT_cwd;
 333         *fastgetcwd     = \&_NT_cwd;
 334         *abs_path       = \&fast_abs_path;
 335     }
 336     elsif ($^O eq 'os2') {
 337         # sys_cwd may keep the builtin command
 338         *cwd            = defined &sys_cwd ? \&sys_cwd : \&_os2_cwd;
 339         *getcwd         = \&cwd;
 340         *fastgetcwd     = \&cwd;
 341         *fastcwd        = \&cwd;
 342         *abs_path       = \&fast_abs_path;
 343     }
 344     elsif ($^O eq 'dos') {
 345         *cwd            = \&_dos_cwd;
 346         *getcwd         = \&_dos_cwd;
 347         *fastgetcwd     = \&_dos_cwd;
 348         *fastcwd        = \&_dos_cwd;
 349         *abs_path       = \&fast_abs_path;
 350     }
 351     elsif ($^O eq 'qnx') {
 352         *cwd            = \&_qnx_cwd;
 353         *getcwd         = \&_qnx_cwd;
 354         *fastgetcwd     = \&_qnx_cwd;
 355         *fastcwd        = \&_qnx_cwd;
 356         *abs_path       = \&_qnx_abs_path;
 357         *fast_abs_path  = \&_qnx_abs_path;
 358     }
 359     elsif ($^O eq 'cygwin') {
 360         *getcwd = \&cwd;
 361         *fastgetcwd     = \&cwd;
 362         *fastcwd        = \&cwd;
 363         *abs_path       = \&fast_abs_path;
 364     }
 365 }
 366
 367 # package main; eval join('',<DATA>) || die $@; # quick test
 368
 369 1;
 370
 371 __END__
 372 BEGIN { import Cwd qw(:DEFAULT chdir); }
 373 print join("\n", cwd, getcwd, fastcwd, "");
 374 chdir('..');
 375 print join("\n", cwd, getcwd, fastcwd, "");
 376 print "$ENV{PWD}\n";