lib/Class/MOP/Method.pm

   1
   2 package Class::MOP::Method;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed';
   9
  10 our $VERSION   = '0.65';
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use base 'Class::MOP::Object';
  14
  15 # NOTE:
  16 # if poked in the right way,
  17 # they should act like CODE refs.
  18 use overload '&{}' => sub { $_[0]->body }, fallback => 1;
  19
  20 our $UPGRADE_ERROR_TEXT = q{
  21 ---------------------------------------------------------
  22 NOTE: this error is likely not an error, but a regression
  23 caused by the latest upgrade to Moose/Class::MOP. Consider
  24 upgrading any MooseX::* modules to their latest versions
  25 before spending too much time chasing this one down.
  26 ---------------------------------------------------------
  27 };
  28
  29 # construction
  30
  31 sub wrap {
  32     my ( $class, @args ) = @_;
  33
  34     unshift @args, 'body' if @args % 2 == 1;
  35
  36     my %params = @args;
  37     my $code = $params{body};
  38
  39     ('CODE' eq ref($code))
  40         || confess "You must supply a CODE reference to bless, not (" . ($code || 'undef') . ")";
  41
  42     ($params{package_name} && $params{name})
  43         || confess "You must supply the package_name and name parameters $UPGRADE_ERROR_TEXT";
  44
  45     bless {
  46         'body'         => $code,
  47         'package_name' => $params{package_name},
  48         'name'         => $params{name},
  49     } => blessed($class) || $class;
  50 }
  51
  52 ## accessors
  53
  54 sub body { (shift)->{'body'} }
  55
  56 # TODO - add associated_class
  57
  58 # informational
  59
  60 sub package_name {
  61     my $self = shift;
  62     $self->{'package_name'} ||= (Class::MOP::get_code_info($self->body))[0];
  63 }
  64
  65 sub name {
  66     my $self = shift;
  67     $self->{'name'} ||= (Class::MOP::get_code_info($self->body))[1];
  68 }
  69
  70 sub fully_qualified_name {
  71     my $code = shift;
  72     $code->package_name . '::' . $code->name;
  73 }
  74
  75 # NOTE:
  76 # the Class::MOP bootstrap
  77 # will create this for us
  78 # - SL
  79 # sub clone { ... }
  80
  81 1;
  82
  83 __END__
  84
  85 =pod
  86
  87 =head1 NAME
  88
  89 Class::MOP::Method - Method Meta Object
  90
  91 =head1 DESCRIPTION
  92
  93 The Method Protocol is very small, since methods in Perl 5 are just
  94 subroutines within the particular package. We provide a very basic
  95 introspection interface.
  96
  97 =head1 METHODS
  98
  99 =head2 Introspection
 100
 101 =over 4
 102
 103 =item B<meta>
 104
 105 This will return a B<Class::MOP::Class> instance which is related
 106 to this class.
 107
 108 =back
 109
 110 =head2 Construction
 111
 112 =over 4
 113
 114 =item B<wrap ($code, %params)>
 115
 116 This is the basic constructor, it returns a B<Class::MOP::Method>
 117 instance which wraps the given C<$code> reference. You can also
 118 set the C<package_name> and C<name> attributes using the C<%params>.
 119 If these are not set, then thier accessors will attempt to figure
 120 it out using the C<Class::MOP::get_code_info> function.
 121
 122 =item B<clone (%params)>
 123
 124 This will make a copy of the object, allowing you to override
 125 any values by stuffing them in C<%params>.
 126
 127 =back
 128
 129 =head2 Informational
 130
 131 =over 4
 132
 133 =item B<body>
 134
 135 This returns the actual CODE reference of the particular instance.
 136
 137 =item B<name>
 138
 139 This returns the name of the CODE reference.
 140
 141 =item B<package_name>
 142
 143 This returns the package name that the CODE reference is attached to.
 144
 145 =item B<fully_qualified_name>
 146
 147 This returns the fully qualified name of the CODE reference.
 148
 149 =back
 150
 151 =head1 AUTHORS
 152
 153 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 154
 155 =head1 COPYRIGHT AND LICENSE
 156
 157 Copyright 2006-2008 by Infinity Interactive, Inc.
 158
 159 L<http://www.iinteractive.com>
 160
 161 This library is free software; you can redistribute it and/or modify
 162 it under the same terms as Perl itself.
 163
 164 =cut
 165