lib/Config.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require "./test.pl";
   7 }
   8
   9 plan 'no_plan';
  10
  11 use_ok('Config');
  12
  13 # Some (safe?) bets.
  14
  15 ok(keys %Config > 500, "Config has more than 500 entries");
  16
  17 ok(each %Config);
  18
  19 is($Config{PERL_REVISION}, 5, "PERL_REVISION is 5");
  20
  21 # Check that old config variable names are aliased to their new ones.
  22 my %grandfathers = ( PERL_VERSION       => 'PATCHLEVEL',
  23                      PERL_SUBVERSION    => 'SUBVERSION',
  24                      PERL_CONFIG_SH     => 'CONFIG'
  25                    );
  26 while( my($new, $old) = each %grandfathers ) {
  27     isnt($Config{$new}, undef,       "$new is defined");
  28     is($Config{$new}, $Config{$old}, "$new is aliased to $old");
  29 }
  30
  31 ok( exists $Config{cc},      "has cc");
  32
  33 ok( exists $Config{ccflags}, "has ccflags");
  34
  35 ok(!exists $Config{python},  "has no python");
  36
  37 ok( exists $Config{d_fork},  "has d_fork");
  38
  39 ok(!exists $Config{d_bork},  "has no d_bork");
  40
  41 like($Config{ivsize},     qr/^(4|8)$/, "ivsize is 4 or 8 (it is $Config{ivsize})");
  42
  43 # byteorder is virtual, but it has rules.
  44
  45 like($Config{byteorder}, qr/^(1234|4321|12345678|87654321)$/, "byteorder is 1234 or 4321 or 12345678 or 87654321 (it is $Config{byteorder})");
  46
  47 is(length $Config{byteorder}, $Config{ivsize}, "byteorder is as long as ivsize (which is $Config{ivsize})");
  48
  49 # ccflags_nolargefiles is virtual, too.
  50
  51 ok(exists $Config{ccflags_nolargefiles}, "has ccflags_nolargefiles");
  52
  53 # Utility functions.
  54
  55 {
  56     # make sure we can export what we say we can export.
  57     package Foo;
  58     my @exports = qw(myconfig config_sh config_vars config_re);
  59     Config->import(@exports);
  60     foreach my $func (@exports) {
  61         ::ok( __PACKAGE__->can($func), "$func exported" );
  62     }
  63 }
  64
  65 like(Config::myconfig(), qr/osname=\Q$Config{osname}\E/,   "myconfig");
  66 like(Config::config_sh(), qr/osname='\Q$Config{osname}\E'/, "config_sh");
  67 like(Config::config_sh(), qr/byteorder='[1-8]+'/,
  68      "config_sh has a valid byteorder");
  69 foreach my $line (Config::config_re('c.*')) {
  70   like($line,                  qr/^c.*?=.*$/,                   'config_re' );
  71 }
  72
  73 my $out = tie *STDOUT, 'FakeOut';
  74
  75 Config::config_vars('cc');      # non-regex test of essential cfg-var
  76 my $out1 = $$out;
  77 $out->clear;
  78
  79 Config::config_vars('d_bork');  # non-regex, non-existent cfg-var
  80 my $out2 = $$out;
  81 $out->clear;
  82
  83 Config::config_vars('PERL_API_.*');     # regex, tagged multi-line answer
  84 my $out3 = $$out;
  85 $out->clear;
  86
  87 Config::config_vars('PERL_API_.*:');    # regex, tagged single-line answer
  88 my $out4 = $$out;
  89 $out->clear;
  90
  91 Config::config_vars(':PERL_API_.*:');   # regex, non-tagged single-line answer
  92 my $out5 = $$out;
  93 $out->clear;
  94
  95 Config::config_vars(':PERL_API_.*');    # regex, non-tagged multi-line answer
  96 my $out6 = $$out;
  97 $out->clear;
  98
  99 Config::config_vars('PERL_API_REVISION.*:'); # regex, tagged
 100 my $out7 = $$out;
 101 $out->clear;
 102
 103 Config::config_vars(':PERL_API_REVISION.*'); # regex, non-tagged multi-line answer
 104 my $out8 = $$out;
 105 $out->clear;
 106
 107 Config::config_vars('PERL_EXPENSIVE_.*:'); # non-matching regex
 108 my $out9 = $$out;
 109 $out->clear;
 110
 111 Config::config_vars('?flags');  # bogus regex, no explicit warning !
 112 my $out10 = $$out;
 113 $out->clear;
 114
 115 untie *STDOUT;
 116
 117 like($out1, qr/^cc='\Q$Config{cc}\E';/, "found config_var cc");
 118 like($out2, qr/^d_bork='UNKNOWN';/, "config_var d_bork is UNKNOWN");
 119
 120 # test for leading, trailing colon effects
 121 is(scalar split(/;\n/, $out3), 3, "3 lines found");
 122 is(scalar split(/;\n/, $out6), 3, "3 lines found");
 123
 124 is($out4 =~ /(;\n)/s, '', "trailing colon gives 1-line response: $out4");
 125 is($out5 =~ /(;\n)/s, '', "trailing colon gives 1-line response: $out5");
 126
 127 is(scalar split(/=/, $out3), 4, "found 'tag='");
 128 is(scalar split(/=/, $out4), 4, "found 'tag='");
 129
 130 my @api;
 131
 132 my @rev = @Config{qw(PERL_API_REVISION PERL_API_VERSION PERL_API_SUBVERSION)};
 133
 134 print ("# test tagged responses, multi-line and single-line\n");
 135 foreach $api ($out3, $out4) {
 136     @api = $api =~ /PERL_API_(\w+)=(.*?)(?:;\n|\s)/mg;
 137     is($api[0], "REVISION", "REVISION tag");
 138     is($api[4], "VERSION",  "VERSION tag");
 139     is($api[2], "SUBVERSION", "SUBVERSION tag");
 140     is($api[1], "'$rev[0]'", "REVISION is $rev[0]");
 141     is($api[5], "'$rev[1]'", "VERSION is $rev[1]");
 142     is($api[3], "'$rev[2]'", "SUBVERSION is $rev[2]");
 143 }
 144
 145 print("# test non-tagged responses, multi-line and single-line\n");
 146 foreach $api ($out5, $out6) {
 147     @api = split /(?: |;\n)/, $api;
 148     is($api[0], "'$rev[0]'", "revision is $rev[0]");
 149     is($api[2], "'$rev[1]'", "version is $rev[1]");
 150     is($api[1], "'$rev[2]'", "subversion is $rev[2]");
 151 }
 152
 153 # compare to each other, the outputs for trailing, leading colon
 154 $out7 =~ s/ $//;
 155 is("$out7;\n", "PERL_API_REVISION=$out8", "got expected diffs");
 156
 157 like($out9, qr/\bnot\s+found\b/, "$out9 - perl is FREE !");
 158 like($out10, qr/\bnot\s+found\b/, "config_vars with invalid regexp");
 159
 160 # Read-only.
 161
 162 undef $@;
 163 eval { $Config{d_bork} = 'borkbork' };
 164 like($@, qr/Config is read-only/, "no STORE");
 165
 166 ok(!exists $Config{d_bork}, "still no d_bork");
 167
 168 undef $@;
 169 eval { delete $Config{d_fork} };
 170 like($@, qr/Config is read-only/, "no DELETE");
 171
 172 ok( exists $Config{d_fork}, "still d_fork");
 173
 174 undef $@;
 175 eval { %Config = () };
 176 like($@, qr/Config is read-only/, "no CLEAR");
 177
 178 ok( exists $Config{d_fork}, "still d_fork");
 179
 180 {
 181     package FakeOut;
 182
 183     sub TIEHANDLE {
 184         bless(\(my $text), $_[0]);
 185     }
 186
 187     sub clear {
 188         ${ $_[0] } = '';
 189     }
 190
 191     sub PRINT {
 192         my $self = shift;
 193         $$self .= join('', @_);
 194     }
 195 }
 196
 197 # Signal-related variables
 198 # (this is actually a regression test for Configure.)
 199
 200 is($Config{sig_num_init}  =~ tr/,/,/, $Config{sig_size}, "sig_num_init size");
 201 is($Config{sig_name_init} =~ tr/,/,/, $Config{sig_size}, "sig_name_init size");
 202
 203 # Test the troublesome virtual stuff
 204 foreach my $pain (qw(byteorder)) {
 205   # No config var is named with anything that is a regexp metachar"
 206   my @result = Config::config_re($pain);
 207   is (scalar @result, 1, "single result for config_re('$pain')");
 208   like ($result[0], qr/^$pain=(['"])$Config{$pain}\1$/, # grr '
 209                                 "which is the expected result for $pain");
 210 }