lib/Cwd.pm

   1 package Cwd;
   2 require 5.000;
   3
   4 =head1 NAME
   5
   6 Cwd - get pathname of current working directory
   7
   8 =head1 SYNOPSIS
   9
  10     use Cwd;
  11     $dir = cwd;
  12
  13     use Cwd;
  14     $dir = getcwd;
  15
  16     use Cwd;
  17     $dir = fastcwd;
  18
  19     use Cwd;
  20     $dir = fastgetcwd;
  21
  22     use Cwd 'chdir';
  23     chdir "/tmp";
  24     print $ENV{'PWD'};
  25
  26     use Cwd 'abs_path';     # aka realpath()
  27     print abs_path($ENV{'PWD'});
  28
  29     use Cwd 'fast_abs_path';
  30     print fast_abs_path($ENV{'PWD'});
  31
  32 =head1 DESCRIPTION
  33
  34 This module provides functions for determining the pathname of the
  35 current working directory.  By default, it exports the functions
  36 cwd(), getcwd(), fastcwd(), and fastgetcwd() into the caller's
  37 namespace.  Each of these functions are called without arguments and
  38 return the absolute path of the current working directory.  It is
  39 recommended that cwd (or another *cwd() function) be used in I<all>
  40 code to ensure portability.
  41
  42 The cwd() is the most natural and safe form for the current
  43 architecture. For most systems it is identical to `pwd` (but without
  44 the trailing line terminator).
  45
  46 The getcwd() function re-implements the getcwd(3) (or getwd(3)) functions
  47 in Perl.
  48
  49 The fastcwd() function looks the same as getcwd(), but runs faster.
  50 It's also more dangerous because it might conceivably chdir() you out
  51 of a directory that it can't chdir() you back into.  If fastcwd
  52 encounters a problem it will return undef but will probably leave you
  53 in a different directory.  For a measure of extra security, if
  54 everything appears to have worked, the fastcwd() function will check
  55 that it leaves you in the same directory that it started in. If it has
  56 changed it will C<die> with the message "Unstable directory path,
  57 current directory changed unexpectedly". That should never happen.
  58
  59 The fastgetcwd() function is provided as a synonym for cwd().
  60
  61 The abs_path() function takes a single argument and returns the
  62 absolute pathname for that argument.  It uses the same algorithm as
  63 getcwd().  (Actually, getcwd() is abs_path("."))  Symbolic links and
  64 relative-path components ("." and "..") are resolved to return the
  65 canonical pathname, just like realpath(3).  This function is also
  66 callable as realpath().
  67
  68 The fast_abs_path() function looks the same as abs_path() but runs
  69 faster and, like fastcwd(), is more dangerous.
  70
  71 If you ask to override your chdir() built-in function, then your PWD
  72 environment variable will be kept up to date.  (See
  73 L<perlsub/Overriding Builtin Functions>.) Note that it will only be
  74 kept up to date if all packages which use chdir import it from Cwd.
  75
  76 =cut
  77
  78 use strict;
  79
  80 use Carp;
  81
  82 our $VERSION = '2.04';
  83
  84 use base qw/ Exporter /;
  85 our @EXPORT = qw(cwd getcwd fastcwd fastgetcwd);
  86 our @EXPORT_OK = qw(chdir abs_path fast_abs_path realpath fast_realpath);
  87
  88 # sys_cwd may keep the builtin command
  89
  90 # All the functionality of this module may provided by builtins,
  91 # there is no sense to process the rest of the file.
  92 # The best choice may be to have this in BEGIN, but how to return from BEGIN?
  93
  94 if ($^O eq 'os2' && defined &sys_cwd && defined &sys_abspath) {
  95     local $^W = 0;
  96     *cwd                = \&sys_cwd;
  97     *getcwd             = \&cwd;
  98     *fastgetcwd         = \&cwd;
  99     *fastcwd            = \&cwd;
 100     *abs_path           = \&sys_abspath;
 101     *fast_abs_path      = \&abs_path;
 102     *realpath           = \&abs_path;
 103     *fast_realpath      = \&abs_path;
 104     return 1;
 105 }
 106
 107 eval {
 108     require XSLoader;
 109     XSLoader::load('Cwd');
 110 };
 111
 112 # The 'natural and safe form' for UNIX (pwd may be setuid root)
 113
 114 sub _backtick_pwd {
 115     my $cwd = `pwd`;
 116     # `pwd` may fail e.g. if the disk is full
 117     chomp($cwd) if defined $cwd;
 118     $cwd;
 119 }
 120
 121 # Since some ports may predefine cwd internally (e.g., NT)
 122 # we take care not to override an existing definition for cwd().
 123
 124 unless(defined &cwd) {
 125     # The pwd command is not available in some chroot(2)'ed environments
 126     if($^O eq 'MacOS' || grep { -x "$_/pwd" } split(':', $ENV{PATH})) {
 127         *cwd = \&_backtick_pwd;
 128     }
 129     else {
 130         *cwd = \&getcwd;
 131     }
 132 }
 133
 134 # set a reasonable (and very safe) default for fastgetcwd, in case it
 135 # isn't redefined later (20001212 rspier)
 136 *fastgetcwd = \&cwd;
 137
 138 # By Brandon S. Allbery
 139 #
 140 # Usage: $cwd = getcwd();
 141
 142 sub getcwd
 143 {
 144     abs_path('.');
 145 }
 146
 147 # Keeps track of current working directory in PWD environment var
 148 # Usage:
 149 #       use Cwd 'chdir';
 150 #       chdir $newdir;
 151
 152 my $chdir_init = 0;
 153
 154 sub chdir_init {
 155     if ($ENV{'PWD'} and $^O ne 'os2' and $^O ne 'dos' and $^O ne 'MSWin32') {
 156         my($dd,$di) = stat('.');
 157         my($pd,$pi) = stat($ENV{'PWD'});
 158         if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
 159             $ENV{'PWD'} = cwd();
 160         }
 161     }
 162     else {
 163         my $wd = cwd();
 164         $wd = Win32::GetFullPathName($wd) if $^O eq 'MSWin32';
 165         $ENV{'PWD'} = $wd;
 166     }
 167     # Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
 168     if ($^O ne 'MSWin32' and $ENV{'PWD'} =~ m|(/[^/]+(/[^/]+/[^/]+))(.*)|s) {
 169         my($pd,$pi) = stat($2);
 170         my($dd,$di) = stat($1);
 171         if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
 172             $ENV{'PWD'}="$2$3";
 173         }
 174     }
 175     $chdir_init = 1;
 176 }
 177
 178 sub chdir {
 179     my $newdir = @_ ? shift : '';       # allow for no arg (chdir to HOME dir)
 180     $newdir =~ s|///*|/|g unless $^O eq 'MSWin32';
 181     chdir_init() unless $chdir_init;
 182     my $newpwd;
 183     if ($^O eq 'MSWin32') {
 184         # get the full path name *before* the chdir()
 185         $newpwd = Win32::GetFullPathName($newdir);
 186     }
 187
 188     return 0 unless CORE::chdir $newdir;
 189
 190     if ($^O eq 'VMS') {
 191         return $ENV{'PWD'} = $ENV{'DEFAULT'}
 192     }
 193     elsif ($^O eq 'MacOS') {
 194         return $ENV{'PWD'} = cwd();
 195     }
 196     elsif ($^O eq 'MSWin32') {
 197         $ENV{'PWD'} = $newpwd;
 198         return 1;
 199     }
 200
 201     if ($newdir =~ m#^/#s) {
 202         $ENV{'PWD'} = $newdir;
 203     } else {
 204         my @curdir = split(m#/#,$ENV{'PWD'});
 205         @curdir = ('') unless @curdir;
 206         my $component;
 207         foreach $component (split(m#/#, $newdir)) {
 208             next if $component eq '.';
 209             pop(@curdir),next if $component eq '..';
 210             push(@curdir,$component);
 211         }
 212         $ENV{'PWD'} = join('/',@curdir) || '/';
 213     }
 214     1;
 215 }
 216
 217 # added function alias for those of us more
 218 # used to the libc function.  --tchrist 27-Jan-00
 219 *realpath = \&abs_path;
 220
 221 sub fast_abs_path {
 222     my $cwd = getcwd();
 223     my $path = @_ ? shift : '.';
 224     CORE::chdir($path) || croak "Cannot chdir to $path:$!";
 225     my $realpath = getcwd();
 226     CORE::chdir($cwd)  || croak "Cannot chdir back to $cwd:$!";
 227     $realpath;
 228 }
 229
 230 # added function alias to follow principle of least surprise
 231 # based on previous aliasing.  --tchrist 27-Jan-00
 232 *fast_realpath = \&fast_abs_path;
 233
 234
 235 # --- PORTING SECTION ---
 236
 237 # VMS: $ENV{'DEFAULT'} points to default directory at all times
 238 # 06-Mar-1996  Charles Bailey  bailey@newman.upenn.edu
 239 # Note: Use of Cwd::chdir() causes the logical name PWD to be defined
 240 #   in the process logical name table as the default device and directory
 241 #   seen by Perl. This may not be the same as the default device
 242 #   and directory seen by DCL after Perl exits, since the effects
 243 #   the CRTL chdir() function persist only until Perl exits.
 244
 245 sub _vms_cwd {
 246     return $ENV{'DEFAULT'};
 247 }
 248
 249 sub _vms_abs_path {
 250     return $ENV{'DEFAULT'} unless @_;
 251     my $path = VMS::Filespec::pathify($_[0]);
 252     croak("Invalid path name $_[0]") unless defined $path;
 253     return VMS::Filespec::rmsexpand($path);
 254 }
 255
 256 sub _os2_cwd {
 257     $ENV{'PWD'} = `cmd /c cd`;
 258     chop $ENV{'PWD'};
 259     $ENV{'PWD'} =~ s:\\:/:g ;
 260     return $ENV{'PWD'};
 261 }
 262
 263 sub _win32_cwd {
 264     $ENV{'PWD'} = Win32::GetCwd();
 265     $ENV{'PWD'} =~ s:\\:/:g ;
 266     return $ENV{'PWD'};
 267 }
 268
 269 *_NT_cwd = \&_win32_cwd if (!defined &_NT_cwd &&
 270                             defined &Win32::GetCwd);
 271
 272 *_NT_cwd = \&_os2_cwd unless defined &_NT_cwd;
 273
 274 sub _dos_cwd {
 275     if (!defined &Dos::GetCwd) {
 276         $ENV{'PWD'} = `command /c cd`;
 277         chop $ENV{'PWD'};
 278         $ENV{'PWD'} =~ s:\\:/:g ;
 279     } else {
 280         $ENV{'PWD'} = Dos::GetCwd();
 281     }
 282     return $ENV{'PWD'};
 283 }
 284
 285 sub _qnx_cwd {
 286     $ENV{'PWD'} = `/usr/bin/fullpath -t`;
 287     chop $ENV{'PWD'};
 288     return $ENV{'PWD'};
 289 }
 290
 291 sub _qnx_abs_path {
 292     my $path = @_ ? shift : '.';
 293     my $realpath=`/usr/bin/fullpath -t $path`;
 294     chop $realpath;
 295     return $realpath;
 296 }
 297
 298 sub _epoc_cwd {
 299     $ENV{'PWD'} = EPOC::getcwd();
 300     return $ENV{'PWD'};
 301 }
 302
 303 {
 304     no warnings;        # assignments trigger 'subroutine redefined' warning
 305
 306     if ($^O eq 'VMS') {
 307         *cwd            = \&_vms_cwd;
 308         *getcwd         = \&_vms_cwd;
 309         *fastcwd        = \&_vms_cwd;
 310         *fastgetcwd     = \&_vms_cwd;
 311         *abs_path       = \&_vms_abs_path;
 312         *fast_abs_path  = \&_vms_abs_path;
 313     }
 314     elsif ($^O eq 'NT' or $^O eq 'MSWin32') {
 315         # We assume that &_NT_cwd is defined as an XSUB or in the core.
 316         *cwd            = \&_NT_cwd;
 317         *getcwd         = \&_NT_cwd;
 318         *fastcwd        = \&_NT_cwd;
 319         *fastgetcwd     = \&_NT_cwd;
 320         *abs_path       = \&fast_abs_path;
 321     }
 322     elsif ($^O eq 'os2') {
 323         # sys_cwd may keep the builtin command
 324         *cwd            = defined &sys_cwd ? \&sys_cwd : \&_os2_cwd;
 325         *getcwd         = \&cwd;
 326         *fastgetcwd     = \&cwd;
 327         *fastcwd        = \&cwd;
 328         *abs_path       = \&fast_abs_path;
 329     }
 330     elsif ($^O eq 'dos') {
 331         *cwd            = \&_dos_cwd;
 332         *getcwd         = \&_dos_cwd;
 333         *fastgetcwd     = \&_dos_cwd;
 334         *fastcwd        = \&_dos_cwd;
 335         *abs_path       = \&fast_abs_path;
 336     }
 337     elsif ($^O eq 'qnx') {
 338         *cwd            = \&_qnx_cwd;
 339         *getcwd         = \&_qnx_cwd;
 340         *fastgetcwd     = \&_qnx_cwd;
 341         *fastcwd        = \&_qnx_cwd;
 342         *abs_path       = \&_qnx_abs_path;
 343         *fast_abs_path  = \&_qnx_abs_path;
 344     }
 345     elsif ($^O eq 'cygwin') {
 346         *getcwd = \&cwd;
 347         *fastgetcwd     = \&cwd;
 348         *fastcwd        = \&cwd;
 349         *abs_path       = \&fast_abs_path;
 350     }
 351     elsif ($^O eq 'epoc') {
 352         *cwd            = \&_epoc_cwd;
 353         *getcwd         = \&_epoc_cwd;
 354         *fastgetcwd     = \&_epoc_cwd;
 355         *fastcwd        = \&_epoc_cwd;
 356         *abs_path       = \&fast_abs_path;
 357     }
 358     elsif ($^O eq 'MacOS') {
 359         *getcwd     = \&cwd;
 360         *fastgetcwd = \&cwd;
 361         *fastcwd    = \&cwd;
 362         *abs_path   = \&fast_abs_path;
 363     }
 364 }
 365
 366 # package main; eval join('',<DATA>) || die $@; # quick test
 367
 368 1;
 369
 370 __END__
 371 BEGIN { import Cwd qw(:DEFAULT chdir); }
 372 print join("\n", cwd, getcwd, fastcwd, "");
 373 chdir('..');
 374 print join("\n", cwd, getcwd, fastcwd, "");
 375 print "$ENV{PWD}\n";