lib/Class/MOP/Module.pm

   1
   2 package Class::MOP::Module;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed';
   9
  10 use base 'Class::MOP::Package';
  11
  12 sub _new {
  13     my $class = shift;
  14     return Class::MOP::Class->initialize($class)->new_object(@_)
  15         if $class ne __PACKAGE__;
  16
  17     my $params = @_ == 1 ? $_[0] : {@_};
  18     return bless {
  19         # Need to quote package to avoid a problem with PPI mis-parsing this
  20         # as a package statement.
  21
  22         # from Class::MOP::Package
  23         'package' => $params->{package},
  24         namespace => \undef,
  25
  26         # attributes
  27         version   => \undef,
  28         authority => \undef
  29     } => $class;
  30 }
  31
  32 sub version {
  33     my $self = shift;
  34     ${$self->get_or_add_package_symbol('$VERSION')};
  35 }
  36
  37 sub authority {
  38     my $self = shift;
  39     ${$self->get_or_add_package_symbol('$AUTHORITY')};
  40 }
  41
  42 sub identifier {
  43     my $self = shift;
  44     join '-' => (
  45         $self->name,
  46         ($self->version   || ()),
  47         ($self->authority || ()),
  48     );
  49 }
  50
  51 sub create {
  52     my $class = shift;
  53     my @args = @_;
  54
  55     unshift @args, 'package' if @args % 2 == 1;
  56     my %options = @args;
  57
  58     my $package   = delete $options{package};
  59     my $version   = delete $options{version};
  60     my $authority = delete $options{authority};
  61
  62     my $meta = $class->SUPER::create($package => %options);
  63
  64     $meta->_instantiate_module($version, $authority);
  65
  66     return $meta;
  67 }
  68
  69 sub _anon_package_prefix { 'Class::MOP::Module::__ANON__::SERIAL::' }
  70 sub _anon_cache_key      { confess "Modules are not cacheable" }
  71
  72
  73 sub _instantiate_module {
  74     my($self, $version, $authority) = @_;
  75     my $package_name = $self->name;
  76
  77     $self->add_package_symbol('$VERSION' => $version)
  78         if defined $version;
  79     $self->add_package_symbol('$AUTHORITY' => $authority)
  80         if defined $authority;
  81
  82     return;
  83 }
  84
  85 1;
  86
  87 # ABSTRACT: Module Meta Object
  88
  89 __END__
  90
  91 =pod
  92
  93 =head1 NAME
  94
  95 Class::MOP::Module - Module Meta Object
  96
  97 =head1 DESCRIPTION
  98
  99 A module is essentially a L<Class::MOP::Package> with metadata, in our
 100 case the version and authority.
 101
 102 =head1 INHERITANCE
 103
 104 B<Class::MOP::Module> is a subclass of L<Class::MOP::Package>.
 105
 106 =head1 METHODS
 107
 108 =over 4
 109
 110 =item B<< Class::MOP::Module->create($package, %options) >>
 111
 112 Overrides C<create> from L<Class::MOP::Package> to provide these additional
 113 options:
 114
 115 =over 4
 116
 117 =item C<version>
 118
 119 A version number, to be installed in the C<$VERSION> package global variable.
 120
 121 =item C<authority>
 122
 123 An authority, to be installed in the C<$AUTHORITY> package global variable.
 124
 125 =back
 126
 127 =item B<< $metamodule->version >>
 128
 129 This is a read-only attribute which returns the C<$VERSION> of the
 130 package, if one exists.
 131
 132 =item B<< $metamodule->authority >>
 133
 134 This is a read-only attribute which returns the C<$AUTHORITY> of the
 135 package, if one exists.
 136
 137 =item B<< $metamodule->identifier >>
 138
 139 This constructs a string which combines the name, version and
 140 authority.
 141
 142 =item B<< Class::MOP::Module->meta >>
 143
 144 This will return a L<Class::MOP::Class> instance for this class.
 145
 146 =back
 147
 148 =cut