lib/Class/MOP.pm

   1
   2 package Class::MOP;
   3
   4 use strict;
   5 use warnings;
   6
   7 use 5.008;
   8
   9 use MRO::Compat;
  10
  11 use Carp          'confess';
  12 use Scalar::Util  'weaken', 'reftype', 'blessed';
  13
  14 use Class::MOP::Class;
  15 use Class::MOP::Attribute;
  16 use Class::MOP::Method;
  17
  18 BEGIN {
  19     *IS_RUNNING_ON_5_10 = ($] < 5.009_005)
  20         ? sub () { 0 }
  21         : sub () { 1 };
  22
  23     sub HAVE_ISAREV () {
  24         Carp::cluck("Class::MOP::HAVE_ISAREV is deprecated and will be removed in a future release. It has always returned 1 anyway.");
  25         return 1;
  26     }
  27
  28     # this is either part of core or set up appropriately by MRO::Compat
  29     *check_package_cache_flag = \&mro::get_pkg_gen;
  30 }
  31
  32 our $VERSION   = '0.83';
  33 our $XS_VERSION = $VERSION;
  34 $VERSION = eval $VERSION;
  35 our $AUTHORITY = 'cpan:STEVAN';
  36
  37 require XSLoader;
  38 XSLoader::load( __PACKAGE__, $XS_VERSION );
  39
  40
  41 {
  42     # Metaclasses are singletons, so we cache them here.
  43     # there is no need to worry about destruction though
  44     # because they should die only when the program dies.
  45     # After all, do package definitions even get reaped?
  46     my %METAS;
  47
  48     # means of accessing all the metaclasses that have
  49     # been initialized thus far (for mugwumps obj browser)
  50     sub get_all_metaclasses         {        %METAS         }
  51     sub get_all_metaclass_instances { values %METAS         }
  52     sub get_all_metaclass_names     { keys   %METAS         }
  53     sub get_metaclass_by_name       { $METAS{$_[0]}         }
  54     sub store_metaclass_by_name     { $METAS{$_[0]} = $_[1] }
  55     sub weaken_metaclass            { weaken($METAS{$_[0]}) }
  56     sub does_metaclass_exist        { exists $METAS{$_[0]} && defined $METAS{$_[0]} }
  57     sub remove_metaclass_by_name    { $METAS{$_[0]} = undef }
  58
  59     # This handles instances as well as class names
  60     sub class_of {
  61         return unless defined $_[0];
  62         my $class = blessed($_[0]) || $_[0];
  63         return $METAS{$class};
  64     }
  65
  66     # NOTE:
  67     # We only cache metaclasses, meaning instances of
  68     # Class::MOP::Class. We do not cache instance of
  69     # Class::MOP::Package or Class::MOP::Module. Mostly
  70     # because I don't yet see a good reason to do so.
  71 }
  72
  73 sub _class_to_pmfile {
  74     my $class = shift;
  75
  76     my $file = $class . '.pm';
  77     $file =~ s{::}{/}g;
  78
  79     return $file;
  80 }
  81
  82 sub load_first_existing_class {
  83     my @classes = @_
  84         or return;
  85
  86     foreach my $class (@classes) {
  87         unless ( _is_valid_class_name($class) ) {
  88             my $display = defined($class) ? $class : 'undef';
  89             confess "Invalid class name ($display)";
  90         }
  91     }
  92
  93     my $found;
  94     my %exceptions;
  95     for my $class (@classes) {
  96         my $pmfile = _class_to_pmfile($class);
  97         my $e = _try_load_one_class($class);
  98
  99         if ($e) {
 100             $exceptions{$class} = $e;
 101             last if $e !~ /^Can't locate \Q$pmfile\E in \@INC/;
 102         }
 103         else {
 104             $found = $class;
 105             last;
 106         }
 107     }
 108
 109     return $found if $found;
 110
 111     confess join(
 112         "\n",
 113         map {
 114             sprintf(
 115                 "Could not load class (%s) because : %s", $_,
 116                 $exceptions{$_}
 117                 )
 118             }
 119         grep {
 120             exists $exceptions{$_}
 121             } @classes
 122     );
 123 }
 124
 125 sub _try_load_one_class {
 126     my $class = shift;
 127
 128     return if is_class_loaded($class);
 129
 130     my $file = _class_to_pmfile($class);
 131
 132     return do {
 133         local $@;
 134         eval { require($file) };
 135         $@;
 136     };
 137 }
 138
 139 sub load_class {
 140     my $class = load_first_existing_class($_[0]);
 141     return get_metaclass_by_name($class) || $class;
 142 }
 143
 144 sub _is_valid_class_name {
 145     my $class = shift;
 146
 147     return 0 if ref($class);
 148     return 0 unless defined($class);
 149     return 0 unless length($class);
 150
 151     return 1 if $class =~ /^\w+(?:::\w+)*$/;
 152
 153     return 0;
 154 }
 155
 156 ## ----------------------------------------------------------------------------
 157 ## Setting up our environment ...
 158 ## ----------------------------------------------------------------------------
 159 ## Class::MOP needs to have a few things in the global perl environment so
 160 ## that it can operate effectively. Those things are done here.
 161 ## ----------------------------------------------------------------------------
 162
 163 # ... nothing yet actually ;)
 164
 165 ## ----------------------------------------------------------------------------
 166 ## Bootstrapping
 167 ## ----------------------------------------------------------------------------
 168 ## The code below here is to bootstrap our MOP with itself. This is also
 169 ## sometimes called "tying the knot". By doing this, we make it much easier
 170 ## to extend the MOP through subclassing and such since now you can use the
 171 ## MOP itself to extend itself.
 172 ##
 173 ## Yes, I know, thats weird and insane, but it's a good thing, trust me :)
 174 ## ----------------------------------------------------------------------------
 175
 176 # We need to add in the meta-attributes here so that
 177 # any subclass of Class::MOP::* will be able to
 178 # inherit them using _construct_instance
 179
 180 ## --------------------------------------------------------
 181 ## Class::MOP::Package
 182
 183 Class::MOP::Package->meta->add_attribute(
 184     Class::MOP::Attribute->new('package' => (
 185         reader   => {
 186             # NOTE: we need to do this in order
 187             # for the instance meta-object to
 188             # not fall into meta-circular death
 189             #
 190             # we just alias the original method
 191             # rather than re-produce it here
 192             'name' => \&Class::MOP::Package::name
 193         },
 194     ))
 195 );
 196
 197 Class::MOP::Package->meta->add_attribute(
 198     Class::MOP::Attribute->new('namespace' => (
 199         reader => {
 200             # NOTE:
 201             # we just alias the original method
 202             # rather than re-produce it here
 203             'namespace' => \&Class::MOP::Package::namespace
 204         },
 205         init_arg => undef,
 206         default  => sub { \undef }
 207     ))
 208 );
 209
 210 ## --------------------------------------------------------
 211 ## Class::MOP::Module
 212
 213 # NOTE:
 214 # yeah this is kind of stretching things a bit,
 215 # but truthfully the version should be an attribute
 216 # of the Module, the weirdness comes from having to
 217 # stick to Perl 5 convention and store it in the
 218 # $VERSION package variable. Basically if you just
 219 # squint at it, it will look how you want it to look.
 220 # Either as a package variable, or as a attribute of
 221 # the metaclass, isn't abstraction great :)
 222
 223 Class::MOP::Module->meta->add_attribute(
 224     Class::MOP::Attribute->new('version' => (
 225         reader => {
 226             # NOTE:
 227             # we just alias the original method
 228             # rather than re-produce it here
 229             'version' => \&Class::MOP::Module::version
 230         },
 231         init_arg => undef,
 232         default  => sub { \undef }
 233     ))
 234 );
 235
 236 # NOTE:
 237 # By following the same conventions as version here,
 238 # we are opening up the possibility that people can
 239 # use the $AUTHORITY in non-Class::MOP modules as
 240 # well.
 241
 242 Class::MOP::Module->meta->add_attribute(
 243     Class::MOP::Attribute->new('authority' => (
 244         reader => {
 245             # NOTE:
 246             # we just alias the original method
 247             # rather than re-produce it here
 248             'authority' => \&Class::MOP::Module::authority
 249         },
 250         init_arg => undef,
 251         default  => sub { \undef }
 252     ))
 253 );
 254
 255 ## --------------------------------------------------------
 256 ## Class::MOP::Class
 257
 258 Class::MOP::Class->meta->add_attribute(
 259     Class::MOP::Attribute->new('attributes' => (
 260         reader   => {
 261             # NOTE: we need to do this in order
 262             # for the instance meta-object to
 263             # not fall into meta-circular death
 264             #
 265             # we just alias the original method
 266             # rather than re-produce it here
 267             'get_attribute_map' => \&Class::MOP::Class::get_attribute_map
 268         },
 269         default  => sub { {} }
 270     ))
 271 );
 272
 273 Class::MOP::Class->meta->add_attribute(
 274     Class::MOP::Attribute->new('methods' => (
 275         reader   => {
 276             # NOTE:
 277             # we just alias the original method
 278             # rather than re-produce it here
 279             'get_method_map' => \&Class::MOP::Class::get_method_map
 280         },
 281         default => sub { {} }
 282     ))
 283 );
 284
 285 Class::MOP::Class->meta->add_attribute(
 286     Class::MOP::Attribute->new('superclasses' => (
 287         accessor => {
 288             # NOTE:
 289             # we just alias the original method
 290             # rather than re-produce it here
 291             'superclasses' => \&Class::MOP::Class::superclasses
 292         },
 293         init_arg => undef,
 294         default  => sub { \undef }
 295     ))
 296 );
 297
 298 Class::MOP::Class->meta->add_attribute(
 299     Class::MOP::Attribute->new('attribute_metaclass' => (
 300         reader   => {
 301             # NOTE:
 302             # we just alias the original method
 303             # rather than re-produce it here
 304             'attribute_metaclass' => \&Class::MOP::Class::attribute_metaclass
 305         },
 306         default  => 'Class::MOP::Attribute',
 307     ))
 308 );
 309
 310 Class::MOP::Class->meta->add_attribute(
 311     Class::MOP::Attribute->new('method_metaclass' => (
 312         reader   => {
 313             # NOTE:
 314             # we just alias the original method
 315             # rather than re-produce it here
 316             'method_metaclass' => \&Class::MOP::Class::method_metaclass
 317         },
 318         default  => 'Class::MOP::Method',
 319     ))
 320 );
 321
 322 Class::MOP::Class->meta->add_attribute(
 323     Class::MOP::Attribute->new('wrapped_method_metaclass' => (
 324         reader   => {
 325             # NOTE:
 326             # we just alias the original method
 327             # rather than re-produce it here
 328             'wrapped_method_metaclass' => \&Class::MOP::Class::wrapped_method_metaclass
 329         },
 330         default  => 'Class::MOP::Method::Wrapped',
 331     ))
 332 );
 333
 334 Class::MOP::Class->meta->add_attribute(
 335     Class::MOP::Attribute->new('instance_metaclass' => (
 336         reader   => {
 337             # NOTE: we need to do this in order
 338             # for the instance meta-object to
 339             # not fall into meta-circular death
 340             #
 341             # we just alias the original method
 342             # rather than re-produce it here
 343             'instance_metaclass' => \&Class::MOP::Class::instance_metaclass
 344         },
 345         default  => 'Class::MOP::Instance',
 346     ))
 347 );
 348
 349 Class::MOP::Class->meta->add_attribute(
 350     Class::MOP::Attribute->new('immutable_trait' => (
 351         reader   => {
 352             'immutable_trait' => \&Class::MOP::Class::immutable_trait
 353         },
 354         default => "Class::MOP::Class::Immutable::Trait",
 355     ))
 356 );
 357
 358 Class::MOP::Class->meta->add_attribute(
 359     Class::MOP::Attribute->new('constructor_name' => (
 360         reader   => {
 361             'constructor_name' => \&Class::MOP::Class::constructor_name,
 362         },
 363         default => "new",
 364     ))
 365 );
 366
 367 Class::MOP::Class->meta->add_attribute(
 368     Class::MOP::Attribute->new('constructor_class' => (
 369         reader   => {
 370             'constructor_class' => \&Class::MOP::Class::constructor_class,
 371         },
 372         default => "Class::MOP::Method::Constructor",
 373     ))
 374 );
 375
 376
 377 Class::MOP::Class->meta->add_attribute(
 378     Class::MOP::Attribute->new('destructor_class' => (
 379         reader   => {
 380             'destructor_class' => \&Class::MOP::Class::destructor_class,
 381         },
 382     ))
 383 );
 384
 385 # NOTE:
 386 # we don't actually need to tie the knot with
 387 # Class::MOP::Class here, it is actually handled
 388 # within Class::MOP::Class itself in the
 389 # _construct_class_instance method.
 390
 391 ## --------------------------------------------------------
 392 ## Class::MOP::Attribute
 393
 394 Class::MOP::Attribute->meta->add_attribute(
 395     Class::MOP::Attribute->new('name' => (
 396         reader   => {
 397             # NOTE: we need to do this in order
 398             # for the instance meta-object to
 399             # not fall into meta-circular death
 400             #
 401             # we just alias the original method
 402             # rather than re-produce it here
 403             'name' => \&Class::MOP::Attribute::name
 404         }
 405     ))
 406 );
 407
 408 Class::MOP::Attribute->meta->add_attribute(
 409     Class::MOP::Attribute->new('associated_class' => (
 410         reader   => {
 411             # NOTE: we need to do this in order
 412             # for the instance meta-object to
 413             # not fall into meta-circular death
 414             #
 415             # we just alias the original method
 416             # rather than re-produce it here
 417             'associated_class' => \&Class::MOP::Attribute::associated_class
 418         }
 419     ))
 420 );
 421
 422 Class::MOP::Attribute->meta->add_attribute(
 423     Class::MOP::Attribute->new('accessor' => (
 424         reader    => { 'accessor'     => \&Class::MOP::Attribute::accessor     },
 425         predicate => { 'has_accessor' => \&Class::MOP::Attribute::has_accessor },
 426     ))
 427 );
 428
 429 Class::MOP::Attribute->meta->add_attribute(
 430     Class::MOP::Attribute->new('reader' => (
 431         reader    => { 'reader'     => \&Class::MOP::Attribute::reader     },
 432         predicate => { 'has_reader' => \&Class::MOP::Attribute::has_reader },
 433     ))
 434 );
 435
 436 Class::MOP::Attribute->meta->add_attribute(
 437     Class::MOP::Attribute->new('initializer' => (
 438         reader    => { 'initializer'     => \&Class::MOP::Attribute::initializer     },
 439         predicate => { 'has_initializer' => \&Class::MOP::Attribute::has_initializer },
 440     ))
 441 );
 442
 443 Class::MOP::Attribute->meta->add_attribute(
 444     Class::MOP::Attribute->new('definition_context' => (
 445         reader    => { 'definition_context'     => \&Class::MOP::Attribute::definition_context     },
 446     ))
 447 );
 448
 449 Class::MOP::Attribute->meta->add_attribute(
 450     Class::MOP::Attribute->new('writer' => (
 451         reader    => { 'writer'     => \&Class::MOP::Attribute::writer     },
 452         predicate => { 'has_writer' => \&Class::MOP::Attribute::has_writer },
 453     ))
 454 );
 455
 456 Class::MOP::Attribute->meta->add_attribute(
 457     Class::MOP::Attribute->new('predicate' => (
 458         reader    => { 'predicate'     => \&Class::MOP::Attribute::predicate     },
 459         predicate => { 'has_predicate' => \&Class::MOP::Attribute::has_predicate },
 460     ))
 461 );
 462
 463 Class::MOP::Attribute->meta->add_attribute(
 464     Class::MOP::Attribute->new('clearer' => (
 465         reader    => { 'clearer'     => \&Class::MOP::Attribute::clearer     },
 466         predicate => { 'has_clearer' => \&Class::MOP::Attribute::has_clearer },
 467     ))
 468 );
 469
 470 Class::MOP::Attribute->meta->add_attribute(
 471     Class::MOP::Attribute->new('builder' => (
 472         reader    => { 'builder'     => \&Class::MOP::Attribute::builder     },
 473         predicate => { 'has_builder' => \&Class::MOP::Attribute::has_builder },
 474     ))
 475 );
 476
 477 Class::MOP::Attribute->meta->add_attribute(
 478     Class::MOP::Attribute->new('init_arg' => (
 479         reader    => { 'init_arg'     => \&Class::MOP::Attribute::init_arg     },
 480         predicate => { 'has_init_arg' => \&Class::MOP::Attribute::has_init_arg },
 481     ))
 482 );
 483
 484 Class::MOP::Attribute->meta->add_attribute(
 485     Class::MOP::Attribute->new('default' => (
 486         # default has a custom 'reader' method ...
 487         predicate => { 'has_default' => \&Class::MOP::Attribute::has_default },
 488     ))
 489 );
 490
 491 Class::MOP::Attribute->meta->add_attribute(
 492     Class::MOP::Attribute->new('associated_methods' => (
 493         reader   => { 'associated_methods' => \&Class::MOP::Attribute::associated_methods },
 494         default  => sub { [] }
 495     ))
 496 );
 497
 498 Class::MOP::Attribute->meta->add_method('clone' => sub {
 499     my $self  = shift;
 500     $self->meta->clone_object($self, @_);
 501 });
 502
 503 ## --------------------------------------------------------
 504 ## Class::MOP::Method
 505 Class::MOP::Method->meta->add_attribute(
 506     Class::MOP::Attribute->new('body' => (
 507         reader   => { 'body' => \&Class::MOP::Method::body },
 508     ))
 509 );
 510
 511 Class::MOP::Method->meta->add_attribute(
 512     Class::MOP::Attribute->new('associated_metaclass' => (
 513         reader   => { 'associated_metaclass' => \&Class::MOP::Method::associated_metaclass },
 514     ))
 515 );
 516
 517 Class::MOP::Method->meta->add_attribute(
 518     Class::MOP::Attribute->new('package_name' => (
 519         reader   => { 'package_name' => \&Class::MOP::Method::package_name },
 520     ))
 521 );
 522
 523 Class::MOP::Method->meta->add_attribute(
 524     Class::MOP::Attribute->new('name' => (
 525         reader   => { 'name' => \&Class::MOP::Method::name },
 526     ))
 527 );
 528
 529 Class::MOP::Method->meta->add_attribute(
 530     Class::MOP::Attribute->new('original_method' => (
 531         reader   => { 'original_method'      => \&Class::MOP::Method::original_method },
 532         writer   => { '_set_original_method' => \&Class::MOP::Method::_set_original_method },
 533     ))
 534 );
 535
 536 Class::MOP::Method->meta->add_method('clone' => sub {
 537     my $self  = shift;
 538     my $clone = $self->meta->clone_object($self, @_);
 539     $clone->_set_original_method($self);
 540     return $clone;
 541 });
 542
 543 ## --------------------------------------------------------
 544 ## Class::MOP::Method::Wrapped
 545
 546 # NOTE:
 547 # the way this item is initialized, this
 548 # really does not follow the standard
 549 # practices of attributes, but we put
 550 # it here for completeness
 551 Class::MOP::Method::Wrapped->meta->add_attribute(
 552     Class::MOP::Attribute->new('modifier_table')
 553 );
 554
 555 ## --------------------------------------------------------
 556 ## Class::MOP::Method::Generated
 557
 558 Class::MOP::Method::Generated->meta->add_attribute(
 559     Class::MOP::Attribute->new('is_inline' => (
 560         reader   => { 'is_inline' => \&Class::MOP::Method::Generated::is_inline },
 561         default  => 0,
 562     ))
 563 );
 564
 565 Class::MOP::Method::Generated->meta->add_attribute(
 566     Class::MOP::Attribute->new('definition_context' => (
 567         reader   => { 'definition_context' => \&Class::MOP::Method::Generated::definition_context },
 568     ))
 569 );
 570
 571
 572 ## --------------------------------------------------------
 573 ## Class::MOP::Method::Inlined
 574
 575 Class::MOP::Method::Inlined->meta->add_attribute(
 576     Class::MOP::Attribute->new('_expected_method_class' => (
 577         reader   => { '_expected_method_class' => \&Class::MOP::Method::Inlined::_expected_method_class },
 578     ))
 579 );
 580
 581 ## --------------------------------------------------------
 582 ## Class::MOP::Method::Accessor
 583
 584 Class::MOP::Method::Accessor->meta->add_attribute(
 585     Class::MOP::Attribute->new('attribute' => (
 586         reader   => {
 587             'associated_attribute' => \&Class::MOP::Method::Accessor::associated_attribute
 588         },
 589     ))
 590 );
 591
 592 Class::MOP::Method::Accessor->meta->add_attribute(
 593     Class::MOP::Attribute->new('accessor_type' => (
 594         reader   => { 'accessor_type' => \&Class::MOP::Method::Accessor::accessor_type },
 595     ))
 596 );
 597
 598 ## --------------------------------------------------------
 599 ## Class::MOP::Method::Constructor
 600
 601 Class::MOP::Method::Constructor->meta->add_attribute(
 602     Class::MOP::Attribute->new('options' => (
 603         reader   => {
 604             'options' => \&Class::MOP::Method::Constructor::options
 605         },
 606         default  => sub { +{} }
 607     ))
 608 );
 609
 610 Class::MOP::Method::Constructor->meta->add_attribute(
 611     Class::MOP::Attribute->new('associated_metaclass' => (
 612         init_arg => "metaclass", # FIXME alias and rename
 613         reader   => {
 614             'associated_metaclass' => \&Class::MOP::Method::Constructor::associated_metaclass
 615         },
 616     ))
 617 );
 618
 619 ## --------------------------------------------------------
 620 ## Class::MOP::Instance
 621
 622 # NOTE:
 623 # these don't yet do much of anything, but are just
 624 # included for completeness
 625
 626 Class::MOP::Instance->meta->add_attribute(
 627     Class::MOP::Attribute->new('associated_metaclass',
 628         reader   => { associated_metaclass => \&Class::MOP::Instance::associated_metaclass },
 629     ),
 630 );
 631
 632 Class::MOP::Instance->meta->add_attribute(
 633     Class::MOP::Attribute->new('_class_name',
 634         init_arg => undef,
 635         reader   => { _class_name => \&Class::MOP::Instance::_class_name },
 636         #lazy     => 1, # not yet supported by Class::MOP but out our version does it anyway
 637         #default  => sub { $_[0]->associated_metaclass->name },
 638     ),
 639 );
 640
 641 Class::MOP::Instance->meta->add_attribute(
 642     Class::MOP::Attribute->new('attributes',
 643         reader   => { attributes => \&Class::MOP::Instance::get_all_attributes },
 644     ),
 645 );
 646
 647 Class::MOP::Instance->meta->add_attribute(
 648     Class::MOP::Attribute->new('slots',
 649         reader   => { slots => \&Class::MOP::Instance::slots },
 650     ),
 651 );
 652
 653 Class::MOP::Instance->meta->add_attribute(
 654     Class::MOP::Attribute->new('slot_hash',
 655         reader   => { slot_hash => \&Class::MOP::Instance::slot_hash },
 656     ),
 657 );
 658
 659
 660 # we need the meta instance of the meta instance to be created now, in order
 661 # for the constructor to be able to use it
 662 Class::MOP::Instance->meta->get_meta_instance;
 663
 664 # pretend the add_method never happenned. it hasn't yet affected anything
 665 undef Class::MOP::Instance->meta->{_package_cache_flag};
 666
 667 ## --------------------------------------------------------
 668 ## Now close all the Class::MOP::* classes
 669
 670 # NOTE: we don't need to inline the the accessors this only lengthens
 671 # the compile time of the MOP, and gives us no actual benefits.
 672
 673 # this is just nitpicking to ensure Class::MOP::Class->meta == ->meta->meta
 674 Class::MOP::Class->meta->_immutable_metaclass;
 675 $Class::MOP::Class::immutable_metaclass_cache{"Class::MOP::Class"}{"Class::MOP::Class::Immutable::Trait"} = Class::MOP::Class::Immutable::Class::MOP::Class->meta;
 676
 677 $_->meta->make_immutable(
 678     inline_constructor  => 1,
 679     replace_constructor => 1,
 680     constructor_name    => "_new",
 681     inline_accessors => 0,
 682 ) for qw/
 683     Class::MOP::Package
 684     Class::MOP::Module
 685     Class::MOP::Class
 686     Class::MOP::Class::Immutable::Trait
 687     Class::MOP::Class::Immutable::Class::MOP::Class
 688
 689     Class::MOP::Attribute
 690     Class::MOP::Method
 691     Class::MOP::Instance
 692
 693     Class::MOP::Object
 694
 695     Class::MOP::Method::Generated
 696     Class::MOP::Method::Inlined
 697
 698     Class::MOP::Method::Accessor
 699     Class::MOP::Method::Constructor
 700     Class::MOP::Method::Wrapped
 701 /;
 702
 703 1;
 704
 705 __END__
 706
 707 =pod
 708
 709 =head1 NAME
 710
 711 Class::MOP - A Meta Object Protocol for Perl 5
 712
 713 =head1 DESCRIPTION
 714
 715 This module is a fully functioning meta object protocol for the
 716 Perl 5 object system. It makes no attempt to change the behavior or
 717 characteristics of the Perl 5 object system, only to create a
 718 protocol for its manipulation and introspection.
 719
 720 That said, it does attempt to create the tools for building a rich set
 721 of extensions to the Perl 5 object system. Every attempt has been made
 722 to abide by the spirit of the Perl 5 object system that we all know
 723 and love.
 724
 725 This documentation is sparse on conceptual details. We suggest looking
 726 at the items listed in the L<SEE ALSO> section for more
 727 information. In particular the book "The Art of the Meta Object
 728 Protocol" was very influential in the development of this system.
 729
 730 =head2 What is a Meta Object Protocol?
 731
 732 A meta object protocol is an API to an object system.
 733
 734 To be more specific, it abstracts the components of an object system
 735 (classes, object, methods, object attributes, etc.). These
 736 abstractions can then be used to inspect and manipulate the object
 737 system which they describe.
 738
 739 It can be said that there are two MOPs for any object system; the
 740 implicit MOP and the explicit MOP. The implicit MOP handles things
 741 like method dispatch or inheritance, which happen automatically as
 742 part of how the object system works. The explicit MOP typically
 743 handles the introspection/reflection features of the object system.
 744
 745 All object systems have implicit MOPs. Without one, they would not
 746 work. Explicit MOPs are much less common, and depending on the
 747 language can vary from restrictive (Reflection in Java or C#) to wide
 748 open (CLOS is a perfect example).
 749
 750 =head2 Yet Another Class Builder! Why?
 751
 752 This is B<not> a class builder so much as a I<class builder
 753 B<builder>>. The intent is that an end user will not use this module
 754 directly, but instead this module is used by module authors to build
 755 extensions and features onto the Perl 5 object system.
 756
 757 This system is used by L<Moose>, which supplies a powerful class
 758 builder system built entirely on top of C<Class::MOP>.
 759
 760 =head2 Who is this module for?
 761
 762 This module is for anyone who has ever created or wanted to create a
 763 module for the Class:: namespace. The tools which this module provides
 764 make doing complex Perl 5 wizardry simpler, by removing such barriers
 765 as the need to hack symbol tables, or understand the fine details of
 766 method dispatch.
 767
 768 =head2 What changes do I have to make to use this module?
 769
 770 This module was designed to be as unintrusive as possible. Many of its
 771 features are accessible without B<any> change to your existing
 772 code. It is meant to be a compliment to your existing code and not an
 773 intrusion on your code base. Unlike many other B<Class::> modules,
 774 this module B<does not> require you subclass it, or even that you
 775 C<use> it in within your module's package.
 776
 777 The only features which requires additions to your code are the
 778 attribute handling and instance construction features, and these are
 779 both completely optional features. The only reason for this is because
 780 Perl 5's object system does not actually have these features built
 781 in. More information about this feature can be found below.
 782
 783 =head2 About Performance
 784
 785 It is a common misconception that explicit MOPs are a performance hit.
 786 This is not a universal truth, it is a side-effect of some specific
 787 implementations. For instance, using Java reflection is slow because
 788 the JVM cannot take advantage of any compiler optimizations, and the
 789 JVM has to deal with much more runtime type information as well.
 790
 791 Reflection in C# is marginally better as it was designed into the
 792 language and runtime (the CLR). In contrast, CLOS (the Common Lisp
 793 Object System) was built to support an explicit MOP, and so
 794 performance is tuned for it.
 795
 796 This library in particular does its absolute best to avoid putting
 797 B<any> drain at all upon your code's performance. In fact, by itself
 798 it does nothing to affect your existing code. So you only pay for what
 799 you actually use.
 800
 801 =head2 About Metaclass compatibility
 802
 803 This module makes sure that all metaclasses created are both upwards
 804 and downwards compatible. The topic of metaclass compatibility is
 805 highly esoteric and is something only encountered when doing deep and
 806 involved metaclass hacking. There are two basic kinds of metaclass
 807 incompatibility; upwards and downwards.
 808
 809 Upwards metaclass compatibility means that the metaclass of a
 810 given class is either the same as (or a subclass of) all of the
 811 class's ancestors.
 812
 813 Downward metaclass compatibility means that the metaclasses of a
 814 given class's ancestors are all either the same as (or a subclass
 815 of) that metaclass.
 816
 817 Here is a diagram showing a set of two classes (C<A> and C<B>) and
 818 two metaclasses (C<Meta::A> and C<Meta::B>) which have correct
 819 metaclass compatibility both upwards and downwards.
 820
 821     +---------+     +---------+
 822     | Meta::A |<----| Meta::B |      <....... (instance of  )
 823     +---------+     +---------+      <------- (inherits from)
 824          ^               ^
 825          :               :
 826     +---------+     +---------+
 827     |    A    |<----|    B    |
 828     +---------+     +---------+
 829
 830 As I said this is a highly esoteric topic and one you will only run
 831 into if you do a lot of subclassing of L<Class::MOP::Class>. If you
 832 are interested in why this is an issue see the paper I<Uniform and
 833 safe metaclass composition> linked to in the L<SEE ALSO> section of
 834 this document.
 835
 836 =head2 Using custom metaclasses
 837
 838 Always use the L<metaclass> pragma when using a custom metaclass, this
 839 will ensure the proper initialization order and not accidentally
 840 create an incorrect type of metaclass for you. This is a very rare
 841 problem, and one which can only occur if you are doing deep metaclass
 842 programming. So in other words, don't worry about it.
 843
 844 Note that if you're using L<Moose> we encourage you to I<not> use
 845 L<metaclass> pragma, and instead use L<Moose::Util::MetaRole> to apply
 846 roles to a class's metaclasses. This topic is covered at length in
 847 various L<Moose::Cookbook> recipes.
 848
 849 =head1 PROTOCOLS
 850
 851 The meta-object protocol is divided into 4 main sub-protocols:
 852
 853 =head2 The Class protocol
 854
 855 This provides a means of manipulating and introspecting a Perl 5
 856 class. It handles symbol table hacking for you, and provides a rich
 857 set of methods that go beyond simple package introspection.
 858
 859 See L<Class::MOP::Class> for more details.
 860
 861 =head2 The Attribute protocol
 862
 863 This provides a consistent representation for an attribute of a Perl 5
 864 class. Since there are so many ways to create and handle attributes in
 865 Perl 5 OO, the Attribute protocol provide as much of a unified
 866 approach as possible. Of course, you are always free to extend this
 867 protocol by subclassing the appropriate classes.
 868
 869 See L<Class::MOP::Attribute> for more details.
 870
 871 =head2 The Method protocol
 872
 873 This provides a means of manipulating and introspecting methods in the
 874 Perl 5 object system. As with attributes, there are many ways to
 875 approach this topic, so we try to keep it pretty basic, while still
 876 making it possible to extend the system in many ways.
 877
 878 See L<Class::MOP::Method> for more details.
 879
 880 =head2 The Instance protocol
 881
 882 This provides a layer of abstraction for creating object instances.
 883 Since the other layers use this protocol, it is relatively easy to
 884 change the type of your instances from the default hash reference to
 885 some other type of reference. Several examples are provided in the
 886 F<examples/> directory included in this distribution.
 887
 888 See L<Class::MOP::Instance> for more details.
 889
 890 =head1 FUNCTIONS
 891
 892 Note that this module does not export any constants or functions.
 893
 894 =head2 Constants
 895
 896 =over 4
 897
 898 =item I<Class::MOP::IS_RUNNING_ON_5_10>
 899
 900 We set this constant depending on what version perl we are on, this
 901 allows us to take advantage of new 5.10 features and stay backwards
 902 compatible.
 903
 904 =back
 905
 906 =head2 Utility functions
 907
 908 Note that these are all called as B<functions, not methods>.
 909
 910 =over 4
 911
 912 =item B<Class::MOP::load_class($class_name)>
 913
 914 This will load the specified C<$class_name>. This function can be used
 915 in place of tricks like C<eval "use $module"> or using C<require>
 916 unconditionally. This will return the metaclass of C<$class_name>.
 917
 918 =item B<Class::MOP::is_class_loaded($class_name)>
 919
 920 Returns a boolean indicating whether or not C<$class_name> has been
 921 loaded.
 922
 923 This does a basic check of the symbol table to try and determine as
 924 best it can if the C<$class_name> is loaded, it is probably correct
 925 about 99% of the time, but it can be fooled into reporting false
 926 positives.
 927
 928 =item B<Class::MOP::get_code_info($code)>
 929
 930 This function returns two values, the name of the package the C<$code>
 931 is from and the name of the C<$code> itself. This is used by several
 932 elements of the MOP to determine where a given C<$code> reference is
 933 from.
 934
 935 =item B<Class::MOP::class_of($instance_or_class_name)>
 936
 937 This will return the metaclass of the given instance or class name.
 938 Even if the class lacks a metaclass, no metaclass will be initialized
 939 and C<undef> will be returned.
 940
 941 =item B<Class::MOP::check_package_cache_flag($pkg)>
 942
 943 B<NOTE: DO NOT USE THIS FUNCTION, IT IS FOR INTERNAL USE ONLY!>
 944
 945 This will return an integer that is managed by L<Class::MOP::Class> to
 946 determine if a module's symbol table has been altered.
 947
 948 In Perl 5.10 or greater, this flag is package specific. However in
 949 versions prior to 5.10, this will use the C<PL_sub_generation>
 950 variable which is not package specific.
 951
 952 =item B<Class::MOP::load_first_existing_class(@class_names)>
 953
 954 B<NOTE: DO NOT USE THIS FUNCTION, IT IS FOR INTERNAL USE ONLY!>
 955
 956 Given a list of class names, this function will attempt to load each
 957 one in turn.
 958
 959 If it finds a class it can load, it will return that class' name.  If
 960 none of the classes can be loaded, it will throw an exception.
 961
 962 =back
 963
 964 =head2 Metaclass cache functions
 965
 966 Class::MOP holds a cache of metaclasses. The following are functions
 967 (B<not methods>) which can be used to access that cache. It is not
 968 recommended that you mess with these. Bad things could happen, but if
 969 you are brave and willing to risk it: go for it!
 970
 971 =over 4
 972
 973 =item B<Class::MOP::get_all_metaclasses>
 974
 975 This will return a hash of all the metaclass instances that have
 976 been cached by L<Class::MOP::Class>, keyed by the package name.
 977
 978 =item B<Class::MOP::get_all_metaclass_instances>
 979
 980 This will return a list of all the metaclass instances that have
 981 been cached by L<Class::MOP::Class>.
 982
 983 =item B<Class::MOP::get_all_metaclass_names>
 984
 985 This will return a list of all the metaclass names that have
 986 been cached by L<Class::MOP::Class>.
 987
 988 =item B<Class::MOP::get_metaclass_by_name($name)>
 989
 990 This will return a cached L<Class::MOP::Class> instance, or nothing
 991 if no metaclass exists with that C<$name>.
 992
 993 =item B<Class::MOP::store_metaclass_by_name($name, $meta)>
 994
 995 This will store a metaclass in the cache at the supplied C<$key>.
 996
 997 =item B<Class::MOP::weaken_metaclass($name)>
 998
 999 In rare cases (e.g. anonymous metaclasses) it is desirable to
1000 store a weakened reference in the metaclass cache. This
1001 function will weaken the reference to the metaclass stored
1002 in C<$name>.
1003
1004 =item B<Class::MOP::does_metaclass_exist($name)>
1005
1006 This will return true of there exists a metaclass stored in the
1007 C<$name> key, and return false otherwise.
1008
1009 =item B<Class::MOP::remove_metaclass_by_name($name)>
1010
1011 This will remove the metaclass stored in the C<$name> key.
1012
1013 =back
1014
1015 =head1 SEE ALSO
1016
1017 =head2 Books
1018
1019 There are very few books out on Meta Object Protocols and Metaclasses
1020 because it is such an esoteric topic. The following books are really
1021 the only ones I have found. If you know of any more, B<I<please>>
1022 email me and let me know, I would love to hear about them.
1023
1024 =over 4
1025
1026 =item I<The Art of the Meta Object Protocol>
1027
1028 =item I<Advances in Object-Oriented Metalevel Architecture and Reflection>
1029
1030 =item I<Putting MetaClasses to Work>
1031
1032 =item I<Smalltalk: The Language>
1033
1034 =back
1035
1036 =head2 Papers
1037
1038 =over 4
1039
1040 =item "Uniform and safe metaclass composition"
1041
1042 An excellent paper by the people who brought us the original Traits paper.
1043 This paper is on how Traits can be used to do safe metaclass composition,
1044 and offers an excellent introduction section which delves into the topic of
1045 metaclass compatibility.
1046
1047 L<http://www.iam.unibe.ch/~scg/Archive/Papers/Duca05ySafeMetaclassTrait.pdf>
1048
1049 =item "Safe Metaclass Programming"
1050
1051 This paper seems to precede the above paper, and propose a mix-in based
1052 approach as opposed to the Traits based approach. Both papers have similar
1053 information on the metaclass compatibility problem space.
1054
1055 L<http://citeseer.ist.psu.edu/37617.html>
1056
1057 =back
1058
1059 =head2 Prior Art
1060
1061 =over 4
1062
1063 =item The Perl 6 MetaModel work in the Pugs project
1064
1065 =over 4
1066
1067 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-MetaModel>
1068
1069 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-ObjectSpace>
1070
1071 =back
1072
1073 =back
1074
1075 =head2 Articles
1076
1077 =over 4
1078
1079 =item CPAN Module Review of Class::MOP
1080
1081 L<http://www.oreillynet.com/onlamp/blog/2006/06/cpan_module_review_classmop.html>
1082
1083 =back
1084
1085 =head1 SIMILAR MODULES
1086
1087 As I have said above, this module is a class-builder-builder, so it is
1088 not the same thing as modules like L<Class::Accessor> and
1089 L<Class::MethodMaker>. That being said there are very few modules on CPAN
1090 with similar goals to this module. The one I have found which is most
1091 like this module is L<Class::Meta>, although it's philosophy and the MOP it
1092 creates are very different from this modules.
1093
1094 =head1 BUGS
1095
1096 All complex software has bugs lurking in it, and this module is no
1097 exception.
1098
1099 Please report any bugs to C<bug-class-mop@rt.cpan.org>, or through the
1100 web interface at L<http://rt.cpan.org>.
1101
1102 You can also discuss feature requests or possible bugs on the Moose
1103 mailing list (moose@perl.org) or on IRC at
1104 L<irc://irc.perl.org/#moose>.
1105
1106 =head1 ACKNOWLEDGEMENTS
1107
1108 =over 4
1109
1110 =item Rob Kinyon
1111
1112 Thanks to Rob for actually getting the development of this module kick-started.
1113
1114 =back
1115
1116 =head1 AUTHORS
1117
1118 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1119
1120 B<with contributions from:>
1121
1122 Brandon (blblack) Black
1123
1124 Florian (rafl) Ragwitz
1125
1126 Guillermo (groditi) Roditi
1127
1128 Dave (autarch) Rolsky
1129
1130 Matt (mst) Trout
1131
1132 Rob (robkinyon) Kinyon
1133
1134 Yuval (nothingmuch) Kogman
1135
1136 Scott (konobi) McWhirter
1137
1138 =head1 COPYRIGHT AND LICENSE
1139
1140 Copyright 2006-2009 by Infinity Interactive, Inc.
1141
1142 L<http://www.iinteractive.com>
1143
1144 This library is free software; you can redistribute it and/or modify
1145 it under the same terms as Perl itself.
1146
1147 =cut