lib/Cwd.pm

   1 package Cwd;
   2 require 5.000;
   3
   4 =head1 NAME
   5
   6 getcwd - get pathname of current working directory
   7
   8 =head1 SYNOPSIS
   9
  10     use Cwd;
  11     $dir = cwd;
  12
  13     use Cwd;
  14     $dir = getcwd;
  15
  16     use Cwd;
  17     $dir = fastgetcwd;
  18
  19     use Cwd 'chdir';
  20     chdir "/tmp";
  21     print $ENV{'PWD'};
  22
  23     use Cwd 'abs_path';     # aka realpath()
  24     print abs_path($ENV{'PWD'});
  25
  26     use Cwd 'fast_abs_path';
  27     print fast_abs_path($ENV{'PWD'});
  28
  29 =head1 DESCRIPTION
  30
  31 The getcwd() function re-implements the getcwd(3) (or getwd(3)) functions
  32 in Perl.
  33
  34 The abs_path() function takes a single argument and returns the
  35 absolute pathname for that argument.  It uses the same algorithm
  36 as getcwd().  (Actually, getcwd() is abs_path("."))  Symbolic links
  37 and relative-path components ("." and "..") are resolved to return
  38 the canonical pathname, just like realpath(3).  Also callable as
  39 realpath().
  40
  41 The fastcwd() function looks the same as getcwd(), but runs faster.
  42 It's also more dangerous because it might conceivably chdir() you out
  43 of a directory that it can't chdir() you back into.  If fastcwd
  44 encounters a problem it will return undef but will probably leave you
  45 in a different directory.  For a measure of extra security, if
  46 everything appears to have worked, the fastcwd() function will check
  47 that it leaves you in the same directory that it started in. If it has
  48 changed it will C<die> with the message "Unstable directory path,
  49 current directory changed unexpectedly". That should never happen.
  50
  51 The fast_abs_path() function looks the same as abs_path(), but runs faster.
  52 And like fastcwd() is more dangerous.
  53
  54 The cwd() function looks the same as getcwd and fastgetcwd but is
  55 implemented using the most natural and safe form for the current
  56 architecture. For most systems it is identical to `pwd` (but without
  57 the trailing line terminator).
  58
  59 It is recommended that cwd (or another *cwd() function) is used in
  60 I<all> code to ensure portability.
  61
  62 If you ask to override your chdir() built-in function, then your PWD
  63 environment variable will be kept up to date.  (See
  64 L<perlsub/Overriding Builtin Functions>.) Note that it will only be
  65 kept up to date if all packages which use chdir import it from Cwd.
  66
  67 =cut
  68
  69 use strict;
  70
  71 use Carp;
  72
  73 our $VERSION = '2.04';
  74
  75 use base qw/ Exporter /;
  76 our @EXPORT = qw(cwd getcwd fastcwd fastgetcwd);
  77 our @EXPORT_OK = qw(chdir abs_path fast_abs_path realpath fast_realpath);
  78
  79
  80 # The 'natural and safe form' for UNIX (pwd may be setuid root)
  81
  82 sub _backtick_pwd {
  83     my $cwd = `pwd`;
  84     # `pwd` may fail e.g. if the disk is full
  85     chomp($cwd) if defined $cwd;
  86     $cwd;
  87 }
  88
  89 # Since some ports may predefine cwd internally (e.g., NT)
  90 # we take care not to override an existing definition for cwd().
  91
  92 unless(defined &cwd) {
  93     # The pwd command is not available in some chroot(2)'ed environments
  94     if(grep { -x "$_/pwd" } split(':', $ENV{PATH})) {
  95         *cwd = \&_backtick_pwd;
  96     }
  97     else {
  98         *cwd = \&getcwd;
  99     }
 100 }
 101
 102 # set a reasonable (and very safe) default for fastgetcwd, in case it
 103 # isn't redefined later (20001212 rspier)
 104 *fastgetcwd = \&cwd;
 105
 106 # By Brandon S. Allbery
 107 #
 108 # Usage: $cwd = getcwd();
 109
 110 sub getcwd
 111 {
 112     abs_path('.');
 113 }
 114
 115 # By John Bazik
 116 #
 117 # Usage: $cwd = &fastcwd;
 118 #
 119 # This is a faster version of getcwd.  It's also more dangerous because
 120 # you might chdir out of a directory that you can't chdir back into.
 121
 122 sub fastcwd {
 123     my($odev, $oino, $cdev, $cino, $tdev, $tino);
 124     my(@path, $path);
 125     local(*DIR);
 126
 127     my($orig_cdev, $orig_cino) = stat('.');
 128     ($cdev, $cino) = ($orig_cdev, $orig_cino);
 129     for (;;) {
 130         my $direntry;
 131         ($odev, $oino) = ($cdev, $cino);
 132         CORE::chdir('..') || return undef;
 133         ($cdev, $cino) = stat('.');
 134         last if $odev == $cdev && $oino == $cino;
 135         opendir(DIR, '.') || return undef;
 136         for (;;) {
 137             $direntry = readdir(DIR);
 138             last unless defined $direntry;
 139             next if $direntry eq '.';
 140             next if $direntry eq '..';
 141
 142             ($tdev, $tino) = lstat($direntry);
 143             last unless $tdev != $odev || $tino != $oino;
 144         }
 145         closedir(DIR);
 146         return undef unless defined $direntry; # should never happen
 147         unshift(@path, $direntry);
 148     }
 149     $path = '/' . join('/', @path);
 150     if ($^O eq 'apollo') { $path = "/".$path; }
 151     # At this point $path may be tainted (if tainting) and chdir would fail.
 152     # To be more useful we untaint it then check that we landed where we started.
 153     $path = $1 if $path =~ /^(.*)\z/s;  # untaint
 154     CORE::chdir($path) || return undef;
 155     ($cdev, $cino) = stat('.');
 156     die "Unstable directory path, current directory changed unexpectedly"
 157         if $cdev != $orig_cdev || $cino != $orig_cino;
 158     $path;
 159 }
 160
 161
 162 # Keeps track of current working directory in PWD environment var
 163 # Usage:
 164 #       use Cwd 'chdir';
 165 #       chdir $newdir;
 166
 167 my $chdir_init = 0;
 168
 169 sub chdir_init {
 170     if ($ENV{'PWD'} and $^O ne 'os2' and $^O ne 'dos' and $^O ne 'MSWin32') {
 171         my($dd,$di) = stat('.');
 172         my($pd,$pi) = stat($ENV{'PWD'});
 173         if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
 174             $ENV{'PWD'} = cwd();
 175         }
 176     }
 177     else {
 178         my $wd = cwd();
 179         $wd = Win32::GetFullPathName($wd) if $^O eq 'MSWin32';
 180         $ENV{'PWD'} = $wd;
 181     }
 182     # Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
 183     if ($^O ne 'MSWin32' and $ENV{'PWD'} =~ m|(/[^/]+(/[^/]+/[^/]+))(.*)|s) {
 184         my($pd,$pi) = stat($2);
 185         my($dd,$di) = stat($1);
 186         if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
 187             $ENV{'PWD'}="$2$3";
 188         }
 189     }
 190     $chdir_init = 1;
 191 }
 192
 193 sub chdir {
 194     my $newdir = @_ ? shift : '';       # allow for no arg (chdir to HOME dir)
 195     $newdir =~ s|///*|/|g unless $^O eq 'MSWin32';
 196     chdir_init() unless $chdir_init;
 197     return 0 unless CORE::chdir $newdir;
 198     if ($^O eq 'VMS') {
 199         return $ENV{'PWD'} = $ENV{'DEFAULT'}
 200     }
 201     elsif ($^O eq 'MSWin32') {
 202         $ENV{'PWD'} = Win32::GetFullPathName($newdir);
 203         return 1;
 204     }
 205
 206     if ($newdir =~ m#^/#s) {
 207         $ENV{'PWD'} = $newdir;
 208     } else {
 209         my @curdir = split(m#/#,$ENV{'PWD'});
 210         @curdir = ('') unless @curdir;
 211         my $component;
 212         foreach $component (split(m#/#, $newdir)) {
 213             next if $component eq '.';
 214             pop(@curdir),next if $component eq '..';
 215             push(@curdir,$component);
 216         }
 217         $ENV{'PWD'} = join('/',@curdir) || '/';
 218     }
 219     1;
 220 }
 221
 222 # Taken from Cwd.pm It is really getcwd with an optional
 223 # parameter instead of '.'
 224 #
 225
 226 sub abs_path
 227 {
 228     my $start = @_ ? shift : '.';
 229     my($dotdots, $cwd, @pst, @cst, $dir, @tst);
 230
 231     unless (@cst = stat( $start ))
 232     {
 233         carp "stat($start): $!";
 234         return '';
 235     }
 236     $cwd = '';
 237     $dotdots = $start;
 238     do
 239     {
 240         $dotdots .= '/..';
 241         @pst = @cst;
 242         unless (opendir(PARENT, $dotdots))
 243         {
 244             carp "opendir($dotdots): $!";
 245             return '';
 246         }
 247         unless (@cst = stat($dotdots))
 248         {
 249             carp "stat($dotdots): $!";
 250             closedir(PARENT);
 251             return '';
 252         }
 253         if ($pst[0] == $cst[0] && $pst[1] == $cst[1])
 254         {
 255             $dir = undef;
 256         }
 257         else
 258         {
 259             do
 260             {
 261                 unless (defined ($dir = readdir(PARENT)))
 262                 {
 263                     carp "readdir($dotdots): $!";
 264                     closedir(PARENT);
 265                     return '';
 266                 }
 267                 $tst[0] = $pst[0]+1 unless (@tst = lstat("$dotdots/$dir"))
 268             }
 269             while ($dir eq '.' || $dir eq '..' || $tst[0] != $pst[0] ||
 270                    $tst[1] != $pst[1]);
 271         }
 272         $cwd = (defined $dir ? "$dir" : "" ) . "/$cwd" ;
 273         closedir(PARENT);
 274     } while (defined $dir);
 275     chop($cwd) unless $cwd eq '/'; # drop the trailing /
 276     $cwd;
 277 }
 278
 279 # added function alias for those of us more
 280 # used to the libc function.  --tchrist 27-Jan-00
 281 *realpath = \&abs_path;
 282
 283 sub fast_abs_path {
 284     my $cwd = getcwd();
 285     my $path = @_ ? shift : '.';
 286     CORE::chdir($path) || croak "Cannot chdir to $path:$!";
 287     my $realpath = getcwd();
 288     CORE::chdir($cwd)  || croak "Cannot chdir back to $cwd:$!";
 289     $realpath;
 290 }
 291
 292 # added function alias to follow principle of least surprise
 293 # based on previous aliasing.  --tchrist 27-Jan-00
 294 *fast_realpath = \&fast_abs_path;
 295
 296
 297 # --- PORTING SECTION ---
 298
 299 # VMS: $ENV{'DEFAULT'} points to default directory at all times
 300 # 06-Mar-1996  Charles Bailey  bailey@newman.upenn.edu
 301 # Note: Use of Cwd::chdir() causes the logical name PWD to be defined
 302 #   in the process logical name table as the default device and directory
 303 #   seen by Perl. This may not be the same as the default device
 304 #   and directory seen by DCL after Perl exits, since the effects
 305 #   the CRTL chdir() function persist only until Perl exits.
 306
 307 sub _vms_cwd {
 308     return $ENV{'DEFAULT'};
 309 }
 310
 311 sub _vms_abs_path {
 312     return $ENV{'DEFAULT'} unless @_;
 313     my $path = VMS::Filespec::pathify($_[0]);
 314     croak("Invalid path name $_[0]") unless defined $path;
 315     return VMS::Filespec::rmsexpand($path);
 316 }
 317
 318 sub _os2_cwd {
 319     $ENV{'PWD'} = `cmd /c cd`;
 320     chop $ENV{'PWD'};
 321     $ENV{'PWD'} =~ s:\\:/:g ;
 322     return $ENV{'PWD'};
 323 }
 324
 325 sub _win32_cwd {
 326     $ENV{'PWD'} = Win32::GetCwd();
 327     $ENV{'PWD'} =~ s:\\:/:g ;
 328     return $ENV{'PWD'};
 329 }
 330
 331 *_NT_cwd = \&_win32_cwd if (!defined &_NT_cwd &&
 332                             defined &Win32::GetCwd);
 333
 334 *_NT_cwd = \&_os2_cwd unless defined &_NT_cwd;
 335
 336 sub _dos_cwd {
 337     if (!defined &Dos::GetCwd) {
 338         $ENV{'PWD'} = `command /c cd`;
 339         chop $ENV{'PWD'};
 340         $ENV{'PWD'} =~ s:\\:/:g ;
 341     } else {
 342         $ENV{'PWD'} = Dos::GetCwd();
 343     }
 344     return $ENV{'PWD'};
 345 }
 346
 347 sub _qnx_cwd {
 348     $ENV{'PWD'} = `/usr/bin/fullpath -t`;
 349     chop $ENV{'PWD'};
 350     return $ENV{'PWD'};
 351 }
 352
 353 sub _qnx_abs_path {
 354     my $path = @_ ? shift : '.';
 355     my $realpath=`/usr/bin/fullpath -t $path`;
 356     chop $realpath;
 357     return $realpath;
 358 }
 359
 360 sub _epoc_cwd {
 361     $ENV{'PWD'} = EPOC::getcwd();
 362     return $ENV{'PWD'};
 363 }
 364
 365 {
 366     no warnings;        # assignments trigger 'subroutine redefined' warning
 367
 368     if ($^O eq 'VMS') {
 369         *cwd            = \&_vms_cwd;
 370         *getcwd         = \&_vms_cwd;
 371         *fastcwd        = \&_vms_cwd;
 372         *fastgetcwd     = \&_vms_cwd;
 373         *abs_path       = \&_vms_abs_path;
 374         *fast_abs_path  = \&_vms_abs_path;
 375     }
 376     elsif ($^O eq 'NT' or $^O eq 'MSWin32') {
 377         # We assume that &_NT_cwd is defined as an XSUB or in the core.
 378         *cwd            = \&_NT_cwd;
 379         *getcwd         = \&_NT_cwd;
 380         *fastcwd        = \&_NT_cwd;
 381         *fastgetcwd     = \&_NT_cwd;
 382         *abs_path       = \&fast_abs_path;
 383     }
 384     elsif ($^O eq 'os2') {
 385         # sys_cwd may keep the builtin command
 386         *cwd            = defined &sys_cwd ? \&sys_cwd : \&_os2_cwd;
 387         *getcwd         = \&cwd;
 388         *fastgetcwd     = \&cwd;
 389         *fastcwd        = \&cwd;
 390         *abs_path       = \&fast_abs_path;
 391     }
 392     elsif ($^O eq 'dos') {
 393         *cwd            = \&_dos_cwd;
 394         *getcwd         = \&_dos_cwd;
 395         *fastgetcwd     = \&_dos_cwd;
 396         *fastcwd        = \&_dos_cwd;
 397         *abs_path       = \&fast_abs_path;
 398     }
 399     elsif ($^O eq 'qnx') {
 400         *cwd            = \&_qnx_cwd;
 401         *getcwd         = \&_qnx_cwd;
 402         *fastgetcwd     = \&_qnx_cwd;
 403         *fastcwd        = \&_qnx_cwd;
 404         *abs_path       = \&_qnx_abs_path;
 405         *fast_abs_path  = \&_qnx_abs_path;
 406     }
 407     elsif ($^O eq 'cygwin') {
 408         *getcwd = \&cwd;
 409         *fastgetcwd     = \&cwd;
 410         *fastcwd        = \&cwd;
 411         *abs_path       = \&fast_abs_path;
 412     }
 413     elsif ($^O eq 'epoc') {
 414         *cwd            = \&_epoc_cwd;
 415         *getcwd         = \&_epoc_cwd;
 416         *fastgetcwd     = \&_epoc_cwd;
 417         *fastcwd        = \&_epoc_cwd;
 418         *abs_path       = \&fast_abs_path;
 419     }
 420 }
 421
 422 # package main; eval join('',<DATA>) || die $@; # quick test
 423
 424 1;
 425
 426 __END__
 427 BEGIN { import Cwd qw(:DEFAULT chdir); }
 428 print join("\n", cwd, getcwd, fastcwd, "");
 429 chdir('..');
 430 print join("\n", cwd, getcwd, fastcwd, "");
 431 print "$ENV{PWD}\n";