lib/Class/MOP.pm

   1
   2 package Class::MOP;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util ();
   9
  10 use Class::MOP::Class;
  11 use Class::MOP::Attribute;
  12 use Class::MOP::Method;
  13
  14 use Class::MOP::Class::Immutable;
  15
  16 our $VERSION   = '0.32';
  17 our $AUTHORITY = 'cpan:STEVAN';
  18
  19 ## ----------------------------------------------------------------------------
  20 ## Setting up our environment ...
  21 ## ----------------------------------------------------------------------------
  22 ## Class::MOP needs to have a few things in the global perl environment so
  23 ## that it can operate effectively. Those things are done here.
  24 ## ----------------------------------------------------------------------------
  25
  26 # ... nothing yet actually ;)
  27
  28 ## ----------------------------------------------------------------------------
  29 ## Bootstrapping
  30 ## ----------------------------------------------------------------------------
  31 ## The code below here is to bootstrap our MOP with itself. This is also
  32 ## sometimes called "tying the knot". By doing this, we make it much easier
  33 ## to extend the MOP through subclassing and such since now you can use the
  34 ## MOP itself to extend itself.
  35 ##
  36 ## Yes, I know, thats weird and insane, but it's a good thing, trust me :)
  37 ## ----------------------------------------------------------------------------
  38
  39 # We need to add in the meta-attributes here so that
  40 # any subclass of Class::MOP::* will be able to
  41 # inherit them using &construct_instance
  42
  43 ## --------------------------------------------------------
  44 ## Class::MOP::Package
  45
  46 Class::MOP::Package->meta->add_attribute(
  47     Class::MOP::Attribute->new('$:package' => (
  48         reader   => {
  49             # NOTE: we need to do this in order
  50             # for the instance meta-object to
  51             # not fall into meta-circular death
  52             'name' => sub { (shift)->{'$:package'} }
  53         },
  54         init_arg => ':package',
  55     ))
  56 );
  57
  58 Class::MOP::Package->meta->add_attribute(
  59     Class::MOP::Attribute->new('%:namespace' => (
  60         reader => {
  61             'namespace' => sub { (shift)->{'%:namespace'} }
  62         },
  63         default => sub {
  64             my ($class) = @_;
  65             no strict 'refs';
  66             return \%{$class->name . '::'};
  67         },
  68         # NOTE:
  69         # protect this from silliness
  70         init_arg => '!............( DO NOT DO THIS )............!',
  71     ))
  72 );
  73
  74 # NOTE:
  75 # use the metaclass to construct the meta-package
  76 # which is a superclass of the metaclass itself :P
  77 Class::MOP::Package->meta->add_method('initialize' => sub {
  78     my $class        = shift;
  79     my $package_name = shift;
  80     $class->meta->new_object(':package' => $package_name, @_);
  81 });
  82
  83 ## --------------------------------------------------------
  84 ## Class::MOP::Module
  85
  86 # NOTE:
  87 # yeah this is kind of stretching things a bit,
  88 # but truthfully the version should be an attribute
  89 # of the Module, the weirdness comes from having to
  90 # stick to Perl 5 convention and store it in the
  91 # $VERSION package variable. Basically if you just
  92 # squint at it, it will look how you want it to look.
  93 # Either as a package variable, or as a attribute of
  94 # the metaclass, isn't abstraction great :)
  95
  96 Class::MOP::Module->meta->add_attribute(
  97     Class::MOP::Attribute->new('$:version' => (
  98         reader => {
  99             'version' => sub {
 100                 my $self = shift;
 101                 ${$self->get_package_symbol('$VERSION')};
 102             }
 103         },
 104         # NOTE:
 105         # protect this from silliness
 106         init_arg => '!............( DO NOT DO THIS )............!',
 107     ))
 108 );
 109
 110 # NOTE:
 111 # By following the same conventions as version here,
 112 # we are opening up the possibility that people can
 113 # use the $AUTHORITY in non-Class::MOP modules as
 114 # well.
 115
 116 Class::MOP::Module->meta->add_attribute(
 117     Class::MOP::Attribute->new('$:authority' => (
 118         reader => {
 119             'authority' => sub {
 120                 my $self = shift;
 121                 ${$self->get_package_symbol('$AUTHORITY')};
 122             }
 123         },
 124         # NOTE:
 125         # protect this from silliness
 126         init_arg => '!............( DO NOT DO THIS )............!',
 127     ))
 128 );
 129
 130 ## --------------------------------------------------------
 131 ## Class::MOP::Class
 132
 133 Class::MOP::Class->meta->add_attribute(
 134     Class::MOP::Attribute->new('%:attributes' => (
 135         reader   => {
 136             # NOTE: we need to do this in order
 137             # for the instance meta-object to
 138             # not fall into meta-circular death
 139             'get_attribute_map' => sub { (shift)->{'%:attributes'} }
 140         },
 141         init_arg => ':attributes',
 142         default  => sub { {} }
 143     ))
 144 );
 145
 146 Class::MOP::Class->meta->add_attribute(
 147     Class::MOP::Attribute->new('$:attribute_metaclass' => (
 148         reader   => 'attribute_metaclass',
 149         init_arg => ':attribute_metaclass',
 150         default  => 'Class::MOP::Attribute',
 151     ))
 152 );
 153
 154 Class::MOP::Class->meta->add_attribute(
 155     Class::MOP::Attribute->new('$:method_metaclass' => (
 156         reader   => 'method_metaclass',
 157         init_arg => ':method_metaclass',
 158         default  => 'Class::MOP::Method',
 159     ))
 160 );
 161
 162 Class::MOP::Class->meta->add_attribute(
 163     Class::MOP::Attribute->new('$:instance_metaclass' => (
 164         reader   => {
 165             # NOTE: we need to do this in order
 166             # for the instance meta-object to
 167             # not fall into meta-circular death
 168             'instance_metaclass' => sub { (shift)->{'$:instance_metaclass'} }
 169         },
 170         init_arg => ':instance_metaclass',
 171         default  => 'Class::MOP::Instance',
 172     ))
 173 );
 174
 175 # NOTE:
 176 # we don't actually need to tie the knot with
 177 # Class::MOP::Class here, it is actually handled
 178 # within Class::MOP::Class itself in the
 179 # construct_class_instance method.
 180
 181 ## --------------------------------------------------------
 182 ## Class::MOP::Attribute
 183
 184 Class::MOP::Attribute->meta->add_attribute(
 185     Class::MOP::Attribute->new('name' => (
 186         reader => {
 187             # NOTE: we need to do this in order
 188             # for the instance meta-object to
 189             # not fall into meta-circular death
 190             'name' => sub { (shift)->{name} }
 191         }
 192     ))
 193 );
 194
 195 Class::MOP::Attribute->meta->add_attribute(
 196     Class::MOP::Attribute->new('associated_class' => (
 197         reader => {
 198             # NOTE: we need to do this in order
 199             # for the instance meta-object to
 200             # not fall into meta-circular death
 201             'associated_class' => sub { (shift)->{associated_class} }
 202         }
 203     ))
 204 );
 205
 206 Class::MOP::Attribute->meta->add_attribute(
 207     Class::MOP::Attribute->new('accessor' => (
 208         reader    => 'accessor',
 209         predicate => 'has_accessor',
 210     ))
 211 );
 212
 213 Class::MOP::Attribute->meta->add_attribute(
 214     Class::MOP::Attribute->new('reader' => (
 215         reader    => 'reader',
 216         predicate => 'has_reader',
 217     ))
 218 );
 219
 220 Class::MOP::Attribute->meta->add_attribute(
 221     Class::MOP::Attribute->new('writer' => (
 222         reader    => 'writer',
 223         predicate => 'has_writer',
 224     ))
 225 );
 226
 227 Class::MOP::Attribute->meta->add_attribute(
 228     Class::MOP::Attribute->new('predicate' => (
 229         reader    => 'predicate',
 230         predicate => 'has_predicate',
 231     ))
 232 );
 233
 234 Class::MOP::Attribute->meta->add_attribute(
 235     Class::MOP::Attribute->new('clearer' => (
 236         reader    => 'clearer',
 237         predicate => 'has_clearer',
 238     ))
 239 );
 240
 241 Class::MOP::Attribute->meta->add_attribute(
 242     Class::MOP::Attribute->new('init_arg' => (
 243         reader    => 'init_arg',
 244         predicate => 'has_init_arg',
 245     ))
 246 );
 247
 248 Class::MOP::Attribute->meta->add_attribute(
 249     Class::MOP::Attribute->new('default' => (
 250         # default has a custom 'reader' method ...
 251         predicate => 'has_default',
 252     ))
 253 );
 254
 255
 256 # NOTE: (meta-circularity)
 257 # This should be one of the last things done
 258 # it will "tie the knot" with Class::MOP::Attribute
 259 # so that it uses the attributes meta-objects
 260 # to construct itself.
 261 Class::MOP::Attribute->meta->add_method('new' => sub {
 262     my $class   = shift;
 263     my $name    = shift;
 264     my %options = @_;
 265
 266     (defined $name && $name)
 267         || confess "You must provide a name for the attribute";
 268     $options{init_arg} = $name
 269         if not exists $options{init_arg};
 270
 271     # return the new object
 272     $class->meta->new_object(name => $name, %options);
 273 });
 274
 275 Class::MOP::Attribute->meta->add_method('clone' => sub {
 276     my $self  = shift;
 277     $self->meta->clone_object($self, @_);
 278 });
 279
 280 ## --------------------------------------------------------
 281 ## Now close all the Class::MOP::* classes
 282
 283 Class::MOP::Package  ->meta->make_immutable(inline_constructor => 0);
 284 Class::MOP::Module   ->meta->make_immutable(inline_constructor => 0);
 285 Class::MOP::Class    ->meta->make_immutable(inline_constructor => 0);
 286 Class::MOP::Attribute->meta->make_immutable(inline_constructor => 0);
 287 Class::MOP::Method   ->meta->make_immutable(inline_constructor => 0);
 288 Class::MOP::Instance ->meta->make_immutable(inline_constructor => 0);
 289
 290 1;
 291
 292 __END__
 293
 294 =pod
 295
 296 =head1 NAME
 297
 298 Class::MOP - A Meta Object Protocol for Perl 5
 299
 300 =head1 SYNOPSIS
 301
 302   # ... This will come later, for now see
 303   # the other SYNOPSIS for more information
 304
 305 =head1 DESCRIPTON
 306
 307 This module is an attempt to create a meta object protocol for the
 308 Perl 5 object system. It makes no attempt to change the behavior or
 309 characteristics of the Perl 5 object system, only to create a
 310 protocol for its manipulation and introspection.
 311
 312 That said, it does attempt to create the tools for building a rich
 313 set of extensions to the Perl 5 object system. Every attempt has been
 314 made for these tools to keep to the spirit of the Perl 5 object
 315 system that we all know and love.
 316
 317 This documentation is admittedly sparse on details, as time permits
 318 I will try to improve them. For now, I suggest looking at the items
 319 listed in the L<SEE ALSO> section for more information. In particular
 320 the book "The Art of the Meta Object Protocol" was very influential
 321 in the development of this system.
 322
 323 =head2 What is a Meta Object Protocol?
 324
 325 A meta object protocol is an API to an object system.
 326
 327 To be more specific, it is a set of abstractions of the components of
 328 an object system (typically things like; classes, object, methods,
 329 object attributes, etc.). These abstractions can then be used to both
 330 inspect and manipulate the object system which they describe.
 331
 332 It can be said that there are two MOPs for any object system; the
 333 implicit MOP, and the explicit MOP. The implicit MOP handles things
 334 like method dispatch or inheritance, which happen automatically as
 335 part of how the object system works. The explicit MOP typically
 336 handles the introspection/reflection features of the object system.
 337 All object systems have implicit MOPs, without one, they would not
 338 work. Explict MOPs however as less common, and depending on the
 339 language can vary from restrictive (Reflection in Java or C#) to
 340 wide open (CLOS is a perfect example).
 341
 342 =head2 Yet Another Class Builder!! Why?
 343
 344 This is B<not> a class builder so much as it is a I<class builder
 345 B<builder>>. My intent is that an end user does not use this module
 346 directly, but instead this module is used by module authors to
 347 build extensions and features onto the Perl 5 object system.
 348
 349 =head2 Who is this module for?
 350
 351 This module is specifically for anyone who has ever created or
 352 wanted to create a module for the Class:: namespace. The tools which
 353 this module will provide will hopefully make it easier to do more
 354 complex things with Perl 5 classes by removing such barriers as
 355 the need to hack the symbol tables, or understand the fine details
 356 of method dispatch.
 357
 358 =head2 What changes do I have to make to use this module?
 359
 360 This module was designed to be as unintrusive as possible. Many of
 361 its features are accessible without B<any> change to your existsing
 362 code at all. It is meant to be a compliment to your existing code and
 363 not an intrusion on your code base. Unlike many other B<Class::>
 364 modules, this module B<does not> require you subclass it, or even that
 365 you C<use> it in within your module's package.
 366
 367 The only features which requires additions to your code are the
 368 attribute handling and instance construction features, and these are
 369 both completely optional features. The only reason for this is because
 370 Perl 5's object system does not actually have these features built
 371 in. More information about this feature can be found below.
 372
 373 =head2 A Note about Performance?
 374
 375 It is a common misconception that explict MOPs are performance drains.
 376 But this is not a universal truth at all, it is an side-effect of
 377 specific implementations. For instance, using Java reflection is much
 378 slower because the JVM cannot take advantage of any compiler
 379 optimizations, and the JVM has to deal with much more runtime type
 380 information as well. Reflection in C# is marginally better as it was
 381 designed into the language and runtime (the CLR). In contrast, CLOS
 382 (the Common Lisp Object System) was built to support an explicit MOP,
 383 and so performance is tuned for it.
 384
 385 This library in particular does it's absolute best to avoid putting
 386 B<any> drain at all upon your code's performance. In fact, by itself
 387 it does nothing to affect your existing code. So you only pay for
 388 what you actually use.
 389
 390 =head2 About Metaclass compatibility
 391
 392 This module makes sure that all metaclasses created are both upwards
 393 and downwards compatible. The topic of metaclass compatibility is
 394 highly esoteric and is something only encountered when doing deep and
 395 involved metaclass hacking. There are two basic kinds of metaclass
 396 incompatibility; upwards and downwards.
 397
 398 Upwards metaclass compatibility means that the metaclass of a
 399 given class is either the same as (or a subclass of) all of the
 400 class's ancestors.
 401
 402 Downward metaclass compatibility means that the metaclasses of a
 403 given class's anscestors are all either the same as (or a subclass
 404 of) that metaclass.
 405
 406 Here is a diagram showing a set of two classes (C<A> and C<B>) and
 407 two metaclasses (C<Meta::A> and C<Meta::B>) which have correct
 408 metaclass compatibility both upwards and downwards.
 409
 410     +---------+     +---------+
 411     | Meta::A |<----| Meta::B |      <....... (instance of  )
 412     +---------+     +---------+      <------- (inherits from)
 413          ^               ^
 414          :               :
 415     +---------+     +---------+
 416     |    A    |<----|    B    |
 417     +---------+     +---------+
 418
 419 As I said this is a highly esoteric topic and one you will only run
 420 into if you do a lot of subclassing of B<Class::MOP::Class>. If you
 421 are interested in why this is an issue see the paper
 422 I<Uniform and safe metaclass composition> linked to in the
 423 L<SEE ALSO> section of this document.
 424
 425 =head2 Using custom metaclasses
 426
 427 Always use the metaclass pragma when using a custom metaclass, this
 428 will ensure the proper initialization order and not accidentely
 429 create an incorrect type of metaclass for you. This is a very rare
 430 problem, and one which can only occur if you are doing deep metaclass
 431 programming. So in other words, don't worry about it.
 432
 433 =head1 PROTOCOLS
 434
 435 The protocol is divided into 3 main sub-protocols:
 436
 437 =over 4
 438
 439 =item The Class protocol
 440
 441 This provides a means of manipulating and introspecting a Perl 5
 442 class. It handles all of symbol table hacking for you, and provides
 443 a rich set of methods that go beyond simple package introspection.
 444
 445 See L<Class::MOP::Class> for more details.
 446
 447 =item The Attribute protocol
 448
 449 This provides a consistent represenation for an attribute of a
 450 Perl 5 class. Since there are so many ways to create and handle
 451 atttributes in Perl 5 OO, this attempts to provide as much of a
 452 unified approach as possible, while giving the freedom and
 453 flexibility to subclass for specialization.
 454
 455 See L<Class::MOP::Attribute> for more details.
 456
 457 =item The Method protocol
 458
 459 This provides a means of manipulating and introspecting methods in
 460 the Perl 5 object system. As with attributes, there are many ways to
 461 approach this topic, so we try to keep it pretty basic, while still
 462 making it possible to extend the system in many ways.
 463
 464 See L<Class::MOP::Method> for more details.
 465
 466 =back
 467
 468 =head1 SEE ALSO
 469
 470 =head2 Books
 471
 472 There are very few books out on Meta Object Protocols and Metaclasses
 473 because it is such an esoteric topic. The following books are really
 474 the only ones I have found. If you know of any more, B<I<please>>
 475 email me and let me know, I would love to hear about them.
 476
 477 =over 4
 478
 479 =item "The Art of the Meta Object Protocol"
 480
 481 =item "Advances in Object-Oriented Metalevel Architecture and Reflection"
 482
 483 =item "Putting MetaClasses to Work"
 484
 485 =item "Smalltalk: The Language"
 486
 487 =back
 488
 489 =head2 Papers
 490
 491 =over 4
 492
 493 =item Uniform and safe metaclass composition
 494
 495 An excellent paper by the people who brought us the original Traits paper.
 496 This paper is on how Traits can be used to do safe metaclass composition,
 497 and offers an excellent introduction section which delves into the topic of
 498 metaclass compatibility.
 499
 500 L<http://www.iam.unibe.ch/~scg/Archive/Papers/Duca05ySafeMetaclassTrait.pdf>
 501
 502 =item Safe Metaclass Programming
 503
 504 This paper seems to precede the above paper, and propose a mix-in based
 505 approach as opposed to the Traits based approach. Both papers have similar
 506 information on the metaclass compatibility problem space.
 507
 508 L<http://citeseer.ist.psu.edu/37617.html>
 509
 510 =back
 511
 512 =head2 Prior Art
 513
 514 =over 4
 515
 516 =item The Perl 6 MetaModel work in the Pugs project
 517
 518 =over 4
 519
 520 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-MetaModel>
 521
 522 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-ObjectSpace>
 523
 524 =back
 525
 526 =back
 527
 528 =head1 SIMILAR MODULES
 529
 530 As I have said above, this module is a class-builder-builder, so it is
 531 not the same thing as modules like L<Class::Accessor> and
 532 L<Class::MethodMaker>. That being said there are very few modules on CPAN
 533 with similar goals to this module. The one I have found which is most
 534 like this module is L<Class::Meta>, although it's philosophy and the MOP it
 535 creates are very different from this modules.
 536
 537 =head1 BUGS
 538
 539 All complex software has bugs lurking in it, and this module is no
 540 exception. If you find a bug please either email me, or add the bug
 541 to cpan-RT.
 542
 543 =head1 CODE COVERAGE
 544
 545 I use L<Devel::Cover> to test the code coverage of my tests, below is the
 546 L<Devel::Cover> report on this module's test suite.
 547
 548  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 549  File                           stmt   bran   cond    sub    pod   time  total
 550  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 551  Class/MOP.pm                  100.0  100.0  100.0  100.0    n/a   19.8  100.0
 552  Class/MOP/Attribute.pm        100.0  100.0   91.7   61.2  100.0   14.3   87.9
 553  Class/MOP/Class.pm             97.6   91.3   77.3   98.4  100.0   56.4   93.2
 554  Class/MOP/Instance.pm          91.1   75.0   33.3   91.7  100.0    6.8   90.7
 555  Class/MOP/Method.pm            97.6   60.0   52.9   76.9  100.0    1.6   82.6
 556  metaclass.pm                  100.0  100.0   83.3  100.0    n/a    1.0   97.7
 557  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 558  Total                          97.5   88.5   75.5   82.8  100.0  100.0   91.2
 559  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 560
 561 =head1 ACKNOWLEDGEMENTS
 562
 563 =over 4
 564
 565 =item Rob Kinyon E<lt>rob@iinteractive.comE<gt>
 566
 567 Thanks to Rob for actually getting the development of this module kick-started.
 568
 569 =back
 570
 571 =head1 AUTHORS
 572
 573 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 574
 575 Yuval Kogman E<lt>nothingmuch@woobling.comE<gt>
 576
 577 =head1 COPYRIGHT AND LICENSE
 578
 579 Copyright 2006 by Infinity Interactive, Inc.
 580
 581 L<http://www.iinteractive.com>
 582
 583 This library is free software; you can redistribute it and/or modify
 584 it under the same terms as Perl itself.
 585
 586 =cut