lib/Class/MOP.pm

   1
   2 package Class::MOP;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util ();
   9
  10 use Class::MOP::Class;
  11 use Class::MOP::Attribute;
  12 use Class::MOP::Method;
  13
  14 our $VERSION = '0.30';
  15
  16 ## ----------------------------------------------------------------------------
  17 ## Setting up our environment ...
  18 ## ----------------------------------------------------------------------------
  19 ## Class::MOP needs to have a few things in the global perl environment so
  20 ## that it can operate effectively. Those things are done here.
  21 ## ----------------------------------------------------------------------------
  22
  23 # ... nothing yet actually ;)
  24
  25 ## ----------------------------------------------------------------------------
  26 ## Bootstrapping
  27 ## ----------------------------------------------------------------------------
  28 ## The code below here is to bootstrap our MOP with itself. This is also
  29 ## sometimes called "tying the knot". By doing this, we make it much easier
  30 ## to extend the MOP through subclassing and such since now you can use the
  31 ## MOP itself to extend itself.
  32 ##
  33 ## Yes, I know, thats weird and insane, but it's a good thing, trust me :)
  34 ## ----------------------------------------------------------------------------
  35
  36 # We need to add in the meta-attributes here so that
  37 # any subclass of Class::MOP::* will be able to
  38 # inherit them using &construct_instance
  39
  40 ## Class::MOP::Class
  41
  42 Class::MOP::Class->meta->add_attribute(
  43     Class::MOP::Attribute->new('$:package' => (
  44         reader   => {
  45             # NOTE: we need to do this in order
  46             # for the instance meta-object to
  47             # not fall into meta-circular death
  48             'name' => sub { (shift)->{'$:package'} }
  49         },
  50         init_arg => ':package',
  51     ))
  52 );
  53
  54 Class::MOP::Class->meta->add_attribute(
  55     Class::MOP::Attribute->new('%:attributes' => (
  56         reader   => 'get_attribute_map',
  57         init_arg => ':attributes',
  58         default  => sub { {} }
  59     ))
  60 );
  61
  62 Class::MOP::Class->meta->add_attribute(
  63     Class::MOP::Attribute->new('$:attribute_metaclass' => (
  64         reader   => 'attribute_metaclass',
  65         init_arg => ':attribute_metaclass',
  66         default  => 'Class::MOP::Attribute',
  67     ))
  68 );
  69
  70 Class::MOP::Class->meta->add_attribute(
  71     Class::MOP::Attribute->new('$:method_metaclass' => (
  72         reader   => 'method_metaclass',
  73         init_arg => ':method_metaclass',
  74         default  => 'Class::MOP::Method',
  75     ))
  76 );
  77
  78 Class::MOP::Class->meta->add_attribute(
  79     Class::MOP::Attribute->new('$:instance_metaclass' => (
  80         reader   => {
  81             # NOTE: we need to do this in order
  82             # for the instance meta-object to
  83             # not fall into meta-circular death
  84             'instance_metaclass' => sub { (shift)->{'$:instance_metaclass'} }
  85         },
  86         init_arg => ':instance_metaclass',
  87         default  => 'Class::MOP::Instance',
  88     ))
  89 );
  90
  91 ## Class::MOP::Attribute
  92
  93 Class::MOP::Attribute->meta->add_attribute(
  94     Class::MOP::Attribute->new('name' => (
  95         reader => {
  96             # NOTE: we need to do this in order
  97             # for the instance meta-object to
  98             # not fall into meta-circular death
  99             'name' => sub { (shift)->{name} }
 100         }
 101     ))
 102 );
 103
 104 Class::MOP::Attribute->meta->add_attribute(
 105     Class::MOP::Attribute->new('associated_class' => (
 106         reader => {
 107             # NOTE: we need to do this in order
 108             # for the instance meta-object to
 109             # not fall into meta-circular death
 110             'associated_class' => sub { (shift)->{associated_class} }
 111         }
 112     ))
 113 );
 114
 115 Class::MOP::Attribute->meta->add_attribute(
 116     Class::MOP::Attribute->new('accessor' => (
 117         reader    => 'accessor',
 118         predicate => 'has_accessor',
 119     ))
 120 );
 121
 122 Class::MOP::Attribute->meta->add_attribute(
 123     Class::MOP::Attribute->new('reader' => (
 124         reader    => 'reader',
 125         predicate => 'has_reader',
 126     ))
 127 );
 128
 129 Class::MOP::Attribute->meta->add_attribute(
 130     Class::MOP::Attribute->new('writer' => (
 131         reader    => 'writer',
 132         predicate => 'has_writer',
 133     ))
 134 );
 135
 136 Class::MOP::Attribute->meta->add_attribute(
 137     Class::MOP::Attribute->new('predicate' => (
 138         reader    => 'predicate',
 139         predicate => 'has_predicate',
 140     ))
 141 );
 142
 143 Class::MOP::Attribute->meta->add_attribute(
 144     Class::MOP::Attribute->new('init_arg' => (
 145         reader    => 'init_arg',
 146         predicate => 'has_init_arg',
 147     ))
 148 );
 149
 150 Class::MOP::Attribute->meta->add_attribute(
 151     Class::MOP::Attribute->new('default' => (
 152         # default has a custom 'reader' method ...
 153         predicate => 'has_default',
 154     ))
 155 );
 156
 157
 158 # NOTE: (meta-circularity)
 159 # This should be one of the last things done
 160 # it will "tie the knot" with Class::MOP::Attribute
 161 # so that it uses the attributes meta-objects
 162 # to construct itself.
 163 Class::MOP::Attribute->meta->add_method('new' => sub {
 164     my $class   = shift;
 165     my $name    = shift;
 166     my %options = @_;
 167
 168     (defined $name && $name)
 169         || confess "You must provide a name for the attribute";
 170     $options{init_arg} = $name
 171         if not exists $options{init_arg};
 172
 173     # return the new object
 174     $class->meta->new_object(name => $name, %options);
 175 });
 176
 177 Class::MOP::Attribute->meta->add_method('clone' => sub {
 178     my $self  = shift;
 179     $self->meta->clone_object($self, @_);
 180 });
 181
 182 1;
 183
 184 __END__
 185
 186 =pod
 187
 188 =head1 NAME
 189
 190 Class::MOP - A Meta Object Protocol for Perl 5
 191
 192 =head1 SYNOPSIS
 193
 194   # ... This will come later, for now see
 195   # the other SYNOPSIS for more information
 196
 197 =head1 DESCRIPTON
 198
 199 This module is an attempt to create a meta object protocol for the
 200 Perl 5 object system. It makes no attempt to change the behavior or
 201 characteristics of the Perl 5 object system, only to create a
 202 protocol for its manipulation and introspection.
 203
 204 That said, it does attempt to create the tools for building a rich
 205 set of extensions to the Perl 5 object system. Every attempt has been
 206 made for these tools to keep to the spirit of the Perl 5 object
 207 system that we all know and love.
 208
 209 =head2 What is a Meta Object Protocol?
 210
 211 A meta object protocol is an API to an object system.
 212
 213 To be more specific, it is a set of abstractions of the components of
 214 an object system (typically things like; classes, object, methods,
 215 object attributes, etc.). These abstractions can then be used to both
 216 inspect and manipulate the object system which they describe.
 217
 218 It can be said that there are two MOPs for any object system; the
 219 implicit MOP, and the explicit MOP. The implicit MOP handles things
 220 like method dispatch or inheritance, which happen automatically as
 221 part of how the object system works. The explicit MOP typically
 222 handles the introspection/reflection features of the object system.
 223 All object systems have implicit MOPs, without one, they would not
 224 work. Explict MOPs however as less common, and depending on the
 225 language can vary from restrictive (Reflection in Java or C#) to
 226 wide open (CLOS is a perfect example).
 227
 228 =head2 Yet Another Class Builder!! Why?
 229
 230 This is B<not> a class builder so much as it is a I<class builder
 231 B<builder>>. My intent is that an end user does not use this module
 232 directly, but instead this module is used by module authors to
 233 build extensions and features onto the Perl 5 object system.
 234
 235 =head2 Who is this module for?
 236
 237 This module is specifically for anyone who has ever created or
 238 wanted to create a module for the Class:: namespace. The tools which
 239 this module will provide will hopefully make it easier to do more
 240 complex things with Perl 5 classes by removing such barriers as
 241 the need to hack the symbol tables, or understand the fine details
 242 of method dispatch.
 243
 244 =head2 What changes do I have to make to use this module?
 245
 246 This module was designed to be as unintrusive as possible. Many of
 247 its features are accessible without B<any> change to your existsing
 248 code at all. It is meant to be a compliment to your existing code and
 249 not an intrusion on your code base. Unlike many other B<Class::>
 250 modules, this module B<does not> require you subclass it, or even that
 251 you C<use> it in within your module's package.
 252
 253 The only features which requires additions to your code are the
 254 attribute handling and instance construction features, and these are
 255 both completely optional features. The only reason for this is because
 256 Perl 5's object system does not actually have these features built
 257 in. More information about this feature can be found below.
 258
 259 =head2 A Note about Performance?
 260
 261 It is a common misconception that explict MOPs are performance drains.
 262 But this is not a universal truth at all, it is an side-effect of
 263 specific implementations. For instance, using Java reflection is much
 264 slower because the JVM cannot take advantage of any compiler
 265 optimizations, and the JVM has to deal with much more runtime type
 266 information as well. Reflection in C# is marginally better as it was
 267 designed into the language and runtime (the CLR). In contrast, CLOS
 268 (the Common Lisp Object System) was built to support an explicit MOP,
 269 and so performance is tuned for it.
 270
 271 This library in particular does it's absolute best to avoid putting
 272 B<any> drain at all upon your code's performance. In fact, by itself
 273 it does nothing to affect your existing code. So you only pay for
 274 what you actually use.
 275
 276 =head2 About Metaclass compatibility
 277
 278 This module makes sure that all metaclasses created are both upwards
 279 and downwards compatible. The topic of metaclass compatibility is
 280 highly esoteric and is something only encountered when doing deep and
 281 involved metaclass hacking. There are two basic kinds of metaclass
 282 incompatibility; upwards and downwards.
 283
 284 Upwards metaclass compatibility means that the metaclass of a
 285 given class is either the same as (or a subclass of) all of the
 286 class's ancestors.
 287
 288 Downward metaclass compatibility means that the metaclasses of a
 289 given class's anscestors are all either the same as (or a subclass
 290 of) that metaclass.
 291
 292 Here is a diagram showing a set of two classes (C<A> and C<B>) and
 293 two metaclasses (C<Meta::A> and C<Meta::B>) which have correct
 294 metaclass compatibility both upwards and downwards.
 295
 296     +---------+     +---------+
 297     | Meta::A |<----| Meta::B |      <....... (instance of  )
 298     +---------+     +---------+      <------- (inherits from)
 299          ^               ^
 300          :               :
 301     +---------+     +---------+
 302     |    A    |<----|    B    |
 303     +---------+     +---------+
 304
 305 As I said this is a highly esoteric topic and one you will only run
 306 into if you do a lot of subclassing of B<Class::MOP::Class>. If you
 307 are interested in why this is an issue see the paper
 308 I<Uniform and safe metaclass composition> linked to in the
 309 L<SEE ALSO> section of this document.
 310
 311 =head2 Using custom metaclasses
 312
 313 Always use the metaclass pragma when using a custom metaclass, this
 314 will ensure the proper initialization order and not accidentely
 315 create an incorrect type of metaclass for you. This is a very rare
 316 problem, and one which can only occur if you are doing deep metaclass
 317 programming. So in other words, don't worry about it.
 318
 319 =head1 PROTOCOLS
 320
 321 The protocol is divided into 3 main sub-protocols:
 322
 323 =over 4
 324
 325 =item The Class protocol
 326
 327 This provides a means of manipulating and introspecting a Perl 5
 328 class. It handles all of symbol table hacking for you, and provides
 329 a rich set of methods that go beyond simple package introspection.
 330
 331 See L<Class::MOP::Class> for more details.
 332
 333 =item The Attribute protocol
 334
 335 This provides a consistent represenation for an attribute of a
 336 Perl 5 class. Since there are so many ways to create and handle
 337 atttributes in Perl 5 OO, this attempts to provide as much of a
 338 unified approach as possible, while giving the freedom and
 339 flexibility to subclass for specialization.
 340
 341 See L<Class::MOP::Attribute> for more details.
 342
 343 =item The Method protocol
 344
 345 This provides a means of manipulating and introspecting methods in
 346 the Perl 5 object system. As with attributes, there are many ways to
 347 approach this topic, so we try to keep it pretty basic, while still
 348 making it possible to extend the system in many ways.
 349
 350 See L<Class::MOP::Method> for more details.
 351
 352 =back
 353
 354 =head1 SEE ALSO
 355
 356 =head2 Books
 357
 358 There are very few books out on Meta Object Protocols and Metaclasses
 359 because it is such an esoteric topic. The following books are really
 360 the only ones I have found. If you know of any more, B<I<please>>
 361 email me and let me know, I would love to hear about them.
 362
 363 =over 4
 364
 365 =item "The Art of the Meta Object Protocol"
 366
 367 =item "Advances in Object-Oriented Metalevel Architecture and Reflection"
 368
 369 =item "Putting MetaClasses to Work"
 370
 371 =item "Smalltalk: The Language"
 372
 373 =back
 374
 375 =head2 Papers
 376
 377 =over 4
 378
 379 =item Uniform and safe metaclass composition
 380
 381 An excellent paper by the people who brought us the original Traits paper.
 382 This paper is on how Traits can be used to do safe metaclass composition,
 383 and offers an excellent introduction section which delves into the topic of
 384 metaclass compatibility.
 385
 386 L<http://www.iam.unibe.ch/~scg/Archive/Papers/Duca05ySafeMetaclassTrait.pdf>
 387
 388 =item Safe Metaclass Programming
 389
 390 This paper seems to precede the above paper, and propose a mix-in based
 391 approach as opposed to the Traits based approach. Both papers have similar
 392 information on the metaclass compatibility problem space.
 393
 394 L<http://citeseer.ist.psu.edu/37617.html>
 395
 396 =back
 397
 398 =head2 Prior Art
 399
 400 =over 4
 401
 402 =item The Perl 6 MetaModel work in the Pugs project
 403
 404 =over 4
 405
 406 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-MetaModel>
 407
 408 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-ObjectSpace>
 409
 410 =back
 411
 412 =back
 413
 414 =head1 SIMILAR MODULES
 415
 416 As I have said above, this module is a class-builder-builder, so it is
 417 not the same thing as modules like L<Class::Accessor> and
 418 L<Class::MethodMaker>. That being said there are very few modules on CPAN
 419 with similar goals to this module. The one I have found which is most
 420 like this module is L<Class::Meta>, although it's philosophy and the MOP it
 421 creates are very different from this modules.
 422
 423 =head1 BUGS
 424
 425 All complex software has bugs lurking in it, and this module is no
 426 exception. If you find a bug please either email me, or add the bug
 427 to cpan-RT.
 428
 429 =head1 CODE COVERAGE
 430
 431 I use L<Devel::Cover> to test the code coverage of my tests, below is the
 432 L<Devel::Cover> report on this module's test suite.
 433
 434  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 435  File                           stmt   bran   cond    sub    pod   time  total
 436  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 437  Class/MOP.pm                  100.0  100.0  100.0  100.0    n/a    9.6  100.0
 438  Class/MOP/Attribute.pm        100.0  100.0   91.7   73.8  100.0   28.4   92.1
 439  Class/MOP/Class.pm            100.0   93.5   82.3   98.2  100.0   56.6   95.7
 440  Class/MOP/Method.pm           100.0   64.3   52.9   80.0  100.0    3.5   85.3
 441  metaclass.pm                  100.0  100.0   80.0  100.0    n/a    1.9   97.4
 442  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 443  Total                         100.0   90.8   79.7   86.2  100.0  100.0   93.6
 444  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 445
 446 =head1 ACKNOWLEDGEMENTS
 447
 448 =over 4
 449
 450 =item Rob Kinyon E<lt>rob@iinteractive.comE<gt>
 451
 452 Thanks to Rob for actually getting the development of this module kick-started.
 453
 454 =back
 455
 456 =head1 AUTHOR
 457
 458 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 459
 460 =head1 COPYRIGHT AND LICENSE
 461
 462 Copyright 2006 by Infinity Interactive, Inc.
 463
 464 L<http://www.iinteractive.com>
 465
 466 This library is free software; you can redistribute it and/or modify
 467 it under the same terms as Perl itself.
 468
 469 =cut