lib/Class/MOP.pm

   1
   2 package Class::MOP;
   3
   4 use strict;
   5 use warnings;
   6
   7 use 5.008;
   8
   9 use MRO::Compat;
  10
  11 use Carp          'confess';
  12 use Scalar::Util  'weaken', 'reftype';
  13
  14
  15 use Class::MOP::Class;
  16 use Class::MOP::Attribute;
  17 use Class::MOP::Method;
  18
  19 use Class::MOP::Immutable;
  20
  21 BEGIN {
  22     *IS_RUNNING_ON_5_10 = ($] < 5.009_005)
  23         ? sub () { 0 }
  24         : sub () { 1 };
  25
  26     *HAVE_ISAREV = defined(&mro::get_isarev)
  27         ? sub () { 1 }
  28         : sub () { 1 };
  29
  30     # this is either part of core or set up appropriately by MRO::Compat
  31     *check_package_cache_flag = \&mro::get_pkg_gen;
  32 }
  33
  34 our $VERSION   = '0.77';
  35 our $XS_VERSION = $VERSION;
  36 $VERSION = eval $VERSION;
  37 our $AUTHORITY = 'cpan:STEVAN';
  38
  39 _try_load_xs() or _load_pure_perl();
  40
  41 sub _try_load_xs {
  42     return if $ENV{CLASS_MOP_NO_XS};
  43
  44     my $e = do {
  45         local $@;
  46         eval {
  47             require XSLoader;
  48             # just doing this - no warnings 'redefine' - doesn't work
  49             # for some reason
  50             local $^W = 0;
  51             __PACKAGE__->XSLoader::load($XS_VERSION);
  52
  53             require Sub::Name;
  54             Sub::Name->import(qw(subname));
  55
  56             require Devel::GlobalDestruction;
  57             Devel::GlobalDestruction->import("in_global_destruction");
  58
  59             *USING_XS = sub () { 1 };
  60         };
  61         $@;
  62     };
  63
  64     die $e if $e && $e !~ /object version|loadable object/;
  65
  66     return $e ? 0 : 1;
  67 }
  68
  69 sub _load_pure_perl {
  70     require Sub::Identify;
  71     Sub::Identify->import('get_code_info');
  72
  73     *subname = sub { $_[1] };
  74     *in_global_destruction = sub () { !1 };
  75
  76     *USING_XS = sub () { 0 };
  77 }
  78
  79
  80 {
  81     # Metaclasses are singletons, so we cache them here.
  82     # there is no need to worry about destruction though
  83     # because they should die only when the program dies.
  84     # After all, do package definitions even get reaped?
  85     my %METAS;
  86
  87     # means of accessing all the metaclasses that have
  88     # been initialized thus far (for mugwumps obj browser)
  89     sub get_all_metaclasses         {        %METAS         }
  90     sub get_all_metaclass_instances { values %METAS         }
  91     sub get_all_metaclass_names     { keys   %METAS         }
  92     sub get_metaclass_by_name       { $METAS{$_[0]}         }
  93     sub store_metaclass_by_name     { $METAS{$_[0]} = $_[1] }
  94     sub weaken_metaclass            { weaken($METAS{$_[0]}) }
  95     sub does_metaclass_exist        { exists $METAS{$_[0]} && defined $METAS{$_[0]} }
  96     sub remove_metaclass_by_name    { $METAS{$_[0]} = undef }
  97
  98     # NOTE:
  99     # We only cache metaclasses, meaning instances of
 100     # Class::MOP::Class. We do not cache instance of
 101     # Class::MOP::Package or Class::MOP::Module. Mostly
 102     # because I don't yet see a good reason to do so.
 103 }
 104
 105 sub load_first_existing_class {
 106     my @classes = @_
 107         or return;
 108
 109     foreach my $class (@classes) {
 110         unless ( _is_valid_class_name($class) ) {
 111             my $display = defined($class) ? $class : 'undef';
 112             confess "Invalid class name ($display)";
 113         }
 114     }
 115
 116     my $found;
 117     my %exceptions;
 118     for my $class (@classes) {
 119         my $e = _try_load_one_class($class);
 120
 121         if ($e) {
 122             $exceptions{$class} = $e;
 123         }
 124         else {
 125             $found = $class;
 126             last;
 127         }
 128     }
 129
 130     return $found if $found;
 131
 132     confess join(
 133         "\n",
 134         map {
 135             sprintf(
 136                 "Could not load class (%s) because : %s", $_,
 137                 $exceptions{$_}
 138                 )
 139             } @classes
 140     );
 141 }
 142
 143 sub _try_load_one_class {
 144     my $class = shift;
 145
 146     return if is_class_loaded($class);
 147
 148     my $file = $class . '.pm';
 149     $file =~ s{::}{/}g;
 150
 151     return do {
 152         local $@;
 153         eval { require($file) };
 154         $@;
 155     };
 156 }
 157
 158 sub load_class {
 159     my $class = load_first_existing_class($_[0]);
 160     return get_metaclass_by_name($class) || $class;
 161 }
 162
 163 sub _is_valid_class_name {
 164     my $class = shift;
 165
 166     return 0 if ref($class);
 167     return 0 unless defined($class);
 168     return 0 unless length($class);
 169
 170     return 1 if $class =~ /^\w+(?:::\w+)*$/;
 171
 172     return 0;
 173 }
 174
 175 sub is_class_loaded {
 176     my $class = shift;
 177
 178     return 0 unless _is_valid_class_name($class);
 179
 180     # walk the symbol table tree to avoid autovififying
 181     # \*{${main::}{"Foo::"}} == \*main::Foo::
 182
 183     my $pack = \*::;
 184     foreach my $part (split('::', $class)) {
 185         return 0 unless exists ${$$pack}{"${part}::"};
 186         $pack = \*{${$$pack}{"${part}::"}};
 187     }
 188
 189     # We used to check in the package stash, but it turns out that
 190     # *{${$$package}{VERSION}{SCALAR}} can end up pointing to a
 191     # reference to undef. It looks
 192
 193     my $version = do {
 194         no strict 'refs';
 195         ${$class . '::VERSION'};
 196     };
 197
 198     return 1 if ! ref $version && defined $version;
 199     # Sometimes $VERSION ends up as a reference to undef (weird)
 200     return 1 if ref $version && reftype $version eq 'SCALAR' && defined ${$version};
 201
 202     return 1 if exists ${$$pack}{ISA}
 203              && defined *{${$$pack}{ISA}}{ARRAY};
 204
 205     # check for any method
 206     foreach ( keys %{$$pack} ) {
 207         next if substr($_, -2, 2) eq '::';
 208
 209         my $glob = ${$$pack}{$_} || next;
 210
 211         # constant subs
 212         if ( IS_RUNNING_ON_5_10 ) {
 213             return 1 if ref $glob eq 'SCALAR';
 214         }
 215
 216         return 1 if defined *{$glob}{CODE};
 217     }
 218
 219     # fail
 220     return 0;
 221 }
 222
 223
 224 ## ----------------------------------------------------------------------------
 225 ## Setting up our environment ...
 226 ## ----------------------------------------------------------------------------
 227 ## Class::MOP needs to have a few things in the global perl environment so
 228 ## that it can operate effectively. Those things are done here.
 229 ## ----------------------------------------------------------------------------
 230
 231 # ... nothing yet actually ;)
 232
 233 ## ----------------------------------------------------------------------------
 234 ## Bootstrapping
 235 ## ----------------------------------------------------------------------------
 236 ## The code below here is to bootstrap our MOP with itself. This is also
 237 ## sometimes called "tying the knot". By doing this, we make it much easier
 238 ## to extend the MOP through subclassing and such since now you can use the
 239 ## MOP itself to extend itself.
 240 ##
 241 ## Yes, I know, thats weird and insane, but it's a good thing, trust me :)
 242 ## ----------------------------------------------------------------------------
 243
 244 # We need to add in the meta-attributes here so that
 245 # any subclass of Class::MOP::* will be able to
 246 # inherit them using &construct_instance
 247
 248 ## --------------------------------------------------------
 249 ## Class::MOP::Package
 250
 251 Class::MOP::Package->meta->add_attribute(
 252     Class::MOP::Attribute->new('package' => (
 253         reader   => {
 254             # NOTE: we need to do this in order
 255             # for the instance meta-object to
 256             # not fall into meta-circular death
 257             #
 258             # we just alias the original method
 259             # rather than re-produce it here
 260             'name' => \&Class::MOP::Package::name
 261         },
 262     ))
 263 );
 264
 265 Class::MOP::Package->meta->add_attribute(
 266     Class::MOP::Attribute->new('namespace' => (
 267         reader => {
 268             # NOTE:
 269             # we just alias the original method
 270             # rather than re-produce it here
 271             'namespace' => \&Class::MOP::Package::namespace
 272         },
 273         init_arg => undef,
 274         default  => sub { \undef }
 275     ))
 276 );
 277
 278 ## --------------------------------------------------------
 279 ## Class::MOP::Module
 280
 281 # NOTE:
 282 # yeah this is kind of stretching things a bit,
 283 # but truthfully the version should be an attribute
 284 # of the Module, the weirdness comes from having to
 285 # stick to Perl 5 convention and store it in the
 286 # $VERSION package variable. Basically if you just
 287 # squint at it, it will look how you want it to look.
 288 # Either as a package variable, or as a attribute of
 289 # the metaclass, isn't abstraction great :)
 290
 291 Class::MOP::Module->meta->add_attribute(
 292     Class::MOP::Attribute->new('version' => (
 293         reader => {
 294             # NOTE:
 295             # we just alias the original method
 296             # rather than re-produce it here
 297             'version' => \&Class::MOP::Module::version
 298         },
 299         init_arg => undef,
 300         default  => sub { \undef }
 301     ))
 302 );
 303
 304 # NOTE:
 305 # By following the same conventions as version here,
 306 # we are opening up the possibility that people can
 307 # use the $AUTHORITY in non-Class::MOP modules as
 308 # well.
 309
 310 Class::MOP::Module->meta->add_attribute(
 311     Class::MOP::Attribute->new('authority' => (
 312         reader => {
 313             # NOTE:
 314             # we just alias the original method
 315             # rather than re-produce it here
 316             'authority' => \&Class::MOP::Module::authority
 317         },
 318         init_arg => undef,
 319         default  => sub { \undef }
 320     ))
 321 );
 322
 323 ## --------------------------------------------------------
 324 ## Class::MOP::Class
 325
 326 Class::MOP::Class->meta->add_attribute(
 327     Class::MOP::Attribute->new('attributes' => (
 328         reader   => {
 329             # NOTE: we need to do this in order
 330             # for the instance meta-object to
 331             # not fall into meta-circular death
 332             #
 333             # we just alias the original method
 334             # rather than re-produce it here
 335             'get_attribute_map' => \&Class::MOP::Class::get_attribute_map
 336         },
 337         default  => sub { {} }
 338     ))
 339 );
 340
 341 Class::MOP::Class->meta->add_attribute(
 342     Class::MOP::Attribute->new('methods' => (
 343         reader   => {
 344             # NOTE:
 345             # we just alias the original method
 346             # rather than re-produce it here
 347             'get_method_map' => \&Class::MOP::Class::get_method_map
 348         },
 349         default => sub { {} }
 350     ))
 351 );
 352
 353 Class::MOP::Class->meta->add_attribute(
 354     Class::MOP::Attribute->new('superclasses' => (
 355         accessor => {
 356             # NOTE:
 357             # we just alias the original method
 358             # rather than re-produce it here
 359             'superclasses' => \&Class::MOP::Class::superclasses
 360         },
 361         init_arg => undef,
 362         default  => sub { \undef }
 363     ))
 364 );
 365
 366 Class::MOP::Class->meta->add_attribute(
 367     Class::MOP::Attribute->new('attribute_metaclass' => (
 368         reader   => {
 369             # NOTE:
 370             # we just alias the original method
 371             # rather than re-produce it here
 372             'attribute_metaclass' => \&Class::MOP::Class::attribute_metaclass
 373         },
 374         default  => 'Class::MOP::Attribute',
 375     ))
 376 );
 377
 378 Class::MOP::Class->meta->add_attribute(
 379     Class::MOP::Attribute->new('method_metaclass' => (
 380         reader   => {
 381             # NOTE:
 382             # we just alias the original method
 383             # rather than re-produce it here
 384             'method_metaclass' => \&Class::MOP::Class::method_metaclass
 385         },
 386         default  => 'Class::MOP::Method',
 387     ))
 388 );
 389
 390 Class::MOP::Class->meta->add_attribute(
 391     Class::MOP::Attribute->new('wrapped_method_metaclass' => (
 392         reader   => {
 393             # NOTE:
 394             # we just alias the original method
 395             # rather than re-produce it here
 396             'wrapped_method_metaclass' => \&Class::MOP::Class::wrapped_method_metaclass
 397         },
 398         default  => 'Class::MOP::Method::Wrapped',
 399     ))
 400 );
 401
 402 Class::MOP::Class->meta->add_attribute(
 403     Class::MOP::Attribute->new('instance_metaclass' => (
 404         reader   => {
 405             # NOTE: we need to do this in order
 406             # for the instance meta-object to
 407             # not fall into meta-circular death
 408             #
 409             # we just alias the original method
 410             # rather than re-produce it here
 411             'instance_metaclass' => \&Class::MOP::Class::instance_metaclass
 412         },
 413         default  => 'Class::MOP::Instance',
 414     ))
 415 );
 416
 417 # NOTE:
 418 # we don't actually need to tie the knot with
 419 # Class::MOP::Class here, it is actually handled
 420 # within Class::MOP::Class itself in the
 421 # construct_class_instance method.
 422
 423 ## --------------------------------------------------------
 424 ## Class::MOP::Attribute
 425
 426 Class::MOP::Attribute->meta->add_attribute(
 427     Class::MOP::Attribute->new('name' => (
 428         reader   => {
 429             # NOTE: we need to do this in order
 430             # for the instance meta-object to
 431             # not fall into meta-circular death
 432             #
 433             # we just alias the original method
 434             # rather than re-produce it here
 435             'name' => \&Class::MOP::Attribute::name
 436         }
 437     ))
 438 );
 439
 440 Class::MOP::Attribute->meta->add_attribute(
 441     Class::MOP::Attribute->new('associated_class' => (
 442         reader   => {
 443             # NOTE: we need to do this in order
 444             # for the instance meta-object to
 445             # not fall into meta-circular death
 446             #
 447             # we just alias the original method
 448             # rather than re-produce it here
 449             'associated_class' => \&Class::MOP::Attribute::associated_class
 450         }
 451     ))
 452 );
 453
 454 Class::MOP::Attribute->meta->add_attribute(
 455     Class::MOP::Attribute->new('accessor' => (
 456         reader    => { 'accessor'     => \&Class::MOP::Attribute::accessor     },
 457         predicate => { 'has_accessor' => \&Class::MOP::Attribute::has_accessor },
 458     ))
 459 );
 460
 461 Class::MOP::Attribute->meta->add_attribute(
 462     Class::MOP::Attribute->new('reader' => (
 463         reader    => { 'reader'     => \&Class::MOP::Attribute::reader     },
 464         predicate => { 'has_reader' => \&Class::MOP::Attribute::has_reader },
 465     ))
 466 );
 467
 468 Class::MOP::Attribute->meta->add_attribute(
 469     Class::MOP::Attribute->new('initializer' => (
 470         reader    => { 'initializer'     => \&Class::MOP::Attribute::initializer     },
 471         predicate => { 'has_initializer' => \&Class::MOP::Attribute::has_initializer },
 472     ))
 473 );
 474
 475 Class::MOP::Attribute->meta->add_attribute(
 476     Class::MOP::Attribute->new('definition_context' => (
 477         reader    => { 'definition_context'     => \&Class::MOP::Attribute::definition_context     },
 478     ))
 479 );
 480
 481 Class::MOP::Attribute->meta->add_attribute(
 482     Class::MOP::Attribute->new('writer' => (
 483         reader    => { 'writer'     => \&Class::MOP::Attribute::writer     },
 484         predicate => { 'has_writer' => \&Class::MOP::Attribute::has_writer },
 485     ))
 486 );
 487
 488 Class::MOP::Attribute->meta->add_attribute(
 489     Class::MOP::Attribute->new('predicate' => (
 490         reader    => { 'predicate'     => \&Class::MOP::Attribute::predicate     },
 491         predicate => { 'has_predicate' => \&Class::MOP::Attribute::has_predicate },
 492     ))
 493 );
 494
 495 Class::MOP::Attribute->meta->add_attribute(
 496     Class::MOP::Attribute->new('clearer' => (
 497         reader    => { 'clearer'     => \&Class::MOP::Attribute::clearer     },
 498         predicate => { 'has_clearer' => \&Class::MOP::Attribute::has_clearer },
 499     ))
 500 );
 501
 502 Class::MOP::Attribute->meta->add_attribute(
 503     Class::MOP::Attribute->new('builder' => (
 504         reader    => { 'builder'     => \&Class::MOP::Attribute::builder     },
 505         predicate => { 'has_builder' => \&Class::MOP::Attribute::has_builder },
 506     ))
 507 );
 508
 509 Class::MOP::Attribute->meta->add_attribute(
 510     Class::MOP::Attribute->new('init_arg' => (
 511         reader    => { 'init_arg'     => \&Class::MOP::Attribute::init_arg     },
 512         predicate => { 'has_init_arg' => \&Class::MOP::Attribute::has_init_arg },
 513     ))
 514 );
 515
 516 Class::MOP::Attribute->meta->add_attribute(
 517     Class::MOP::Attribute->new('default' => (
 518         # default has a custom 'reader' method ...
 519         predicate => { 'has_default' => \&Class::MOP::Attribute::has_default },
 520     ))
 521 );
 522
 523 Class::MOP::Attribute->meta->add_attribute(
 524     Class::MOP::Attribute->new('associated_methods' => (
 525         reader   => { 'associated_methods' => \&Class::MOP::Attribute::associated_methods },
 526         default  => sub { [] }
 527     ))
 528 );
 529
 530 Class::MOP::Attribute->meta->add_method('clone' => sub {
 531     my $self  = shift;
 532     $self->meta->clone_object($self, @_);
 533 });
 534
 535 ## --------------------------------------------------------
 536 ## Class::MOP::Method
 537 Class::MOP::Method->meta->add_attribute(
 538     Class::MOP::Attribute->new('body' => (
 539         reader   => { 'body' => \&Class::MOP::Method::body },
 540     ))
 541 );
 542
 543 Class::MOP::Method->meta->add_attribute(
 544     Class::MOP::Attribute->new('associated_metaclass' => (
 545         reader   => { 'associated_metaclass' => \&Class::MOP::Method::associated_metaclass },
 546     ))
 547 );
 548
 549 Class::MOP::Method->meta->add_attribute(
 550     Class::MOP::Attribute->new('package_name' => (
 551         reader   => { 'package_name' => \&Class::MOP::Method::package_name },
 552     ))
 553 );
 554
 555 Class::MOP::Method->meta->add_attribute(
 556     Class::MOP::Attribute->new('name' => (
 557         reader   => { 'name' => \&Class::MOP::Method::name },
 558     ))
 559 );
 560
 561 Class::MOP::Method->meta->add_attribute(
 562     Class::MOP::Attribute->new('original_method' => (
 563         reader   => { 'original_method'      => \&Class::MOP::Method::original_method },
 564         writer   => { '_set_original_method' => \&Class::MOP::Method::_set_original_method },
 565     ))
 566 );
 567
 568 Class::MOP::Method->meta->add_method('clone' => sub {
 569     my $self  = shift;
 570     my $clone = $self->meta->clone_object($self, @_);
 571     $clone->_set_original_method($self);
 572     return $clone;
 573 });
 574
 575 ## --------------------------------------------------------
 576 ## Class::MOP::Method::Wrapped
 577
 578 # NOTE:
 579 # the way this item is initialized, this
 580 # really does not follow the standard
 581 # practices of attributes, but we put
 582 # it here for completeness
 583 Class::MOP::Method::Wrapped->meta->add_attribute(
 584     Class::MOP::Attribute->new('modifier_table')
 585 );
 586
 587 ## --------------------------------------------------------
 588 ## Class::MOP::Method::Generated
 589
 590 Class::MOP::Method::Generated->meta->add_attribute(
 591     Class::MOP::Attribute->new('is_inline' => (
 592         reader   => { 'is_inline' => \&Class::MOP::Method::Generated::is_inline },
 593         default  => 0,
 594     ))
 595 );
 596
 597 Class::MOP::Method::Generated->meta->add_attribute(
 598     Class::MOP::Attribute->new('definition_context' => (
 599         reader   => { 'definition_context' => \&Class::MOP::Method::Generated::definition_context },
 600     ))
 601 );
 602
 603 ## --------------------------------------------------------
 604 ## Class::MOP::Method::Accessor
 605
 606 Class::MOP::Method::Accessor->meta->add_attribute(
 607     Class::MOP::Attribute->new('attribute' => (
 608         reader   => {
 609             'associated_attribute' => \&Class::MOP::Method::Accessor::associated_attribute
 610         },
 611     ))
 612 );
 613
 614 Class::MOP::Method::Accessor->meta->add_attribute(
 615     Class::MOP::Attribute->new('accessor_type' => (
 616         reader   => { 'accessor_type' => \&Class::MOP::Method::Accessor::accessor_type },
 617     ))
 618 );
 619
 620 ## --------------------------------------------------------
 621 ## Class::MOP::Method::Constructor
 622
 623 Class::MOP::Method::Constructor->meta->add_attribute(
 624     Class::MOP::Attribute->new('options' => (
 625         reader   => {
 626             'options' => \&Class::MOP::Method::Constructor::options
 627         },
 628         default  => sub { +{} }
 629     ))
 630 );
 631
 632 Class::MOP::Method::Constructor->meta->add_attribute(
 633     Class::MOP::Attribute->new('associated_metaclass' => (
 634         init_arg => "metaclass", # FIXME alias and rename
 635         reader   => {
 636             'associated_metaclass' => \&Class::MOP::Method::Constructor::associated_metaclass
 637         },
 638     ))
 639 );
 640
 641 ## --------------------------------------------------------
 642 ## Class::MOP::Instance
 643
 644 # NOTE:
 645 # these don't yet do much of anything, but are just
 646 # included for completeness
 647
 648 Class::MOP::Instance->meta->add_attribute(
 649     Class::MOP::Attribute->new('associated_metaclass',
 650         reader   => { associated_metaclass => \&Class::MOP::Instance::associated_metaclass },
 651     ),
 652 );
 653
 654 Class::MOP::Instance->meta->add_attribute(
 655     Class::MOP::Attribute->new('_class_name',
 656         init_arg => undef,
 657         reader   => { _class_name => \&Class::MOP::Instance::_class_name },
 658         #lazy     => 1, # not yet supported by Class::MOP but out our version does it anyway
 659         #default  => sub { $_[0]->associated_metaclass->name },
 660     ),
 661 );
 662
 663 Class::MOP::Instance->meta->add_attribute(
 664     Class::MOP::Attribute->new('attributes',
 665         reader   => { attributes => \&Class::MOP::Instance::get_all_attributes },
 666     ),
 667 );
 668
 669 Class::MOP::Instance->meta->add_attribute(
 670     Class::MOP::Attribute->new('slots',
 671         reader   => { slots => \&Class::MOP::Instance::slots },
 672     ),
 673 );
 674
 675 Class::MOP::Instance->meta->add_attribute(
 676     Class::MOP::Attribute->new('slot_hash',
 677         reader   => { slot_hash => \&Class::MOP::Instance::slot_hash },
 678     ),
 679 );
 680
 681
 682 # we need the meta instance of the meta instance to be created now, in order
 683 # for the constructor to be able to use it
 684 Class::MOP::Instance->meta->get_meta_instance;
 685
 686 # pretend the add_method never happenned. it hasn't yet affected anything
 687 undef Class::MOP::Instance->meta->{_package_cache_flag};
 688
 689 ## --------------------------------------------------------
 690 ## Now close all the Class::MOP::* classes
 691
 692 # NOTE: we don't need to inline the the accessors this only lengthens
 693 # the compile time of the MOP, and gives us no actual benefits.
 694
 695 $_->meta->make_immutable(
 696     inline_constructor  => 1,
 697     replace_constructor => 1,
 698     constructor_name    => "_new",
 699     inline_accessors => 0,
 700 ) for qw/
 701     Class::MOP::Package
 702     Class::MOP::Module
 703     Class::MOP::Class
 704
 705     Class::MOP::Attribute
 706     Class::MOP::Method
 707     Class::MOP::Instance
 708
 709     Class::MOP::Object
 710
 711     Class::MOP::Method::Generated
 712
 713     Class::MOP::Method::Accessor
 714     Class::MOP::Method::Constructor
 715     Class::MOP::Method::Wrapped
 716 /;
 717
 718 1;
 719
 720 __END__
 721
 722 =pod
 723
 724 =head1 NAME
 725
 726 Class::MOP - A Meta Object Protocol for Perl 5
 727
 728 =head1 DESCRIPTON
 729
 730 This module is a fully functioning meta object protocol for the
 731 Perl 5 object system. It makes no attempt to change the behavior or
 732 characteristics of the Perl 5 object system, only to create a
 733 protocol for its manipulation and introspection.
 734
 735 That said, it does attempt to create the tools for building a rich
 736 set of extensions to the Perl 5 object system. Every attempt has been
 737 made for these tools to keep to the spirit of the Perl 5 object
 738 system that we all know and love.
 739
 740 This documentation is admittedly sparse on details, as time permits
 741 I will try to improve them. For now, I suggest looking at the items
 742 listed in the L<SEE ALSO> section for more information. In particular
 743 the book "The Art of the Meta Object Protocol" was very influential
 744 in the development of this system.
 745
 746 =head2 What is a Meta Object Protocol?
 747
 748 A meta object protocol is an API to an object system.
 749
 750 To be more specific, it is a set of abstractions of the components of
 751 an object system (typically things like; classes, object, methods,
 752 object attributes, etc.). These abstractions can then be used to both
 753 inspect and manipulate the object system which they describe.
 754
 755 It can be said that there are two MOPs for any object system; the
 756 implicit MOP, and the explicit MOP. The implicit MOP handles things
 757 like method dispatch or inheritance, which happen automatically as
 758 part of how the object system works. The explicit MOP typically
 759 handles the introspection/reflection features of the object system.
 760 All object systems have implicit MOPs, without one, they would not
 761 work. Explict MOPs however as less common, and depending on the
 762 language can vary from restrictive (Reflection in Java or C#) to
 763 wide open (CLOS is a perfect example).
 764
 765 =head2 Yet Another Class Builder!! Why?
 766
 767 This is B<not> a class builder so much as it is a I<class builder
 768 B<builder>>. My intent is that an end user does not use this module
 769 directly, but instead this module is used by module authors to
 770 build extensions and features onto the Perl 5 object system.
 771
 772 =head2 Who is this module for?
 773
 774 This module is specifically for anyone who has ever created or
 775 wanted to create a module for the Class:: namespace. The tools which
 776 this module will provide will hopefully make it easier to do more
 777 complex things with Perl 5 classes by removing such barriers as
 778 the need to hack the symbol tables, or understand the fine details
 779 of method dispatch.
 780
 781 =head2 What changes do I have to make to use this module?
 782
 783 This module was designed to be as unintrusive as possible. Many of
 784 its features are accessible without B<any> change to your existsing
 785 code at all. It is meant to be a compliment to your existing code and
 786 not an intrusion on your code base. Unlike many other B<Class::>
 787 modules, this module B<does not> require you subclass it, or even that
 788 you C<use> it in within your module's package.
 789
 790 The only features which requires additions to your code are the
 791 attribute handling and instance construction features, and these are
 792 both completely optional features. The only reason for this is because
 793 Perl 5's object system does not actually have these features built
 794 in. More information about this feature can be found below.
 795
 796 =head2 A Note about Performance?
 797
 798 It is a common misconception that explict MOPs are performance drains.
 799 But this is not a universal truth at all, it is an side-effect of
 800 specific implementations. For instance, using Java reflection is much
 801 slower because the JVM cannot take advantage of any compiler
 802 optimizations, and the JVM has to deal with much more runtime type
 803 information as well. Reflection in C# is marginally better as it was
 804 designed into the language and runtime (the CLR). In contrast, CLOS
 805 (the Common Lisp Object System) was built to support an explicit MOP,
 806 and so performance is tuned for it.
 807
 808 This library in particular does it's absolute best to avoid putting
 809 B<any> drain at all upon your code's performance. In fact, by itself
 810 it does nothing to affect your existing code. So you only pay for
 811 what you actually use.
 812
 813 =head2 About Metaclass compatibility
 814
 815 This module makes sure that all metaclasses created are both upwards
 816 and downwards compatible. The topic of metaclass compatibility is
 817 highly esoteric and is something only encountered when doing deep and
 818 involved metaclass hacking. There are two basic kinds of metaclass
 819 incompatibility; upwards and downwards.
 820
 821 Upwards metaclass compatibility means that the metaclass of a
 822 given class is either the same as (or a subclass of) all of the
 823 class's ancestors.
 824
 825 Downward metaclass compatibility means that the metaclasses of a
 826 given class's anscestors are all either the same as (or a subclass
 827 of) that metaclass.
 828
 829 Here is a diagram showing a set of two classes (C<A> and C<B>) and
 830 two metaclasses (C<Meta::A> and C<Meta::B>) which have correct
 831 metaclass compatibility both upwards and downwards.
 832
 833     +---------+     +---------+
 834     | Meta::A |<----| Meta::B |      <....... (instance of  )
 835     +---------+     +---------+      <------- (inherits from)
 836          ^               ^
 837          :               :
 838     +---------+     +---------+
 839     |    A    |<----|    B    |
 840     +---------+     +---------+
 841
 842 As I said this is a highly esoteric topic and one you will only run
 843 into if you do a lot of subclassing of B<Class::MOP::Class>. If you
 844 are interested in why this is an issue see the paper
 845 I<Uniform and safe metaclass composition> linked to in the
 846 L<SEE ALSO> section of this document.
 847
 848 =head2 Using custom metaclasses
 849
 850 Always use the metaclass pragma when using a custom metaclass, this
 851 will ensure the proper initialization order and not accidentely
 852 create an incorrect type of metaclass for you. This is a very rare
 853 problem, and one which can only occur if you are doing deep metaclass
 854 programming. So in other words, don't worry about it.
 855
 856 =head1 PROTOCOLS
 857
 858 The protocol is divided into 4 main sub-protocols:
 859
 860 =over 4
 861
 862 =item The Class protocol
 863
 864 This provides a means of manipulating and introspecting a Perl 5
 865 class. It handles all of symbol table hacking for you, and provides
 866 a rich set of methods that go beyond simple package introspection.
 867
 868 See L<Class::MOP::Class> for more details.
 869
 870 =item The Attribute protocol
 871
 872 This provides a consistent represenation for an attribute of a
 873 Perl 5 class. Since there are so many ways to create and handle
 874 attributes in Perl 5 OO, this attempts to provide as much of a
 875 unified approach as possible, while giving the freedom and
 876 flexibility to subclass for specialization.
 877
 878 See L<Class::MOP::Attribute> for more details.
 879
 880 =item The Method protocol
 881
 882 This provides a means of manipulating and introspecting methods in
 883 the Perl 5 object system. As with attributes, there are many ways to
 884 approach this topic, so we try to keep it pretty basic, while still
 885 making it possible to extend the system in many ways.
 886
 887 See L<Class::MOP::Method> for more details.
 888
 889 =item The Instance protocol
 890
 891 This provides a layer of abstraction for creating object instances.
 892 Since the other layers use this protocol, it is relatively easy to
 893 change the type of your instances from the default HASH ref to other
 894 types of references. Several examples are provided in the F<examples/>
 895 directory included in this distribution.
 896
 897 See L<Class::MOP::Instance> for more details.
 898
 899 =back
 900
 901 =head1 FUNCTIONS
 902
 903 =head2 Constants
 904
 905 =over 4
 906
 907 =item I<IS_RUNNING_ON_5_10>
 908
 909 We set this constant depending on what version perl we are on, this
 910 allows us to take advantage of new 5.10 features and stay backwards
 911 compat.
 912
 913 =item I<HAVE_ISAREV>
 914
 915 Whether or not C<mro> provides C<get_isarev>, a much faster way to get all the
 916 subclasses of a certain class.
 917
 918 =item I<USING_XS>
 919
 920 Whether or not the running C<Class::MOP> is using its XS version.
 921
 922 =back
 923
 924 =head2 Utility functions
 925
 926 Note that these are all called as B<functions, not methods>.
 927
 928 =over 4
 929
 930 =item B<load_class ($class_name)>
 931
 932 This will load a given C<$class_name> and if it does not have an
 933 already initialized metaclass, then it will intialize one for it.
 934 This function can be used in place of tricks like
 935 C<eval "use $module"> or using C<require>.
 936
 937 =item B<is_class_loaded ($class_name)>
 938
 939 This will return a boolean depending on if the C<$class_name> has
 940 been loaded.
 941
 942 NOTE: This does a basic check of the symbol table to try and
 943 determine as best it can if the C<$class_name> is loaded, it
 944 is probably correct about 99% of the time.
 945
 946 =item B<check_package_cache_flag ($pkg)>
 947
 948 B<NOTE: DO NOT USE THIS FUNCTION, IT IS FOR INTERNAL USE ONLY!>
 949
 950 This will return an integer that is managed by C<Class::MOP::Class>
 951 to determine if a module's symbol table has been altered.
 952
 953 In Perl 5.10 or greater, this flag is package specific. However in
 954 versions prior to 5.10, this will use the C<PL_sub_generation> variable
 955 which is not package specific.
 956
 957 =item B<get_code_info ($code)>
 958
 959 B<NOTE: DO NOT USE THIS FUNCTION, IT IS FOR INTERNAL USE ONLY!>
 960
 961 This function returns two values, the name of the package the C<$code>
 962 is from and the name of the C<$code> itself. This is used by several
 963 elements of the MOP to detemine where a given C<$code> reference is from.
 964
 965 =item B<subname ($name, $code)>
 966
 967 B<NOTE: DO NOT USE THIS FUNCTION, IT IS FOR INTERNAL USE ONLY!>
 968
 969 If possible, we will load the L<Sub::Name> module and this will function
 970 as C<Sub::Name::subname> does, otherwise it will just return the C<$code>
 971 argument.
 972
 973 =item B<in_global_destruction>
 974
 975 B<NOTE: DO NOT USE THIS FUNCTION, IT IS FOR INTERNAL USE ONLY!>
 976
 977 If L<Devel::GlobalDestruction> is available, this returns true under global
 978 destruction.
 979
 980 Otherwise it's a constant returning false.
 981
 982 =item B<load_first_existing_class ($class_name, [$class_name, ...])>
 983
 984 B<NOTE: DO NOT USE THIS FUNCTION, IT IS FOR INTERNAL USE ONLY!>
 985
 986 Given a list of class names, this function will attempt to load each
 987 one in turn.
 988
 989 If it finds a class it can load, it will return that class' name.
 990 If none of the classes can be loaded, it will throw an exception.
 991
 992 =back
 993
 994 =head2 Metaclass cache functions
 995
 996 Class::MOP holds a cache of metaclasses. The following are functions
 997 (B<not methods>) which can be used to access that cache. It is not
 998 recommended that you mess with these. Bad things could happen, but if
 999 you are brave and willing to risk it: go for it!
1000
1001 =over 4
1002
1003 =item B<get_all_metaclasses>
1004
1005 This will return a hash of all the metaclass instances that have
1006 been cached by B<Class::MOP::Class>, keyed by the package name.
1007
1008 =item B<get_all_metaclass_instances>
1009
1010 This will return a list of all the metaclass instances that have
1011 been cached by B<Class::MOP::Class>.
1012
1013 =item B<get_all_metaclass_names>
1014
1015 This will return a list of all the metaclass names that have
1016 been cached by B<Class::MOP::Class>.
1017
1018 =item B<get_metaclass_by_name ($name)>
1019
1020 This will return a cached B<Class::MOP::Class> instance, or nothing
1021 if no metaclass exists with that C<$name>.
1022
1023 =item B<store_metaclass_by_name ($name, $meta)>
1024
1025 This will store a metaclass in the cache at the supplied C<$key>.
1026
1027 =item B<weaken_metaclass ($name)>
1028
1029 In rare cases (e.g. anonymous metaclasses) it is desirable to
1030 store a weakened reference in the metaclass cache. This
1031 function will weaken the reference to the metaclass stored
1032 in C<$name>.
1033
1034 =item B<does_metaclass_exist ($name)>
1035
1036 This will return true of there exists a metaclass stored in the
1037 C<$name> key, and return false otherwise.
1038
1039 =item B<remove_metaclass_by_name ($name)>
1040
1041 This will remove the metaclass stored in the C<$name> key.
1042
1043 =back
1044
1045 =head1 SEE ALSO
1046
1047 =head2 Books
1048
1049 There are very few books out on Meta Object Protocols and Metaclasses
1050 because it is such an esoteric topic. The following books are really
1051 the only ones I have found. If you know of any more, B<I<please>>
1052 email me and let me know, I would love to hear about them.
1053
1054 =over 4
1055
1056 =item "The Art of the Meta Object Protocol"
1057
1058 =item "Advances in Object-Oriented Metalevel Architecture and Reflection"
1059
1060 =item "Putting MetaClasses to Work"
1061
1062 =item "Smalltalk: The Language"
1063
1064 =back
1065
1066 =head2 Papers
1067
1068 =over 4
1069
1070 =item Uniform and safe metaclass composition
1071
1072 An excellent paper by the people who brought us the original Traits paper.
1073 This paper is on how Traits can be used to do safe metaclass composition,
1074 and offers an excellent introduction section which delves into the topic of
1075 metaclass compatibility.
1076
1077 L<http://www.iam.unibe.ch/~scg/Archive/Papers/Duca05ySafeMetaclassTrait.pdf>
1078
1079 =item Safe Metaclass Programming
1080
1081 This paper seems to precede the above paper, and propose a mix-in based
1082 approach as opposed to the Traits based approach. Both papers have similar
1083 information on the metaclass compatibility problem space.
1084
1085 L<http://citeseer.ist.psu.edu/37617.html>
1086
1087 =back
1088
1089 =head2 Prior Art
1090
1091 =over 4
1092
1093 =item The Perl 6 MetaModel work in the Pugs project
1094
1095 =over 4
1096
1097 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-MetaModel>
1098
1099 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-ObjectSpace>
1100
1101 =back
1102
1103 =back
1104
1105 =head2 Articles
1106
1107 =over 4
1108
1109 =item CPAN Module Review of Class::MOP
1110
1111 L<http://www.oreillynet.com/onlamp/blog/2006/06/cpan_module_review_classmop.html>
1112
1113 =back
1114
1115 =head1 SIMILAR MODULES
1116
1117 As I have said above, this module is a class-builder-builder, so it is
1118 not the same thing as modules like L<Class::Accessor> and
1119 L<Class::MethodMaker>. That being said there are very few modules on CPAN
1120 with similar goals to this module. The one I have found which is most
1121 like this module is L<Class::Meta>, although it's philosophy and the MOP it
1122 creates are very different from this modules.
1123
1124 =head1 BUGS
1125
1126 All complex software has bugs lurking in it, and this module is no
1127 exception. If you find a bug please either email me, or add the bug
1128 to cpan-RT.
1129
1130 =head1 ACKNOWLEDGEMENTS
1131
1132 =over 4
1133
1134 =item Rob Kinyon
1135
1136 Thanks to Rob for actually getting the development of this module kick-started.
1137
1138 =back
1139
1140 =head1 AUTHORS
1141
1142 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1143
1144 B<with contributions from:>
1145
1146 Brandon (blblack) Black
1147
1148 Florian (rafl) Ragwitz
1149
1150 Guillermo (groditi) Roditi
1151
1152 Matt (mst) Trout
1153
1154 Rob (robkinyon) Kinyon
1155
1156 Yuval (nothingmuch) Kogman
1157
1158 Scott (konobi) McWhirter
1159
1160 =head1 COPYRIGHT AND LICENSE
1161
1162 Copyright 2006-2008 by Infinity Interactive, Inc.
1163
1164 L<http://www.iinteractive.com>
1165
1166 This library is free software; you can redistribute it and/or modify
1167 it under the same terms as Perl itself.
1168
1169 =cut