lib/Class/MOP.pm

   1
   2 package Class::MOP;
   3
   4 use strict;
   5 use warnings;
   6
   7 use 5.008;
   8
   9 use MRO::Compat;
  10
  11 use Carp          'confess';
  12 use Scalar::Util  'weaken', 'reftype', 'blessed';
  13
  14 use Class::MOP::Class;
  15 use Class::MOP::Attribute;
  16 use Class::MOP::Method;
  17
  18 BEGIN {
  19     *IS_RUNNING_ON_5_10 = ($] < 5.009_005)
  20         ? sub () { 0 }
  21         : sub () { 1 };
  22
  23     sub HAVE_ISAREV () {
  24         Carp::cluck("Class::MOP::HAVE_ISAREV is deprecated and will be removed in a future release. It has always returned 1 anyway.");
  25         return 1;
  26     }
  27
  28     # this is either part of core or set up appropriately by MRO::Compat
  29     *check_package_cache_flag = \&mro::get_pkg_gen;
  30 }
  31
  32 our $VERSION   = '0.88';
  33 our $XS_VERSION = $VERSION;
  34 $VERSION = eval $VERSION;
  35 our $AUTHORITY = 'cpan:STEVAN';
  36
  37 require XSLoader;
  38 XSLoader::load( __PACKAGE__, $XS_VERSION );
  39
  40
  41 {
  42     # Metaclasses are singletons, so we cache them here.
  43     # there is no need to worry about destruction though
  44     # because they should die only when the program dies.
  45     # After all, do package definitions even get reaped?
  46     my %METAS;
  47
  48     # means of accessing all the metaclasses that have
  49     # been initialized thus far (for mugwumps obj browser)
  50     sub get_all_metaclasses         {        %METAS         }
  51     sub get_all_metaclass_instances { values %METAS         }
  52     sub get_all_metaclass_names     { keys   %METAS         }
  53     sub get_metaclass_by_name       { $METAS{$_[0]}         }
  54     sub store_metaclass_by_name     { $METAS{$_[0]} = $_[1] }
  55     sub weaken_metaclass            { weaken($METAS{$_[0]}) }
  56     sub does_metaclass_exist        { exists $METAS{$_[0]} && defined $METAS{$_[0]} }
  57     sub remove_metaclass_by_name    { $METAS{$_[0]} = undef }
  58
  59     # This handles instances as well as class names
  60     sub class_of {
  61         return unless defined $_[0];
  62         my $class = blessed($_[0]) || $_[0];
  63         return $METAS{$class};
  64     }
  65
  66     # NOTE:
  67     # We only cache metaclasses, meaning instances of
  68     # Class::MOP::Class. We do not cache instance of
  69     # Class::MOP::Package or Class::MOP::Module. Mostly
  70     # because I don't yet see a good reason to do so.
  71 }
  72
  73 sub _class_to_pmfile {
  74     my $class = shift;
  75
  76     my $file = $class . '.pm';
  77     $file =~ s{::}{/}g;
  78
  79     return $file;
  80 }
  81
  82 sub load_first_existing_class {
  83     my @classes = @_
  84         or return;
  85
  86     foreach my $class (@classes) {
  87         unless ( _is_valid_class_name($class) ) {
  88             my $display = defined($class) ? $class : 'undef';
  89             confess "Invalid class name ($display)";
  90         }
  91     }
  92
  93     my $found;
  94     my %exceptions;
  95     for my $class (@classes) {
  96         my $pmfile = _class_to_pmfile($class);
  97         my $e = _try_load_one_class($class);
  98
  99         if ($e) {
 100             $exceptions{$class} = $e;
 101             last if $e !~ /^Can't locate \Q$pmfile\E in \@INC/;
 102         }
 103         else {
 104             $found = $class;
 105             last;
 106         }
 107     }
 108
 109     return $found if $found;
 110
 111     confess join(
 112         "\n",
 113         map {
 114             sprintf(
 115                 "Could not load class (%s) because : %s", $_,
 116                 $exceptions{$_}
 117                 )
 118             }
 119         grep {
 120             exists $exceptions{$_}
 121             } @classes
 122     );
 123 }
 124
 125 sub _try_load_one_class {
 126     my $class = shift;
 127
 128     return if is_class_loaded($class);
 129
 130     my $file = _class_to_pmfile($class);
 131
 132     return do {
 133         local $@;
 134         local $SIG{__DIE__};
 135         eval { require($file) };
 136         $@;
 137     };
 138 }
 139
 140 sub load_class {
 141     my $class = load_first_existing_class($_[0]);
 142     return get_metaclass_by_name($class) || $class;
 143 }
 144
 145 sub _is_valid_class_name {
 146     my $class = shift;
 147
 148     return 0 if ref($class);
 149     return 0 unless defined($class);
 150     return 0 unless length($class);
 151
 152     return 1 if $class =~ /^\w+(?:::\w+)*$/;
 153
 154     return 0;
 155 }
 156
 157 sub subname {
 158     require Sub::Name;
 159     Carp::carp("Class::MOP::subname is deprecated. Please use Sub::Name directly.");
 160     goto \&Sub::Name::subname;
 161 }
 162
 163 sub in_global_destruction {
 164     require Devel::GlobalDestruction;
 165     Carp::carp("Class::MOP::in_global_destruction is deprecated. Please use Devel::GlobalDestruction directly.");
 166     goto \&Devel::GlobalDestruction::in_global_destruction;
 167 }
 168
 169 ## ----------------------------------------------------------------------------
 170 ## Setting up our environment ...
 171 ## ----------------------------------------------------------------------------
 172 ## Class::MOP needs to have a few things in the global perl environment so
 173 ## that it can operate effectively. Those things are done here.
 174 ## ----------------------------------------------------------------------------
 175
 176 # ... nothing yet actually ;)
 177
 178 ## ----------------------------------------------------------------------------
 179 ## Bootstrapping
 180 ## ----------------------------------------------------------------------------
 181 ## The code below here is to bootstrap our MOP with itself. This is also
 182 ## sometimes called "tying the knot". By doing this, we make it much easier
 183 ## to extend the MOP through subclassing and such since now you can use the
 184 ## MOP itself to extend itself.
 185 ##
 186 ## Yes, I know, thats weird and insane, but it's a good thing, trust me :)
 187 ## ----------------------------------------------------------------------------
 188
 189 # We need to add in the meta-attributes here so that
 190 # any subclass of Class::MOP::* will be able to
 191 # inherit them using _construct_instance
 192
 193 ## --------------------------------------------------------
 194 ## Class::MOP::Package
 195
 196 Class::MOP::Package->meta->add_attribute(
 197     Class::MOP::Attribute->new('package' => (
 198         reader   => {
 199             # NOTE: we need to do this in order
 200             # for the instance meta-object to
 201             # not fall into meta-circular death
 202             #
 203             # we just alias the original method
 204             # rather than re-produce it here
 205             'name' => \&Class::MOP::Package::name
 206         },
 207     ))
 208 );
 209
 210 Class::MOP::Package->meta->add_attribute(
 211     Class::MOP::Attribute->new('namespace' => (
 212         reader => {
 213             # NOTE:
 214             # we just alias the original method
 215             # rather than re-produce it here
 216             'namespace' => \&Class::MOP::Package::namespace
 217         },
 218         init_arg => undef,
 219         default  => sub { \undef }
 220     ))
 221 );
 222
 223 ## --------------------------------------------------------
 224 ## Class::MOP::Module
 225
 226 # NOTE:
 227 # yeah this is kind of stretching things a bit,
 228 # but truthfully the version should be an attribute
 229 # of the Module, the weirdness comes from having to
 230 # stick to Perl 5 convention and store it in the
 231 # $VERSION package variable. Basically if you just
 232 # squint at it, it will look how you want it to look.
 233 # Either as a package variable, or as a attribute of
 234 # the metaclass, isn't abstraction great :)
 235
 236 Class::MOP::Module->meta->add_attribute(
 237     Class::MOP::Attribute->new('version' => (
 238         reader => {
 239             # NOTE:
 240             # we just alias the original method
 241             # rather than re-produce it here
 242             'version' => \&Class::MOP::Module::version
 243         },
 244         init_arg => undef,
 245         default  => sub { \undef }
 246     ))
 247 );
 248
 249 # NOTE:
 250 # By following the same conventions as version here,
 251 # we are opening up the possibility that people can
 252 # use the $AUTHORITY in non-Class::MOP modules as
 253 # well.
 254
 255 Class::MOP::Module->meta->add_attribute(
 256     Class::MOP::Attribute->new('authority' => (
 257         reader => {
 258             # NOTE:
 259             # we just alias the original method
 260             # rather than re-produce it here
 261             'authority' => \&Class::MOP::Module::authority
 262         },
 263         init_arg => undef,
 264         default  => sub { \undef }
 265     ))
 266 );
 267
 268 ## --------------------------------------------------------
 269 ## Class::MOP::Class
 270
 271 Class::MOP::Class->meta->add_attribute(
 272     Class::MOP::Attribute->new('attributes' => (
 273         reader   => {
 274             # NOTE: we need to do this in order
 275             # for the instance meta-object to
 276             # not fall into meta-circular death
 277             #
 278             # we just alias the original method
 279             # rather than re-produce it here
 280             'get_attribute_map' => \&Class::MOP::Class::get_attribute_map
 281         },
 282         default  => sub { {} }
 283     ))
 284 );
 285
 286 Class::MOP::Class->meta->add_attribute(
 287     Class::MOP::Attribute->new('methods' => (
 288         reader   => {
 289             # NOTE:
 290             # we just alias the original method
 291             # rather than re-produce it here
 292             'get_method_map' => \&Class::MOP::Class::get_method_map
 293         },
 294         default => sub { {} }
 295     ))
 296 );
 297
 298 Class::MOP::Class->meta->add_attribute(
 299     Class::MOP::Attribute->new('superclasses' => (
 300         accessor => {
 301             # NOTE:
 302             # we just alias the original method
 303             # rather than re-produce it here
 304             'superclasses' => \&Class::MOP::Class::superclasses
 305         },
 306         init_arg => undef,
 307         default  => sub { \undef }
 308     ))
 309 );
 310
 311 Class::MOP::Class->meta->add_attribute(
 312     Class::MOP::Attribute->new('attribute_metaclass' => (
 313         reader   => {
 314             # NOTE:
 315             # we just alias the original method
 316             # rather than re-produce it here
 317             'attribute_metaclass' => \&Class::MOP::Class::attribute_metaclass
 318         },
 319         default  => 'Class::MOP::Attribute',
 320     ))
 321 );
 322
 323 Class::MOP::Class->meta->add_attribute(
 324     Class::MOP::Attribute->new('method_metaclass' => (
 325         reader   => {
 326             # NOTE:
 327             # we just alias the original method
 328             # rather than re-produce it here
 329             'method_metaclass' => \&Class::MOP::Class::method_metaclass
 330         },
 331         default  => 'Class::MOP::Method',
 332     ))
 333 );
 334
 335 Class::MOP::Class->meta->add_attribute(
 336     Class::MOP::Attribute->new('wrapped_method_metaclass' => (
 337         reader   => {
 338             # NOTE:
 339             # we just alias the original method
 340             # rather than re-produce it here
 341             'wrapped_method_metaclass' => \&Class::MOP::Class::wrapped_method_metaclass
 342         },
 343         default  => 'Class::MOP::Method::Wrapped',
 344     ))
 345 );
 346
 347 Class::MOP::Class->meta->add_attribute(
 348     Class::MOP::Attribute->new('instance_metaclass' => (
 349         reader   => {
 350             # NOTE: we need to do this in order
 351             # for the instance meta-object to
 352             # not fall into meta-circular death
 353             #
 354             # we just alias the original method
 355             # rather than re-produce it here
 356             'instance_metaclass' => \&Class::MOP::Class::instance_metaclass
 357         },
 358         default  => 'Class::MOP::Instance',
 359     ))
 360 );
 361
 362 Class::MOP::Class->meta->add_attribute(
 363     Class::MOP::Attribute->new('immutable_trait' => (
 364         reader   => {
 365             'immutable_trait' => \&Class::MOP::Class::immutable_trait
 366         },
 367         default => "Class::MOP::Class::Immutable::Trait",
 368     ))
 369 );
 370
 371 Class::MOP::Class->meta->add_attribute(
 372     Class::MOP::Attribute->new('constructor_name' => (
 373         reader   => {
 374             'constructor_name' => \&Class::MOP::Class::constructor_name,
 375         },
 376         default => "new",
 377     ))
 378 );
 379
 380 Class::MOP::Class->meta->add_attribute(
 381     Class::MOP::Attribute->new('constructor_class' => (
 382         reader   => {
 383             'constructor_class' => \&Class::MOP::Class::constructor_class,
 384         },
 385         default => "Class::MOP::Method::Constructor",
 386     ))
 387 );
 388
 389
 390 Class::MOP::Class->meta->add_attribute(
 391     Class::MOP::Attribute->new('destructor_class' => (
 392         reader   => {
 393             'destructor_class' => \&Class::MOP::Class::destructor_class,
 394         },
 395     ))
 396 );
 397
 398 # NOTE:
 399 # we don't actually need to tie the knot with
 400 # Class::MOP::Class here, it is actually handled
 401 # within Class::MOP::Class itself in the
 402 # _construct_class_instance method.
 403
 404 ## --------------------------------------------------------
 405 ## Class::MOP::Attribute
 406
 407 Class::MOP::Attribute->meta->add_attribute(
 408     Class::MOP::Attribute->new('name' => (
 409         reader   => {
 410             # NOTE: we need to do this in order
 411             # for the instance meta-object to
 412             # not fall into meta-circular death
 413             #
 414             # we just alias the original method
 415             # rather than re-produce it here
 416             'name' => \&Class::MOP::Attribute::name
 417         }
 418     ))
 419 );
 420
 421 Class::MOP::Attribute->meta->add_attribute(
 422     Class::MOP::Attribute->new('associated_class' => (
 423         reader   => {
 424             # NOTE: we need to do this in order
 425             # for the instance meta-object to
 426             # not fall into meta-circular death
 427             #
 428             # we just alias the original method
 429             # rather than re-produce it here
 430             'associated_class' => \&Class::MOP::Attribute::associated_class
 431         }
 432     ))
 433 );
 434
 435 Class::MOP::Attribute->meta->add_attribute(
 436     Class::MOP::Attribute->new('accessor' => (
 437         reader    => { 'accessor'     => \&Class::MOP::Attribute::accessor     },
 438         predicate => { 'has_accessor' => \&Class::MOP::Attribute::has_accessor },
 439     ))
 440 );
 441
 442 Class::MOP::Attribute->meta->add_attribute(
 443     Class::MOP::Attribute->new('reader' => (
 444         reader    => { 'reader'     => \&Class::MOP::Attribute::reader     },
 445         predicate => { 'has_reader' => \&Class::MOP::Attribute::has_reader },
 446     ))
 447 );
 448
 449 Class::MOP::Attribute->meta->add_attribute(
 450     Class::MOP::Attribute->new('initializer' => (
 451         reader    => { 'initializer'     => \&Class::MOP::Attribute::initializer     },
 452         predicate => { 'has_initializer' => \&Class::MOP::Attribute::has_initializer },
 453     ))
 454 );
 455
 456 Class::MOP::Attribute->meta->add_attribute(
 457     Class::MOP::Attribute->new('definition_context' => (
 458         reader    => { 'definition_context'     => \&Class::MOP::Attribute::definition_context     },
 459     ))
 460 );
 461
 462 Class::MOP::Attribute->meta->add_attribute(
 463     Class::MOP::Attribute->new('writer' => (
 464         reader    => { 'writer'     => \&Class::MOP::Attribute::writer     },
 465         predicate => { 'has_writer' => \&Class::MOP::Attribute::has_writer },
 466     ))
 467 );
 468
 469 Class::MOP::Attribute->meta->add_attribute(
 470     Class::MOP::Attribute->new('predicate' => (
 471         reader    => { 'predicate'     => \&Class::MOP::Attribute::predicate     },
 472         predicate => { 'has_predicate' => \&Class::MOP::Attribute::has_predicate },
 473     ))
 474 );
 475
 476 Class::MOP::Attribute->meta->add_attribute(
 477     Class::MOP::Attribute->new('clearer' => (
 478         reader    => { 'clearer'     => \&Class::MOP::Attribute::clearer     },
 479         predicate => { 'has_clearer' => \&Class::MOP::Attribute::has_clearer },
 480     ))
 481 );
 482
 483 Class::MOP::Attribute->meta->add_attribute(
 484     Class::MOP::Attribute->new('builder' => (
 485         reader    => { 'builder'     => \&Class::MOP::Attribute::builder     },
 486         predicate => { 'has_builder' => \&Class::MOP::Attribute::has_builder },
 487     ))
 488 );
 489
 490 Class::MOP::Attribute->meta->add_attribute(
 491     Class::MOP::Attribute->new('init_arg' => (
 492         reader    => { 'init_arg'     => \&Class::MOP::Attribute::init_arg     },
 493         predicate => { 'has_init_arg' => \&Class::MOP::Attribute::has_init_arg },
 494     ))
 495 );
 496
 497 Class::MOP::Attribute->meta->add_attribute(
 498     Class::MOP::Attribute->new('default' => (
 499         # default has a custom 'reader' method ...
 500         predicate => { 'has_default' => \&Class::MOP::Attribute::has_default },
 501     ))
 502 );
 503
 504 Class::MOP::Attribute->meta->add_attribute(
 505     Class::MOP::Attribute->new('associated_methods' => (
 506         reader   => { 'associated_methods' => \&Class::MOP::Attribute::associated_methods },
 507         default  => sub { [] }
 508     ))
 509 );
 510
 511 Class::MOP::Attribute->meta->add_attribute(
 512     Class::MOP::Attribute->new('insertion_order' => (
 513         reader      => { 'insertion_order' => \&Class::MOP::Attribute::insertion_order },
 514         writer      => { '_set_insertion_order' => \&Class::MOP::Attribute::_set_insertion_order },
 515         predicate   => { 'has_insertion_order' => \&Class::MOP::Attribute::has_insertion_order },
 516     ))
 517 );
 518
 519 Class::MOP::Attribute->meta->add_method('clone' => sub {
 520     my $self  = shift;
 521     $self->meta->clone_object($self, @_);
 522 });
 523
 524 ## --------------------------------------------------------
 525 ## Class::MOP::Method
 526 Class::MOP::Method->meta->add_attribute(
 527     Class::MOP::Attribute->new('body' => (
 528         reader   => { 'body' => \&Class::MOP::Method::body },
 529     ))
 530 );
 531
 532 Class::MOP::Method->meta->add_attribute(
 533     Class::MOP::Attribute->new('associated_metaclass' => (
 534         reader   => { 'associated_metaclass' => \&Class::MOP::Method::associated_metaclass },
 535     ))
 536 );
 537
 538 Class::MOP::Method->meta->add_attribute(
 539     Class::MOP::Attribute->new('package_name' => (
 540         reader   => { 'package_name' => \&Class::MOP::Method::package_name },
 541     ))
 542 );
 543
 544 Class::MOP::Method->meta->add_attribute(
 545     Class::MOP::Attribute->new('name' => (
 546         reader   => { 'name' => \&Class::MOP::Method::name },
 547     ))
 548 );
 549
 550 Class::MOP::Method->meta->add_attribute(
 551     Class::MOP::Attribute->new('original_method' => (
 552         reader   => { 'original_method'      => \&Class::MOP::Method::original_method },
 553         writer   => { '_set_original_method' => \&Class::MOP::Method::_set_original_method },
 554     ))
 555 );
 556
 557 Class::MOP::Method->meta->add_method('clone' => sub {
 558     my $self  = shift;
 559     my $clone = $self->meta->clone_object($self, @_);
 560     $clone->_set_original_method($self);
 561     return $clone;
 562 });
 563
 564 ## --------------------------------------------------------
 565 ## Class::MOP::Method::Wrapped
 566
 567 # NOTE:
 568 # the way this item is initialized, this
 569 # really does not follow the standard
 570 # practices of attributes, but we put
 571 # it here for completeness
 572 Class::MOP::Method::Wrapped->meta->add_attribute(
 573     Class::MOP::Attribute->new('modifier_table')
 574 );
 575
 576 ## --------------------------------------------------------
 577 ## Class::MOP::Method::Generated
 578
 579 Class::MOP::Method::Generated->meta->add_attribute(
 580     Class::MOP::Attribute->new('is_inline' => (
 581         reader   => { 'is_inline' => \&Class::MOP::Method::Generated::is_inline },
 582         default  => 0,
 583     ))
 584 );
 585
 586 Class::MOP::Method::Generated->meta->add_attribute(
 587     Class::MOP::Attribute->new('definition_context' => (
 588         reader   => { 'definition_context' => \&Class::MOP::Method::Generated::definition_context },
 589     ))
 590 );
 591
 592
 593 ## --------------------------------------------------------
 594 ## Class::MOP::Method::Inlined
 595
 596 Class::MOP::Method::Inlined->meta->add_attribute(
 597     Class::MOP::Attribute->new('_expected_method_class' => (
 598         reader   => { '_expected_method_class' => \&Class::MOP::Method::Inlined::_expected_method_class },
 599     ))
 600 );
 601
 602 ## --------------------------------------------------------
 603 ## Class::MOP::Method::Accessor
 604
 605 Class::MOP::Method::Accessor->meta->add_attribute(
 606     Class::MOP::Attribute->new('attribute' => (
 607         reader   => {
 608             'associated_attribute' => \&Class::MOP::Method::Accessor::associated_attribute
 609         },
 610     ))
 611 );
 612
 613 Class::MOP::Method::Accessor->meta->add_attribute(
 614     Class::MOP::Attribute->new('accessor_type' => (
 615         reader   => { 'accessor_type' => \&Class::MOP::Method::Accessor::accessor_type },
 616     ))
 617 );
 618
 619 ## --------------------------------------------------------
 620 ## Class::MOP::Method::Constructor
 621
 622 Class::MOP::Method::Constructor->meta->add_attribute(
 623     Class::MOP::Attribute->new('options' => (
 624         reader   => {
 625             'options' => \&Class::MOP::Method::Constructor::options
 626         },
 627         default  => sub { +{} }
 628     ))
 629 );
 630
 631 Class::MOP::Method::Constructor->meta->add_attribute(
 632     Class::MOP::Attribute->new('associated_metaclass' => (
 633         init_arg => "metaclass", # FIXME alias and rename
 634         reader   => {
 635             'associated_metaclass' => \&Class::MOP::Method::Constructor::associated_metaclass
 636         },
 637     ))
 638 );
 639
 640 ## --------------------------------------------------------
 641 ## Class::MOP::Instance
 642
 643 # NOTE:
 644 # these don't yet do much of anything, but are just
 645 # included for completeness
 646
 647 Class::MOP::Instance->meta->add_attribute(
 648     Class::MOP::Attribute->new('associated_metaclass',
 649         reader   => { associated_metaclass => \&Class::MOP::Instance::associated_metaclass },
 650     ),
 651 );
 652
 653 Class::MOP::Instance->meta->add_attribute(
 654     Class::MOP::Attribute->new('_class_name',
 655         init_arg => undef,
 656         reader   => { _class_name => \&Class::MOP::Instance::_class_name },
 657         #lazy     => 1, # not yet supported by Class::MOP but out our version does it anyway
 658         #default  => sub { $_[0]->associated_metaclass->name },
 659     ),
 660 );
 661
 662 Class::MOP::Instance->meta->add_attribute(
 663     Class::MOP::Attribute->new('attributes',
 664         reader   => { attributes => \&Class::MOP::Instance::get_all_attributes },
 665     ),
 666 );
 667
 668 Class::MOP::Instance->meta->add_attribute(
 669     Class::MOP::Attribute->new('slots',
 670         reader   => { slots => \&Class::MOP::Instance::slots },
 671     ),
 672 );
 673
 674 Class::MOP::Instance->meta->add_attribute(
 675     Class::MOP::Attribute->new('slot_hash',
 676         reader   => { slot_hash => \&Class::MOP::Instance::slot_hash },
 677     ),
 678 );
 679
 680
 681 # we need the meta instance of the meta instance to be created now, in order
 682 # for the constructor to be able to use it
 683 Class::MOP::Instance->meta->get_meta_instance;
 684
 685 # pretend the add_method never happenned. it hasn't yet affected anything
 686 undef Class::MOP::Instance->meta->{_package_cache_flag};
 687
 688 ## --------------------------------------------------------
 689 ## Now close all the Class::MOP::* classes
 690
 691 # NOTE: we don't need to inline the the accessors this only lengthens
 692 # the compile time of the MOP, and gives us no actual benefits.
 693
 694 # this is just nitpicking to ensure Class::MOP::Class->meta == ->meta->meta
 695 Class::MOP::Class->meta->_immutable_metaclass;
 696 $Class::MOP::Class::immutable_metaclass_cache{"Class::MOP::Class"}{"Class::MOP::Class::Immutable::Trait"} = Class::MOP::Class::Immutable::Class::MOP::Class->meta;
 697
 698 $_->meta->make_immutable(
 699     inline_constructor  => 1,
 700     replace_constructor => 1,
 701     constructor_name    => "_new",
 702     inline_accessors => 0,
 703 ) for qw/
 704     Class::MOP::Package
 705     Class::MOP::Module
 706     Class::MOP::Class
 707     Class::MOP::Class::Immutable::Class::MOP::Class
 708
 709     Class::MOP::Attribute
 710     Class::MOP::Method
 711     Class::MOP::Instance
 712
 713     Class::MOP::Object
 714
 715     Class::MOP::Method::Generated
 716     Class::MOP::Method::Inlined
 717
 718     Class::MOP::Method::Accessor
 719     Class::MOP::Method::Constructor
 720     Class::MOP::Method::Wrapped
 721 /;
 722
 723 1;
 724
 725 __END__
 726
 727 =pod
 728
 729 =head1 NAME
 730
 731 Class::MOP - A Meta Object Protocol for Perl 5
 732
 733 =head1 DESCRIPTION
 734
 735 This module is a fully functioning meta object protocol for the
 736 Perl 5 object system. It makes no attempt to change the behavior or
 737 characteristics of the Perl 5 object system, only to create a
 738 protocol for its manipulation and introspection.
 739
 740 That said, it does attempt to create the tools for building a rich set
 741 of extensions to the Perl 5 object system. Every attempt has been made
 742 to abide by the spirit of the Perl 5 object system that we all know
 743 and love.
 744
 745 This documentation is sparse on conceptual details. We suggest looking
 746 at the items listed in the L<SEE ALSO> section for more
 747 information. In particular the book "The Art of the Meta Object
 748 Protocol" was very influential in the development of this system.
 749
 750 =head2 What is a Meta Object Protocol?
 751
 752 A meta object protocol is an API to an object system.
 753
 754 To be more specific, it abstracts the components of an object system
 755 (classes, object, methods, object attributes, etc.). These
 756 abstractions can then be used to inspect and manipulate the object
 757 system which they describe.
 758
 759 It can be said that there are two MOPs for any object system; the
 760 implicit MOP and the explicit MOP. The implicit MOP handles things
 761 like method dispatch or inheritance, which happen automatically as
 762 part of how the object system works. The explicit MOP typically
 763 handles the introspection/reflection features of the object system.
 764
 765 All object systems have implicit MOPs. Without one, they would not
 766 work. Explicit MOPs are much less common, and depending on the
 767 language can vary from restrictive (Reflection in Java or C#) to wide
 768 open (CLOS is a perfect example).
 769
 770 =head2 Yet Another Class Builder! Why?
 771
 772 This is B<not> a class builder so much as a I<class builder
 773 B<builder>>. The intent is that an end user will not use this module
 774 directly, but instead this module is used by module authors to build
 775 extensions and features onto the Perl 5 object system.
 776
 777 This system is used by L<Moose>, which supplies a powerful class
 778 builder system built entirely on top of C<Class::MOP>.
 779
 780 =head2 Who is this module for?
 781
 782 This module is for anyone who has ever created or wanted to create a
 783 module for the Class:: namespace. The tools which this module provides
 784 make doing complex Perl 5 wizardry simpler, by removing such barriers
 785 as the need to hack symbol tables, or understand the fine details of
 786 method dispatch.
 787
 788 =head2 What changes do I have to make to use this module?
 789
 790 This module was designed to be as unintrusive as possible. Many of its
 791 features are accessible without B<any> change to your existing
 792 code. It is meant to be a compliment to your existing code and not an
 793 intrusion on your code base. Unlike many other B<Class::> modules,
 794 this module B<does not> require you subclass it, or even that you
 795 C<use> it in within your module's package.
 796
 797 The only features which requires additions to your code are the
 798 attribute handling and instance construction features, and these are
 799 both completely optional features. The only reason for this is because
 800 Perl 5's object system does not actually have these features built
 801 in. More information about this feature can be found below.
 802
 803 =head2 About Performance
 804
 805 It is a common misconception that explicit MOPs are a performance hit.
 806 This is not a universal truth, it is a side-effect of some specific
 807 implementations. For instance, using Java reflection is slow because
 808 the JVM cannot take advantage of any compiler optimizations, and the
 809 JVM has to deal with much more runtime type information as well.
 810
 811 Reflection in C# is marginally better as it was designed into the
 812 language and runtime (the CLR). In contrast, CLOS (the Common Lisp
 813 Object System) was built to support an explicit MOP, and so
 814 performance is tuned for it.
 815
 816 This library in particular does its absolute best to avoid putting
 817 B<any> drain at all upon your code's performance. In fact, by itself
 818 it does nothing to affect your existing code. So you only pay for what
 819 you actually use.
 820
 821 =head2 About Metaclass compatibility
 822
 823 This module makes sure that all metaclasses created are both upwards
 824 and downwards compatible. The topic of metaclass compatibility is
 825 highly esoteric and is something only encountered when doing deep and
 826 involved metaclass hacking. There are two basic kinds of metaclass
 827 incompatibility; upwards and downwards.
 828
 829 Upwards metaclass compatibility means that the metaclass of a
 830 given class is either the same as (or a subclass of) all of the
 831 class's ancestors.
 832
 833 Downward metaclass compatibility means that the metaclasses of a
 834 given class's ancestors are all either the same as (or a subclass
 835 of) that metaclass.
 836
 837 Here is a diagram showing a set of two classes (C<A> and C<B>) and
 838 two metaclasses (C<Meta::A> and C<Meta::B>) which have correct
 839 metaclass compatibility both upwards and downwards.
 840
 841     +---------+     +---------+
 842     | Meta::A |<----| Meta::B |      <....... (instance of  )
 843     +---------+     +---------+      <------- (inherits from)
 844          ^               ^
 845          :               :
 846     +---------+     +---------+
 847     |    A    |<----|    B    |
 848     +---------+     +---------+
 849
 850 As I said this is a highly esoteric topic and one you will only run
 851 into if you do a lot of subclassing of L<Class::MOP::Class>. If you
 852 are interested in why this is an issue see the paper I<Uniform and
 853 safe metaclass composition> linked to in the L<SEE ALSO> section of
 854 this document.
 855
 856 =head2 Using custom metaclasses
 857
 858 Always use the L<metaclass> pragma when using a custom metaclass, this
 859 will ensure the proper initialization order and not accidentally
 860 create an incorrect type of metaclass for you. This is a very rare
 861 problem, and one which can only occur if you are doing deep metaclass
 862 programming. So in other words, don't worry about it.
 863
 864 Note that if you're using L<Moose> we encourage you to I<not> use
 865 L<metaclass> pragma, and instead use L<Moose::Util::MetaRole> to apply
 866 roles to a class's metaclasses. This topic is covered at length in
 867 various L<Moose::Cookbook> recipes.
 868
 869 =head1 PROTOCOLS
 870
 871 The meta-object protocol is divided into 4 main sub-protocols:
 872
 873 =head2 The Class protocol
 874
 875 This provides a means of manipulating and introspecting a Perl 5
 876 class. It handles symbol table hacking for you, and provides a rich
 877 set of methods that go beyond simple package introspection.
 878
 879 See L<Class::MOP::Class> for more details.
 880
 881 =head2 The Attribute protocol
 882
 883 This provides a consistent representation for an attribute of a Perl 5
 884 class. Since there are so many ways to create and handle attributes in
 885 Perl 5 OO, the Attribute protocol provide as much of a unified
 886 approach as possible. Of course, you are always free to extend this
 887 protocol by subclassing the appropriate classes.
 888
 889 See L<Class::MOP::Attribute> for more details.
 890
 891 =head2 The Method protocol
 892
 893 This provides a means of manipulating and introspecting methods in the
 894 Perl 5 object system. As with attributes, there are many ways to
 895 approach this topic, so we try to keep it pretty basic, while still
 896 making it possible to extend the system in many ways.
 897
 898 See L<Class::MOP::Method> for more details.
 899
 900 =head2 The Instance protocol
 901
 902 This provides a layer of abstraction for creating object instances.
 903 Since the other layers use this protocol, it is relatively easy to
 904 change the type of your instances from the default hash reference to
 905 some other type of reference. Several examples are provided in the
 906 F<examples/> directory included in this distribution.
 907
 908 See L<Class::MOP::Instance> for more details.
 909
 910 =head1 FUNCTIONS
 911
 912 Note that this module does not export any constants or functions.
 913
 914 =head2 Constants
 915
 916 =over 4
 917
 918 =item I<Class::MOP::IS_RUNNING_ON_5_10>
 919
 920 We set this constant depending on what version perl we are on, this
 921 allows us to take advantage of new 5.10 features and stay backwards
 922 compatible.
 923
 924 =back
 925
 926 =head2 Utility functions
 927
 928 Note that these are all called as B<functions, not methods>.
 929
 930 =over 4
 931
 932 =item B<Class::MOP::load_class($class_name)>
 933
 934 This will load the specified C<$class_name>, if it is not already
 935 loaded (as reported by C<is_class_loaded>). This function can be used
 936 in place of tricks like C<eval "use $module"> or using C<require>
 937 unconditionally. This will return the metaclass of C<$class_name> if
 938 one exists, otherwise it will return C<$class_name>.
 939
 940 =item B<Class::MOP::is_class_loaded($class_name)>
 941
 942 Returns a boolean indicating whether or not C<$class_name> has been
 943 loaded.
 944
 945 This does a basic check of the symbol table to try and determine as
 946 best it can if the C<$class_name> is loaded, it is probably correct
 947 about 99% of the time, but it can be fooled into reporting false
 948 positives. In particular, loading any of the core L<IO> modules will
 949 cause most of the rest of the core L<IO> modules to falsely report
 950 having been loaded, due to the way the base L<IO> module works.
 951
 952 =item B<Class::MOP::get_code_info($code)>
 953
 954 This function returns two values, the name of the package the C<$code>
 955 is from and the name of the C<$code> itself. This is used by several
 956 elements of the MOP to determine where a given C<$code> reference is
 957 from.
 958
 959 =item B<Class::MOP::class_of($instance_or_class_name)>
 960
 961 This will return the metaclass of the given instance or class name.  If the
 962 class lacks a metaclass, no metaclass will be initialized, and C<undef> will be
 963 returned.
 964
 965 =item B<Class::MOP::check_package_cache_flag($pkg)>
 966
 967 B<NOTE: DO NOT USE THIS FUNCTION, IT IS FOR INTERNAL USE ONLY!>
 968
 969 This will return an integer that is managed by L<Class::MOP::Class> to
 970 determine if a module's symbol table has been altered.
 971
 972 In Perl 5.10 or greater, this flag is package specific. However in
 973 versions prior to 5.10, this will use the C<PL_sub_generation>
 974 variable which is not package specific.
 975
 976 =item B<Class::MOP::load_first_existing_class(@class_names)>
 977
 978 B<NOTE: DO NOT USE THIS FUNCTION, IT IS FOR INTERNAL USE ONLY!>
 979
 980 Given a list of class names, this function will attempt to load each
 981 one in turn.
 982
 983 If it finds a class it can load, it will return that class' name.  If
 984 none of the classes can be loaded, it will throw an exception.
 985
 986 =back
 987
 988 =head2 Metaclass cache functions
 989
 990 Class::MOP holds a cache of metaclasses. The following are functions
 991 (B<not methods>) which can be used to access that cache. It is not
 992 recommended that you mess with these. Bad things could happen, but if
 993 you are brave and willing to risk it: go for it!
 994
 995 =over 4
 996
 997 =item B<Class::MOP::get_all_metaclasses>
 998
 999 This will return a hash of all the metaclass instances that have
1000 been cached by L<Class::MOP::Class>, keyed by the package name.
1001
1002 =item B<Class::MOP::get_all_metaclass_instances>
1003
1004 This will return a list of all the metaclass instances that have
1005 been cached by L<Class::MOP::Class>.
1006
1007 =item B<Class::MOP::get_all_metaclass_names>
1008
1009 This will return a list of all the metaclass names that have
1010 been cached by L<Class::MOP::Class>.
1011
1012 =item B<Class::MOP::get_metaclass_by_name($name)>
1013
1014 This will return a cached L<Class::MOP::Class> instance, or nothing
1015 if no metaclass exists with that C<$name>.
1016
1017 =item B<Class::MOP::store_metaclass_by_name($name, $meta)>
1018
1019 This will store a metaclass in the cache at the supplied C<$key>.
1020
1021 =item B<Class::MOP::weaken_metaclass($name)>
1022
1023 In rare cases (e.g. anonymous metaclasses) it is desirable to
1024 store a weakened reference in the metaclass cache. This
1025 function will weaken the reference to the metaclass stored
1026 in C<$name>.
1027
1028 =item B<Class::MOP::does_metaclass_exist($name)>
1029
1030 This will return true of there exists a metaclass stored in the
1031 C<$name> key, and return false otherwise.
1032
1033 =item B<Class::MOP::remove_metaclass_by_name($name)>
1034
1035 This will remove the metaclass stored in the C<$name> key.
1036
1037 =back
1038
1039 =head1 SEE ALSO
1040
1041 =head2 Books
1042
1043 There are very few books out on Meta Object Protocols and Metaclasses
1044 because it is such an esoteric topic. The following books are really
1045 the only ones I have found. If you know of any more, B<I<please>>
1046 email me and let me know, I would love to hear about them.
1047
1048 =over 4
1049
1050 =item I<The Art of the Meta Object Protocol>
1051
1052 =item I<Advances in Object-Oriented Metalevel Architecture and Reflection>
1053
1054 =item I<Putting MetaClasses to Work>
1055
1056 =item I<Smalltalk: The Language>
1057
1058 =back
1059
1060 =head2 Papers
1061
1062 =over 4
1063
1064 =item "Uniform and safe metaclass composition"
1065
1066 An excellent paper by the people who brought us the original Traits paper.
1067 This paper is on how Traits can be used to do safe metaclass composition,
1068 and offers an excellent introduction section which delves into the topic of
1069 metaclass compatibility.
1070
1071 L<http://www.iam.unibe.ch/~scg/Archive/Papers/Duca05ySafeMetaclassTrait.pdf>
1072
1073 =item "Safe Metaclass Programming"
1074
1075 This paper seems to precede the above paper, and propose a mix-in based
1076 approach as opposed to the Traits based approach. Both papers have similar
1077 information on the metaclass compatibility problem space.
1078
1079 L<http://citeseer.ist.psu.edu/37617.html>
1080
1081 =back
1082
1083 =head2 Prior Art
1084
1085 =over 4
1086
1087 =item The Perl 6 MetaModel work in the Pugs project
1088
1089 =over 4
1090
1091 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-MetaModel>
1092
1093 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-ObjectSpace>
1094
1095 =back
1096
1097 =back
1098
1099 =head2 Articles
1100
1101 =over 4
1102
1103 =item CPAN Module Review of Class::MOP
1104
1105 L<http://www.oreillynet.com/onlamp/blog/2006/06/cpan_module_review_classmop.html>
1106
1107 =back
1108
1109 =head1 SIMILAR MODULES
1110
1111 As I have said above, this module is a class-builder-builder, so it is
1112 not the same thing as modules like L<Class::Accessor> and
1113 L<Class::MethodMaker>. That being said there are very few modules on CPAN
1114 with similar goals to this module. The one I have found which is most
1115 like this module is L<Class::Meta>, although it's philosophy and the MOP it
1116 creates are very different from this modules.
1117
1118 =head1 BUGS
1119
1120 All complex software has bugs lurking in it, and this module is no
1121 exception.
1122
1123 Please report any bugs to C<bug-class-mop@rt.cpan.org>, or through the
1124 web interface at L<http://rt.cpan.org>.
1125
1126 You can also discuss feature requests or possible bugs on the Moose
1127 mailing list (moose@perl.org) or on IRC at
1128 L<irc://irc.perl.org/#moose>.
1129
1130 =head1 ACKNOWLEDGEMENTS
1131
1132 =over 4
1133
1134 =item Rob Kinyon
1135
1136 Thanks to Rob for actually getting the development of this module kick-started.
1137
1138 =back
1139
1140 =head1 AUTHORS
1141
1142 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1143
1144 B<with contributions from:>
1145
1146 Brandon (blblack) Black
1147
1148 Florian (rafl) Ragwitz
1149
1150 Guillermo (groditi) Roditi
1151
1152 Dave (autarch) Rolsky
1153
1154 Matt (mst) Trout
1155
1156 Rob (robkinyon) Kinyon
1157
1158 Yuval (nothingmuch) Kogman
1159
1160 Scott (konobi) McWhirter
1161
1162 Dylan Hardison
1163
1164 =head1 COPYRIGHT AND LICENSE
1165
1166 Copyright 2006-2009 by Infinity Interactive, Inc.
1167
1168 L<http://www.iinteractive.com>
1169
1170 This library is free software; you can redistribute it and/or modify
1171 it under the same terms as Perl itself.
1172
1173 =cut