lib/Class/MOP.pm

   1
   2 package Class::MOP;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util ();
   9
  10 use Class::MOP::Class;
  11 use Class::MOP::Attribute;
  12 use Class::MOP::Method;
  13
  14 our $VERSION = '0.30';
  15
  16 ## ----------------------------------------------------------------------------
  17 ## Setting up our environment ...
  18 ## ----------------------------------------------------------------------------
  19 ## Class::MOP needs to have a few things in the global perl environment so
  20 ## that it can operate effectively. Those things are done here.
  21 ## ----------------------------------------------------------------------------
  22
  23 # ... nothing yet actually ;)
  24
  25 ## ----------------------------------------------------------------------------
  26 ## Bootstrapping
  27 ## ----------------------------------------------------------------------------
  28 ## The code below here is to bootstrap our MOP with itself. This is also
  29 ## sometimes called "tying the knot". By doing this, we make it much easier
  30 ## to extend the MOP through subclassing and such since now you can use the
  31 ## MOP itself to extend itself.
  32 ##
  33 ## Yes, I know, thats weird and insane, but it's a good thing, trust me :)
  34 ## ----------------------------------------------------------------------------
  35
  36 # We need to add in the meta-attributes here so that
  37 # any subclass of Class::MOP::* will be able to
  38 # inherit them using &construct_instance
  39
  40 ## Class::MOP::Class
  41
  42 Class::MOP::Class->meta->add_attribute(
  43     Class::MOP::Attribute->new('$:package' => (
  44         reader   => 'name',
  45         init_arg => ':package',
  46     ))
  47 );
  48
  49 Class::MOP::Class->meta->add_attribute(
  50     Class::MOP::Attribute->new('%:attributes' => (
  51         reader   => 'get_attribute_map',
  52         init_arg => ':attributes',
  53         default  => sub { {} }
  54     ))
  55 );
  56
  57 Class::MOP::Class->meta->add_attribute(
  58     Class::MOP::Attribute->new('$:attribute_metaclass' => (
  59         reader   => 'attribute_metaclass',
  60         init_arg => ':attribute_metaclass',
  61         default  => 'Class::MOP::Attribute',
  62     ))
  63 );
  64
  65 Class::MOP::Class->meta->add_attribute(
  66     Class::MOP::Attribute->new('$:method_metaclass' => (
  67         reader   => 'method_metaclass',
  68         init_arg => ':method_metaclass',
  69         default  => 'Class::MOP::Method',
  70     ))
  71 );
  72
  73 Class::MOP::Class->meta->add_attribute(
  74     Class::MOP::Attribute->new('$:instance_metaclass' => (
  75         reader   => 'instance_metaclass',
  76         init_arg => ':instance_metaclass',
  77         default  => 'Class::MOP::Instance',
  78     ))
  79 );
  80
  81 ## Class::MOP::Attribute
  82
  83 Class::MOP::Attribute->meta->add_attribute(
  84     Class::MOP::Attribute->new('name' => (
  85         reader => 'name'
  86     ))
  87 );
  88
  89 Class::MOP::Attribute->meta->add_attribute(
  90     Class::MOP::Attribute->new('associated_class' => (
  91         reader => 'associated_class'
  92     ))
  93 );
  94
  95 Class::MOP::Attribute->meta->add_attribute(
  96     Class::MOP::Attribute->new('accessor' => (
  97         reader    => 'accessor',
  98         predicate => 'has_accessor',
  99     ))
 100 );
 101
 102 Class::MOP::Attribute->meta->add_attribute(
 103     Class::MOP::Attribute->new('reader' => (
 104         reader    => 'reader',
 105         predicate => 'has_reader',
 106     ))
 107 );
 108
 109 Class::MOP::Attribute->meta->add_attribute(
 110     Class::MOP::Attribute->new('writer' => (
 111         reader    => 'writer',
 112         predicate => 'has_writer',
 113     ))
 114 );
 115
 116 Class::MOP::Attribute->meta->add_attribute(
 117     Class::MOP::Attribute->new('predicate' => (
 118         reader    => 'predicate',
 119         predicate => 'has_predicate',
 120     ))
 121 );
 122
 123 Class::MOP::Attribute->meta->add_attribute(
 124     Class::MOP::Attribute->new('init_arg' => (
 125         reader    => 'init_arg',
 126         predicate => 'has_init_arg',
 127     ))
 128 );
 129
 130 Class::MOP::Attribute->meta->add_attribute(
 131     Class::MOP::Attribute->new('default' => (
 132         # default has a custom 'reader' method ...
 133         predicate => 'has_default',
 134     ))
 135 );
 136
 137
 138 # NOTE: (meta-circularity)
 139 # This should be one of the last things done
 140 # it will "tie the knot" with Class::MOP::Attribute
 141 # so that it uses the attributes meta-objects
 142 # to construct itself.
 143 Class::MOP::Attribute->meta->add_method('new' => sub {
 144     my $class   = shift;
 145     my $name    = shift;
 146     my %options = @_;
 147
 148     (defined $name && $name)
 149         || confess "You must provide a name for the attribute";
 150     $options{init_arg} = $name
 151         if not exists $options{init_arg};
 152
 153     # return the new object
 154     $class->meta->new_object(name => $name, %options);
 155 });
 156
 157 Class::MOP::Attribute->meta->add_method('clone' => sub {
 158     my $self  = shift;
 159     $self->meta->clone_object($self, @_);
 160 });
 161
 162 1;
 163
 164 __END__
 165
 166 =pod
 167
 168 =head1 NAME
 169
 170 Class::MOP - A Meta Object Protocol for Perl 5
 171
 172 =head1 SYNOPSIS
 173
 174   # ... This will come later, for now see
 175   # the other SYNOPSIS for more information
 176
 177 =head1 DESCRIPTON
 178
 179 This module is an attempt to create a meta object protocol for the
 180 Perl 5 object system. It makes no attempt to change the behavior or
 181 characteristics of the Perl 5 object system, only to create a
 182 protocol for its manipulation and introspection.
 183
 184 That said, it does attempt to create the tools for building a rich
 185 set of extensions to the Perl 5 object system. Every attempt has been
 186 made for these tools to keep to the spirit of the Perl 5 object
 187 system that we all know and love.
 188
 189 =head2 What is a Meta Object Protocol?
 190
 191 A meta object protocol is an API to an object system.
 192
 193 To be more specific, it is a set of abstractions of the components of
 194 an object system (typically things like; classes, object, methods,
 195 object attributes, etc.). These abstractions can then be used to both
 196 inspect and manipulate the object system which they describe.
 197
 198 It can be said that there are two MOPs for any object system; the
 199 implicit MOP, and the explicit MOP. The implicit MOP handles things
 200 like method dispatch or inheritance, which happen automatically as
 201 part of how the object system works. The explicit MOP typically
 202 handles the introspection/reflection features of the object system.
 203 All object systems have implicit MOPs, without one, they would not
 204 work. Explict MOPs however as less common, and depending on the
 205 language can vary from restrictive (Reflection in Java or C#) to
 206 wide open (CLOS is a perfect example).
 207
 208 =head2 Yet Another Class Builder!! Why?
 209
 210 This is B<not> a class builder so much as it is a I<class builder
 211 B<builder>>. My intent is that an end user does not use this module
 212 directly, but instead this module is used by module authors to
 213 build extensions and features onto the Perl 5 object system.
 214
 215 =head2 Who is this module for?
 216
 217 This module is specifically for anyone who has ever created or
 218 wanted to create a module for the Class:: namespace. The tools which
 219 this module will provide will hopefully make it easier to do more
 220 complex things with Perl 5 classes by removing such barriers as
 221 the need to hack the symbol tables, or understand the fine details
 222 of method dispatch.
 223
 224 =head2 What changes do I have to make to use this module?
 225
 226 This module was designed to be as unintrusive as possible. Many of
 227 its features are accessible without B<any> change to your existsing
 228 code at all. It is meant to be a compliment to your existing code and
 229 not an intrusion on your code base. Unlike many other B<Class::>
 230 modules, this module B<does not> require you subclass it, or even that
 231 you C<use> it in within your module's package.
 232
 233 The only features which requires additions to your code are the
 234 attribute handling and instance construction features, and these are
 235 both completely optional features. The only reason for this is because
 236 Perl 5's object system does not actually have these features built
 237 in. More information about this feature can be found below.
 238
 239 =head2 A Note about Performance?
 240
 241 It is a common misconception that explict MOPs are performance drains.
 242 But this is not a universal truth at all, it is an side-effect of
 243 specific implementations. For instance, using Java reflection is much
 244 slower because the JVM cannot take advantage of any compiler
 245 optimizations, and the JVM has to deal with much more runtime type
 246 information as well. Reflection in C# is marginally better as it was
 247 designed into the language and runtime (the CLR). In contrast, CLOS
 248 (the Common Lisp Object System) was built to support an explicit MOP,
 249 and so performance is tuned for it.
 250
 251 This library in particular does it's absolute best to avoid putting
 252 B<any> drain at all upon your code's performance. In fact, by itself
 253 it does nothing to affect your existing code. So you only pay for
 254 what you actually use.
 255
 256 =head2 About Metaclass compatibility
 257
 258 This module makes sure that all metaclasses created are both upwards
 259 and downwards compatible. The topic of metaclass compatibility is
 260 highly esoteric and is something only encountered when doing deep and
 261 involved metaclass hacking. There are two basic kinds of metaclass
 262 incompatibility; upwards and downwards.
 263
 264 Upwards metaclass compatibility means that the metaclass of a
 265 given class is either the same as (or a subclass of) all of the
 266 class's ancestors.
 267
 268 Downward metaclass compatibility means that the metaclasses of a
 269 given class's anscestors are all either the same as (or a subclass
 270 of) that metaclass.
 271
 272 Here is a diagram showing a set of two classes (C<A> and C<B>) and
 273 two metaclasses (C<Meta::A> and C<Meta::B>) which have correct
 274 metaclass compatibility both upwards and downwards.
 275
 276     +---------+     +---------+
 277     | Meta::A |<----| Meta::B |      <....... (instance of  )
 278     +---------+     +---------+      <------- (inherits from)
 279          ^               ^
 280          :               :
 281     +---------+     +---------+
 282     |    A    |<----|    B    |
 283     +---------+     +---------+
 284
 285 As I said this is a highly esoteric topic and one you will only run
 286 into if you do a lot of subclassing of B<Class::MOP::Class>. If you
 287 are interested in why this is an issue see the paper
 288 I<Uniform and safe metaclass composition> linked to in the
 289 L<SEE ALSO> section of this document.
 290
 291 =head2 Using custom metaclasses
 292
 293 Always use the metaclass pragma when using a custom metaclass, this
 294 will ensure the proper initialization order and not accidentely
 295 create an incorrect type of metaclass for you. This is a very rare
 296 problem, and one which can only occur if you are doing deep metaclass
 297 programming. So in other words, don't worry about it.
 298
 299 =head1 PROTOCOLS
 300
 301 The protocol is divided into 3 main sub-protocols:
 302
 303 =over 4
 304
 305 =item The Class protocol
 306
 307 This provides a means of manipulating and introspecting a Perl 5
 308 class. It handles all of symbol table hacking for you, and provides
 309 a rich set of methods that go beyond simple package introspection.
 310
 311 See L<Class::MOP::Class> for more details.
 312
 313 =item The Attribute protocol
 314
 315 This provides a consistent represenation for an attribute of a
 316 Perl 5 class. Since there are so many ways to create and handle
 317 atttributes in Perl 5 OO, this attempts to provide as much of a
 318 unified approach as possible, while giving the freedom and
 319 flexibility to subclass for specialization.
 320
 321 See L<Class::MOP::Attribute> for more details.
 322
 323 =item The Method protocol
 324
 325 This provides a means of manipulating and introspecting methods in
 326 the Perl 5 object system. As with attributes, there are many ways to
 327 approach this topic, so we try to keep it pretty basic, while still
 328 making it possible to extend the system in many ways.
 329
 330 See L<Class::MOP::Method> for more details.
 331
 332 =back
 333
 334 =head1 SEE ALSO
 335
 336 =head2 Books
 337
 338 There are very few books out on Meta Object Protocols and Metaclasses
 339 because it is such an esoteric topic. The following books are really
 340 the only ones I have found. If you know of any more, B<I<please>>
 341 email me and let me know, I would love to hear about them.
 342
 343 =over 4
 344
 345 =item "The Art of the Meta Object Protocol"
 346
 347 =item "Advances in Object-Oriented Metalevel Architecture and Reflection"
 348
 349 =item "Putting MetaClasses to Work"
 350
 351 =item "Smalltalk: The Language"
 352
 353 =back
 354
 355 =head2 Papers
 356
 357 =over 4
 358
 359 =item Uniform and safe metaclass composition
 360
 361 An excellent paper by the people who brought us the original Traits paper.
 362 This paper is on how Traits can be used to do safe metaclass composition,
 363 and offers an excellent introduction section which delves into the topic of
 364 metaclass compatibility.
 365
 366 L<http://www.iam.unibe.ch/~scg/Archive/Papers/Duca05ySafeMetaclassTrait.pdf>
 367
 368 =item Safe Metaclass Programming
 369
 370 This paper seems to precede the above paper, and propose a mix-in based
 371 approach as opposed to the Traits based approach. Both papers have similar
 372 information on the metaclass compatibility problem space.
 373
 374 L<http://citeseer.ist.psu.edu/37617.html>
 375
 376 =back
 377
 378 =head2 Prior Art
 379
 380 =over 4
 381
 382 =item The Perl 6 MetaModel work in the Pugs project
 383
 384 =over 4
 385
 386 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-MetaModel>
 387
 388 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-ObjectSpace>
 389
 390 =back
 391
 392 =back
 393
 394 =head1 SIMILAR MODULES
 395
 396 As I have said above, this module is a class-builder-builder, so it is
 397 not the same thing as modules like L<Class::Accessor> and
 398 L<Class::MethodMaker>. That being said there are very few modules on CPAN
 399 with similar goals to this module. The one I have found which is most
 400 like this module is L<Class::Meta>, although it's philosophy and the MOP it
 401 creates are very different from this modules.
 402
 403 =head1 BUGS
 404
 405 All complex software has bugs lurking in it, and this module is no
 406 exception. If you find a bug please either email me, or add the bug
 407 to cpan-RT.
 408
 409 =head1 CODE COVERAGE
 410
 411 I use L<Devel::Cover> to test the code coverage of my tests, below is the
 412 L<Devel::Cover> report on this module's test suite.
 413
 414  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 415  File                           stmt   bran   cond    sub    pod   time  total
 416  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 417  Class/MOP.pm                  100.0  100.0  100.0  100.0    n/a    9.6  100.0
 418  Class/MOP/Attribute.pm        100.0  100.0   91.7   73.8  100.0   28.4   92.1
 419  Class/MOP/Class.pm            100.0   93.5   82.3   98.2  100.0   56.6   95.7
 420  Class/MOP/Method.pm           100.0   64.3   52.9   80.0  100.0    3.5   85.3
 421  metaclass.pm                  100.0  100.0   80.0  100.0    n/a    1.9   97.4
 422  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 423  Total                         100.0   90.8   79.7   86.2  100.0  100.0   93.6
 424  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 425
 426 =head1 ACKNOWLEDGEMENTS
 427
 428 =over 4
 429
 430 =item Rob Kinyon E<lt>rob@iinteractive.comE<gt>
 431
 432 Thanks to Rob for actually getting the development of this module kick-started.
 433
 434 =back
 435
 436 =head1 AUTHOR
 437
 438 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 439
 440 =head1 COPYRIGHT AND LICENSE
 441
 442 Copyright 2006 by Infinity Interactive, Inc.
 443
 444 L<http://www.iinteractive.com>
 445
 446 This library is free software; you can redistribute it and/or modify
 447 it under the same terms as Perl itself.
 448
 449 =cut