5cc151acf4effb1f1a9e919174161f8383a67846
[gitmo/Moose.git] / lib / Class / MOP / Module.pm
1
2 package Class::MOP::Module;
3
4 use strict;
5 use warnings;
6
7 use Carp         'confess';
8 use Scalar::Util 'blessed';
9
10 use base 'Class::MOP::Package';
11
12 sub _new {
13     my $class = shift;
14     return Class::MOP::Class->initialize($class)->new_object(@_)
15         if $class ne __PACKAGE__;
16
17     my $params = @_ == 1 ? $_[0] : {@_};
18     return bless {
19         # Need to quote package to avoid a problem with PPI mis-parsing this
20         # as a package statement.
21
22         # from Class::MOP::Package
23         'package' => $params->{package},
24         namespace => \undef,
25
26         # attributes
27         version   => \undef,
28         authority => \undef
29     } => $class;
30 }
31
32 sub version {  
33     my $self = shift;
34     ${$self->get_or_add_package_symbol('$VERSION')};
35 }
36
37 sub authority {  
38     my $self = shift;
39     ${$self->get_or_add_package_symbol('$AUTHORITY')};
40 }
41
42 sub identifier {
43     my $self = shift;
44     join '-' => (
45         $self->name,
46         ($self->version   || ()),
47         ($self->authority || ()),
48     );
49 }
50
51 sub create {
52     my $class = shift;
53     my @args = @_;
54
55     unshift @args, 'package' if @args % 2 == 1;
56     my %options = @args;
57
58     my $package   = delete $options{package};
59     my $version   = delete $options{version};
60     my $authority = delete $options{authority};
61
62     my $meta = $class->SUPER::create($package => %options);
63
64     $meta->_instantiate_module($version, $authority);
65
66     return $meta;
67 }
68
69 sub _anon_package_prefix { 'Class::MOP::Module::__ANON__::SERIAL::' }
70 sub _anon_cache_key      { confess "Modules are not cacheable" }
71
72
73 sub _instantiate_module {
74     my($self, $version, $authority) = @_;
75     my $package_name = $self->name;
76
77     _is_valid_class_name($package_name)
78         || confess "creation of $package_name failed: invalid package name";
79
80     $self->add_package_symbol('$VERSION' => $version)
81         if defined $version;
82     $self->add_package_symbol('$AUTHORITY' => $authority)
83         if defined $authority;
84
85     return;
86 }
87
88 sub _is_valid_class_name {
89     my $class = shift;
90
91     return 0 if ref($class);
92     return 0 unless defined($class);
93     return 0 unless length($class);
94
95     return 1 if $class =~ /^\w+(?:::\w+)*$/;
96
97     return 0;
98 }
99
100 1;
101
102 # ABSTRACT: Module Meta Object
103
104 __END__
105
106 =pod
107
108 =head1 NAME 
109
110 Class::MOP::Module - Module Meta Object
111
112 =head1 DESCRIPTION
113
114 A module is essentially a L<Class::MOP::Package> with metadata, in our
115 case the version and authority.
116
117 =head1 INHERITANCE
118
119 B<Class::MOP::Module> is a subclass of L<Class::MOP::Package>.
120
121 =head1 METHODS
122
123 =over 4
124
125 =item B<< Class::MOP::Module->create($package, %options) >>
126
127 Overrides C<create> from L<Class::MOP::Package> to provide these additional
128 options:
129
130 =over 4
131
132 =item C<version>
133
134 A version number, to be installed in the C<$VERSION> package global variable.
135
136 =item C<authority>
137
138 An authority, to be installed in the C<$AUTHORITY> package global variable.
139
140 =back
141
142 =item B<< $metamodule->version >>
143
144 This is a read-only attribute which returns the C<$VERSION> of the
145 package, if one exists.
146
147 =item B<< $metamodule->authority >>
148
149 This is a read-only attribute which returns the C<$AUTHORITY> of the
150 package, if one exists.
151
152 =item B<< $metamodule->identifier >>
153
154 This constructs a string which combines the name, version and
155 authority.
156
157 =item B<< Class::MOP::Module->meta >>
158
159 This will return a L<Class::MOP::Class> instance for this class.
160
161 =back
162
163 =cut