lib/Cwd.pm

   1 package Cwd;
   2 require 5.000;
   3
   4 =head1 NAME
   5
   6 Cwd - get pathname of current working directory
   7
   8 =head1 SYNOPSIS
   9
  10     use Cwd;
  11     $dir = cwd;
  12
  13     use Cwd;
  14     $dir = getcwd;
  15
  16     use Cwd;
  17     $dir = fastcwd;
  18
  19     use Cwd;
  20     $dir = fastgetcwd;
  21
  22     use Cwd 'chdir';
  23     chdir "/tmp";
  24     print $ENV{'PWD'};
  25
  26     use Cwd 'abs_path';     # aka realpath()
  27     print abs_path($ENV{'PWD'});
  28
  29     use Cwd 'fast_abs_path';
  30     print fast_abs_path($ENV{'PWD'});
  31
  32 =head1 DESCRIPTION
  33
  34 This module provides functions for determining the pathname of the
  35 current working directory.  By default, it exports the functions
  36 cwd(), getcwd(), fastcwd(), and fastgetcwd() into the caller's
  37 namespace.  Each of these functions are called without arguments and
  38 return the absolute path of the current working directory.  It is
  39 recommended that cwd (or another *cwd() function) be used in I<all>
  40 code to ensure portability.
  41
  42 The cwd() is the most natural and safe form for the current
  43 architecture. For most systems it is identical to `pwd` (but without
  44 the trailing line terminator).
  45
  46 The getcwd() function re-implements the getcwd(3) (or getwd(3)) functions
  47 in Perl.
  48
  49 The fastcwd() function looks the same as getcwd(), but runs faster.
  50 It's also more dangerous because it might conceivably chdir() you out
  51 of a directory that it can't chdir() you back into.  If fastcwd
  52 encounters a problem it will return undef but will probably leave you
  53 in a different directory.  For a measure of extra security, if
  54 everything appears to have worked, the fastcwd() function will check
  55 that it leaves you in the same directory that it started in. If it has
  56 changed it will C<die> with the message "Unstable directory path,
  57 current directory changed unexpectedly". That should never happen.
  58
  59 The fastgetcwd() function is provided as a synonym for cwd().
  60
  61 The abs_path() function takes a single argument and returns the
  62 absolute pathname for that argument.  It uses the same algorithm as
  63 getcwd().  (Actually, getcwd() is abs_path("."))  Symbolic links and
  64 relative-path components ("." and "..") are resolved to return the
  65 canonical pathname, just like realpath(3).  This function is also
  66 callable as realpath().
  67
  68 The fast_abs_path() function looks the same as abs_path() but runs
  69 faster and, like fastcwd(), is more dangerous.
  70
  71 If you ask to override your chdir() built-in function, then your PWD
  72 environment variable will be kept up to date.  (See
  73 L<perlsub/Overriding Builtin Functions>.) Note that it will only be
  74 kept up to date if all packages which use chdir import it from Cwd.
  75
  76 =cut
  77
  78 use strict;
  79
  80 use Carp;
  81
  82 our $VERSION = '2.04';
  83
  84 use base qw/ Exporter /;
  85 our @EXPORT = qw(cwd getcwd fastcwd fastgetcwd);
  86 our @EXPORT_OK = qw(chdir abs_path fast_abs_path realpath fast_realpath);
  87
  88 # Indicates if the XS portion has been loaded or not
  89 my $Booted = 0;
  90
  91 # The 'natural and safe form' for UNIX (pwd may be setuid root)
  92
  93 sub _backtick_pwd {
  94     my $cwd = `pwd`;
  95     # `pwd` may fail e.g. if the disk is full
  96     chomp($cwd) if defined $cwd;
  97     $cwd;
  98 }
  99
 100 # Since some ports may predefine cwd internally (e.g., NT)
 101 # we take care not to override an existing definition for cwd().
 102
 103 unless(defined &cwd) {
 104     # The pwd command is not available in some chroot(2)'ed environments
 105     if($^O eq 'MacOS' || grep { -x "$_/pwd" } split(':', $ENV{PATH})) {
 106         *cwd = \&_backtick_pwd;
 107     }
 108     else {
 109         *cwd = \&getcwd;
 110     }
 111 }
 112
 113 # set a reasonable (and very safe) default for fastgetcwd, in case it
 114 # isn't redefined later (20001212 rspier)
 115 *fastgetcwd = \&cwd;
 116
 117 # By Brandon S. Allbery
 118 #
 119 # Usage: $cwd = getcwd();
 120
 121 sub getcwd
 122 {
 123     abs_path('.');
 124 }
 125
 126 # Now a callout to an XSUB.  We have to delay booting of the XSUB
 127 # until the first time fastcwd is called since Cwd::cwd is needed in the
 128 # building of perl when dynamic loading may be unavailable
 129 sub fastcwd {
 130     unless ($Booted) {
 131         require XSLoader;
 132         XSLoader::load("Cwd");
 133         ++$Booted;
 134     }
 135     return &Cwd::_fastcwd;
 136 }
 137
 138
 139 # Keeps track of current working directory in PWD environment var
 140 # Usage:
 141 #       use Cwd 'chdir';
 142 #       chdir $newdir;
 143
 144 my $chdir_init = 0;
 145
 146 sub chdir_init {
 147     if ($ENV{'PWD'} and $^O ne 'os2' and $^O ne 'dos' and $^O ne 'MSWin32') {
 148         my($dd,$di) = stat('.');
 149         my($pd,$pi) = stat($ENV{'PWD'});
 150         if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
 151             $ENV{'PWD'} = cwd();
 152         }
 153     }
 154     else {
 155         my $wd = cwd();
 156         $wd = Win32::GetFullPathName($wd) if $^O eq 'MSWin32';
 157         $ENV{'PWD'} = $wd;
 158     }
 159     # Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
 160     if ($^O ne 'MSWin32' and $ENV{'PWD'} =~ m|(/[^/]+(/[^/]+/[^/]+))(.*)|s) {
 161         my($pd,$pi) = stat($2);
 162         my($dd,$di) = stat($1);
 163         if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
 164             $ENV{'PWD'}="$2$3";
 165         }
 166     }
 167     $chdir_init = 1;
 168 }
 169
 170 sub chdir {
 171     my $newdir = @_ ? shift : '';       # allow for no arg (chdir to HOME dir)
 172     $newdir =~ s|///*|/|g unless $^O eq 'MSWin32';
 173     chdir_init() unless $chdir_init;
 174     my $newpwd;
 175     if ($^O eq 'MSWin32') {
 176         # get the full path name *before* the chdir()
 177         $newpwd = Win32::GetFullPathName($newdir);
 178     }
 179
 180     return 0 unless CORE::chdir $newdir;
 181
 182     if ($^O eq 'VMS') {
 183         return $ENV{'PWD'} = $ENV{'DEFAULT'}
 184     }
 185     elsif ($^O eq 'MacOS') {
 186         return $ENV{'PWD'} = cwd();
 187     }
 188     elsif ($^O eq 'MSWin32') {
 189         $ENV{'PWD'} = $newpwd;
 190         return 1;
 191     }
 192
 193     if ($newdir =~ m#^/#s) {
 194         $ENV{'PWD'} = $newdir;
 195     } else {
 196         my @curdir = split(m#/#,$ENV{'PWD'});
 197         @curdir = ('') unless @curdir;
 198         my $component;
 199         foreach $component (split(m#/#, $newdir)) {
 200             next if $component eq '.';
 201             pop(@curdir),next if $component eq '..';
 202             push(@curdir,$component);
 203         }
 204         $ENV{'PWD'} = join('/',@curdir) || '/';
 205     }
 206     1;
 207 }
 208
 209 # Now a callout to an XSUB
 210 sub abs_path
 211 {
 212     unless ($Booted) {
 213         require XSLoader;
 214         XSLoader::load("Cwd");
 215         ++$Booted;
 216     }
 217     return &Cwd::_abs_path(@_);
 218 }
 219
 220 # added function alias for those of us more
 221 # used to the libc function.  --tchrist 27-Jan-00
 222 *realpath = \&abs_path;
 223
 224 sub fast_abs_path {
 225     my $cwd = getcwd();
 226     my $path = @_ ? shift : '.';
 227     CORE::chdir($path) || croak "Cannot chdir to $path:$!";
 228     my $realpath = getcwd();
 229     CORE::chdir($cwd)  || croak "Cannot chdir back to $cwd:$!";
 230     $realpath;
 231 }
 232
 233 # added function alias to follow principle of least surprise
 234 # based on previous aliasing.  --tchrist 27-Jan-00
 235 *fast_realpath = \&fast_abs_path;
 236
 237
 238 # --- PORTING SECTION ---
 239
 240 # VMS: $ENV{'DEFAULT'} points to default directory at all times
 241 # 06-Mar-1996  Charles Bailey  bailey@newman.upenn.edu
 242 # Note: Use of Cwd::chdir() causes the logical name PWD to be defined
 243 #   in the process logical name table as the default device and directory
 244 #   seen by Perl. This may not be the same as the default device
 245 #   and directory seen by DCL after Perl exits, since the effects
 246 #   the CRTL chdir() function persist only until Perl exits.
 247
 248 sub _vms_cwd {
 249     return $ENV{'DEFAULT'};
 250 }
 251
 252 sub _vms_abs_path {
 253     return $ENV{'DEFAULT'} unless @_;
 254     my $path = VMS::Filespec::pathify($_[0]);
 255     croak("Invalid path name $_[0]") unless defined $path;
 256     return VMS::Filespec::rmsexpand($path);
 257 }
 258
 259 sub _os2_cwd {
 260     $ENV{'PWD'} = `cmd /c cd`;
 261     chop $ENV{'PWD'};
 262     $ENV{'PWD'} =~ s:\\:/:g ;
 263     return $ENV{'PWD'};
 264 }
 265
 266 sub _win32_cwd {
 267     $ENV{'PWD'} = Win32::GetCwd();
 268     $ENV{'PWD'} =~ s:\\:/:g ;
 269     return $ENV{'PWD'};
 270 }
 271
 272 *_NT_cwd = \&_win32_cwd if (!defined &_NT_cwd &&
 273                             defined &Win32::GetCwd);
 274
 275 *_NT_cwd = \&_os2_cwd unless defined &_NT_cwd;
 276
 277 sub _dos_cwd {
 278     if (!defined &Dos::GetCwd) {
 279         $ENV{'PWD'} = `command /c cd`;
 280         chop $ENV{'PWD'};
 281         $ENV{'PWD'} =~ s:\\:/:g ;
 282     } else {
 283         $ENV{'PWD'} = Dos::GetCwd();
 284     }
 285     return $ENV{'PWD'};
 286 }
 287
 288 sub _qnx_cwd {
 289     $ENV{'PWD'} = `/usr/bin/fullpath -t`;
 290     chop $ENV{'PWD'};
 291     return $ENV{'PWD'};
 292 }
 293
 294 sub _qnx_abs_path {
 295     my $path = @_ ? shift : '.';
 296     my $realpath=`/usr/bin/fullpath -t $path`;
 297     chop $realpath;
 298     return $realpath;
 299 }
 300
 301 sub _epoc_cwd {
 302     $ENV{'PWD'} = EPOC::getcwd();
 303     return $ENV{'PWD'};
 304 }
 305
 306 {
 307     no warnings;        # assignments trigger 'subroutine redefined' warning
 308
 309     if ($^O eq 'VMS') {
 310         *cwd            = \&_vms_cwd;
 311         *getcwd         = \&_vms_cwd;
 312         *fastcwd        = \&_vms_cwd;
 313         *fastgetcwd     = \&_vms_cwd;
 314         *abs_path       = \&_vms_abs_path;
 315         *fast_abs_path  = \&_vms_abs_path;
 316     }
 317     elsif ($^O eq 'NT' or $^O eq 'MSWin32') {
 318         # We assume that &_NT_cwd is defined as an XSUB or in the core.
 319         *cwd            = \&_NT_cwd;
 320         *getcwd         = \&_NT_cwd;
 321         *fastcwd        = \&_NT_cwd;
 322         *fastgetcwd     = \&_NT_cwd;
 323         *abs_path       = \&fast_abs_path;
 324     }
 325     elsif ($^O eq 'os2') {
 326         # sys_cwd may keep the builtin command
 327         *cwd            = defined &sys_cwd ? \&sys_cwd : \&_os2_cwd;
 328         *getcwd         = \&cwd;
 329         *fastgetcwd     = \&cwd;
 330         *fastcwd        = \&cwd;
 331         *abs_path       = \&fast_abs_path;
 332     }
 333     elsif ($^O eq 'dos') {
 334         *cwd            = \&_dos_cwd;
 335         *getcwd         = \&_dos_cwd;
 336         *fastgetcwd     = \&_dos_cwd;
 337         *fastcwd        = \&_dos_cwd;
 338         *abs_path       = \&fast_abs_path;
 339     }
 340     elsif ($^O eq 'qnx') {
 341         *cwd            = \&_qnx_cwd;
 342         *getcwd         = \&_qnx_cwd;
 343         *fastgetcwd     = \&_qnx_cwd;
 344         *fastcwd        = \&_qnx_cwd;
 345         *abs_path       = \&_qnx_abs_path;
 346         *fast_abs_path  = \&_qnx_abs_path;
 347     }
 348     elsif ($^O eq 'cygwin') {
 349         *getcwd = \&cwd;
 350         *fastgetcwd     = \&cwd;
 351         *fastcwd        = \&cwd;
 352         *abs_path       = \&fast_abs_path;
 353     }
 354     elsif ($^O eq 'epoc') {
 355         *cwd            = \&_epoc_cwd;
 356         *getcwd         = \&_epoc_cwd;
 357         *fastgetcwd     = \&_epoc_cwd;
 358         *fastcwd        = \&_epoc_cwd;
 359         *abs_path       = \&fast_abs_path;
 360     }
 361     elsif ($^O eq 'MacOS') {
 362         *getcwd     = \&cwd;
 363         *fastgetcwd = \&cwd;
 364         *fastcwd    = \&cwd;
 365         *abs_path   = \&fast_abs_path;
 366     }
 367 }
 368
 369 # package main; eval join('',<DATA>) || die $@; # quick test
 370
 371 1;
 372
 373 __END__
 374 BEGIN { import Cwd qw(:DEFAULT chdir); }
 375 print join("\n", cwd, getcwd, fastcwd, "");
 376 chdir('..');
 377 print join("\n", cwd, getcwd, fastcwd, "");
 378 print "$ENV{PWD}\n";