lib/Class/MOP/Module.pm

   1
   2 package Class::MOP::Module;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed';
   9
  10 our $VERSION   = '0.94';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use base 'Class::MOP::Package';
  15
  16 sub _new {
  17     my $class = shift;
  18     return Class::MOP::Class->initialize($class)->new_object(@_)
  19         if $class ne __PACKAGE__;
  20
  21     my $params = @_ == 1 ? $_[0] : {@_};
  22     return bless {
  23
  24         # from Class::MOP::Package
  25         package   => $params->{package},
  26         namespace => \undef,
  27
  28         # attributes
  29         version   => \undef,
  30         authority => \undef
  31     } => $class;
  32 }
  33
  34 sub version {
  35     my $self = shift;
  36     ${$self->get_package_symbol({ sigil => '$', type => 'SCALAR', name => 'VERSION' })};
  37 }
  38
  39 sub authority {
  40     my $self = shift;
  41     ${$self->get_package_symbol({ sigil => '$', type => 'SCALAR', name => 'AUTHORITY' })};
  42 }
  43
  44 sub identifier {
  45     my $self = shift;
  46     join '-' => (
  47         $self->name,
  48         ($self->version   || ()),
  49         ($self->authority || ()),
  50     );
  51 }
  52
  53 sub create {
  54     confess "The Class::MOP::Module->create method has been made a private object method.\n";
  55 }
  56
  57 sub _instantiate_module {
  58     my($self, $version, $authority) = @_;
  59     my $package_name = $self->name;
  60
  61     Class::MOP::_is_valid_class_name($package_name)
  62         || confess "creation of $package_name failed: invalid package name";
  63
  64     no strict 'refs';
  65     scalar %{ $package_name . '::' };    # touch the stash
  66     ${ $package_name . '::VERSION' }   = $version   if defined $version;
  67     ${ $package_name . '::AUTHORITY' } = $authority if defined $authority;
  68
  69     return;
  70 }
  71
  72 1;
  73
  74 __END__
  75
  76 =pod
  77
  78 =head1 NAME
  79
  80 Class::MOP::Module - Module Meta Object
  81
  82 =head1 DESCRIPTION
  83
  84 A module is essentially a L<Class::MOP::Package> with metadata, in our
  85 case the version and authority.
  86
  87 =head1 INHERITANCE
  88
  89 B<Class::MOP::Module> is a subclass of L<Class::MOP::Package>.
  90
  91 =head1 METHODS
  92
  93 =over 4
  94
  95 =item B<< $metamodule->version >>
  96
  97 This is a read-only attribute which returns the C<$VERSION> of the
  98 package, if one exists.
  99
 100 =item B<< $metamodule->authority >>
 101
 102 This is a read-only attribute which returns the C<$AUTHORITY> of the
 103 package, if one exists.
 104
 105 =item B<< $metamodule->identifier >>
 106
 107 This constructs a string which combines the name, version and
 108 authority.
 109
 110 =item B<< Class::MOP::Module->meta >>
 111
 112 This will return a L<Class::MOP::Class> instance for this class.
 113
 114 =back
 115
 116 =head1 AUTHORS
 117
 118 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 119
 120 =head1 COPYRIGHT AND LICENSE
 121
 122 Copyright 2006-2009 by Infinity Interactive, Inc.
 123
 124 L<http://www.iinteractive.com>
 125
 126 This library is free software; you can redistribute it and/or modify
 127 it under the same terms as Perl itself.
 128
 129 =cut