lib/Class/MOP.pm

   1
   2 package Class::MOP;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util ();
   9
  10 use Class::MOP::Class;
  11 use Class::MOP::Attribute;
  12 use Class::MOP::Method;
  13
  14 our $VERSION = '0.30';
  15
  16 ## ----------------------------------------------------------------------------
  17 ## Setting up our environment ...
  18 ## ----------------------------------------------------------------------------
  19 ## Class::MOP needs to have a few things in the global perl environment so
  20 ## that it can operate effectively. Those things are done here.
  21 ## ----------------------------------------------------------------------------
  22
  23 # ... nothing yet actually ;)
  24
  25 ## ----------------------------------------------------------------------------
  26 ## Bootstrapping
  27 ## ----------------------------------------------------------------------------
  28 ## The code below here is to bootstrap our MOP with itself. This is also
  29 ## sometimes called "tying the knot". By doing this, we make it much easier
  30 ## to extend the MOP through subclassing and such since now you can use the
  31 ## MOP itself to extend itself.
  32 ##
  33 ## Yes, I know, thats weird and insane, but it's a good thing, trust me :)
  34 ## ----------------------------------------------------------------------------
  35
  36 # We need to add in the meta-attributes here so that
  37 # any subclass of Class::MOP::* will be able to
  38 # inherit them using &construct_instance
  39
  40 ## Class::MOP::Class
  41
  42 Class::MOP::Class->meta->add_attribute(
  43     Class::MOP::Attribute->new('$:package' => (
  44         reader   => {
  45             # NOTE: we need to do this in order
  46             # for the instance meta-object to
  47             # not fall into meta-circular death
  48             'name' => sub { (shift)->{'$:package'} }
  49         },
  50         init_arg => ':package',
  51     ))
  52 );
  53
  54 Class::MOP::Class->meta->add_attribute(
  55     Class::MOP::Attribute->new('%:attributes' => (
  56         reader   => {
  57             # NOTE: we need to do this in order
  58             # for the instance meta-object to
  59             # not fall into meta-circular death
  60             'get_attribute_map' => sub { (shift)->{'%:attributes'} }
  61         },
  62         init_arg => ':attributes',
  63         default  => sub { {} }
  64     ))
  65 );
  66
  67 Class::MOP::Class->meta->add_attribute(
  68     Class::MOP::Attribute->new('$:attribute_metaclass' => (
  69         reader   => 'attribute_metaclass',
  70         init_arg => ':attribute_metaclass',
  71         default  => 'Class::MOP::Attribute',
  72     ))
  73 );
  74
  75 Class::MOP::Class->meta->add_attribute(
  76     Class::MOP::Attribute->new('$:method_metaclass' => (
  77         reader   => 'method_metaclass',
  78         init_arg => ':method_metaclass',
  79         default  => 'Class::MOP::Method',
  80     ))
  81 );
  82
  83 Class::MOP::Class->meta->add_attribute(
  84     Class::MOP::Attribute->new('$:instance_metaclass' => (
  85         reader   => {
  86             # NOTE: we need to do this in order
  87             # for the instance meta-object to
  88             # not fall into meta-circular death
  89             'instance_metaclass' => sub { (shift)->{'$:instance_metaclass'} }
  90         },
  91         init_arg => ':instance_metaclass',
  92         default  => 'Class::MOP::Instance',
  93     ))
  94 );
  95
  96 ## Class::MOP::Attribute
  97
  98 Class::MOP::Attribute->meta->add_attribute(
  99     Class::MOP::Attribute->new('name' => (
 100         reader => {
 101             # NOTE: we need to do this in order
 102             # for the instance meta-object to
 103             # not fall into meta-circular death
 104             'name' => sub { (shift)->{name} }
 105         }
 106     ))
 107 );
 108
 109 Class::MOP::Attribute->meta->add_attribute(
 110     Class::MOP::Attribute->new('associated_class' => (
 111         reader => {
 112             # NOTE: we need to do this in order
 113             # for the instance meta-object to
 114             # not fall into meta-circular death
 115             'associated_class' => sub { (shift)->{associated_class} }
 116         }
 117     ))
 118 );
 119
 120 Class::MOP::Attribute->meta->add_attribute(
 121     Class::MOP::Attribute->new('accessor' => (
 122         reader    => 'accessor',
 123         predicate => 'has_accessor',
 124     ))
 125 );
 126
 127 Class::MOP::Attribute->meta->add_attribute(
 128     Class::MOP::Attribute->new('reader' => (
 129         reader    => 'reader',
 130         predicate => 'has_reader',
 131     ))
 132 );
 133
 134 Class::MOP::Attribute->meta->add_attribute(
 135     Class::MOP::Attribute->new('writer' => (
 136         reader    => 'writer',
 137         predicate => 'has_writer',
 138     ))
 139 );
 140
 141 Class::MOP::Attribute->meta->add_attribute(
 142     Class::MOP::Attribute->new('predicate' => (
 143         reader    => 'predicate',
 144         predicate => 'has_predicate',
 145     ))
 146 );
 147
 148 Class::MOP::Attribute->meta->add_attribute(
 149     Class::MOP::Attribute->new('init_arg' => (
 150         reader    => 'init_arg',
 151         predicate => 'has_init_arg',
 152     ))
 153 );
 154
 155 Class::MOP::Attribute->meta->add_attribute(
 156     Class::MOP::Attribute->new('default' => (
 157         # default has a custom 'reader' method ...
 158         predicate => 'has_default',
 159     ))
 160 );
 161
 162
 163 # NOTE: (meta-circularity)
 164 # This should be one of the last things done
 165 # it will "tie the knot" with Class::MOP::Attribute
 166 # so that it uses the attributes meta-objects
 167 # to construct itself.
 168 Class::MOP::Attribute->meta->add_method('new' => sub {
 169     my $class   = shift;
 170     my $name    = shift;
 171     my %options = @_;
 172
 173     (defined $name && $name)
 174         || confess "You must provide a name for the attribute";
 175     $options{init_arg} = $name
 176         if not exists $options{init_arg};
 177
 178     # return the new object
 179     $class->meta->new_object(name => $name, %options);
 180 });
 181
 182 Class::MOP::Attribute->meta->add_method('clone' => sub {
 183     my $self  = shift;
 184     $self->meta->clone_object($self, @_);
 185 });
 186
 187 1;
 188
 189 __END__
 190
 191 =pod
 192
 193 =head1 NAME
 194
 195 Class::MOP - A Meta Object Protocol for Perl 5
 196
 197 =head1 SYNOPSIS
 198
 199   # ... This will come later, for now see
 200   # the other SYNOPSIS for more information
 201
 202 =head1 DESCRIPTON
 203
 204 This module is an attempt to create a meta object protocol for the
 205 Perl 5 object system. It makes no attempt to change the behavior or
 206 characteristics of the Perl 5 object system, only to create a
 207 protocol for its manipulation and introspection.
 208
 209 That said, it does attempt to create the tools for building a rich
 210 set of extensions to the Perl 5 object system. Every attempt has been
 211 made for these tools to keep to the spirit of the Perl 5 object
 212 system that we all know and love.
 213
 214 =head2 What is a Meta Object Protocol?
 215
 216 A meta object protocol is an API to an object system.
 217
 218 To be more specific, it is a set of abstractions of the components of
 219 an object system (typically things like; classes, object, methods,
 220 object attributes, etc.). These abstractions can then be used to both
 221 inspect and manipulate the object system which they describe.
 222
 223 It can be said that there are two MOPs for any object system; the
 224 implicit MOP, and the explicit MOP. The implicit MOP handles things
 225 like method dispatch or inheritance, which happen automatically as
 226 part of how the object system works. The explicit MOP typically
 227 handles the introspection/reflection features of the object system.
 228 All object systems have implicit MOPs, without one, they would not
 229 work. Explict MOPs however as less common, and depending on the
 230 language can vary from restrictive (Reflection in Java or C#) to
 231 wide open (CLOS is a perfect example).
 232
 233 =head2 Yet Another Class Builder!! Why?
 234
 235 This is B<not> a class builder so much as it is a I<class builder
 236 B<builder>>. My intent is that an end user does not use this module
 237 directly, but instead this module is used by module authors to
 238 build extensions and features onto the Perl 5 object system.
 239
 240 =head2 Who is this module for?
 241
 242 This module is specifically for anyone who has ever created or
 243 wanted to create a module for the Class:: namespace. The tools which
 244 this module will provide will hopefully make it easier to do more
 245 complex things with Perl 5 classes by removing such barriers as
 246 the need to hack the symbol tables, or understand the fine details
 247 of method dispatch.
 248
 249 =head2 What changes do I have to make to use this module?
 250
 251 This module was designed to be as unintrusive as possible. Many of
 252 its features are accessible without B<any> change to your existsing
 253 code at all. It is meant to be a compliment to your existing code and
 254 not an intrusion on your code base. Unlike many other B<Class::>
 255 modules, this module B<does not> require you subclass it, or even that
 256 you C<use> it in within your module's package.
 257
 258 The only features which requires additions to your code are the
 259 attribute handling and instance construction features, and these are
 260 both completely optional features. The only reason for this is because
 261 Perl 5's object system does not actually have these features built
 262 in. More information about this feature can be found below.
 263
 264 =head2 A Note about Performance?
 265
 266 It is a common misconception that explict MOPs are performance drains.
 267 But this is not a universal truth at all, it is an side-effect of
 268 specific implementations. For instance, using Java reflection is much
 269 slower because the JVM cannot take advantage of any compiler
 270 optimizations, and the JVM has to deal with much more runtime type
 271 information as well. Reflection in C# is marginally better as it was
 272 designed into the language and runtime (the CLR). In contrast, CLOS
 273 (the Common Lisp Object System) was built to support an explicit MOP,
 274 and so performance is tuned for it.
 275
 276 This library in particular does it's absolute best to avoid putting
 277 B<any> drain at all upon your code's performance. In fact, by itself
 278 it does nothing to affect your existing code. So you only pay for
 279 what you actually use.
 280
 281 =head2 About Metaclass compatibility
 282
 283 This module makes sure that all metaclasses created are both upwards
 284 and downwards compatible. The topic of metaclass compatibility is
 285 highly esoteric and is something only encountered when doing deep and
 286 involved metaclass hacking. There are two basic kinds of metaclass
 287 incompatibility; upwards and downwards.
 288
 289 Upwards metaclass compatibility means that the metaclass of a
 290 given class is either the same as (or a subclass of) all of the
 291 class's ancestors.
 292
 293 Downward metaclass compatibility means that the metaclasses of a
 294 given class's anscestors are all either the same as (or a subclass
 295 of) that metaclass.
 296
 297 Here is a diagram showing a set of two classes (C<A> and C<B>) and
 298 two metaclasses (C<Meta::A> and C<Meta::B>) which have correct
 299 metaclass compatibility both upwards and downwards.
 300
 301     +---------+     +---------+
 302     | Meta::A |<----| Meta::B |      <....... (instance of  )
 303     +---------+     +---------+      <------- (inherits from)
 304          ^               ^
 305          :               :
 306     +---------+     +---------+
 307     |    A    |<----|    B    |
 308     +---------+     +---------+
 309
 310 As I said this is a highly esoteric topic and one you will only run
 311 into if you do a lot of subclassing of B<Class::MOP::Class>. If you
 312 are interested in why this is an issue see the paper
 313 I<Uniform and safe metaclass composition> linked to in the
 314 L<SEE ALSO> section of this document.
 315
 316 =head2 Using custom metaclasses
 317
 318 Always use the metaclass pragma when using a custom metaclass, this
 319 will ensure the proper initialization order and not accidentely
 320 create an incorrect type of metaclass for you. This is a very rare
 321 problem, and one which can only occur if you are doing deep metaclass
 322 programming. So in other words, don't worry about it.
 323
 324 =head1 PROTOCOLS
 325
 326 The protocol is divided into 3 main sub-protocols:
 327
 328 =over 4
 329
 330 =item The Class protocol
 331
 332 This provides a means of manipulating and introspecting a Perl 5
 333 class. It handles all of symbol table hacking for you, and provides
 334 a rich set of methods that go beyond simple package introspection.
 335
 336 See L<Class::MOP::Class> for more details.
 337
 338 =item The Attribute protocol
 339
 340 This provides a consistent represenation for an attribute of a
 341 Perl 5 class. Since there are so many ways to create and handle
 342 atttributes in Perl 5 OO, this attempts to provide as much of a
 343 unified approach as possible, while giving the freedom and
 344 flexibility to subclass for specialization.
 345
 346 See L<Class::MOP::Attribute> for more details.
 347
 348 =item The Method protocol
 349
 350 This provides a means of manipulating and introspecting methods in
 351 the Perl 5 object system. As with attributes, there are many ways to
 352 approach this topic, so we try to keep it pretty basic, while still
 353 making it possible to extend the system in many ways.
 354
 355 See L<Class::MOP::Method> for more details.
 356
 357 =back
 358
 359 =head1 SEE ALSO
 360
 361 =head2 Books
 362
 363 There are very few books out on Meta Object Protocols and Metaclasses
 364 because it is such an esoteric topic. The following books are really
 365 the only ones I have found. If you know of any more, B<I<please>>
 366 email me and let me know, I would love to hear about them.
 367
 368 =over 4
 369
 370 =item "The Art of the Meta Object Protocol"
 371
 372 =item "Advances in Object-Oriented Metalevel Architecture and Reflection"
 373
 374 =item "Putting MetaClasses to Work"
 375
 376 =item "Smalltalk: The Language"
 377
 378 =back
 379
 380 =head2 Papers
 381
 382 =over 4
 383
 384 =item Uniform and safe metaclass composition
 385
 386 An excellent paper by the people who brought us the original Traits paper.
 387 This paper is on how Traits can be used to do safe metaclass composition,
 388 and offers an excellent introduction section which delves into the topic of
 389 metaclass compatibility.
 390
 391 L<http://www.iam.unibe.ch/~scg/Archive/Papers/Duca05ySafeMetaclassTrait.pdf>
 392
 393 =item Safe Metaclass Programming
 394
 395 This paper seems to precede the above paper, and propose a mix-in based
 396 approach as opposed to the Traits based approach. Both papers have similar
 397 information on the metaclass compatibility problem space.
 398
 399 L<http://citeseer.ist.psu.edu/37617.html>
 400
 401 =back
 402
 403 =head2 Prior Art
 404
 405 =over 4
 406
 407 =item The Perl 6 MetaModel work in the Pugs project
 408
 409 =over 4
 410
 411 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-MetaModel>
 412
 413 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-ObjectSpace>
 414
 415 =back
 416
 417 =back
 418
 419 =head1 SIMILAR MODULES
 420
 421 As I have said above, this module is a class-builder-builder, so it is
 422 not the same thing as modules like L<Class::Accessor> and
 423 L<Class::MethodMaker>. That being said there are very few modules on CPAN
 424 with similar goals to this module. The one I have found which is most
 425 like this module is L<Class::Meta>, although it's philosophy and the MOP it
 426 creates are very different from this modules.
 427
 428 =head1 BUGS
 429
 430 All complex software has bugs lurking in it, and this module is no
 431 exception. If you find a bug please either email me, or add the bug
 432 to cpan-RT.
 433
 434 =head1 CODE COVERAGE
 435
 436 I use L<Devel::Cover> to test the code coverage of my tests, below is the
 437 L<Devel::Cover> report on this module's test suite.
 438
 439  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 440  File                           stmt   bran   cond    sub    pod   time  total
 441  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 442  Class/MOP.pm                  100.0  100.0  100.0  100.0    n/a    9.6  100.0
 443  Class/MOP/Attribute.pm        100.0  100.0   91.7   73.8  100.0   28.4   92.1
 444  Class/MOP/Class.pm            100.0   93.5   82.3   98.2  100.0   56.6   95.7
 445  Class/MOP/Method.pm           100.0   64.3   52.9   80.0  100.0    3.5   85.3
 446  metaclass.pm                  100.0  100.0   80.0  100.0    n/a    1.9   97.4
 447  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 448  Total                         100.0   90.8   79.7   86.2  100.0  100.0   93.6
 449  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 450
 451 =head1 ACKNOWLEDGEMENTS
 452
 453 =over 4
 454
 455 =item Rob Kinyon E<lt>rob@iinteractive.comE<gt>
 456
 457 Thanks to Rob for actually getting the development of this module kick-started.
 458
 459 =back
 460
 461 =head1 AUTHOR
 462
 463 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 464
 465 =head1 COPYRIGHT AND LICENSE
 466
 467 Copyright 2006 by Infinity Interactive, Inc.
 468
 469 L<http://www.iinteractive.com>
 470
 471 This library is free software; you can redistribute it and/or modify
 472 it under the same terms as Perl itself.
 473
 474 =cut