lib/Class/MOP.pm

   1
   2 package Class::MOP;
   3
   4 use strict;
   5 use warnings;
   6
   7 use 5.008;
   8
   9 use MRO::Compat;
  10
  11 use Carp          'confess';
  12 use Devel::GlobalDestruction qw( in_global_destruction );
  13 use Scalar::Util  'weaken', 'reftype', 'blessed';
  14 use Sub::Name qw( subname );
  15
  16 use Class::MOP::Class;
  17 use Class::MOP::Attribute;
  18 use Class::MOP::Method;
  19
  20 BEGIN {
  21     *IS_RUNNING_ON_5_10 = ($] < 5.009_005)
  22         ? sub () { 0 }
  23         : sub () { 1 };
  24
  25     sub HAVE_ISAREV () {
  26         Carp::cluck("Class::MOP::HAVE_ISAREV is deprecated and will be removed in a future release. It has always returned 1 anyway.");
  27         return 1;
  28     }
  29
  30     # this is either part of core or set up appropriately by MRO::Compat
  31     *check_package_cache_flag = \&mro::get_pkg_gen;
  32 }
  33
  34 our $VERSION   = '0.83';
  35 our $XS_VERSION = $VERSION;
  36 $VERSION = eval $VERSION;
  37 our $AUTHORITY = 'cpan:STEVAN';
  38
  39 require XSLoader;
  40 XSLoader::load( __PACKAGE__, $XS_VERSION );
  41
  42
  43 {
  44     # Metaclasses are singletons, so we cache them here.
  45     # there is no need to worry about destruction though
  46     # because they should die only when the program dies.
  47     # After all, do package definitions even get reaped?
  48     my %METAS;
  49
  50     # means of accessing all the metaclasses that have
  51     # been initialized thus far (for mugwumps obj browser)
  52     sub get_all_metaclasses         {        %METAS         }
  53     sub get_all_metaclass_instances { values %METAS         }
  54     sub get_all_metaclass_names     { keys   %METAS         }
  55     sub get_metaclass_by_name       { $METAS{$_[0]}         }
  56     sub store_metaclass_by_name     { $METAS{$_[0]} = $_[1] }
  57     sub weaken_metaclass            { weaken($METAS{$_[0]}) }
  58     sub does_metaclass_exist        { exists $METAS{$_[0]} && defined $METAS{$_[0]} }
  59     sub remove_metaclass_by_name    { $METAS{$_[0]} = undef }
  60
  61     # This handles instances as well as class names
  62     sub class_of {
  63         return unless defined $_[0];
  64         my $class = blessed($_[0]) || $_[0];
  65         return $METAS{$class};
  66     }
  67
  68     # NOTE:
  69     # We only cache metaclasses, meaning instances of
  70     # Class::MOP::Class. We do not cache instance of
  71     # Class::MOP::Package or Class::MOP::Module. Mostly
  72     # because I don't yet see a good reason to do so.
  73 }
  74
  75 sub _class_to_pmfile {
  76     my $class = shift;
  77
  78     my $file = $class . '.pm';
  79     $file =~ s{::}{/}g;
  80
  81     return $file;
  82 }
  83
  84 sub load_first_existing_class {
  85     my @classes = @_
  86         or return;
  87
  88     foreach my $class (@classes) {
  89         unless ( _is_valid_class_name($class) ) {
  90             my $display = defined($class) ? $class : 'undef';
  91             confess "Invalid class name ($display)";
  92         }
  93     }
  94
  95     my $found;
  96     my %exceptions;
  97     for my $class (@classes) {
  98         my $pmfile = _class_to_pmfile($class);
  99         my $e = _try_load_one_class($class);
 100
 101         if ($e) {
 102             $exceptions{$class} = $e;
 103             last if $e !~ /^Can't locate \Q$pmfile\E in \@INC/;
 104         }
 105         else {
 106             $found = $class;
 107             last;
 108         }
 109     }
 110
 111     return $found if $found;
 112
 113     confess join(
 114         "\n",
 115         map {
 116             sprintf(
 117                 "Could not load class (%s) because : %s", $_,
 118                 $exceptions{$_}
 119                 )
 120             }
 121         grep {
 122             exists $exceptions{$_}
 123             } @classes
 124     );
 125 }
 126
 127 sub _try_load_one_class {
 128     my $class = shift;
 129
 130     return if is_class_loaded($class);
 131
 132     my $file = _class_to_pmfile($class);
 133
 134     return do {
 135         local $@;
 136         eval { require($file) };
 137         $@;
 138     };
 139 }
 140
 141 sub load_class {
 142     my $class = load_first_existing_class($_[0]);
 143     return get_metaclass_by_name($class) || $class;
 144 }
 145
 146 sub _is_valid_class_name {
 147     my $class = shift;
 148
 149     return 0 if ref($class);
 150     return 0 unless defined($class);
 151     return 0 unless length($class);
 152
 153     return 1 if $class =~ /^\w+(?:::\w+)*$/;
 154
 155     return 0;
 156 }
 157
 158 ## ----------------------------------------------------------------------------
 159 ## Setting up our environment ...
 160 ## ----------------------------------------------------------------------------
 161 ## Class::MOP needs to have a few things in the global perl environment so
 162 ## that it can operate effectively. Those things are done here.
 163 ## ----------------------------------------------------------------------------
 164
 165 # ... nothing yet actually ;)
 166
 167 ## ----------------------------------------------------------------------------
 168 ## Bootstrapping
 169 ## ----------------------------------------------------------------------------
 170 ## The code below here is to bootstrap our MOP with itself. This is also
 171 ## sometimes called "tying the knot". By doing this, we make it much easier
 172 ## to extend the MOP through subclassing and such since now you can use the
 173 ## MOP itself to extend itself.
 174 ##
 175 ## Yes, I know, thats weird and insane, but it's a good thing, trust me :)
 176 ## ----------------------------------------------------------------------------
 177
 178 # We need to add in the meta-attributes here so that
 179 # any subclass of Class::MOP::* will be able to
 180 # inherit them using _construct_instance
 181
 182 ## --------------------------------------------------------
 183 ## Class::MOP::Package
 184
 185 Class::MOP::Package->meta->add_attribute(
 186     Class::MOP::Attribute->new('package' => (
 187         reader   => {
 188             # NOTE: we need to do this in order
 189             # for the instance meta-object to
 190             # not fall into meta-circular death
 191             #
 192             # we just alias the original method
 193             # rather than re-produce it here
 194             'name' => \&Class::MOP::Package::name
 195         },
 196     ))
 197 );
 198
 199 Class::MOP::Package->meta->add_attribute(
 200     Class::MOP::Attribute->new('namespace' => (
 201         reader => {
 202             # NOTE:
 203             # we just alias the original method
 204             # rather than re-produce it here
 205             'namespace' => \&Class::MOP::Package::namespace
 206         },
 207         init_arg => undef,
 208         default  => sub { \undef }
 209     ))
 210 );
 211
 212 ## --------------------------------------------------------
 213 ## Class::MOP::Module
 214
 215 # NOTE:
 216 # yeah this is kind of stretching things a bit,
 217 # but truthfully the version should be an attribute
 218 # of the Module, the weirdness comes from having to
 219 # stick to Perl 5 convention and store it in the
 220 # $VERSION package variable. Basically if you just
 221 # squint at it, it will look how you want it to look.
 222 # Either as a package variable, or as a attribute of
 223 # the metaclass, isn't abstraction great :)
 224
 225 Class::MOP::Module->meta->add_attribute(
 226     Class::MOP::Attribute->new('version' => (
 227         reader => {
 228             # NOTE:
 229             # we just alias the original method
 230             # rather than re-produce it here
 231             'version' => \&Class::MOP::Module::version
 232         },
 233         init_arg => undef,
 234         default  => sub { \undef }
 235     ))
 236 );
 237
 238 # NOTE:
 239 # By following the same conventions as version here,
 240 # we are opening up the possibility that people can
 241 # use the $AUTHORITY in non-Class::MOP modules as
 242 # well.
 243
 244 Class::MOP::Module->meta->add_attribute(
 245     Class::MOP::Attribute->new('authority' => (
 246         reader => {
 247             # NOTE:
 248             # we just alias the original method
 249             # rather than re-produce it here
 250             'authority' => \&Class::MOP::Module::authority
 251         },
 252         init_arg => undef,
 253         default  => sub { \undef }
 254     ))
 255 );
 256
 257 ## --------------------------------------------------------
 258 ## Class::MOP::Class
 259
 260 Class::MOP::Class->meta->add_attribute(
 261     Class::MOP::Attribute->new('attributes' => (
 262         reader   => {
 263             # NOTE: we need to do this in order
 264             # for the instance meta-object to
 265             # not fall into meta-circular death
 266             #
 267             # we just alias the original method
 268             # rather than re-produce it here
 269             'get_attribute_map' => \&Class::MOP::Class::get_attribute_map
 270         },
 271         default  => sub { {} }
 272     ))
 273 );
 274
 275 Class::MOP::Class->meta->add_attribute(
 276     Class::MOP::Attribute->new('methods' => (
 277         reader   => {
 278             # NOTE:
 279             # we just alias the original method
 280             # rather than re-produce it here
 281             'get_method_map' => \&Class::MOP::Class::get_method_map
 282         },
 283         default => sub { {} }
 284     ))
 285 );
 286
 287 Class::MOP::Class->meta->add_attribute(
 288     Class::MOP::Attribute->new('superclasses' => (
 289         accessor => {
 290             # NOTE:
 291             # we just alias the original method
 292             # rather than re-produce it here
 293             'superclasses' => \&Class::MOP::Class::superclasses
 294         },
 295         init_arg => undef,
 296         default  => sub { \undef }
 297     ))
 298 );
 299
 300 Class::MOP::Class->meta->add_attribute(
 301     Class::MOP::Attribute->new('attribute_metaclass' => (
 302         reader   => {
 303             # NOTE:
 304             # we just alias the original method
 305             # rather than re-produce it here
 306             'attribute_metaclass' => \&Class::MOP::Class::attribute_metaclass
 307         },
 308         default  => 'Class::MOP::Attribute',
 309     ))
 310 );
 311
 312 Class::MOP::Class->meta->add_attribute(
 313     Class::MOP::Attribute->new('method_metaclass' => (
 314         reader   => {
 315             # NOTE:
 316             # we just alias the original method
 317             # rather than re-produce it here
 318             'method_metaclass' => \&Class::MOP::Class::method_metaclass
 319         },
 320         default  => 'Class::MOP::Method',
 321     ))
 322 );
 323
 324 Class::MOP::Class->meta->add_attribute(
 325     Class::MOP::Attribute->new('wrapped_method_metaclass' => (
 326         reader   => {
 327             # NOTE:
 328             # we just alias the original method
 329             # rather than re-produce it here
 330             'wrapped_method_metaclass' => \&Class::MOP::Class::wrapped_method_metaclass
 331         },
 332         default  => 'Class::MOP::Method::Wrapped',
 333     ))
 334 );
 335
 336 Class::MOP::Class->meta->add_attribute(
 337     Class::MOP::Attribute->new('instance_metaclass' => (
 338         reader   => {
 339             # NOTE: we need to do this in order
 340             # for the instance meta-object to
 341             # not fall into meta-circular death
 342             #
 343             # we just alias the original method
 344             # rather than re-produce it here
 345             'instance_metaclass' => \&Class::MOP::Class::instance_metaclass
 346         },
 347         default  => 'Class::MOP::Instance',
 348     ))
 349 );
 350
 351 Class::MOP::Class->meta->add_attribute(
 352     Class::MOP::Attribute->new('immutable_trait' => (
 353         reader   => {
 354             'immutable_trait' => \&Class::MOP::Class::immutable_trait
 355         },
 356         default => "Class::MOP::Class::Immutable::Trait",
 357     ))
 358 );
 359
 360 Class::MOP::Class->meta->add_attribute(
 361     Class::MOP::Attribute->new('constructor_name' => (
 362         reader   => {
 363             'constructor_name' => \&Class::MOP::Class::constructor_name,
 364         },
 365         default => "new",
 366     ))
 367 );
 368
 369 Class::MOP::Class->meta->add_attribute(
 370     Class::MOP::Attribute->new('constructor_class' => (
 371         reader   => {
 372             'constructor_class' => \&Class::MOP::Class::constructor_class,
 373         },
 374         default => "Class::MOP::Method::Constructor",
 375     ))
 376 );
 377
 378
 379 Class::MOP::Class->meta->add_attribute(
 380     Class::MOP::Attribute->new('destructor_class' => (
 381         reader   => {
 382             'destructor_class' => \&Class::MOP::Class::destructor_class,
 383         },
 384     ))
 385 );
 386
 387 # NOTE:
 388 # we don't actually need to tie the knot with
 389 # Class::MOP::Class here, it is actually handled
 390 # within Class::MOP::Class itself in the
 391 # _construct_class_instance method.
 392
 393 ## --------------------------------------------------------
 394 ## Class::MOP::Attribute
 395
 396 Class::MOP::Attribute->meta->add_attribute(
 397     Class::MOP::Attribute->new('name' => (
 398         reader   => {
 399             # NOTE: we need to do this in order
 400             # for the instance meta-object to
 401             # not fall into meta-circular death
 402             #
 403             # we just alias the original method
 404             # rather than re-produce it here
 405             'name' => \&Class::MOP::Attribute::name
 406         }
 407     ))
 408 );
 409
 410 Class::MOP::Attribute->meta->add_attribute(
 411     Class::MOP::Attribute->new('associated_class' => (
 412         reader   => {
 413             # NOTE: we need to do this in order
 414             # for the instance meta-object to
 415             # not fall into meta-circular death
 416             #
 417             # we just alias the original method
 418             # rather than re-produce it here
 419             'associated_class' => \&Class::MOP::Attribute::associated_class
 420         }
 421     ))
 422 );
 423
 424 Class::MOP::Attribute->meta->add_attribute(
 425     Class::MOP::Attribute->new('accessor' => (
 426         reader    => { 'accessor'     => \&Class::MOP::Attribute::accessor     },
 427         predicate => { 'has_accessor' => \&Class::MOP::Attribute::has_accessor },
 428     ))
 429 );
 430
 431 Class::MOP::Attribute->meta->add_attribute(
 432     Class::MOP::Attribute->new('reader' => (
 433         reader    => { 'reader'     => \&Class::MOP::Attribute::reader     },
 434         predicate => { 'has_reader' => \&Class::MOP::Attribute::has_reader },
 435     ))
 436 );
 437
 438 Class::MOP::Attribute->meta->add_attribute(
 439     Class::MOP::Attribute->new('initializer' => (
 440         reader    => { 'initializer'     => \&Class::MOP::Attribute::initializer     },
 441         predicate => { 'has_initializer' => \&Class::MOP::Attribute::has_initializer },
 442     ))
 443 );
 444
 445 Class::MOP::Attribute->meta->add_attribute(
 446     Class::MOP::Attribute->new('definition_context' => (
 447         reader    => { 'definition_context'     => \&Class::MOP::Attribute::definition_context     },
 448     ))
 449 );
 450
 451 Class::MOP::Attribute->meta->add_attribute(
 452     Class::MOP::Attribute->new('writer' => (
 453         reader    => { 'writer'     => \&Class::MOP::Attribute::writer     },
 454         predicate => { 'has_writer' => \&Class::MOP::Attribute::has_writer },
 455     ))
 456 );
 457
 458 Class::MOP::Attribute->meta->add_attribute(
 459     Class::MOP::Attribute->new('predicate' => (
 460         reader    => { 'predicate'     => \&Class::MOP::Attribute::predicate     },
 461         predicate => { 'has_predicate' => \&Class::MOP::Attribute::has_predicate },
 462     ))
 463 );
 464
 465 Class::MOP::Attribute->meta->add_attribute(
 466     Class::MOP::Attribute->new('clearer' => (
 467         reader    => { 'clearer'     => \&Class::MOP::Attribute::clearer     },
 468         predicate => { 'has_clearer' => \&Class::MOP::Attribute::has_clearer },
 469     ))
 470 );
 471
 472 Class::MOP::Attribute->meta->add_attribute(
 473     Class::MOP::Attribute->new('builder' => (
 474         reader    => { 'builder'     => \&Class::MOP::Attribute::builder     },
 475         predicate => { 'has_builder' => \&Class::MOP::Attribute::has_builder },
 476     ))
 477 );
 478
 479 Class::MOP::Attribute->meta->add_attribute(
 480     Class::MOP::Attribute->new('init_arg' => (
 481         reader    => { 'init_arg'     => \&Class::MOP::Attribute::init_arg     },
 482         predicate => { 'has_init_arg' => \&Class::MOP::Attribute::has_init_arg },
 483     ))
 484 );
 485
 486 Class::MOP::Attribute->meta->add_attribute(
 487     Class::MOP::Attribute->new('default' => (
 488         # default has a custom 'reader' method ...
 489         predicate => { 'has_default' => \&Class::MOP::Attribute::has_default },
 490     ))
 491 );
 492
 493 Class::MOP::Attribute->meta->add_attribute(
 494     Class::MOP::Attribute->new('associated_methods' => (
 495         reader   => { 'associated_methods' => \&Class::MOP::Attribute::associated_methods },
 496         default  => sub { [] }
 497     ))
 498 );
 499
 500 Class::MOP::Attribute->meta->add_method('clone' => sub {
 501     my $self  = shift;
 502     $self->meta->clone_object($self, @_);
 503 });
 504
 505 ## --------------------------------------------------------
 506 ## Class::MOP::Method
 507 Class::MOP::Method->meta->add_attribute(
 508     Class::MOP::Attribute->new('body' => (
 509         reader   => { 'body' => \&Class::MOP::Method::body },
 510     ))
 511 );
 512
 513 Class::MOP::Method->meta->add_attribute(
 514     Class::MOP::Attribute->new('associated_metaclass' => (
 515         reader   => { 'associated_metaclass' => \&Class::MOP::Method::associated_metaclass },
 516     ))
 517 );
 518
 519 Class::MOP::Method->meta->add_attribute(
 520     Class::MOP::Attribute->new('package_name' => (
 521         reader   => { 'package_name' => \&Class::MOP::Method::package_name },
 522     ))
 523 );
 524
 525 Class::MOP::Method->meta->add_attribute(
 526     Class::MOP::Attribute->new('name' => (
 527         reader   => { 'name' => \&Class::MOP::Method::name },
 528     ))
 529 );
 530
 531 Class::MOP::Method->meta->add_attribute(
 532     Class::MOP::Attribute->new('original_method' => (
 533         reader   => { 'original_method'      => \&Class::MOP::Method::original_method },
 534         writer   => { '_set_original_method' => \&Class::MOP::Method::_set_original_method },
 535     ))
 536 );
 537
 538 Class::MOP::Method->meta->add_method('clone' => sub {
 539     my $self  = shift;
 540     my $clone = $self->meta->clone_object($self, @_);
 541     $clone->_set_original_method($self);
 542     return $clone;
 543 });
 544
 545 ## --------------------------------------------------------
 546 ## Class::MOP::Method::Wrapped
 547
 548 # NOTE:
 549 # the way this item is initialized, this
 550 # really does not follow the standard
 551 # practices of attributes, but we put
 552 # it here for completeness
 553 Class::MOP::Method::Wrapped->meta->add_attribute(
 554     Class::MOP::Attribute->new('modifier_table')
 555 );
 556
 557 ## --------------------------------------------------------
 558 ## Class::MOP::Method::Generated
 559
 560 Class::MOP::Method::Generated->meta->add_attribute(
 561     Class::MOP::Attribute->new('is_inline' => (
 562         reader   => { 'is_inline' => \&Class::MOP::Method::Generated::is_inline },
 563         default  => 0,
 564     ))
 565 );
 566
 567 Class::MOP::Method::Generated->meta->add_attribute(
 568     Class::MOP::Attribute->new('definition_context' => (
 569         reader   => { 'definition_context' => \&Class::MOP::Method::Generated::definition_context },
 570     ))
 571 );
 572
 573
 574 ## --------------------------------------------------------
 575 ## Class::MOP::Method::Inlined
 576
 577 Class::MOP::Method::Inlined->meta->add_attribute(
 578     Class::MOP::Attribute->new('_expected_method_class' => (
 579         reader   => { '_expected_method_class' => \&Class::MOP::Method::Inlined::_expected_method_class },
 580     ))
 581 );
 582
 583 ## --------------------------------------------------------
 584 ## Class::MOP::Method::Accessor
 585
 586 Class::MOP::Method::Accessor->meta->add_attribute(
 587     Class::MOP::Attribute->new('attribute' => (
 588         reader   => {
 589             'associated_attribute' => \&Class::MOP::Method::Accessor::associated_attribute
 590         },
 591     ))
 592 );
 593
 594 Class::MOP::Method::Accessor->meta->add_attribute(
 595     Class::MOP::Attribute->new('accessor_type' => (
 596         reader   => { 'accessor_type' => \&Class::MOP::Method::Accessor::accessor_type },
 597     ))
 598 );
 599
 600 ## --------------------------------------------------------
 601 ## Class::MOP::Method::Constructor
 602
 603 Class::MOP::Method::Constructor->meta->add_attribute(
 604     Class::MOP::Attribute->new('options' => (
 605         reader   => {
 606             'options' => \&Class::MOP::Method::Constructor::options
 607         },
 608         default  => sub { +{} }
 609     ))
 610 );
 611
 612 Class::MOP::Method::Constructor->meta->add_attribute(
 613     Class::MOP::Attribute->new('associated_metaclass' => (
 614         init_arg => "metaclass", # FIXME alias and rename
 615         reader   => {
 616             'associated_metaclass' => \&Class::MOP::Method::Constructor::associated_metaclass
 617         },
 618     ))
 619 );
 620
 621 ## --------------------------------------------------------
 622 ## Class::MOP::Instance
 623
 624 # NOTE:
 625 # these don't yet do much of anything, but are just
 626 # included for completeness
 627
 628 Class::MOP::Instance->meta->add_attribute(
 629     Class::MOP::Attribute->new('associated_metaclass',
 630         reader   => { associated_metaclass => \&Class::MOP::Instance::associated_metaclass },
 631     ),
 632 );
 633
 634 Class::MOP::Instance->meta->add_attribute(
 635     Class::MOP::Attribute->new('_class_name',
 636         init_arg => undef,
 637         reader   => { _class_name => \&Class::MOP::Instance::_class_name },
 638         #lazy     => 1, # not yet supported by Class::MOP but out our version does it anyway
 639         #default  => sub { $_[0]->associated_metaclass->name },
 640     ),
 641 );
 642
 643 Class::MOP::Instance->meta->add_attribute(
 644     Class::MOP::Attribute->new('attributes',
 645         reader   => { attributes => \&Class::MOP::Instance::get_all_attributes },
 646     ),
 647 );
 648
 649 Class::MOP::Instance->meta->add_attribute(
 650     Class::MOP::Attribute->new('slots',
 651         reader   => { slots => \&Class::MOP::Instance::slots },
 652     ),
 653 );
 654
 655 Class::MOP::Instance->meta->add_attribute(
 656     Class::MOP::Attribute->new('slot_hash',
 657         reader   => { slot_hash => \&Class::MOP::Instance::slot_hash },
 658     ),
 659 );
 660
 661
 662 # we need the meta instance of the meta instance to be created now, in order
 663 # for the constructor to be able to use it
 664 Class::MOP::Instance->meta->get_meta_instance;
 665
 666 # pretend the add_method never happenned. it hasn't yet affected anything
 667 undef Class::MOP::Instance->meta->{_package_cache_flag};
 668
 669 ## --------------------------------------------------------
 670 ## Now close all the Class::MOP::* classes
 671
 672 # NOTE: we don't need to inline the the accessors this only lengthens
 673 # the compile time of the MOP, and gives us no actual benefits.
 674
 675 # this is just nitpicking to ensure Class::MOP::Class->meta == ->meta->meta
 676 Class::MOP::Class->meta->_immutable_metaclass;
 677 $Class::MOP::Class::immutable_metaclass_cache{"Class::MOP::Class"}{"Class::MOP::Class::Immutable::Trait"} = Class::MOP::Class::Immutable::Class::MOP::Class->meta;
 678
 679 $_->meta->make_immutable(
 680     inline_constructor  => 1,
 681     replace_constructor => 1,
 682     constructor_name    => "_new",
 683     inline_accessors => 0,
 684 ) for qw/
 685     Class::MOP::Package
 686     Class::MOP::Module
 687     Class::MOP::Class
 688     Class::MOP::Class::Immutable::Trait
 689     Class::MOP::Class::Immutable::Class::MOP::Class
 690
 691     Class::MOP::Attribute
 692     Class::MOP::Method
 693     Class::MOP::Instance
 694
 695     Class::MOP::Object
 696
 697     Class::MOP::Method::Generated
 698     Class::MOP::Method::Inlined
 699
 700     Class::MOP::Method::Accessor
 701     Class::MOP::Method::Constructor
 702     Class::MOP::Method::Wrapped
 703 /;
 704
 705 1;
 706
 707 __END__
 708
 709 =pod
 710
 711 =head1 NAME
 712
 713 Class::MOP - A Meta Object Protocol for Perl 5
 714
 715 =head1 DESCRIPTION
 716
 717 This module is a fully functioning meta object protocol for the
 718 Perl 5 object system. It makes no attempt to change the behavior or
 719 characteristics of the Perl 5 object system, only to create a
 720 protocol for its manipulation and introspection.
 721
 722 That said, it does attempt to create the tools for building a rich set
 723 of extensions to the Perl 5 object system. Every attempt has been made
 724 to abide by the spirit of the Perl 5 object system that we all know
 725 and love.
 726
 727 This documentation is sparse on conceptual details. We suggest looking
 728 at the items listed in the L<SEE ALSO> section for more
 729 information. In particular the book "The Art of the Meta Object
 730 Protocol" was very influential in the development of this system.
 731
 732 =head2 What is a Meta Object Protocol?
 733
 734 A meta object protocol is an API to an object system.
 735
 736 To be more specific, it abstracts the components of an object system
 737 (classes, object, methods, object attributes, etc.). These
 738 abstractions can then be used to inspect and manipulate the object
 739 system which they describe.
 740
 741 It can be said that there are two MOPs for any object system; the
 742 implicit MOP and the explicit MOP. The implicit MOP handles things
 743 like method dispatch or inheritance, which happen automatically as
 744 part of how the object system works. The explicit MOP typically
 745 handles the introspection/reflection features of the object system.
 746
 747 All object systems have implicit MOPs. Without one, they would not
 748 work. Explicit MOPs are much less common, and depending on the
 749 language can vary from restrictive (Reflection in Java or C#) to wide
 750 open (CLOS is a perfect example).
 751
 752 =head2 Yet Another Class Builder! Why?
 753
 754 This is B<not> a class builder so much as a I<class builder
 755 B<builder>>. The intent is that an end user will not use this module
 756 directly, but instead this module is used by module authors to build
 757 extensions and features onto the Perl 5 object system.
 758
 759 This system is used by L<Moose>, which supplies a powerful class
 760 builder system built entirely on top of C<Class::MOP>.
 761
 762 =head2 Who is this module for?
 763
 764 This module is for anyone who has ever created or wanted to create a
 765 module for the Class:: namespace. The tools which this module provides
 766 make doing complex Perl 5 wizardry simpler, by removing such barriers
 767 as the need to hack symbol tables, or understand the fine details of
 768 method dispatch.
 769
 770 =head2 What changes do I have to make to use this module?
 771
 772 This module was designed to be as unintrusive as possible. Many of its
 773 features are accessible without B<any> change to your existing
 774 code. It is meant to be a compliment to your existing code and not an
 775 intrusion on your code base. Unlike many other B<Class::> modules,
 776 this module B<does not> require you subclass it, or even that you
 777 C<use> it in within your module's package.
 778
 779 The only features which requires additions to your code are the
 780 attribute handling and instance construction features, and these are
 781 both completely optional features. The only reason for this is because
 782 Perl 5's object system does not actually have these features built
 783 in. More information about this feature can be found below.
 784
 785 =head2 About Performance
 786
 787 It is a common misconception that explicit MOPs are a performance hit.
 788 This is not a universal truth, it is a side-effect of some specific
 789 implementations. For instance, using Java reflection is slow because
 790 the JVM cannot take advantage of any compiler optimizations, and the
 791 JVM has to deal with much more runtime type information as well.
 792
 793 Reflection in C# is marginally better as it was designed into the
 794 language and runtime (the CLR). In contrast, CLOS (the Common Lisp
 795 Object System) was built to support an explicit MOP, and so
 796 performance is tuned for it.
 797
 798 This library in particular does its absolute best to avoid putting
 799 B<any> drain at all upon your code's performance. In fact, by itself
 800 it does nothing to affect your existing code. So you only pay for what
 801 you actually use.
 802
 803 =head2 About Metaclass compatibility
 804
 805 This module makes sure that all metaclasses created are both upwards
 806 and downwards compatible. The topic of metaclass compatibility is
 807 highly esoteric and is something only encountered when doing deep and
 808 involved metaclass hacking. There are two basic kinds of metaclass
 809 incompatibility; upwards and downwards.
 810
 811 Upwards metaclass compatibility means that the metaclass of a
 812 given class is either the same as (or a subclass of) all of the
 813 class's ancestors.
 814
 815 Downward metaclass compatibility means that the metaclasses of a
 816 given class's ancestors are all either the same as (or a subclass
 817 of) that metaclass.
 818
 819 Here is a diagram showing a set of two classes (C<A> and C<B>) and
 820 two metaclasses (C<Meta::A> and C<Meta::B>) which have correct
 821 metaclass compatibility both upwards and downwards.
 822
 823     +---------+     +---------+
 824     | Meta::A |<----| Meta::B |      <....... (instance of  )
 825     +---------+     +---------+      <------- (inherits from)
 826          ^               ^
 827          :               :
 828     +---------+     +---------+
 829     |    A    |<----|    B    |
 830     +---------+     +---------+
 831
 832 As I said this is a highly esoteric topic and one you will only run
 833 into if you do a lot of subclassing of L<Class::MOP::Class>. If you
 834 are interested in why this is an issue see the paper I<Uniform and
 835 safe metaclass composition> linked to in the L<SEE ALSO> section of
 836 this document.
 837
 838 =head2 Using custom metaclasses
 839
 840 Always use the L<metaclass> pragma when using a custom metaclass, this
 841 will ensure the proper initialization order and not accidentally
 842 create an incorrect type of metaclass for you. This is a very rare
 843 problem, and one which can only occur if you are doing deep metaclass
 844 programming. So in other words, don't worry about it.
 845
 846 Note that if you're using L<Moose> we encourage you to I<not> use
 847 L<metaclass> pragma, and instead use L<Moose::Util::MetaRole> to apply
 848 roles to a class's metaclasses. This topic is covered at length in
 849 various L<Moose::Cookbook> recipes.
 850
 851 =head1 PROTOCOLS
 852
 853 The meta-object protocol is divided into 4 main sub-protocols:
 854
 855 =head2 The Class protocol
 856
 857 This provides a means of manipulating and introspecting a Perl 5
 858 class. It handles symbol table hacking for you, and provides a rich
 859 set of methods that go beyond simple package introspection.
 860
 861 See L<Class::MOP::Class> for more details.
 862
 863 =head2 The Attribute protocol
 864
 865 This provides a consistent representation for an attribute of a Perl 5
 866 class. Since there are so many ways to create and handle attributes in
 867 Perl 5 OO, the Attribute protocol provide as much of a unified
 868 approach as possible. Of course, you are always free to extend this
 869 protocol by subclassing the appropriate classes.
 870
 871 See L<Class::MOP::Attribute> for more details.
 872
 873 =head2 The Method protocol
 874
 875 This provides a means of manipulating and introspecting methods in the
 876 Perl 5 object system. As with attributes, there are many ways to
 877 approach this topic, so we try to keep it pretty basic, while still
 878 making it possible to extend the system in many ways.
 879
 880 See L<Class::MOP::Method> for more details.
 881
 882 =head2 The Instance protocol
 883
 884 This provides a layer of abstraction for creating object instances.
 885 Since the other layers use this protocol, it is relatively easy to
 886 change the type of your instances from the default hash reference to
 887 some other type of reference. Several examples are provided in the
 888 F<examples/> directory included in this distribution.
 889
 890 See L<Class::MOP::Instance> for more details.
 891
 892 =head1 FUNCTIONS
 893
 894 Note that this module does not export any constants or functions.
 895
 896 =head2 Constants
 897
 898 =over 4
 899
 900 =item I<Class::MOP::IS_RUNNING_ON_5_10>
 901
 902 We set this constant depending on what version perl we are on, this
 903 allows us to take advantage of new 5.10 features and stay backwards
 904 compatible.
 905
 906 =back
 907
 908 =head2 Utility functions
 909
 910 Note that these are all called as B<functions, not methods>.
 911
 912 =over 4
 913
 914 =item B<Class::MOP::load_class($class_name)>
 915
 916 This will load the specified C<$class_name>. This function can be used
 917 in place of tricks like C<eval "use $module"> or using C<require>
 918 unconditionally. This will return the metaclass of C<$class_name>.
 919
 920 =item B<Class::MOP::is_class_loaded($class_name)>
 921
 922 Returns a boolean indicating whether or not C<$class_name> has been
 923 loaded.
 924
 925 This does a basic check of the symbol table to try and determine as
 926 best it can if the C<$class_name> is loaded, it is probably correct
 927 about 99% of the time, but it can be fooled into reporting false
 928 positives.
 929
 930 =item B<Class::MOP::get_code_info($code)>
 931
 932 This function returns two values, the name of the package the C<$code>
 933 is from and the name of the C<$code> itself. This is used by several
 934 elements of the MOP to determine where a given C<$code> reference is
 935 from.
 936
 937 =item B<Class::MOP::class_of($instance_or_class_name)>
 938
 939 This will return the metaclass of the given instance or class name.
 940 Even if the class lacks a metaclass, no metaclass will be initialized
 941 and C<undef> will be returned.
 942
 943 =item B<Class::MOP::check_package_cache_flag($pkg)>
 944
 945 B<NOTE: DO NOT USE THIS FUNCTION, IT IS FOR INTERNAL USE ONLY!>
 946
 947 This will return an integer that is managed by L<Class::MOP::Class> to
 948 determine if a module's symbol table has been altered.
 949
 950 In Perl 5.10 or greater, this flag is package specific. However in
 951 versions prior to 5.10, this will use the C<PL_sub_generation>
 952 variable which is not package specific.
 953
 954 =item B<Class::MOP::load_first_existing_class(@class_names)>
 955
 956 B<NOTE: DO NOT USE THIS FUNCTION, IT IS FOR INTERNAL USE ONLY!>
 957
 958 Given a list of class names, this function will attempt to load each
 959 one in turn.
 960
 961 If it finds a class it can load, it will return that class' name.  If
 962 none of the classes can be loaded, it will throw an exception.
 963
 964 =back
 965
 966 =head2 Metaclass cache functions
 967
 968 Class::MOP holds a cache of metaclasses. The following are functions
 969 (B<not methods>) which can be used to access that cache. It is not
 970 recommended that you mess with these. Bad things could happen, but if
 971 you are brave and willing to risk it: go for it!
 972
 973 =over 4
 974
 975 =item B<Class::MOP::get_all_metaclasses>
 976
 977 This will return a hash of all the metaclass instances that have
 978 been cached by L<Class::MOP::Class>, keyed by the package name.
 979
 980 =item B<Class::MOP::get_all_metaclass_instances>
 981
 982 This will return a list of all the metaclass instances that have
 983 been cached by L<Class::MOP::Class>.
 984
 985 =item B<Class::MOP::get_all_metaclass_names>
 986
 987 This will return a list of all the metaclass names that have
 988 been cached by L<Class::MOP::Class>.
 989
 990 =item B<Class::MOP::get_metaclass_by_name($name)>
 991
 992 This will return a cached L<Class::MOP::Class> instance, or nothing
 993 if no metaclass exists with that C<$name>.
 994
 995 =item B<Class::MOP::store_metaclass_by_name($name, $meta)>
 996
 997 This will store a metaclass in the cache at the supplied C<$key>.
 998
 999 =item B<Class::MOP::weaken_metaclass($name)>
1000
1001 In rare cases (e.g. anonymous metaclasses) it is desirable to
1002 store a weakened reference in the metaclass cache. This
1003 function will weaken the reference to the metaclass stored
1004 in C<$name>.
1005
1006 =item B<Class::MOP::does_metaclass_exist($name)>
1007
1008 This will return true of there exists a metaclass stored in the
1009 C<$name> key, and return false otherwise.
1010
1011 =item B<Class::MOP::remove_metaclass_by_name($name)>
1012
1013 This will remove the metaclass stored in the C<$name> key.
1014
1015 =back
1016
1017 =head1 SEE ALSO
1018
1019 =head2 Books
1020
1021 There are very few books out on Meta Object Protocols and Metaclasses
1022 because it is such an esoteric topic. The following books are really
1023 the only ones I have found. If you know of any more, B<I<please>>
1024 email me and let me know, I would love to hear about them.
1025
1026 =over 4
1027
1028 =item I<The Art of the Meta Object Protocol>
1029
1030 =item I<Advances in Object-Oriented Metalevel Architecture and Reflection>
1031
1032 =item I<Putting MetaClasses to Work>
1033
1034 =item I<Smalltalk: The Language>
1035
1036 =back
1037
1038 =head2 Papers
1039
1040 =over 4
1041
1042 =item "Uniform and safe metaclass composition"
1043
1044 An excellent paper by the people who brought us the original Traits paper.
1045 This paper is on how Traits can be used to do safe metaclass composition,
1046 and offers an excellent introduction section which delves into the topic of
1047 metaclass compatibility.
1048
1049 L<http://www.iam.unibe.ch/~scg/Archive/Papers/Duca05ySafeMetaclassTrait.pdf>
1050
1051 =item "Safe Metaclass Programming"
1052
1053 This paper seems to precede the above paper, and propose a mix-in based
1054 approach as opposed to the Traits based approach. Both papers have similar
1055 information on the metaclass compatibility problem space.
1056
1057 L<http://citeseer.ist.psu.edu/37617.html>
1058
1059 =back
1060
1061 =head2 Prior Art
1062
1063 =over 4
1064
1065 =item The Perl 6 MetaModel work in the Pugs project
1066
1067 =over 4
1068
1069 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-MetaModel>
1070
1071 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-ObjectSpace>
1072
1073 =back
1074
1075 =back
1076
1077 =head2 Articles
1078
1079 =over 4
1080
1081 =item CPAN Module Review of Class::MOP
1082
1083 L<http://www.oreillynet.com/onlamp/blog/2006/06/cpan_module_review_classmop.html>
1084
1085 =back
1086
1087 =head1 SIMILAR MODULES
1088
1089 As I have said above, this module is a class-builder-builder, so it is
1090 not the same thing as modules like L<Class::Accessor> and
1091 L<Class::MethodMaker>. That being said there are very few modules on CPAN
1092 with similar goals to this module. The one I have found which is most
1093 like this module is L<Class::Meta>, although it's philosophy and the MOP it
1094 creates are very different from this modules.
1095
1096 =head1 BUGS
1097
1098 All complex software has bugs lurking in it, and this module is no
1099 exception.
1100
1101 Please report any bugs to C<bug-class-mop@rt.cpan.org>, or through the
1102 web interface at L<http://rt.cpan.org>.
1103
1104 You can also discuss feature requests or possible bugs on the Moose
1105 mailing list (moose@perl.org) or on IRC at
1106 L<irc://irc.perl.org/#moose>.
1107
1108 =head1 ACKNOWLEDGEMENTS
1109
1110 =over 4
1111
1112 =item Rob Kinyon
1113
1114 Thanks to Rob for actually getting the development of this module kick-started.
1115
1116 =back
1117
1118 =head1 AUTHORS
1119
1120 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1121
1122 B<with contributions from:>
1123
1124 Brandon (blblack) Black
1125
1126 Florian (rafl) Ragwitz
1127
1128 Guillermo (groditi) Roditi
1129
1130 Dave (autarch) Rolsky
1131
1132 Matt (mst) Trout
1133
1134 Rob (robkinyon) Kinyon
1135
1136 Yuval (nothingmuch) Kogman
1137
1138 Scott (konobi) McWhirter
1139
1140 =head1 COPYRIGHT AND LICENSE
1141
1142 Copyright 2006-2009 by Infinity Interactive, Inc.
1143
1144 L<http://www.iinteractive.com>
1145
1146 This library is free software; you can redistribute it and/or modify
1147 it under the same terms as Perl itself.
1148
1149 =cut