lib/Class/MOP/Mixin/HasMethods.pm

   1 package Class::MOP::Mixin::HasMethods;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Class::MOP::Method::Meta;
   7
   8 our $VERSION   = '1.11';
   9 $VERSION = eval $VERSION;
  10 our $AUTHORITY = 'cpan:STEVAN';
  11
  12 use Scalar::Util 'blessed';
  13 use Carp         'confess';
  14 use Sub::Name    'subname';
  15
  16 use base 'Class::MOP::Mixin';
  17
  18 sub method_metaclass         { $_[0]->{'method_metaclass'}            }
  19 sub wrapped_method_metaclass { $_[0]->{'wrapped_method_metaclass'}    }
  20 sub _meta_method_class       { 'Class::MOP::Method::Meta'             }
  21
  22 sub _add_meta_method {
  23     my $self = shift;
  24     my ($name) = @_;
  25     my $existing_method = $self->can('find_method_by_name')
  26                               ? $self->find_method_by_name($name)
  27                               : $self->get_method($name);
  28     return if $existing_method
  29            && $existing_method->isa($self->_meta_method_class);
  30     $self->add_method(
  31         $name => $self->_meta_method_class->wrap(
  32             name                 => $name,
  33             package_name         => $self->name,
  34             associated_metaclass => $self,
  35         )
  36     );
  37 }
  38
  39 sub wrap_method_body {
  40     my ( $self, %args ) = @_;
  41
  42     ( 'CODE' eq ref $args{body} )
  43         || confess "Your code block must be a CODE reference";
  44
  45     $self->method_metaclass->wrap(
  46         package_name => $self->name,
  47         %args,
  48     );
  49 }
  50
  51 sub add_method {
  52     my ( $self, $method_name, $method ) = @_;
  53     ( defined $method_name && length $method_name )
  54         || confess "You must define a method name";
  55
  56     my $package_name = $self->name;
  57
  58     my $body;
  59     if ( blessed($method) ) {
  60         $body = $method->body;
  61         if ( $method->package_name ne $package_name ) {
  62             $method = $method->clone(
  63                 package_name => $package_name,
  64                 name         => $method_name,
  65             ) if $method->can('clone');
  66         }
  67
  68         $method->attach_to_class($self);
  69     }
  70     else {
  71         # If a raw code reference is supplied, its method object is not created.
  72         # The method object won't be created until required.
  73         $body = $method;
  74     }
  75
  76     $self->_method_map->{$method_name} = $method;
  77
  78     my ( $current_package, $current_name ) = Class::MOP::get_code_info($body);
  79
  80     if ( !defined $current_name || $current_name =~ /^__ANON__/ ) {
  81         my $full_method_name = ( $package_name . '::' . $method_name );
  82         subname( $full_method_name => $body );
  83     }
  84
  85     $self->add_package_symbol(
  86         { sigil => '&', type => 'CODE', name => $method_name },
  87         $body,
  88     );
  89 }
  90
  91 sub _code_is_mine {
  92     my ( $self, $code ) = @_;
  93
  94     my ( $code_package, $code_name ) = Class::MOP::get_code_info($code);
  95
  96     return $code_package && $code_package eq $self->name
  97         || ( $code_package eq 'constant' && $code_name eq '__ANON__' );
  98 }
  99
 100 sub has_method {
 101     my ( $self, $method_name ) = @_;
 102
 103     ( defined $method_name && length $method_name )
 104         || confess "You must define a method name";
 105
 106     return defined( $self->_get_maybe_raw_method($method_name) );
 107 }
 108
 109 sub get_method {
 110     my ( $self, $method_name ) = @_;
 111
 112     ( defined $method_name && length $method_name )
 113         || confess "You must define a method name";
 114
 115     my $method = $self->_get_maybe_raw_method($method_name)
 116         or return;
 117
 118     return $method if blessed $method;
 119
 120     return $self->_method_map->{$method_name} = $self->wrap_method_body(
 121         body                 => $method,
 122         name                 => $method_name,
 123         associated_metaclass => $self,
 124     );
 125 }
 126
 127 sub _get_maybe_raw_method {
 128     my ( $self, $method_name ) = @_;
 129
 130     my $map_entry = $self->_method_map->{$method_name};
 131     return $map_entry if blessed $map_entry;
 132
 133     my $code = $self->get_package_symbol(
 134         {
 135             name  => $method_name,
 136             sigil => '&',
 137             type  => 'CODE',
 138         }
 139     );
 140
 141     unless ($map_entry) {
 142         return unless $code && $self->_code_is_mine($code);
 143     }
 144
 145     return $code;
 146 }
 147
 148 sub remove_method {
 149     my ( $self, $method_name ) = @_;
 150     ( defined $method_name && length $method_name )
 151         || confess "You must define a method name";
 152
 153     my $removed_method = delete $self->_method_map->{$method_name};
 154
 155     $self->remove_package_symbol(
 156         { sigil => '&', type => 'CODE', name => $method_name } );
 157
 158     $removed_method->detach_from_class
 159         if $removed_method && blessed $removed_method;
 160
 161     # still valid, since we just removed the method from the map
 162     $self->update_package_cache_flag;
 163
 164     return $removed_method;
 165 }
 166
 167 sub get_method_list {
 168     my $self = shift;
 169
 170     return keys %{ $self->_full_method_map };
 171 }
 172
 173 # This should probably be what get_method_list actually does, instead of just
 174 # returning names. This was created as a much faster alternative to
 175 # $meta->get_method($_) for $meta->get_method_list
 176 sub _get_local_methods {
 177     my $self = shift;
 178
 179     return values %{ $self->_full_method_map };
 180 }
 181
 182 sub _restore_metamethods_from {
 183     my $self = shift;
 184     my ($old_meta) = @_;
 185
 186     for my $method ($old_meta->_get_local_methods) {
 187         $method->_make_compatible_with($self->method_metaclass);
 188         $self->add_method($method->name => $method);
 189     }
 190 }
 191
 192 sub reset_package_cache_flag  { (shift)->{'_package_cache_flag'} = undef }
 193 sub update_package_cache_flag {
 194     my $self = shift;
 195     # NOTE:
 196     # we can manually update the cache number
 197     # since we are actually adding the method
 198     # to our cache as well. This avoids us
 199     # having to regenerate the method_map.
 200     # - SL
 201     $self->{'_package_cache_flag'} = Class::MOP::check_package_cache_flag($self->name);
 202 }
 203
 204 sub _full_method_map {
 205     my $self = shift;
 206
 207     my $pkg_gen = Class::MOP::check_package_cache_flag($self->name);
 208
 209     if (($self->{_package_cache_flag_full} || -1) != $pkg_gen) {
 210         # forcibly reify all method map entries
 211         $self->get_method($_)
 212             for $self->list_all_package_symbols('CODE');
 213         $self->{_package_cache_flag_full} = $pkg_gen;
 214     }
 215
 216     return $self->_method_map;
 217 }
 218
 219 1;
 220
 221 __END__
 222
 223 =pod
 224
 225 =head1 NAME
 226
 227 Class::MOP::Mixin::HasMethods - Methods for metaclasses which have methods
 228
 229 =head1 DESCRIPTION
 230
 231 This class implements methods for metaclasses which have methods
 232 (L<Class::MOP::Package> and L<Moose::Meta::Role>). See L<Class::MOP::Package>
 233 for API details.
 234
 235 =head1 AUTHORS
 236
 237 Dave Rolsky E<lt>autarch@urth.orgE<gt>
 238
 239 =head1 COPYRIGHT AND LICENSE
 240
 241 Copyright 2006-2010 by Infinity Interactive, Inc.
 242
 243 L<http://www.iinteractive.com>
 244
 245 This library is free software; you can redistribute it and/or modify
 246 it under the same terms as Perl itself.
 247
 248 =cut