lib/Class/MOP.pm

   1
   2 package Class::MOP;
   3
   4 use strict;
   5 use warnings;
   6
   7 use 5.008;
   8
   9 use MRO::Compat;
  10
  11 use Carp          'confess';
  12 use Scalar::Util  'weaken', 'reftype', 'blessed';
  13 use Data::OptList;
  14 use Try::Tiny;
  15
  16 use Class::MOP::Mixin::AttributeCore;
  17 use Class::MOP::Mixin::HasAttributes;
  18 use Class::MOP::Mixin::HasMethods;
  19 use Class::MOP::Class;
  20 use Class::MOP::Attribute;
  21 use Class::MOP::Method;
  22
  23 BEGIN {
  24     *IS_RUNNING_ON_5_10 = ($] < 5.009_005)
  25         ? sub () { 0 }
  26         : sub () { 1 };
  27
  28     # this is either part of core or set up appropriately by MRO::Compat
  29     *check_package_cache_flag = \&mro::get_pkg_gen;
  30 }
  31
  32 our $VERSION   = '1.00';
  33 our $XS_VERSION = $VERSION;
  34 $VERSION = eval $VERSION;
  35 our $AUTHORITY = 'cpan:STEVAN';
  36
  37 require XSLoader;
  38 XSLoader::load( __PACKAGE__, $XS_VERSION );
  39
  40
  41 {
  42     # Metaclasses are singletons, so we cache them here.
  43     # there is no need to worry about destruction though
  44     # because they should die only when the program dies.
  45     # After all, do package definitions even get reaped?
  46     # Anonymous classes manage their own destruction.
  47     my %METAS;
  48
  49     sub get_all_metaclasses         {        %METAS         }
  50     sub get_all_metaclass_instances { values %METAS         }
  51     sub get_all_metaclass_names     { keys   %METAS         }
  52     sub get_metaclass_by_name       { $METAS{$_[0]}         }
  53     sub store_metaclass_by_name     { $METAS{$_[0]} = $_[1] }
  54     sub weaken_metaclass            { weaken($METAS{$_[0]}) }
  55     sub does_metaclass_exist        { exists $METAS{$_[0]} && defined $METAS{$_[0]} }
  56     sub remove_metaclass_by_name    { delete $METAS{$_[0]}; return }
  57
  58     # This handles instances as well as class names
  59     sub class_of {
  60         return unless defined $_[0];
  61         my $class = blessed($_[0]) || $_[0];
  62         return $METAS{$class};
  63     }
  64
  65     # NOTE:
  66     # We only cache metaclasses, meaning instances of
  67     # Class::MOP::Class. We do not cache instance of
  68     # Class::MOP::Package or Class::MOP::Module. Mostly
  69     # because I don't yet see a good reason to do so.
  70 }
  71
  72 sub _class_to_pmfile {
  73     my $class = shift;
  74
  75     my $file = $class . '.pm';
  76     $file =~ s{::}{/}g;
  77
  78     return $file;
  79 }
  80
  81 sub load_first_existing_class {
  82     my $classes = Data::OptList::mkopt(\@_)
  83       or return;
  84
  85     foreach my $class (@{ $classes }) {
  86         my $name = $class->[0];
  87         unless ( _is_valid_class_name($name) ) {
  88             my $display = defined($name) ? $name : 'undef';
  89             confess "Invalid class name ($display)";
  90         }
  91     }
  92
  93     my $found;
  94     my %exceptions;
  95
  96     for my $class (@{ $classes }) {
  97         my ($name, $options) = @{ $class };
  98
  99         if ($options) {
 100             return $name if is_class_loaded($name, $options);
 101             if (is_class_loaded($name)) {
 102                 # we already know it's loaded and too old, but we call
 103                 # ->VERSION anyway to generate the exception for us
 104                 $name->VERSION($options->{-version});
 105             }
 106         }
 107         else {
 108             return $name if is_class_loaded($name);
 109         }
 110
 111         my $file = _class_to_pmfile($name);
 112         return $name if try {
 113             local $SIG{__DIE__};
 114             require $file;
 115             $name->VERSION($options->{-version})
 116                 if defined $options->{-version};
 117             return 1;
 118         }
 119         catch {
 120             unless (/^Can't locate \Q$file\E in \@INC/) {
 121                 confess "Couldn't load class ($name) because: $_";
 122             }
 123
 124             return;
 125         };
 126     }
 127
 128     if ( @{ $classes } > 1 ) {
 129         my @list = map { $_->[0] } @{ $classes };
 130         confess "Can't locate any of @list in \@INC (\@INC contains: @INC).";
 131     } else {
 132         confess "Can't locate " . _class_to_pmfile($classes->[0]->[0]) . " in \@INC (\@INC contains: @INC).";
 133     }
 134 }
 135
 136 sub load_class {
 137     load_first_existing_class($_[0], ref $_[1] ? $_[1] : ());
 138
 139     # This is done to avoid breaking code which checked the return value. Said
 140     # code is dumb. The return value was _always_ true, since it dies on
 141     # failure!
 142     return 1;
 143 }
 144
 145 sub _is_valid_class_name {
 146     my $class = shift;
 147
 148     return 0 if ref($class);
 149     return 0 unless defined($class);
 150     return 0 unless length($class);
 151
 152     return 1 if $class =~ /^\w+(?:::\w+)*$/;
 153
 154     return 0;
 155 }
 156
 157 ## ----------------------------------------------------------------------------
 158 ## Setting up our environment ...
 159 ## ----------------------------------------------------------------------------
 160 ## Class::MOP needs to have a few things in the global perl environment so
 161 ## that it can operate effectively. Those things are done here.
 162 ## ----------------------------------------------------------------------------
 163
 164 # ... nothing yet actually ;)
 165
 166 ## ----------------------------------------------------------------------------
 167 ## Bootstrapping
 168 ## ----------------------------------------------------------------------------
 169 ## The code below here is to bootstrap our MOP with itself. This is also
 170 ## sometimes called "tying the knot". By doing this, we make it much easier
 171 ## to extend the MOP through subclassing and such since now you can use the
 172 ## MOP itself to extend itself.
 173 ##
 174 ## Yes, I know, thats weird and insane, but it's a good thing, trust me :)
 175 ## ----------------------------------------------------------------------------
 176
 177 # We need to add in the meta-attributes here so that
 178 # any subclass of Class::MOP::* will be able to
 179 # inherit them using _construct_instance
 180
 181 ## --------------------------------------------------------
 182 ## Class::MOP::Mixin::HasMethods
 183
 184 Class::MOP::Mixin::HasMethods->meta->add_attribute(
 185     Class::MOP::Attribute->new('_methods' => (
 186         reader   => {
 187             # NOTE:
 188             # we just alias the original method
 189             # rather than re-produce it here
 190             '_full_method_map' => \&Class::MOP::Mixin::HasMethods::_full_method_map
 191         },
 192         default => sub { {} }
 193     ))
 194 );
 195
 196 Class::MOP::Mixin::HasMethods->meta->add_attribute(
 197     Class::MOP::Attribute->new('method_metaclass' => (
 198         reader   => {
 199             # NOTE:
 200             # we just alias the original method
 201             # rather than re-produce it here
 202             'method_metaclass' => \&Class::MOP::Mixin::HasMethods::method_metaclass
 203         },
 204         default  => 'Class::MOP::Method',
 205     ))
 206 );
 207
 208 Class::MOP::Mixin::HasMethods->meta->add_attribute(
 209     Class::MOP::Attribute->new('wrapped_method_metaclass' => (
 210         reader   => {
 211             # NOTE:
 212             # we just alias the original method
 213             # rather than re-produce it here
 214             'wrapped_method_metaclass' => \&Class::MOP::Mixin::HasMethods::wrapped_method_metaclass
 215         },
 216         default  => 'Class::MOP::Method::Wrapped',
 217     ))
 218 );
 219
 220 ## --------------------------------------------------------
 221 ## Class::MOP::Mixin::HasMethods
 222
 223 Class::MOP::Mixin::HasAttributes->meta->add_attribute(
 224     Class::MOP::Attribute->new('attributes' => (
 225         reader   => {
 226             # NOTE: we need to do this in order
 227             # for the instance meta-object to
 228             # not fall into meta-circular death
 229             #
 230             # we just alias the original method
 231             # rather than re-produce it here
 232             '_attribute_map' => \&Class::MOP::Mixin::HasAttributes::_attribute_map
 233         },
 234         default  => sub { {} }
 235     ))
 236 );
 237
 238 Class::MOP::Mixin::HasAttributes->meta->add_attribute(
 239     Class::MOP::Attribute->new('attribute_metaclass' => (
 240         reader   => {
 241             # NOTE:
 242             # we just alias the original method
 243             # rather than re-produce it here
 244             'attribute_metaclass' => \&Class::MOP::Mixin::HasAttributes::attribute_metaclass
 245         },
 246         default  => 'Class::MOP::Attribute',
 247     ))
 248 );
 249
 250 ## --------------------------------------------------------
 251 ## Class::MOP::Package
 252
 253 Class::MOP::Package->meta->add_attribute(
 254     Class::MOP::Attribute->new('package' => (
 255         reader   => {
 256             # NOTE: we need to do this in order
 257             # for the instance meta-object to
 258             # not fall into meta-circular death
 259             #
 260             # we just alias the original method
 261             # rather than re-produce it here
 262             'name' => \&Class::MOP::Package::name
 263         },
 264     ))
 265 );
 266
 267 Class::MOP::Package->meta->add_attribute(
 268     Class::MOP::Attribute->new('namespace' => (
 269         reader => {
 270             # NOTE:
 271             # we just alias the original method
 272             # rather than re-produce it here
 273             'namespace' => \&Class::MOP::Package::namespace
 274         },
 275         init_arg => undef,
 276         default  => sub { \undef }
 277     ))
 278 );
 279
 280 ## --------------------------------------------------------
 281 ## Class::MOP::Module
 282
 283 # NOTE:
 284 # yeah this is kind of stretching things a bit,
 285 # but truthfully the version should be an attribute
 286 # of the Module, the weirdness comes from having to
 287 # stick to Perl 5 convention and store it in the
 288 # $VERSION package variable. Basically if you just
 289 # squint at it, it will look how you want it to look.
 290 # Either as a package variable, or as a attribute of
 291 # the metaclass, isn't abstraction great :)
 292
 293 Class::MOP::Module->meta->add_attribute(
 294     Class::MOP::Attribute->new('version' => (
 295         reader => {
 296             # NOTE:
 297             # we just alias the original method
 298             # rather than re-produce it here
 299             'version' => \&Class::MOP::Module::version
 300         },
 301         init_arg => undef,
 302         default  => sub { \undef }
 303     ))
 304 );
 305
 306 # NOTE:
 307 # By following the same conventions as version here,
 308 # we are opening up the possibility that people can
 309 # use the $AUTHORITY in non-Class::MOP modules as
 310 # well.
 311
 312 Class::MOP::Module->meta->add_attribute(
 313     Class::MOP::Attribute->new('authority' => (
 314         reader => {
 315             # NOTE:
 316             # we just alias the original method
 317             # rather than re-produce it here
 318             'authority' => \&Class::MOP::Module::authority
 319         },
 320         init_arg => undef,
 321         default  => sub { \undef }
 322     ))
 323 );
 324
 325 ## --------------------------------------------------------
 326 ## Class::MOP::Class
 327
 328 Class::MOP::Class->meta->add_attribute(
 329     Class::MOP::Attribute->new('superclasses' => (
 330         accessor => {
 331             # NOTE:
 332             # we just alias the original method
 333             # rather than re-produce it here
 334             'superclasses' => \&Class::MOP::Class::superclasses
 335         },
 336         init_arg => undef,
 337         default  => sub { \undef }
 338     ))
 339 );
 340
 341 Class::MOP::Class->meta->add_attribute(
 342     Class::MOP::Attribute->new('instance_metaclass' => (
 343         reader   => {
 344             # NOTE: we need to do this in order
 345             # for the instance meta-object to
 346             # not fall into meta-circular death
 347             #
 348             # we just alias the original method
 349             # rather than re-produce it here
 350             'instance_metaclass' => \&Class::MOP::Class::instance_metaclass
 351         },
 352         default  => 'Class::MOP::Instance',
 353     ))
 354 );
 355
 356 Class::MOP::Class->meta->add_attribute(
 357     Class::MOP::Attribute->new('immutable_trait' => (
 358         reader   => {
 359             'immutable_trait' => \&Class::MOP::Class::immutable_trait
 360         },
 361         default => "Class::MOP::Class::Immutable::Trait",
 362     ))
 363 );
 364
 365 Class::MOP::Class->meta->add_attribute(
 366     Class::MOP::Attribute->new('constructor_name' => (
 367         reader   => {
 368             'constructor_name' => \&Class::MOP::Class::constructor_name,
 369         },
 370         default => "new",
 371     ))
 372 );
 373
 374 Class::MOP::Class->meta->add_attribute(
 375     Class::MOP::Attribute->new('constructor_class' => (
 376         reader   => {
 377             'constructor_class' => \&Class::MOP::Class::constructor_class,
 378         },
 379         default => "Class::MOP::Method::Constructor",
 380     ))
 381 );
 382
 383
 384 Class::MOP::Class->meta->add_attribute(
 385     Class::MOP::Attribute->new('destructor_class' => (
 386         reader   => {
 387             'destructor_class' => \&Class::MOP::Class::destructor_class,
 388         },
 389     ))
 390 );
 391
 392 # NOTE:
 393 # we don't actually need to tie the knot with
 394 # Class::MOP::Class here, it is actually handled
 395 # within Class::MOP::Class itself in the
 396 # _construct_class_instance method.
 397
 398 ## --------------------------------------------------------
 399 ## Class::MOP::Mixin::AttributeCore
 400 Class::MOP::Mixin::AttributeCore->meta->add_attribute(
 401     Class::MOP::Attribute->new('name' => (
 402         reader   => {
 403             # NOTE: we need to do this in order
 404             # for the instance meta-object to
 405             # not fall into meta-circular death
 406             #
 407             # we just alias the original method
 408             # rather than re-produce it here
 409             'name' => \&Class::MOP::Mixin::AttributeCore::name
 410         }
 411     ))
 412 );
 413
 414 Class::MOP::Mixin::AttributeCore->meta->add_attribute(
 415     Class::MOP::Attribute->new('accessor' => (
 416         reader    => { 'accessor'     => \&Class::MOP::Mixin::AttributeCore::accessor     },
 417         predicate => { 'has_accessor' => \&Class::MOP::Mixin::AttributeCore::has_accessor },
 418     ))
 419 );
 420
 421 Class::MOP::Mixin::AttributeCore->meta->add_attribute(
 422     Class::MOP::Attribute->new('reader' => (
 423         reader    => { 'reader'     => \&Class::MOP::Mixin::AttributeCore::reader     },
 424         predicate => { 'has_reader' => \&Class::MOP::Mixin::AttributeCore::has_reader },
 425     ))
 426 );
 427
 428 Class::MOP::Mixin::AttributeCore->meta->add_attribute(
 429     Class::MOP::Attribute->new('initializer' => (
 430         reader    => { 'initializer'     => \&Class::MOP::Mixin::AttributeCore::initializer     },
 431         predicate => { 'has_initializer' => \&Class::MOP::Mixin::AttributeCore::has_initializer },
 432     ))
 433 );
 434
 435 Class::MOP::Mixin::AttributeCore->meta->add_attribute(
 436     Class::MOP::Attribute->new('definition_context' => (
 437         reader    => { 'definition_context'     => \&Class::MOP::Mixin::AttributeCore::definition_context     },
 438     ))
 439 );
 440
 441 Class::MOP::Mixin::AttributeCore->meta->add_attribute(
 442     Class::MOP::Attribute->new('writer' => (
 443         reader    => { 'writer'     => \&Class::MOP::Mixin::AttributeCore::writer     },
 444         predicate => { 'has_writer' => \&Class::MOP::Mixin::AttributeCore::has_writer },
 445     ))
 446 );
 447
 448 Class::MOP::Mixin::AttributeCore->meta->add_attribute(
 449     Class::MOP::Attribute->new('predicate' => (
 450         reader    => { 'predicate'     => \&Class::MOP::Mixin::AttributeCore::predicate     },
 451         predicate => { 'has_predicate' => \&Class::MOP::Mixin::AttributeCore::has_predicate },
 452     ))
 453 );
 454
 455 Class::MOP::Mixin::AttributeCore->meta->add_attribute(
 456     Class::MOP::Attribute->new('clearer' => (
 457         reader    => { 'clearer'     => \&Class::MOP::Mixin::AttributeCore::clearer     },
 458         predicate => { 'has_clearer' => \&Class::MOP::Mixin::AttributeCore::has_clearer },
 459     ))
 460 );
 461
 462 Class::MOP::Mixin::AttributeCore->meta->add_attribute(
 463     Class::MOP::Attribute->new('builder' => (
 464         reader    => { 'builder'     => \&Class::MOP::Mixin::AttributeCore::builder     },
 465         predicate => { 'has_builder' => \&Class::MOP::Mixin::AttributeCore::has_builder },
 466     ))
 467 );
 468
 469 Class::MOP::Mixin::AttributeCore->meta->add_attribute(
 470     Class::MOP::Attribute->new('init_arg' => (
 471         reader    => { 'init_arg'     => \&Class::MOP::Mixin::AttributeCore::init_arg     },
 472         predicate => { 'has_init_arg' => \&Class::MOP::Mixin::AttributeCore::has_init_arg },
 473     ))
 474 );
 475
 476 Class::MOP::Mixin::AttributeCore->meta->add_attribute(
 477     Class::MOP::Attribute->new('default' => (
 478         # default has a custom 'reader' method ...
 479         predicate => { 'has_default' => \&Class::MOP::Mixin::AttributeCore::has_default },
 480     ))
 481 );
 482
 483 Class::MOP::Mixin::AttributeCore->meta->add_attribute(
 484     Class::MOP::Attribute->new('insertion_order' => (
 485         reader      => { 'insertion_order' => \&Class::MOP::Mixin::AttributeCore::insertion_order },
 486         writer      => { '_set_insertion_order' => \&Class::MOP::Mixin::AttributeCore::_set_insertion_order },
 487         predicate   => { 'has_insertion_order' => \&Class::MOP::Mixin::AttributeCore::has_insertion_order },
 488     ))
 489 );
 490
 491 ## --------------------------------------------------------
 492 ## Class::MOP::Attribute
 493 Class::MOP::Attribute->meta->add_attribute(
 494     Class::MOP::Attribute->new('associated_class' => (
 495         reader   => {
 496             # NOTE: we need to do this in order
 497             # for the instance meta-object to
 498             # not fall into meta-circular death
 499             #
 500             # we just alias the original method
 501             # rather than re-produce it here
 502             'associated_class' => \&Class::MOP::Attribute::associated_class
 503         }
 504     ))
 505 );
 506
 507 Class::MOP::Attribute->meta->add_attribute(
 508     Class::MOP::Attribute->new('associated_methods' => (
 509         reader   => { 'associated_methods' => \&Class::MOP::Attribute::associated_methods },
 510         default  => sub { [] }
 511     ))
 512 );
 513
 514 Class::MOP::Attribute->meta->add_method('clone' => sub {
 515     my $self  = shift;
 516     $self->meta->clone_object($self, @_);
 517 });
 518
 519 ## --------------------------------------------------------
 520 ## Class::MOP::Method
 521 Class::MOP::Method->meta->add_attribute(
 522     Class::MOP::Attribute->new('body' => (
 523         reader   => { 'body' => \&Class::MOP::Method::body },
 524     ))
 525 );
 526
 527 Class::MOP::Method->meta->add_attribute(
 528     Class::MOP::Attribute->new('associated_metaclass' => (
 529         reader   => { 'associated_metaclass' => \&Class::MOP::Method::associated_metaclass },
 530     ))
 531 );
 532
 533 Class::MOP::Method->meta->add_attribute(
 534     Class::MOP::Attribute->new('package_name' => (
 535         reader   => { 'package_name' => \&Class::MOP::Method::package_name },
 536     ))
 537 );
 538
 539 Class::MOP::Method->meta->add_attribute(
 540     Class::MOP::Attribute->new('name' => (
 541         reader   => { 'name' => \&Class::MOP::Method::name },
 542     ))
 543 );
 544
 545 Class::MOP::Method->meta->add_attribute(
 546     Class::MOP::Attribute->new('original_method' => (
 547         reader   => { 'original_method'      => \&Class::MOP::Method::original_method },
 548         writer   => { '_set_original_method' => \&Class::MOP::Method::_set_original_method },
 549     ))
 550 );
 551
 552 Class::MOP::Method->meta->add_method('clone' => sub {
 553     my $self  = shift;
 554     my $clone = $self->meta->clone_object($self, @_);
 555     $clone->_set_original_method($self);
 556     return $clone;
 557 });
 558
 559 ## --------------------------------------------------------
 560 ## Class::MOP::Method::Wrapped
 561
 562 # NOTE:
 563 # the way this item is initialized, this
 564 # really does not follow the standard
 565 # practices of attributes, but we put
 566 # it here for completeness
 567 Class::MOP::Method::Wrapped->meta->add_attribute(
 568     Class::MOP::Attribute->new('modifier_table')
 569 );
 570
 571 ## --------------------------------------------------------
 572 ## Class::MOP::Method::Generated
 573
 574 Class::MOP::Method::Generated->meta->add_attribute(
 575     Class::MOP::Attribute->new('is_inline' => (
 576         reader   => { 'is_inline' => \&Class::MOP::Method::Generated::is_inline },
 577         default  => 0,
 578     ))
 579 );
 580
 581 Class::MOP::Method::Generated->meta->add_attribute(
 582     Class::MOP::Attribute->new('definition_context' => (
 583         reader   => { 'definition_context' => \&Class::MOP::Method::Generated::definition_context },
 584     ))
 585 );
 586
 587
 588 ## --------------------------------------------------------
 589 ## Class::MOP::Method::Inlined
 590
 591 Class::MOP::Method::Inlined->meta->add_attribute(
 592     Class::MOP::Attribute->new('_expected_method_class' => (
 593         reader   => { '_expected_method_class' => \&Class::MOP::Method::Inlined::_expected_method_class },
 594     ))
 595 );
 596
 597 ## --------------------------------------------------------
 598 ## Class::MOP::Method::Accessor
 599
 600 Class::MOP::Method::Accessor->meta->add_attribute(
 601     Class::MOP::Attribute->new('attribute' => (
 602         reader   => {
 603             'associated_attribute' => \&Class::MOP::Method::Accessor::associated_attribute
 604         },
 605     ))
 606 );
 607
 608 Class::MOP::Method::Accessor->meta->add_attribute(
 609     Class::MOP::Attribute->new('accessor_type' => (
 610         reader   => { 'accessor_type' => \&Class::MOP::Method::Accessor::accessor_type },
 611     ))
 612 );
 613
 614 ## --------------------------------------------------------
 615 ## Class::MOP::Method::Constructor
 616
 617 Class::MOP::Method::Constructor->meta->add_attribute(
 618     Class::MOP::Attribute->new('options' => (
 619         reader   => {
 620             'options' => \&Class::MOP::Method::Constructor::options
 621         },
 622         default  => sub { +{} }
 623     ))
 624 );
 625
 626 Class::MOP::Method::Constructor->meta->add_attribute(
 627     Class::MOP::Attribute->new('associated_metaclass' => (
 628         init_arg => "metaclass", # FIXME alias and rename
 629         reader   => {
 630             'associated_metaclass' => \&Class::MOP::Method::Constructor::associated_metaclass
 631         },
 632     ))
 633 );
 634
 635 ## --------------------------------------------------------
 636 ## Class::MOP::Instance
 637
 638 # NOTE:
 639 # these don't yet do much of anything, but are just
 640 # included for completeness
 641
 642 Class::MOP::Instance->meta->add_attribute(
 643     Class::MOP::Attribute->new('associated_metaclass',
 644         reader   => { associated_metaclass => \&Class::MOP::Instance::associated_metaclass },
 645     ),
 646 );
 647
 648 Class::MOP::Instance->meta->add_attribute(
 649     Class::MOP::Attribute->new('_class_name',
 650         init_arg => undef,
 651         reader   => { _class_name => \&Class::MOP::Instance::_class_name },
 652         #lazy     => 1, # not yet supported by Class::MOP but out our version does it anyway
 653         #default  => sub { $_[0]->associated_metaclass->name },
 654     ),
 655 );
 656
 657 Class::MOP::Instance->meta->add_attribute(
 658     Class::MOP::Attribute->new('attributes',
 659         reader   => { attributes => \&Class::MOP::Instance::get_all_attributes },
 660     ),
 661 );
 662
 663 Class::MOP::Instance->meta->add_attribute(
 664     Class::MOP::Attribute->new('slots',
 665         reader   => { slots => \&Class::MOP::Instance::slots },
 666     ),
 667 );
 668
 669 Class::MOP::Instance->meta->add_attribute(
 670     Class::MOP::Attribute->new('slot_hash',
 671         reader   => { slot_hash => \&Class::MOP::Instance::slot_hash },
 672     ),
 673 );
 674
 675 require Class::MOP::Deprecated unless our $no_deprecated;
 676
 677 # we need the meta instance of the meta instance to be created now, in order
 678 # for the constructor to be able to use it
 679 Class::MOP::Instance->meta->get_meta_instance;
 680
 681 # pretend the add_method never happenned. it hasn't yet affected anything
 682 undef Class::MOP::Instance->meta->{_package_cache_flag};
 683
 684 ## --------------------------------------------------------
 685 ## Now close all the Class::MOP::* classes
 686
 687 # NOTE: we don't need to inline the the accessors this only lengthens
 688 # the compile time of the MOP, and gives us no actual benefits.
 689
 690 $_->meta->make_immutable(
 691     inline_constructor  => 0,
 692     constructor_name    => "_new",
 693     inline_accessors => 0,
 694 ) for qw/
 695     Class::MOP::Package
 696     Class::MOP::Module
 697     Class::MOP::Class
 698
 699     Class::MOP::Attribute
 700     Class::MOP::Method
 701     Class::MOP::Instance
 702
 703     Class::MOP::Object
 704
 705     Class::MOP::Method::Generated
 706     Class::MOP::Method::Inlined
 707
 708     Class::MOP::Method::Accessor
 709     Class::MOP::Method::Constructor
 710     Class::MOP::Method::Wrapped
 711 /;
 712
 713 $_->meta->make_immutable(
 714     inline_constructor  => 0,
 715     constructor_name    => undef,
 716     inline_accessors => 0,
 717 ) for qw/
 718     Class::MOP::Mixin
 719     Class::MOP::Mixin::AttributeCore
 720     Class::MOP::Mixin::HasAttributes
 721     Class::MOP::Mixin::HasMethods
 722 /;
 723
 724 1;
 725
 726 __END__
 727
 728 =pod
 729
 730 =head1 NAME
 731
 732 Class::MOP - A Meta Object Protocol for Perl 5
 733
 734 =head1 DESCRIPTION
 735
 736 This module is a fully functioning meta object protocol for the
 737 Perl 5 object system. It makes no attempt to change the behavior or
 738 characteristics of the Perl 5 object system, only to create a
 739 protocol for its manipulation and introspection.
 740
 741 That said, it does attempt to create the tools for building a rich set
 742 of extensions to the Perl 5 object system. Every attempt has been made
 743 to abide by the spirit of the Perl 5 object system that we all know
 744 and love.
 745
 746 This documentation is sparse on conceptual details. We suggest looking
 747 at the items listed in the L<SEE ALSO> section for more
 748 information. In particular the book "The Art of the Meta Object
 749 Protocol" was very influential in the development of this system.
 750
 751 =head2 What is a Meta Object Protocol?
 752
 753 A meta object protocol is an API to an object system.
 754
 755 To be more specific, it abstracts the components of an object system
 756 (classes, object, methods, object attributes, etc.). These
 757 abstractions can then be used to inspect and manipulate the object
 758 system which they describe.
 759
 760 It can be said that there are two MOPs for any object system; the
 761 implicit MOP and the explicit MOP. The implicit MOP handles things
 762 like method dispatch or inheritance, which happen automatically as
 763 part of how the object system works. The explicit MOP typically
 764 handles the introspection/reflection features of the object system.
 765
 766 All object systems have implicit MOPs. Without one, they would not
 767 work. Explicit MOPs are much less common, and depending on the
 768 language can vary from restrictive (Reflection in Java or C#) to wide
 769 open (CLOS is a perfect example).
 770
 771 =head2 Yet Another Class Builder! Why?
 772
 773 This is B<not> a class builder so much as a I<class builder
 774 B<builder>>. The intent is that an end user will not use this module
 775 directly, but instead this module is used by module authors to build
 776 extensions and features onto the Perl 5 object system.
 777
 778 This system is used by L<Moose>, which supplies a powerful class
 779 builder system built entirely on top of C<Class::MOP>.
 780
 781 =head2 Who is this module for?
 782
 783 This module is for anyone who has ever created or wanted to create a
 784 module for the Class:: namespace. The tools which this module provides
 785 make doing complex Perl 5 wizardry simpler, by removing such barriers
 786 as the need to hack symbol tables, or understand the fine details of
 787 method dispatch.
 788
 789 =head2 What changes do I have to make to use this module?
 790
 791 This module was designed to be as unintrusive as possible. Many of its
 792 features are accessible without B<any> change to your existing
 793 code. It is meant to be a compliment to your existing code and not an
 794 intrusion on your code base. Unlike many other B<Class::> modules,
 795 this module B<does not> require you subclass it, or even that you
 796 C<use> it in within your module's package.
 797
 798 The only features which requires additions to your code are the
 799 attribute handling and instance construction features, and these are
 800 both completely optional features. The only reason for this is because
 801 Perl 5's object system does not actually have these features built
 802 in. More information about this feature can be found below.
 803
 804 =head2 About Performance
 805
 806 It is a common misconception that explicit MOPs are a performance hit.
 807 This is not a universal truth, it is a side-effect of some specific
 808 implementations. For instance, using Java reflection is slow because
 809 the JVM cannot take advantage of any compiler optimizations, and the
 810 JVM has to deal with much more runtime type information as well.
 811
 812 Reflection in C# is marginally better as it was designed into the
 813 language and runtime (the CLR). In contrast, CLOS (the Common Lisp
 814 Object System) was built to support an explicit MOP, and so
 815 performance is tuned for it.
 816
 817 This library in particular does its absolute best to avoid putting
 818 B<any> drain at all upon your code's performance. In fact, by itself
 819 it does nothing to affect your existing code. So you only pay for what
 820 you actually use.
 821
 822 =head2 About Metaclass compatibility
 823
 824 This module makes sure that all metaclasses created are both upwards
 825 and downwards compatible. The topic of metaclass compatibility is
 826 highly esoteric and is something only encountered when doing deep and
 827 involved metaclass hacking. There are two basic kinds of metaclass
 828 incompatibility; upwards and downwards.
 829
 830 Upwards metaclass compatibility means that the metaclass of a
 831 given class is either the same as (or a subclass of) all of the
 832 class's ancestors.
 833
 834 Downward metaclass compatibility means that the metaclasses of a
 835 given class's ancestors are all either the same as (or a subclass
 836 of) that metaclass.
 837
 838 Here is a diagram showing a set of two classes (C<A> and C<B>) and
 839 two metaclasses (C<Meta::A> and C<Meta::B>) which have correct
 840 metaclass compatibility both upwards and downwards.
 841
 842     +---------+     +---------+
 843     | Meta::A |<----| Meta::B |      <....... (instance of  )
 844     +---------+     +---------+      <------- (inherits from)
 845          ^               ^
 846          :               :
 847     +---------+     +---------+
 848     |    A    |<----|    B    |
 849     +---------+     +---------+
 850
 851 As I said this is a highly esoteric topic and one you will only run
 852 into if you do a lot of subclassing of L<Class::MOP::Class>. If you
 853 are interested in why this is an issue see the paper I<Uniform and
 854 safe metaclass composition> linked to in the L<SEE ALSO> section of
 855 this document.
 856
 857 =head2 Using custom metaclasses
 858
 859 Always use the L<metaclass> pragma when using a custom metaclass, this
 860 will ensure the proper initialization order and not accidentally
 861 create an incorrect type of metaclass for you. This is a very rare
 862 problem, and one which can only occur if you are doing deep metaclass
 863 programming. So in other words, don't worry about it.
 864
 865 Note that if you're using L<Moose> we encourage you to I<not> use
 866 L<metaclass> pragma, and instead use L<Moose::Util::MetaRole> to apply
 867 roles to a class's metaclasses. This topic is covered at length in
 868 various L<Moose::Cookbook> recipes.
 869
 870 =head1 PROTOCOLS
 871
 872 The meta-object protocol is divided into 4 main sub-protocols:
 873
 874 =head2 The Class protocol
 875
 876 This provides a means of manipulating and introspecting a Perl 5
 877 class. It handles symbol table hacking for you, and provides a rich
 878 set of methods that go beyond simple package introspection.
 879
 880 See L<Class::MOP::Class> for more details.
 881
 882 =head2 The Attribute protocol
 883
 884 This provides a consistent representation for an attribute of a Perl 5
 885 class. Since there are so many ways to create and handle attributes in
 886 Perl 5 OO, the Attribute protocol provide as much of a unified
 887 approach as possible. Of course, you are always free to extend this
 888 protocol by subclassing the appropriate classes.
 889
 890 See L<Class::MOP::Attribute> for more details.
 891
 892 =head2 The Method protocol
 893
 894 This provides a means of manipulating and introspecting methods in the
 895 Perl 5 object system. As with attributes, there are many ways to
 896 approach this topic, so we try to keep it pretty basic, while still
 897 making it possible to extend the system in many ways.
 898
 899 See L<Class::MOP::Method> for more details.
 900
 901 =head2 The Instance protocol
 902
 903 This provides a layer of abstraction for creating object instances.
 904 Since the other layers use this protocol, it is relatively easy to
 905 change the type of your instances from the default hash reference to
 906 some other type of reference. Several examples are provided in the
 907 F<examples/> directory included in this distribution.
 908
 909 See L<Class::MOP::Instance> for more details.
 910
 911 =head1 FUNCTIONS
 912
 913 Note that this module does not export any constants or functions.
 914
 915 =head2 Constants
 916
 917 =over 4
 918
 919 =item I<Class::MOP::IS_RUNNING_ON_5_10>
 920
 921 We set this constant depending on what version perl we are on, this
 922 allows us to take advantage of new 5.10 features and stay backwards
 923 compatible.
 924
 925 =back
 926
 927 =head2 Utility functions
 928
 929 Note that these are all called as B<functions, not methods>.
 930
 931 =over 4
 932
 933 =item B<Class::MOP::load_class($class_name, \%options?)>
 934
 935 This will load the specified C<$class_name>, if it is not already
 936 loaded (as reported by C<is_class_loaded>). This function can be used
 937 in place of tricks like C<eval "use $module"> or using C<require>
 938 unconditionally.
 939
 940 If the module cannot be loaded, an exception is thrown.
 941
 942 You can pass a hash reference with options as second argument. The
 943 only option currently recognised is C<-version>, which will ensure
 944 that the loaded class has at least the required version.
 945
 946 See also L</Class Loading Options>.
 947
 948 For historical reasons, this function explicitly returns a true value.
 949
 950 =item B<Class::MOP::is_class_loaded($class_name, \%options?)>
 951
 952 Returns a boolean indicating whether or not C<$class_name> has been
 953 loaded.
 954
 955 This does a basic check of the symbol table to try and determine as
 956 best it can if the C<$class_name> is loaded, it is probably correct
 957 about 99% of the time, but it can be fooled into reporting false
 958 positives. In particular, loading any of the core L<IO> modules will
 959 cause most of the rest of the core L<IO> modules to falsely report
 960 having been loaded, due to the way the base L<IO> module works.
 961
 962 You can pass a hash reference with options as second argument. The
 963 only option currently recognised is C<-version>, which will ensure
 964 that the loaded class has at least the required version.
 965
 966 See also L</Class Loading Options>.
 967
 968 =item B<Class::MOP::get_code_info($code)>
 969
 970 This function returns two values, the name of the package the C<$code>
 971 is from and the name of the C<$code> itself. This is used by several
 972 elements of the MOP to determine where a given C<$code> reference is
 973 from.
 974
 975 =item B<Class::MOP::class_of($instance_or_class_name)>
 976
 977 This will return the metaclass of the given instance or class name.  If the
 978 class lacks a metaclass, no metaclass will be initialized, and C<undef> will be
 979 returned.
 980
 981 =item B<Class::MOP::check_package_cache_flag($pkg)>
 982
 983 B<NOTE: DO NOT USE THIS FUNCTION, IT IS FOR INTERNAL USE ONLY!>
 984
 985 This will return an integer that is managed by L<Class::MOP::Class> to
 986 determine if a module's symbol table has been altered.
 987
 988 In Perl 5.10 or greater, this flag is package specific. However in
 989 versions prior to 5.10, this will use the C<PL_sub_generation>
 990 variable which is not package specific.
 991
 992 =item B<Class::MOP::load_first_existing_class(@class_names)>
 993
 994 =item B<Class::MOP::load_first_existing_class($classA, \%optionsA?, $classB, ...)>
 995
 996 B<NOTE: DO NOT USE THIS FUNCTION, IT IS FOR INTERNAL USE ONLY!>
 997
 998 Given a list of class names, this function will attempt to load each
 999 one in turn.
1000
1001 If it finds a class it can load, it will return that class' name.  If
1002 none of the classes can be loaded, it will throw an exception.
1003
1004 Additionally, you can pass a hash reference with options after each
1005 class name. Currently, only C<-version> is recognised and will ensure
1006 that the loaded class has at least the required version. If the class
1007 version is not sufficient, an exception will be raised.
1008
1009 See also L</Class Loading Options>.
1010
1011 =back
1012
1013 =head2 Metaclass cache functions
1014
1015 Class::MOP holds a cache of metaclasses. The following are functions
1016 (B<not methods>) which can be used to access that cache. It is not
1017 recommended that you mess with these. Bad things could happen, but if
1018 you are brave and willing to risk it: go for it!
1019
1020 =over 4
1021
1022 =item B<Class::MOP::get_all_metaclasses>
1023
1024 This will return a hash of all the metaclass instances that have
1025 been cached by L<Class::MOP::Class>, keyed by the package name.
1026
1027 =item B<Class::MOP::get_all_metaclass_instances>
1028
1029 This will return a list of all the metaclass instances that have
1030 been cached by L<Class::MOP::Class>.
1031
1032 =item B<Class::MOP::get_all_metaclass_names>
1033
1034 This will return a list of all the metaclass names that have
1035 been cached by L<Class::MOP::Class>.
1036
1037 =item B<Class::MOP::get_metaclass_by_name($name)>
1038
1039 This will return a cached L<Class::MOP::Class> instance, or nothing
1040 if no metaclass exists with that C<$name>.
1041
1042 =item B<Class::MOP::store_metaclass_by_name($name, $meta)>
1043
1044 This will store a metaclass in the cache at the supplied C<$key>.
1045
1046 =item B<Class::MOP::weaken_metaclass($name)>
1047
1048 In rare cases (e.g. anonymous metaclasses) it is desirable to
1049 store a weakened reference in the metaclass cache. This
1050 function will weaken the reference to the metaclass stored
1051 in C<$name>.
1052
1053 =item B<Class::MOP::does_metaclass_exist($name)>
1054
1055 This will return true of there exists a metaclass stored in the
1056 C<$name> key, and return false otherwise.
1057
1058 =item B<Class::MOP::remove_metaclass_by_name($name)>
1059
1060 This will remove the metaclass stored in the C<$name> key.
1061
1062 =back
1063
1064 =head2 Class Loading Options
1065
1066 =over 4
1067
1068 =item -version
1069
1070 Can be used to pass a minimum required version that will be checked
1071 against the class version after it was loaded.
1072
1073 =back
1074
1075 =head1 SEE ALSO
1076
1077 =head2 Books
1078
1079 There are very few books out on Meta Object Protocols and Metaclasses
1080 because it is such an esoteric topic. The following books are really
1081 the only ones I have found. If you know of any more, B<I<please>>
1082 email me and let me know, I would love to hear about them.
1083
1084 =over 4
1085
1086 =item I<The Art of the Meta Object Protocol>
1087
1088 =item I<Advances in Object-Oriented Metalevel Architecture and Reflection>
1089
1090 =item I<Putting MetaClasses to Work>
1091
1092 =item I<Smalltalk: The Language>
1093
1094 =back
1095
1096 =head2 Papers
1097
1098 =over 4
1099
1100 =item "Uniform and safe metaclass composition"
1101
1102 An excellent paper by the people who brought us the original Traits paper.
1103 This paper is on how Traits can be used to do safe metaclass composition,
1104 and offers an excellent introduction section which delves into the topic of
1105 metaclass compatibility.
1106
1107 L<http://www.iam.unibe.ch/~scg/Archive/Papers/Duca05ySafeMetaclassTrait.pdf>
1108
1109 =item "Safe Metaclass Programming"
1110
1111 This paper seems to precede the above paper, and propose a mix-in based
1112 approach as opposed to the Traits based approach. Both papers have similar
1113 information on the metaclass compatibility problem space.
1114
1115 L<http://citeseer.ist.psu.edu/37617.html>
1116
1117 =back
1118
1119 =head2 Prior Art
1120
1121 =over 4
1122
1123 =item The Perl 6 MetaModel work in the Pugs project
1124
1125 =over 4
1126
1127 =item L<http://svn.openfoundry.org/pugs/misc/Perl-MetaModel/>
1128
1129 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-ObjectSpace>
1130
1131 =back
1132
1133 =back
1134
1135 =head2 Articles
1136
1137 =over 4
1138
1139 =item CPAN Module Review of Class::MOP
1140
1141 L<http://www.oreillynet.com/onlamp/blog/2006/06/cpan_module_review_classmop.html>
1142
1143 =back
1144
1145 =head1 SIMILAR MODULES
1146
1147 As I have said above, this module is a class-builder-builder, so it is
1148 not the same thing as modules like L<Class::Accessor> and
1149 L<Class::MethodMaker>. That being said there are very few modules on CPAN
1150 with similar goals to this module. The one I have found which is most
1151 like this module is L<Class::Meta>, although it's philosophy and the MOP it
1152 creates are very different from this modules.
1153
1154 =head1 BUGS
1155
1156 All complex software has bugs lurking in it, and this module is no
1157 exception.
1158
1159 Please report any bugs to C<bug-class-mop@rt.cpan.org>, or through the
1160 web interface at L<http://rt.cpan.org>.
1161
1162 You can also discuss feature requests or possible bugs on the Moose
1163 mailing list (moose@perl.org) or on IRC at
1164 L<irc://irc.perl.org/#moose>.
1165
1166 =head1 ACKNOWLEDGEMENTS
1167
1168 =over 4
1169
1170 =item Rob Kinyon
1171
1172 Thanks to Rob for actually getting the development of this module kick-started.
1173
1174 =back
1175
1176 =head1 AUTHORS
1177
1178 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1179
1180 B<with contributions from:>
1181
1182 Brandon (blblack) Black
1183
1184 Florian (rafl) Ragwitz
1185
1186 Guillermo (groditi) Roditi
1187
1188 Dave (autarch) Rolsky
1189
1190 Matt (mst) Trout
1191
1192 Rob (robkinyon) Kinyon
1193
1194 Yuval (nothingmuch) Kogman
1195
1196 Scott (konobi) McWhirter
1197
1198 Dylan Hardison
1199
1200 =head1 COPYRIGHT AND LICENSE
1201
1202 Copyright 2006-2010 by Infinity Interactive, Inc.
1203
1204 L<http://www.iinteractive.com>
1205
1206 This library is free software; you can redistribute it and/or modify
1207 it under the same terms as Perl itself.
1208
1209 =cut