lib/Class/MOP.pm

   1
   2 package Class::MOP;
   3
   4 use strict;
   5 use warnings;
   6
   7 use 5.008;
   8
   9 use MRO::Compat;
  10
  11 use Carp          'confess';
  12 use Scalar::Util  'weaken', 'reftype', 'blessed';
  13
  14 use Class::MOP::Class;
  15 use Class::MOP::Attribute;
  16 use Class::MOP::Method;
  17
  18 BEGIN {
  19     *IS_RUNNING_ON_5_10 = ($] < 5.009_005)
  20         ? sub () { 0 }
  21         : sub () { 1 };
  22
  23     sub HAVE_ISAREV () {
  24         Carp::cluck("Class::MOP::HAVE_ISAREV is deprecated and will be removed in a future release. It has always returned 1 anyway.");
  25         return 1;
  26     }
  27
  28     # this is either part of core or set up appropriately by MRO::Compat
  29     *check_package_cache_flag = \&mro::get_pkg_gen;
  30 }
  31
  32 our $VERSION   = '0.83';
  33 our $XS_VERSION = $VERSION;
  34 $VERSION = eval $VERSION;
  35 our $AUTHORITY = 'cpan:STEVAN';
  36
  37 require XSLoader;
  38 XSLoader::load( __PACKAGE__, $XS_VERSION );
  39
  40
  41 {
  42     # Metaclasses are singletons, so we cache them here.
  43     # there is no need to worry about destruction though
  44     # because they should die only when the program dies.
  45     # After all, do package definitions even get reaped?
  46     my %METAS;
  47
  48     # means of accessing all the metaclasses that have
  49     # been initialized thus far (for mugwumps obj browser)
  50     sub get_all_metaclasses         {        %METAS         }
  51     sub get_all_metaclass_instances { values %METAS         }
  52     sub get_all_metaclass_names     { keys   %METAS         }
  53     sub get_metaclass_by_name       { $METAS{$_[0]}         }
  54     sub store_metaclass_by_name     { $METAS{$_[0]} = $_[1] }
  55     sub weaken_metaclass            { weaken($METAS{$_[0]}) }
  56     sub does_metaclass_exist        { exists $METAS{$_[0]} && defined $METAS{$_[0]} }
  57     sub remove_metaclass_by_name    { $METAS{$_[0]} = undef }
  58
  59     # This handles instances as well as class names
  60     sub class_of {
  61         return unless defined $_[0];
  62         my $class = blessed($_[0]) || $_[0];
  63         return $METAS{$class};
  64     }
  65
  66     # NOTE:
  67     # We only cache metaclasses, meaning instances of
  68     # Class::MOP::Class. We do not cache instance of
  69     # Class::MOP::Package or Class::MOP::Module. Mostly
  70     # because I don't yet see a good reason to do so.
  71 }
  72
  73 sub _class_to_pmfile {
  74     my $class = shift;
  75
  76     my $file = $class . '.pm';
  77     $file =~ s{::}{/}g;
  78
  79     return $file;
  80 }
  81
  82 sub load_first_existing_class {
  83     my @classes = @_
  84         or return;
  85
  86     foreach my $class (@classes) {
  87         unless ( _is_valid_class_name($class) ) {
  88             my $display = defined($class) ? $class : 'undef';
  89             confess "Invalid class name ($display)";
  90         }
  91     }
  92
  93     my $found;
  94     my %exceptions;
  95     for my $class (@classes) {
  96         my $pmfile = _class_to_pmfile($class);
  97         my $e = _try_load_one_class($class);
  98
  99         if ($e) {
 100             $exceptions{$class} = $e;
 101             last if $e !~ /^Can't locate \Q$pmfile\E in \@INC/;
 102         }
 103         else {
 104             $found = $class;
 105             last;
 106         }
 107     }
 108
 109     return $found if $found;
 110
 111     confess join(
 112         "\n",
 113         map {
 114             sprintf(
 115                 "Could not load class (%s) because : %s", $_,
 116                 $exceptions{$_}
 117                 )
 118             }
 119         grep {
 120             exists $exceptions{$_}
 121             } @classes
 122     );
 123 }
 124
 125 sub _try_load_one_class {
 126     my $class = shift;
 127
 128     return if is_class_loaded($class);
 129
 130     my $file = _class_to_pmfile($class);
 131
 132     return do {
 133         local $@;
 134         eval { require($file) };
 135         $@;
 136     };
 137 }
 138
 139 sub load_class {
 140     my $class = load_first_existing_class($_[0]);
 141     return get_metaclass_by_name($class) || $class;
 142 }
 143
 144 sub _is_valid_class_name {
 145     my $class = shift;
 146
 147     return 0 if ref($class);
 148     return 0 unless defined($class);
 149     return 0 unless length($class);
 150
 151     return 1 if $class =~ /^\w+(?:::\w+)*$/;
 152
 153     return 0;
 154 }
 155
 156 sub subname {
 157     require Sub::Name;
 158     Carp::carp("Class::MOP::subname is deprecated. Please use Sub::Name directly.");
 159     goto \&Sub::Name::subname;
 160 }
 161
 162 sub in_global_destruction {
 163     require Devel::GlobalDestruction;
 164     Carp::carp("Class::MOP::in_global_destruction is deprecated. Please use Devel::GlobalDestruction directly.");
 165     goto \&Devel::GlobalDestruction::in_global_destruction;
 166 }
 167
 168 ## ----------------------------------------------------------------------------
 169 ## Setting up our environment ...
 170 ## ----------------------------------------------------------------------------
 171 ## Class::MOP needs to have a few things in the global perl environment so
 172 ## that it can operate effectively. Those things are done here.
 173 ## ----------------------------------------------------------------------------
 174
 175 # ... nothing yet actually ;)
 176
 177 ## ----------------------------------------------------------------------------
 178 ## Bootstrapping
 179 ## ----------------------------------------------------------------------------
 180 ## The code below here is to bootstrap our MOP with itself. This is also
 181 ## sometimes called "tying the knot". By doing this, we make it much easier
 182 ## to extend the MOP through subclassing and such since now you can use the
 183 ## MOP itself to extend itself.
 184 ##
 185 ## Yes, I know, thats weird and insane, but it's a good thing, trust me :)
 186 ## ----------------------------------------------------------------------------
 187
 188 # We need to add in the meta-attributes here so that
 189 # any subclass of Class::MOP::* will be able to
 190 # inherit them using _construct_instance
 191
 192 ## --------------------------------------------------------
 193 ## Class::MOP::Package
 194
 195 Class::MOP::Package->meta->add_attribute(
 196     Class::MOP::Attribute->new('package' => (
 197         reader   => {
 198             # NOTE: we need to do this in order
 199             # for the instance meta-object to
 200             # not fall into meta-circular death
 201             #
 202             # we just alias the original method
 203             # rather than re-produce it here
 204             'name' => \&Class::MOP::Package::name
 205         },
 206     ))
 207 );
 208
 209 Class::MOP::Package->meta->add_attribute(
 210     Class::MOP::Attribute->new('namespace' => (
 211         reader => {
 212             # NOTE:
 213             # we just alias the original method
 214             # rather than re-produce it here
 215             'namespace' => \&Class::MOP::Package::namespace
 216         },
 217         init_arg => undef,
 218         default  => sub { \undef }
 219     ))
 220 );
 221
 222 ## --------------------------------------------------------
 223 ## Class::MOP::Module
 224
 225 # NOTE:
 226 # yeah this is kind of stretching things a bit,
 227 # but truthfully the version should be an attribute
 228 # of the Module, the weirdness comes from having to
 229 # stick to Perl 5 convention and store it in the
 230 # $VERSION package variable. Basically if you just
 231 # squint at it, it will look how you want it to look.
 232 # Either as a package variable, or as a attribute of
 233 # the metaclass, isn't abstraction great :)
 234
 235 Class::MOP::Module->meta->add_attribute(
 236     Class::MOP::Attribute->new('version' => (
 237         reader => {
 238             # NOTE:
 239             # we just alias the original method
 240             # rather than re-produce it here
 241             'version' => \&Class::MOP::Module::version
 242         },
 243         init_arg => undef,
 244         default  => sub { \undef }
 245     ))
 246 );
 247
 248 # NOTE:
 249 # By following the same conventions as version here,
 250 # we are opening up the possibility that people can
 251 # use the $AUTHORITY in non-Class::MOP modules as
 252 # well.
 253
 254 Class::MOP::Module->meta->add_attribute(
 255     Class::MOP::Attribute->new('authority' => (
 256         reader => {
 257             # NOTE:
 258             # we just alias the original method
 259             # rather than re-produce it here
 260             'authority' => \&Class::MOP::Module::authority
 261         },
 262         init_arg => undef,
 263         default  => sub { \undef }
 264     ))
 265 );
 266
 267 ## --------------------------------------------------------
 268 ## Class::MOP::Class
 269
 270 Class::MOP::Class->meta->add_attribute(
 271     Class::MOP::Attribute->new('attributes' => (
 272         reader   => {
 273             # NOTE: we need to do this in order
 274             # for the instance meta-object to
 275             # not fall into meta-circular death
 276             #
 277             # we just alias the original method
 278             # rather than re-produce it here
 279             'get_attribute_map' => \&Class::MOP::Class::get_attribute_map
 280         },
 281         default  => sub { {} }
 282     ))
 283 );
 284
 285 Class::MOP::Class->meta->add_attribute(
 286     Class::MOP::Attribute->new('methods' => (
 287         reader   => {
 288             # NOTE:
 289             # we just alias the original method
 290             # rather than re-produce it here
 291             'get_method_map' => \&Class::MOP::Class::get_method_map
 292         },
 293         default => sub { {} }
 294     ))
 295 );
 296
 297 Class::MOP::Class->meta->add_attribute(
 298     Class::MOP::Attribute->new('superclasses' => (
 299         accessor => {
 300             # NOTE:
 301             # we just alias the original method
 302             # rather than re-produce it here
 303             'superclasses' => \&Class::MOP::Class::superclasses
 304         },
 305         init_arg => undef,
 306         default  => sub { \undef }
 307     ))
 308 );
 309
 310 Class::MOP::Class->meta->add_attribute(
 311     Class::MOP::Attribute->new('attribute_metaclass' => (
 312         reader   => {
 313             # NOTE:
 314             # we just alias the original method
 315             # rather than re-produce it here
 316             'attribute_metaclass' => \&Class::MOP::Class::attribute_metaclass
 317         },
 318         default  => 'Class::MOP::Attribute',
 319     ))
 320 );
 321
 322 Class::MOP::Class->meta->add_attribute(
 323     Class::MOP::Attribute->new('method_metaclass' => (
 324         reader   => {
 325             # NOTE:
 326             # we just alias the original method
 327             # rather than re-produce it here
 328             'method_metaclass' => \&Class::MOP::Class::method_metaclass
 329         },
 330         default  => 'Class::MOP::Method',
 331     ))
 332 );
 333
 334 Class::MOP::Class->meta->add_attribute(
 335     Class::MOP::Attribute->new('wrapped_method_metaclass' => (
 336         reader   => {
 337             # NOTE:
 338             # we just alias the original method
 339             # rather than re-produce it here
 340             'wrapped_method_metaclass' => \&Class::MOP::Class::wrapped_method_metaclass
 341         },
 342         default  => 'Class::MOP::Method::Wrapped',
 343     ))
 344 );
 345
 346 Class::MOP::Class->meta->add_attribute(
 347     Class::MOP::Attribute->new('instance_metaclass' => (
 348         reader   => {
 349             # NOTE: we need to do this in order
 350             # for the instance meta-object to
 351             # not fall into meta-circular death
 352             #
 353             # we just alias the original method
 354             # rather than re-produce it here
 355             'instance_metaclass' => \&Class::MOP::Class::instance_metaclass
 356         },
 357         default  => 'Class::MOP::Instance',
 358     ))
 359 );
 360
 361 Class::MOP::Class->meta->add_attribute(
 362     Class::MOP::Attribute->new('immutable_trait' => (
 363         reader   => {
 364             'immutable_trait' => \&Class::MOP::Class::immutable_trait
 365         },
 366         default => "Class::MOP::Class::Immutable::Trait",
 367     ))
 368 );
 369
 370 Class::MOP::Class->meta->add_attribute(
 371     Class::MOP::Attribute->new('constructor_name' => (
 372         reader   => {
 373             'constructor_name' => \&Class::MOP::Class::constructor_name,
 374         },
 375         default => "new",
 376     ))
 377 );
 378
 379 Class::MOP::Class->meta->add_attribute(
 380     Class::MOP::Attribute->new('constructor_class' => (
 381         reader   => {
 382             'constructor_class' => \&Class::MOP::Class::constructor_class,
 383         },
 384         default => "Class::MOP::Method::Constructor",
 385     ))
 386 );
 387
 388
 389 Class::MOP::Class->meta->add_attribute(
 390     Class::MOP::Attribute->new('destructor_class' => (
 391         reader   => {
 392             'destructor_class' => \&Class::MOP::Class::destructor_class,
 393         },
 394     ))
 395 );
 396
 397 # NOTE:
 398 # we don't actually need to tie the knot with
 399 # Class::MOP::Class here, it is actually handled
 400 # within Class::MOP::Class itself in the
 401 # _construct_class_instance method.
 402
 403 ## --------------------------------------------------------
 404 ## Class::MOP::Attribute
 405
 406 Class::MOP::Attribute->meta->add_attribute(
 407     Class::MOP::Attribute->new('name' => (
 408         reader   => {
 409             # NOTE: we need to do this in order
 410             # for the instance meta-object to
 411             # not fall into meta-circular death
 412             #
 413             # we just alias the original method
 414             # rather than re-produce it here
 415             'name' => \&Class::MOP::Attribute::name
 416         }
 417     ))
 418 );
 419
 420 Class::MOP::Attribute->meta->add_attribute(
 421     Class::MOP::Attribute->new('associated_class' => (
 422         reader   => {
 423             # NOTE: we need to do this in order
 424             # for the instance meta-object to
 425             # not fall into meta-circular death
 426             #
 427             # we just alias the original method
 428             # rather than re-produce it here
 429             'associated_class' => \&Class::MOP::Attribute::associated_class
 430         }
 431     ))
 432 );
 433
 434 Class::MOP::Attribute->meta->add_attribute(
 435     Class::MOP::Attribute->new('accessor' => (
 436         reader    => { 'accessor'     => \&Class::MOP::Attribute::accessor     },
 437         predicate => { 'has_accessor' => \&Class::MOP::Attribute::has_accessor },
 438     ))
 439 );
 440
 441 Class::MOP::Attribute->meta->add_attribute(
 442     Class::MOP::Attribute->new('reader' => (
 443         reader    => { 'reader'     => \&Class::MOP::Attribute::reader     },
 444         predicate => { 'has_reader' => \&Class::MOP::Attribute::has_reader },
 445     ))
 446 );
 447
 448 Class::MOP::Attribute->meta->add_attribute(
 449     Class::MOP::Attribute->new('initializer' => (
 450         reader    => { 'initializer'     => \&Class::MOP::Attribute::initializer     },
 451         predicate => { 'has_initializer' => \&Class::MOP::Attribute::has_initializer },
 452     ))
 453 );
 454
 455 Class::MOP::Attribute->meta->add_attribute(
 456     Class::MOP::Attribute->new('definition_context' => (
 457         reader    => { 'definition_context'     => \&Class::MOP::Attribute::definition_context     },
 458     ))
 459 );
 460
 461 Class::MOP::Attribute->meta->add_attribute(
 462     Class::MOP::Attribute->new('writer' => (
 463         reader    => { 'writer'     => \&Class::MOP::Attribute::writer     },
 464         predicate => { 'has_writer' => \&Class::MOP::Attribute::has_writer },
 465     ))
 466 );
 467
 468 Class::MOP::Attribute->meta->add_attribute(
 469     Class::MOP::Attribute->new('predicate' => (
 470         reader    => { 'predicate'     => \&Class::MOP::Attribute::predicate     },
 471         predicate => { 'has_predicate' => \&Class::MOP::Attribute::has_predicate },
 472     ))
 473 );
 474
 475 Class::MOP::Attribute->meta->add_attribute(
 476     Class::MOP::Attribute->new('clearer' => (
 477         reader    => { 'clearer'     => \&Class::MOP::Attribute::clearer     },
 478         predicate => { 'has_clearer' => \&Class::MOP::Attribute::has_clearer },
 479     ))
 480 );
 481
 482 Class::MOP::Attribute->meta->add_attribute(
 483     Class::MOP::Attribute->new('builder' => (
 484         reader    => { 'builder'     => \&Class::MOP::Attribute::builder     },
 485         predicate => { 'has_builder' => \&Class::MOP::Attribute::has_builder },
 486     ))
 487 );
 488
 489 Class::MOP::Attribute->meta->add_attribute(
 490     Class::MOP::Attribute->new('init_arg' => (
 491         reader    => { 'init_arg'     => \&Class::MOP::Attribute::init_arg     },
 492         predicate => { 'has_init_arg' => \&Class::MOP::Attribute::has_init_arg },
 493     ))
 494 );
 495
 496 Class::MOP::Attribute->meta->add_attribute(
 497     Class::MOP::Attribute->new('default' => (
 498         # default has a custom 'reader' method ...
 499         predicate => { 'has_default' => \&Class::MOP::Attribute::has_default },
 500     ))
 501 );
 502
 503 Class::MOP::Attribute->meta->add_attribute(
 504     Class::MOP::Attribute->new('associated_methods' => (
 505         reader   => { 'associated_methods' => \&Class::MOP::Attribute::associated_methods },
 506         default  => sub { [] }
 507     ))
 508 );
 509
 510 Class::MOP::Attribute->meta->add_method('clone' => sub {
 511     my $self  = shift;
 512     $self->meta->clone_object($self, @_);
 513 });
 514
 515 ## --------------------------------------------------------
 516 ## Class::MOP::Method
 517 Class::MOP::Method->meta->add_attribute(
 518     Class::MOP::Attribute->new('body' => (
 519         reader   => { 'body' => \&Class::MOP::Method::body },
 520     ))
 521 );
 522
 523 Class::MOP::Method->meta->add_attribute(
 524     Class::MOP::Attribute->new('associated_metaclass' => (
 525         reader   => { 'associated_metaclass' => \&Class::MOP::Method::associated_metaclass },
 526     ))
 527 );
 528
 529 Class::MOP::Method->meta->add_attribute(
 530     Class::MOP::Attribute->new('package_name' => (
 531         reader   => { 'package_name' => \&Class::MOP::Method::package_name },
 532     ))
 533 );
 534
 535 Class::MOP::Method->meta->add_attribute(
 536     Class::MOP::Attribute->new('name' => (
 537         reader   => { 'name' => \&Class::MOP::Method::name },
 538     ))
 539 );
 540
 541 Class::MOP::Method->meta->add_attribute(
 542     Class::MOP::Attribute->new('original_method' => (
 543         reader   => { 'original_method'      => \&Class::MOP::Method::original_method },
 544         writer   => { '_set_original_method' => \&Class::MOP::Method::_set_original_method },
 545     ))
 546 );
 547
 548 Class::MOP::Method->meta->add_method('clone' => sub {
 549     my $self  = shift;
 550     my $clone = $self->meta->clone_object($self, @_);
 551     $clone->_set_original_method($self);
 552     return $clone;
 553 });
 554
 555 ## --------------------------------------------------------
 556 ## Class::MOP::Method::Wrapped
 557
 558 # NOTE:
 559 # the way this item is initialized, this
 560 # really does not follow the standard
 561 # practices of attributes, but we put
 562 # it here for completeness
 563 Class::MOP::Method::Wrapped->meta->add_attribute(
 564     Class::MOP::Attribute->new('modifier_table')
 565 );
 566
 567 ## --------------------------------------------------------
 568 ## Class::MOP::Method::Generated
 569
 570 Class::MOP::Method::Generated->meta->add_attribute(
 571     Class::MOP::Attribute->new('is_inline' => (
 572         reader   => { 'is_inline' => \&Class::MOP::Method::Generated::is_inline },
 573         default  => 0,
 574     ))
 575 );
 576
 577 Class::MOP::Method::Generated->meta->add_attribute(
 578     Class::MOP::Attribute->new('definition_context' => (
 579         reader   => { 'definition_context' => \&Class::MOP::Method::Generated::definition_context },
 580     ))
 581 );
 582
 583
 584 ## --------------------------------------------------------
 585 ## Class::MOP::Method::Inlined
 586
 587 Class::MOP::Method::Inlined->meta->add_attribute(
 588     Class::MOP::Attribute->new('_expected_method_class' => (
 589         reader   => { '_expected_method_class' => \&Class::MOP::Method::Inlined::_expected_method_class },
 590     ))
 591 );
 592
 593 ## --------------------------------------------------------
 594 ## Class::MOP::Method::Accessor
 595
 596 Class::MOP::Method::Accessor->meta->add_attribute(
 597     Class::MOP::Attribute->new('attribute' => (
 598         reader   => {
 599             'associated_attribute' => \&Class::MOP::Method::Accessor::associated_attribute
 600         },
 601     ))
 602 );
 603
 604 Class::MOP::Method::Accessor->meta->add_attribute(
 605     Class::MOP::Attribute->new('accessor_type' => (
 606         reader   => { 'accessor_type' => \&Class::MOP::Method::Accessor::accessor_type },
 607     ))
 608 );
 609
 610 ## --------------------------------------------------------
 611 ## Class::MOP::Method::Constructor
 612
 613 Class::MOP::Method::Constructor->meta->add_attribute(
 614     Class::MOP::Attribute->new('options' => (
 615         reader   => {
 616             'options' => \&Class::MOP::Method::Constructor::options
 617         },
 618         default  => sub { +{} }
 619     ))
 620 );
 621
 622 Class::MOP::Method::Constructor->meta->add_attribute(
 623     Class::MOP::Attribute->new('associated_metaclass' => (
 624         init_arg => "metaclass", # FIXME alias and rename
 625         reader   => {
 626             'associated_metaclass' => \&Class::MOP::Method::Constructor::associated_metaclass
 627         },
 628     ))
 629 );
 630
 631 ## --------------------------------------------------------
 632 ## Class::MOP::Instance
 633
 634 # NOTE:
 635 # these don't yet do much of anything, but are just
 636 # included for completeness
 637
 638 Class::MOP::Instance->meta->add_attribute(
 639     Class::MOP::Attribute->new('associated_metaclass',
 640         reader   => { associated_metaclass => \&Class::MOP::Instance::associated_metaclass },
 641     ),
 642 );
 643
 644 Class::MOP::Instance->meta->add_attribute(
 645     Class::MOP::Attribute->new('_class_name',
 646         init_arg => undef,
 647         reader   => { _class_name => \&Class::MOP::Instance::_class_name },
 648         #lazy     => 1, # not yet supported by Class::MOP but out our version does it anyway
 649         #default  => sub { $_[0]->associated_metaclass->name },
 650     ),
 651 );
 652
 653 Class::MOP::Instance->meta->add_attribute(
 654     Class::MOP::Attribute->new('attributes',
 655         reader   => { attributes => \&Class::MOP::Instance::get_all_attributes },
 656     ),
 657 );
 658
 659 Class::MOP::Instance->meta->add_attribute(
 660     Class::MOP::Attribute->new('slots',
 661         reader   => { slots => \&Class::MOP::Instance::slots },
 662     ),
 663 );
 664
 665 Class::MOP::Instance->meta->add_attribute(
 666     Class::MOP::Attribute->new('slot_hash',
 667         reader   => { slot_hash => \&Class::MOP::Instance::slot_hash },
 668     ),
 669 );
 670
 671
 672 # we need the meta instance of the meta instance to be created now, in order
 673 # for the constructor to be able to use it
 674 Class::MOP::Instance->meta->get_meta_instance;
 675
 676 # pretend the add_method never happenned. it hasn't yet affected anything
 677 undef Class::MOP::Instance->meta->{_package_cache_flag};
 678
 679 ## --------------------------------------------------------
 680 ## Now close all the Class::MOP::* classes
 681
 682 # NOTE: we don't need to inline the the accessors this only lengthens
 683 # the compile time of the MOP, and gives us no actual benefits.
 684
 685 # this is just nitpicking to ensure Class::MOP::Class->meta == ->meta->meta
 686 Class::MOP::Class->meta->_immutable_metaclass;
 687 $Class::MOP::Class::immutable_metaclass_cache{"Class::MOP::Class"}{"Class::MOP::Class::Immutable::Trait"} = Class::MOP::Class::Immutable::Class::MOP::Class->meta;
 688
 689 $_->meta->make_immutable(
 690     inline_constructor  => 1,
 691     replace_constructor => 1,
 692     constructor_name    => "_new",
 693     inline_accessors => 0,
 694 ) for qw/
 695     Class::MOP::Package
 696     Class::MOP::Module
 697     Class::MOP::Class
 698     Class::MOP::Class::Immutable::Trait
 699     Class::MOP::Class::Immutable::Class::MOP::Class
 700
 701     Class::MOP::Attribute
 702     Class::MOP::Method
 703     Class::MOP::Instance
 704
 705     Class::MOP::Object
 706
 707     Class::MOP::Method::Generated
 708     Class::MOP::Method::Inlined
 709
 710     Class::MOP::Method::Accessor
 711     Class::MOP::Method::Constructor
 712     Class::MOP::Method::Wrapped
 713 /;
 714
 715 1;
 716
 717 __END__
 718
 719 =pod
 720
 721 =head1 NAME
 722
 723 Class::MOP - A Meta Object Protocol for Perl 5
 724
 725 =head1 DESCRIPTION
 726
 727 This module is a fully functioning meta object protocol for the
 728 Perl 5 object system. It makes no attempt to change the behavior or
 729 characteristics of the Perl 5 object system, only to create a
 730 protocol for its manipulation and introspection.
 731
 732 That said, it does attempt to create the tools for building a rich set
 733 of extensions to the Perl 5 object system. Every attempt has been made
 734 to abide by the spirit of the Perl 5 object system that we all know
 735 and love.
 736
 737 This documentation is sparse on conceptual details. We suggest looking
 738 at the items listed in the L<SEE ALSO> section for more
 739 information. In particular the book "The Art of the Meta Object
 740 Protocol" was very influential in the development of this system.
 741
 742 =head2 What is a Meta Object Protocol?
 743
 744 A meta object protocol is an API to an object system.
 745
 746 To be more specific, it abstracts the components of an object system
 747 (classes, object, methods, object attributes, etc.). These
 748 abstractions can then be used to inspect and manipulate the object
 749 system which they describe.
 750
 751 It can be said that there are two MOPs for any object system; the
 752 implicit MOP and the explicit MOP. The implicit MOP handles things
 753 like method dispatch or inheritance, which happen automatically as
 754 part of how the object system works. The explicit MOP typically
 755 handles the introspection/reflection features of the object system.
 756
 757 All object systems have implicit MOPs. Without one, they would not
 758 work. Explicit MOPs are much less common, and depending on the
 759 language can vary from restrictive (Reflection in Java or C#) to wide
 760 open (CLOS is a perfect example).
 761
 762 =head2 Yet Another Class Builder! Why?
 763
 764 This is B<not> a class builder so much as a I<class builder
 765 B<builder>>. The intent is that an end user will not use this module
 766 directly, but instead this module is used by module authors to build
 767 extensions and features onto the Perl 5 object system.
 768
 769 This system is used by L<Moose>, which supplies a powerful class
 770 builder system built entirely on top of C<Class::MOP>.
 771
 772 =head2 Who is this module for?
 773
 774 This module is for anyone who has ever created or wanted to create a
 775 module for the Class:: namespace. The tools which this module provides
 776 make doing complex Perl 5 wizardry simpler, by removing such barriers
 777 as the need to hack symbol tables, or understand the fine details of
 778 method dispatch.
 779
 780 =head2 What changes do I have to make to use this module?
 781
 782 This module was designed to be as unintrusive as possible. Many of its
 783 features are accessible without B<any> change to your existing
 784 code. It is meant to be a compliment to your existing code and not an
 785 intrusion on your code base. Unlike many other B<Class::> modules,
 786 this module B<does not> require you subclass it, or even that you
 787 C<use> it in within your module's package.
 788
 789 The only features which requires additions to your code are the
 790 attribute handling and instance construction features, and these are
 791 both completely optional features. The only reason for this is because
 792 Perl 5's object system does not actually have these features built
 793 in. More information about this feature can be found below.
 794
 795 =head2 About Performance
 796
 797 It is a common misconception that explicit MOPs are a performance hit.
 798 This is not a universal truth, it is a side-effect of some specific
 799 implementations. For instance, using Java reflection is slow because
 800 the JVM cannot take advantage of any compiler optimizations, and the
 801 JVM has to deal with much more runtime type information as well.
 802
 803 Reflection in C# is marginally better as it was designed into the
 804 language and runtime (the CLR). In contrast, CLOS (the Common Lisp
 805 Object System) was built to support an explicit MOP, and so
 806 performance is tuned for it.
 807
 808 This library in particular does its absolute best to avoid putting
 809 B<any> drain at all upon your code's performance. In fact, by itself
 810 it does nothing to affect your existing code. So you only pay for what
 811 you actually use.
 812
 813 =head2 About Metaclass compatibility
 814
 815 This module makes sure that all metaclasses created are both upwards
 816 and downwards compatible. The topic of metaclass compatibility is
 817 highly esoteric and is something only encountered when doing deep and
 818 involved metaclass hacking. There are two basic kinds of metaclass
 819 incompatibility; upwards and downwards.
 820
 821 Upwards metaclass compatibility means that the metaclass of a
 822 given class is either the same as (or a subclass of) all of the
 823 class's ancestors.
 824
 825 Downward metaclass compatibility means that the metaclasses of a
 826 given class's ancestors are all either the same as (or a subclass
 827 of) that metaclass.
 828
 829 Here is a diagram showing a set of two classes (C<A> and C<B>) and
 830 two metaclasses (C<Meta::A> and C<Meta::B>) which have correct
 831 metaclass compatibility both upwards and downwards.
 832
 833     +---------+     +---------+
 834     | Meta::A |<----| Meta::B |      <....... (instance of  )
 835     +---------+     +---------+      <------- (inherits from)
 836          ^               ^
 837          :               :
 838     +---------+     +---------+
 839     |    A    |<----|    B    |
 840     +---------+     +---------+
 841
 842 As I said this is a highly esoteric topic and one you will only run
 843 into if you do a lot of subclassing of L<Class::MOP::Class>. If you
 844 are interested in why this is an issue see the paper I<Uniform and
 845 safe metaclass composition> linked to in the L<SEE ALSO> section of
 846 this document.
 847
 848 =head2 Using custom metaclasses
 849
 850 Always use the L<metaclass> pragma when using a custom metaclass, this
 851 will ensure the proper initialization order and not accidentally
 852 create an incorrect type of metaclass for you. This is a very rare
 853 problem, and one which can only occur if you are doing deep metaclass
 854 programming. So in other words, don't worry about it.
 855
 856 Note that if you're using L<Moose> we encourage you to I<not> use
 857 L<metaclass> pragma, and instead use L<Moose::Util::MetaRole> to apply
 858 roles to a class's metaclasses. This topic is covered at length in
 859 various L<Moose::Cookbook> recipes.
 860
 861 =head1 PROTOCOLS
 862
 863 The meta-object protocol is divided into 4 main sub-protocols:
 864
 865 =head2 The Class protocol
 866
 867 This provides a means of manipulating and introspecting a Perl 5
 868 class. It handles symbol table hacking for you, and provides a rich
 869 set of methods that go beyond simple package introspection.
 870
 871 See L<Class::MOP::Class> for more details.
 872
 873 =head2 The Attribute protocol
 874
 875 This provides a consistent representation for an attribute of a Perl 5
 876 class. Since there are so many ways to create and handle attributes in
 877 Perl 5 OO, the Attribute protocol provide as much of a unified
 878 approach as possible. Of course, you are always free to extend this
 879 protocol by subclassing the appropriate classes.
 880
 881 See L<Class::MOP::Attribute> for more details.
 882
 883 =head2 The Method protocol
 884
 885 This provides a means of manipulating and introspecting methods in the
 886 Perl 5 object system. As with attributes, there are many ways to
 887 approach this topic, so we try to keep it pretty basic, while still
 888 making it possible to extend the system in many ways.
 889
 890 See L<Class::MOP::Method> for more details.
 891
 892 =head2 The Instance protocol
 893
 894 This provides a layer of abstraction for creating object instances.
 895 Since the other layers use this protocol, it is relatively easy to
 896 change the type of your instances from the default hash reference to
 897 some other type of reference. Several examples are provided in the
 898 F<examples/> directory included in this distribution.
 899
 900 See L<Class::MOP::Instance> for more details.
 901
 902 =head1 FUNCTIONS
 903
 904 Note that this module does not export any constants or functions.
 905
 906 =head2 Constants
 907
 908 =over 4
 909
 910 =item I<Class::MOP::IS_RUNNING_ON_5_10>
 911
 912 We set this constant depending on what version perl we are on, this
 913 allows us to take advantage of new 5.10 features and stay backwards
 914 compatible.
 915
 916 =back
 917
 918 =head2 Utility functions
 919
 920 Note that these are all called as B<functions, not methods>.
 921
 922 =over 4
 923
 924 =item B<Class::MOP::load_class($class_name)>
 925
 926 This will load the specified C<$class_name>. This function can be used
 927 in place of tricks like C<eval "use $module"> or using C<require>
 928 unconditionally. This will return the metaclass of C<$class_name>.
 929
 930 =item B<Class::MOP::is_class_loaded($class_name)>
 931
 932 Returns a boolean indicating whether or not C<$class_name> has been
 933 loaded.
 934
 935 This does a basic check of the symbol table to try and determine as
 936 best it can if the C<$class_name> is loaded, it is probably correct
 937 about 99% of the time, but it can be fooled into reporting false
 938 positives.
 939
 940 =item B<Class::MOP::get_code_info($code)>
 941
 942 This function returns two values, the name of the package the C<$code>
 943 is from and the name of the C<$code> itself. This is used by several
 944 elements of the MOP to determine where a given C<$code> reference is
 945 from.
 946
 947 =item B<Class::MOP::class_of($instance_or_class_name)>
 948
 949 This will return the metaclass of the given instance or class name.
 950 Even if the class lacks a metaclass, no metaclass will be initialized
 951 and C<undef> will be returned.
 952
 953 =item B<Class::MOP::check_package_cache_flag($pkg)>
 954
 955 B<NOTE: DO NOT USE THIS FUNCTION, IT IS FOR INTERNAL USE ONLY!>
 956
 957 This will return an integer that is managed by L<Class::MOP::Class> to
 958 determine if a module's symbol table has been altered.
 959
 960 In Perl 5.10 or greater, this flag is package specific. However in
 961 versions prior to 5.10, this will use the C<PL_sub_generation>
 962 variable which is not package specific.
 963
 964 =item B<Class::MOP::load_first_existing_class(@class_names)>
 965
 966 B<NOTE: DO NOT USE THIS FUNCTION, IT IS FOR INTERNAL USE ONLY!>
 967
 968 Given a list of class names, this function will attempt to load each
 969 one in turn.
 970
 971 If it finds a class it can load, it will return that class' name.  If
 972 none of the classes can be loaded, it will throw an exception.
 973
 974 =back
 975
 976 =head2 Metaclass cache functions
 977
 978 Class::MOP holds a cache of metaclasses. The following are functions
 979 (B<not methods>) which can be used to access that cache. It is not
 980 recommended that you mess with these. Bad things could happen, but if
 981 you are brave and willing to risk it: go for it!
 982
 983 =over 4
 984
 985 =item B<Class::MOP::get_all_metaclasses>
 986
 987 This will return a hash of all the metaclass instances that have
 988 been cached by L<Class::MOP::Class>, keyed by the package name.
 989
 990 =item B<Class::MOP::get_all_metaclass_instances>
 991
 992 This will return a list of all the metaclass instances that have
 993 been cached by L<Class::MOP::Class>.
 994
 995 =item B<Class::MOP::get_all_metaclass_names>
 996
 997 This will return a list of all the metaclass names that have
 998 been cached by L<Class::MOP::Class>.
 999
1000 =item B<Class::MOP::get_metaclass_by_name($name)>
1001
1002 This will return a cached L<Class::MOP::Class> instance, or nothing
1003 if no metaclass exists with that C<$name>.
1004
1005 =item B<Class::MOP::store_metaclass_by_name($name, $meta)>
1006
1007 This will store a metaclass in the cache at the supplied C<$key>.
1008
1009 =item B<Class::MOP::weaken_metaclass($name)>
1010
1011 In rare cases (e.g. anonymous metaclasses) it is desirable to
1012 store a weakened reference in the metaclass cache. This
1013 function will weaken the reference to the metaclass stored
1014 in C<$name>.
1015
1016 =item B<Class::MOP::does_metaclass_exist($name)>
1017
1018 This will return true of there exists a metaclass stored in the
1019 C<$name> key, and return false otherwise.
1020
1021 =item B<Class::MOP::remove_metaclass_by_name($name)>
1022
1023 This will remove the metaclass stored in the C<$name> key.
1024
1025 =back
1026
1027 =head1 SEE ALSO
1028
1029 =head2 Books
1030
1031 There are very few books out on Meta Object Protocols and Metaclasses
1032 because it is such an esoteric topic. The following books are really
1033 the only ones I have found. If you know of any more, B<I<please>>
1034 email me and let me know, I would love to hear about them.
1035
1036 =over 4
1037
1038 =item I<The Art of the Meta Object Protocol>
1039
1040 =item I<Advances in Object-Oriented Metalevel Architecture and Reflection>
1041
1042 =item I<Putting MetaClasses to Work>
1043
1044 =item I<Smalltalk: The Language>
1045
1046 =back
1047
1048 =head2 Papers
1049
1050 =over 4
1051
1052 =item "Uniform and safe metaclass composition"
1053
1054 An excellent paper by the people who brought us the original Traits paper.
1055 This paper is on how Traits can be used to do safe metaclass composition,
1056 and offers an excellent introduction section which delves into the topic of
1057 metaclass compatibility.
1058
1059 L<http://www.iam.unibe.ch/~scg/Archive/Papers/Duca05ySafeMetaclassTrait.pdf>
1060
1061 =item "Safe Metaclass Programming"
1062
1063 This paper seems to precede the above paper, and propose a mix-in based
1064 approach as opposed to the Traits based approach. Both papers have similar
1065 information on the metaclass compatibility problem space.
1066
1067 L<http://citeseer.ist.psu.edu/37617.html>
1068
1069 =back
1070
1071 =head2 Prior Art
1072
1073 =over 4
1074
1075 =item The Perl 6 MetaModel work in the Pugs project
1076
1077 =over 4
1078
1079 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-MetaModel>
1080
1081 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-ObjectSpace>
1082
1083 =back
1084
1085 =back
1086
1087 =head2 Articles
1088
1089 =over 4
1090
1091 =item CPAN Module Review of Class::MOP
1092
1093 L<http://www.oreillynet.com/onlamp/blog/2006/06/cpan_module_review_classmop.html>
1094
1095 =back
1096
1097 =head1 SIMILAR MODULES
1098
1099 As I have said above, this module is a class-builder-builder, so it is
1100 not the same thing as modules like L<Class::Accessor> and
1101 L<Class::MethodMaker>. That being said there are very few modules on CPAN
1102 with similar goals to this module. The one I have found which is most
1103 like this module is L<Class::Meta>, although it's philosophy and the MOP it
1104 creates are very different from this modules.
1105
1106 =head1 BUGS
1107
1108 All complex software has bugs lurking in it, and this module is no
1109 exception.
1110
1111 Please report any bugs to C<bug-class-mop@rt.cpan.org>, or through the
1112 web interface at L<http://rt.cpan.org>.
1113
1114 You can also discuss feature requests or possible bugs on the Moose
1115 mailing list (moose@perl.org) or on IRC at
1116 L<irc://irc.perl.org/#moose>.
1117
1118 =head1 ACKNOWLEDGEMENTS
1119
1120 =over 4
1121
1122 =item Rob Kinyon
1123
1124 Thanks to Rob for actually getting the development of this module kick-started.
1125
1126 =back
1127
1128 =head1 AUTHORS
1129
1130 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1131
1132 B<with contributions from:>
1133
1134 Brandon (blblack) Black
1135
1136 Florian (rafl) Ragwitz
1137
1138 Guillermo (groditi) Roditi
1139
1140 Dave (autarch) Rolsky
1141
1142 Matt (mst) Trout
1143
1144 Rob (robkinyon) Kinyon
1145
1146 Yuval (nothingmuch) Kogman
1147
1148 Scott (konobi) McWhirter
1149
1150 =head1 COPYRIGHT AND LICENSE
1151
1152 Copyright 2006-2009 by Infinity Interactive, Inc.
1153
1154 L<http://www.iinteractive.com>
1155
1156 This library is free software; you can redistribute it and/or modify
1157 it under the same terms as Perl itself.
1158
1159 =cut