lib/Cwd.pm

   1 package Cwd;
   2 require 5.000;
   3 require Exporter;
   4 require Config;
   5
   6 # Use osname for portability switches (doubled to cheaply avoid -w warning)
   7 my $osname = $Config::Config{'osname'} || $Config::Config{'osname'};
   8
   9
  10 =head1 NAME
  11
  12 getcwd - get pathname of current working directory
  13
  14 =head1 SYNOPSIS
  15
  16     use Cwd;
  17     $dir = cwd;
  18
  19     use Cwd;
  20     $dir = getcwd;
  21
  22     use Cwd;
  23     $dir = fastgetcwd;
  24
  25     use Cwd 'chdir';
  26     chdir "/tmp";
  27     print $ENV{'PWD'};
  28
  29 =head1 DESCRIPTION
  30
  31 The getcwd() function re-implements the getcwd(3) (or getwd(3)) functions
  32 in Perl.
  33
  34 The fastcwd() function looks the same as getcwd(), but runs faster.
  35 It's also more dangerous because you might conceivably chdir() out of a
  36 directory that you can't chdir() back into.
  37
  38 The cwd() function looks the same as getcwd and fastgetcwd but is
  39 implemented using the most natural and safe form for the current
  40 architecture. For most systems it is identical to `pwd` (but without
  41 the trailing line terminator). It is recommended that cwd (or another
  42 *cwd() function) is used in I<all> code to ensure portability.
  43
  44 If you ask to override your chdir() built-in function, then your PWD
  45 environment variable will be kept up to date.  (See
  46 L<perlsub/Overriding builtin functions>.) Note that it will only be
  47 kept up to date it all packages which use chdir import it from Cwd.
  48
  49 =cut
  50
  51 @ISA = qw(Exporter);
  52 @EXPORT = qw(cwd getcwd fastcwd);
  53 @EXPORT_OK = qw(chdir);
  54
  55 # use strict;
  56
  57 sub _backtick_pwd {  # The 'natural and safe form' for UNIX (pwd may be setuid root)
  58     my $cwd;
  59     chop($cwd = `pwd`);
  60     $cwd;
  61 }
  62
  63 # Since some ports may predefine cwd internally (e.g., NT)
  64 # we take care not to override an existing definition for cwd().
  65
  66 *cwd = \&_backtick_pwd unless defined &cwd;
  67
  68
  69 # By Brandon S. Allbery
  70 #
  71 # Usage: $cwd = getcwd();
  72
  73 sub getcwd
  74 {
  75     my($dotdots, $cwd, @pst, @cst, $dir, @tst);
  76
  77     unless (@cst = stat('.'))
  78     {
  79         warn "stat(.): $!";
  80         return '';
  81     }
  82     $cwd = '';
  83     $dotdots = '';
  84     do
  85     {
  86         $dotdots .= '/' if $dotdots;
  87         $dotdots .= '..';
  88         @pst = @cst;
  89         unless (opendir(PARENT, $dotdots))
  90         {
  91             warn "opendir($dotdots): $!";
  92             return '';
  93         }
  94         unless (@cst = stat($dotdots))
  95         {
  96             warn "stat($dotdots): $!";
  97             closedir(PARENT);
  98             return '';
  99         }
 100         if ($pst[0] == $cst[0] && $pst[1] == $cst[1])
 101         {
 102             $dir = '';
 103         }
 104         else
 105         {
 106             do
 107             {
 108                 unless (defined ($dir = readdir(PARENT)))
 109                 {
 110                     warn "readdir($dotdots): $!";
 111                     closedir(PARENT);
 112                     return '';
 113                 }
 114                 unless (@tst = lstat("$dotdots/$dir"))
 115                 {
 116                     warn "lstat($dotdots/$dir): $!";
 117                     # Just because you can't lstat this directory
 118                     # doesn't mean you'll never find the right one.
 119                     # closedir(PARENT);
 120                     # return '';
 121                 }
 122             }
 123             while ($dir eq '.' || $dir eq '..' || $tst[0] != $pst[0] ||
 124                    $tst[1] != $pst[1]);
 125         }
 126         $cwd = "$dir/$cwd";
 127         closedir(PARENT);
 128     } while ($dir);
 129     chop($cwd); # drop the trailing /
 130     $cwd;
 131 }
 132
 133
 134
 135 # By John Bazik
 136 #
 137 # Usage: $cwd = &fastcwd;
 138 #
 139 # This is a faster version of getcwd.  It's also more dangerous because
 140 # you might chdir out of a directory that you can't chdir back into.
 141
 142 sub fastcwd {
 143     my($odev, $oino, $cdev, $cino, $tdev, $tino);
 144     my(@path, $path);
 145     local(*DIR);
 146
 147     ($cdev, $cino) = stat('.');
 148     for (;;) {
 149         my $direntry;
 150         ($odev, $oino) = ($cdev, $cino);
 151         chdir('..');
 152         ($cdev, $cino) = stat('.');
 153         last if $odev == $cdev && $oino == $cino;
 154         opendir(DIR, '.');
 155         for (;;) {
 156             $direntry = readdir(DIR);
 157             next if $direntry eq '.';
 158             next if $direntry eq '..';
 159
 160             last unless defined $direntry;
 161             ($tdev, $tino) = lstat($direntry);
 162             last unless $tdev != $odev || $tino != $oino;
 163         }
 164         closedir(DIR);
 165         unshift(@path, $direntry);
 166     }
 167     chdir($path = '/' . join('/', @path));
 168     $path;
 169 }
 170
 171
 172 # Keeps track of current working directory in PWD environment var
 173 # Usage:
 174 #       use Cwd 'chdir';
 175 #       chdir $newdir;
 176
 177 my $chdir_init = 0;
 178
 179 sub chdir_init {
 180     if ($ENV{'PWD'} and $osname ne 'os2') {
 181         my($dd,$di) = stat('.');
 182         my($pd,$pi) = stat($ENV{'PWD'});
 183         if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
 184             $ENV{'PWD'} = cwd();
 185         }
 186     }
 187     else {
 188         $ENV{'PWD'} = cwd();
 189     }
 190     # Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
 191     if ($ENV{'PWD'} =~ m|(/[^/]+(/[^/]+/[^/]+))(.*)|) {
 192         my($pd,$pi) = stat($2);
 193         my($dd,$di) = stat($1);
 194         if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
 195             $ENV{'PWD'}="$2$3";
 196         }
 197     }
 198     $chdir_init = 1;
 199 }
 200
 201 sub chdir {
 202     my $newdir = shift || '';   # allow for no arg (chdir to HOME dir)
 203     $newdir =~ s|///*|/|g;
 204     chdir_init() unless $chdir_init;
 205     return 0 unless CORE::chdir $newdir;
 206     if ($osname eq 'VMS') { return $ENV{'PWD'} = $ENV{'DEFAULT'} }
 207
 208     if ($newdir =~ m#^/#) {
 209         $ENV{'PWD'} = $newdir;
 210     } else {
 211         my @curdir = split(m#/#,$ENV{'PWD'});
 212         @curdir = ('') unless @curdir;
 213         my $component;
 214         foreach $component (split(m#/#, $newdir)) {
 215             next if $component eq '.';
 216             pop(@curdir),next if $component eq '..';
 217             push(@curdir,$component);
 218         }
 219         $ENV{'PWD'} = join('/',@curdir) || '/';
 220     }
 221     1;
 222 }
 223
 224
 225 # --- PORTING SECTION ---
 226
 227 # VMS: $ENV{'DEFAULT'} points to default directory at all times
 228 # 08-Dec-1994  Charles Bailey  bailey@genetics.upenn.edu
 229 # Note: Use of Cwd::getcwd() or Cwd::chdir() (but not Cwd::fastcwd())
 230 #   causes the logical name PWD to be defined in the process
 231 #   logical name table as the default device and directory
 232 #   seen by Perl. This may not be the same as the default device
 233 #   and directory seen by DCL after Perl exits, since the effects
 234 #   the CRTL chdir() function persist only until Perl exits.
 235 # This does not apply to other systems (where only chdir() sets PWD).
 236
 237 sub _vms_cwd {
 238     return $ENV{'DEFAULT'}
 239 }
 240 sub _vms_pwd {
 241     return $ENV{'PWD'} = $ENV{'DEFAULT'}
 242 }
 243 sub _os2_cwd {
 244     $ENV{'PWD'} = `cmd /c cd`;
 245     chop $ENV{'PWD'};
 246     $ENV{'PWD'} =~ s:\\:/:g ;
 247     return $ENV{'PWD'};
 248 }
 249
 250 if ($osname eq 'VMS') {
 251
 252     *cwd        = \&_vms_pwd;
 253     *getcwd     = \&_vms_pwd;
 254     *fastgetcwd = \&_vms_cwd;
 255 }
 256 elsif ($osname eq 'NT') {
 257
 258     *getcwd     = \&cwd;
 259     *fastgetcwd = \&cwd;
 260 }
 261 elsif ($osname eq 'os2') {
 262     *cwd     = \&_os2_cwd;
 263     *getcwd     = \&_os2_cwd;
 264     *fastgetcwd = \&_os2_cwd;
 265     *fastcwd = \&_os2_cwd;
 266 }
 267
 268 # package main; eval join('',<DATA>) || die $@; # quick test
 269
 270 1;
 271
 272 __END__
 273 BEGIN { import Cwd qw(:DEFAULT chdir); }
 274 print join("\n", cwd, getcwd, fastcwd, "");
 275 chdir('..');
 276 print join("\n", cwd, getcwd, fastcwd, "");
 277 print "$ENV{PWD}\n";