lib/Class/MOP/Mixin/HasMethods.pm

   1 package Class::MOP::Mixin::HasMethods;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Class::MOP::Method::Meta;
   7
   8 our $VERSION   = '1.11';
   9 $VERSION = eval $VERSION;
  10 our $AUTHORITY = 'cpan:STEVAN';
  11
  12 use Scalar::Util 'blessed';
  13 use Carp         'confess';
  14 use Sub::Name    'subname';
  15
  16 use base 'Class::MOP::Mixin';
  17
  18 sub method_metaclass         { $_[0]->{'method_metaclass'}            }
  19 sub wrapped_method_metaclass { $_[0]->{'wrapped_method_metaclass'}    }
  20 sub _meta_method_class       { 'Class::MOP::Method::Meta'             }
  21
  22 sub _add_meta_method {
  23     my $self = shift;
  24     my ($name) = @_;
  25     my $existing_method = $self->can('find_method_by_name')
  26                               ? $self->find_method_by_name($name)
  27                               : $self->get_method($name);
  28     return if $existing_method
  29            && $existing_method->isa($self->_meta_method_class);
  30     $self->add_method(
  31         $name => $self->_meta_method_class->wrap(
  32             name                 => $name,
  33             package_name         => $self->name,
  34             associated_metaclass => $self,
  35         )
  36     );
  37 }
  38
  39 sub wrap_method_body {
  40     my ( $self, %args ) = @_;
  41
  42     ( 'CODE' eq ref $args{body} )
  43         || confess "Your code block must be a CODE reference";
  44
  45     $self->method_metaclass->wrap(
  46         package_name => $self->name,
  47         %args,
  48     );
  49 }
  50
  51 sub add_method {
  52     my ( $self, $method_name, $method ) = @_;
  53     ( defined $method_name && length $method_name )
  54         || confess "You must define a method name";
  55
  56     my $package_name = $self->name;
  57
  58     my $body;
  59     if ( blessed($method) ) {
  60         $body = $method->body;
  61         if ( $method->package_name ne $package_name ) {
  62             $method = $method->clone(
  63                 package_name => $package_name,
  64                 name         => $method_name,
  65             ) if $method->can('clone');
  66         }
  67
  68         $method->attach_to_class($self);
  69     }
  70     else {
  71         # If a raw code reference is supplied, its method object is not created.
  72         # The method object won't be created until required.
  73         $body = $method;
  74     }
  75
  76     $self->_method_map->{$method_name} = $method;
  77
  78     my ( $current_package, $current_name ) = Class::MOP::get_code_info($body);
  79
  80     if ( !defined $current_name || $current_name =~ /^__ANON__/ ) {
  81         my $full_method_name = ( $package_name . '::' . $method_name );
  82         subname( $full_method_name => $body );
  83     }
  84
  85     $self->add_package_symbol("&$method_name", $body);
  86 }
  87
  88 sub _code_is_mine {
  89     my ( $self, $code ) = @_;
  90
  91     my ( $code_package, $code_name ) = Class::MOP::get_code_info($code);
  92
  93     return $code_package && $code_package eq $self->name
  94         || ( $code_package eq 'constant' && $code_name eq '__ANON__' );
  95 }
  96
  97 sub has_method {
  98     my ( $self, $method_name ) = @_;
  99
 100     ( defined $method_name && length $method_name )
 101         || confess "You must define a method name";
 102
 103     my $method = $self->_get_maybe_raw_method($method_name)
 104         or return;
 105
 106     return defined($self->_method_map->{$method_name} = $method);
 107 }
 108
 109 sub get_method {
 110     my ( $self, $method_name ) = @_;
 111
 112     ( defined $method_name && length $method_name )
 113         || confess "You must define a method name";
 114
 115     my $method = $self->_get_maybe_raw_method($method_name)
 116         or return;
 117
 118     return $method if blessed $method;
 119
 120     return $self->_method_map->{$method_name} = $self->wrap_method_body(
 121         body                 => $method,
 122         name                 => $method_name,
 123         associated_metaclass => $self,
 124     );
 125 }
 126
 127 sub _get_maybe_raw_method {
 128     my ( $self, $method_name ) = @_;
 129
 130     my $map_entry = $self->_method_map->{$method_name};
 131     return $map_entry if defined $map_entry;
 132
 133     my $code = $self->get_package_symbol("&$method_name");
 134
 135     unless ($map_entry) {
 136         return unless $code && $self->_code_is_mine($code);
 137     }
 138
 139     return $code;
 140 }
 141
 142 sub remove_method {
 143     my ( $self, $method_name ) = @_;
 144     ( defined $method_name && length $method_name )
 145         || confess "You must define a method name";
 146
 147     my $removed_method = delete $self->_method_map->{$method_name};
 148
 149     $self->remove_package_symbol("&$method_name");
 150
 151     $removed_method->detach_from_class
 152         if $removed_method && blessed $removed_method;
 153
 154     # still valid, since we just removed the method from the map
 155     $self->update_package_cache_flag;
 156
 157     return $removed_method;
 158 }
 159
 160 sub get_method_list {
 161     my $self = shift;
 162
 163     return keys %{ $self->_full_method_map };
 164 }
 165
 166 # This should probably be what get_method_list actually does, instead of just
 167 # returning names. This was created as a much faster alternative to
 168 # $meta->get_method($_) for $meta->get_method_list
 169 sub _get_local_methods {
 170     my $self = shift;
 171
 172     return values %{ $self->_full_method_map };
 173 }
 174
 175 sub _restore_metamethods_from {
 176     my $self = shift;
 177     my ($old_meta) = @_;
 178
 179     for my $method ($old_meta->_get_local_methods) {
 180         $method->_make_compatible_with($self->method_metaclass);
 181         $self->add_method($method->name => $method);
 182     }
 183 }
 184
 185 sub reset_package_cache_flag  { (shift)->{'_package_cache_flag'} = undef }
 186 sub update_package_cache_flag {
 187     my $self = shift;
 188     # NOTE:
 189     # we can manually update the cache number
 190     # since we are actually adding the method
 191     # to our cache as well. This avoids us
 192     # having to regenerate the method_map.
 193     # - SL
 194     $self->{'_package_cache_flag'} = Class::MOP::check_package_cache_flag($self->name);
 195 }
 196
 197 sub _full_method_map {
 198     my $self = shift;
 199
 200     my $pkg_gen = Class::MOP::check_package_cache_flag($self->name);
 201
 202     if (($self->{_package_cache_flag_full} || -1) != $pkg_gen) {
 203         # forcibly reify all method map entries
 204         $self->get_method($_)
 205             for $self->list_all_package_symbols('CODE');
 206         $self->{_package_cache_flag_full} = $pkg_gen;
 207     }
 208
 209     return $self->_method_map;
 210 }
 211
 212 1;
 213
 214 __END__
 215
 216 =pod
 217
 218 =head1 NAME
 219
 220 Class::MOP::Mixin::HasMethods - Methods for metaclasses which have methods
 221
 222 =head1 DESCRIPTION
 223
 224 This class implements methods for metaclasses which have methods
 225 (L<Class::MOP::Package> and L<Moose::Meta::Role>). See L<Class::MOP::Package>
 226 for API details.
 227
 228 =head1 AUTHORS
 229
 230 Dave Rolsky E<lt>autarch@urth.orgE<gt>
 231
 232 =head1 COPYRIGHT AND LICENSE
 233
 234 Copyright 2006-2010 by Infinity Interactive, Inc.
 235
 236 L<http://www.iinteractive.com>
 237
 238 This library is free software; you can redistribute it and/or modify
 239 it under the same terms as Perl itself.
 240
 241 =cut