missed one bit
[gitmo/Class-MOP.git] / lib / Class / MOP / Method / Constructor.pm
1
2 package Class::MOP::Method::Constructor;
3
4 use strict;
5 use warnings;
6
7 use Carp         'confess';
8 use Scalar::Util 'blessed', 'weaken', 'looks_like_number';
9
10 our $VERSION   = '0.02';
11 our $AUTHORITY = 'cpan:STEVAN';
12
13 use base 'Class::MOP::Method::Generated';
14
15 sub new {
16     my $class   = shift;
17     my %options = @_;
18         
19     (blessed $options{metaclass} && $options{metaclass}->isa('Class::MOP::Class'))
20         || confess "You must pass a metaclass instance if you want to inline"
21             if $options{is_inline}; 
22     
23     my $self = bless {
24         # from our superclass
25         '&!body'          => undef,
26         # specific to this subclass
27         '%!options'              => $options{options} || {},
28         '$!associated_metaclass' => $options{metaclass},
29         '$!is_inline'            => ($options{is_inline} || 0),        
30     } => $class;
31
32     # we don't want this creating 
33     # a cycle in the code, if not 
34     # needed
35     weaken($self->{'$!associated_metaclass'});    
36
37     $self->initialize_body;
38
39     return $self;    
40 }
41
42 ## accessors 
43
44 sub options              { (shift)->{'%!options'}              }
45 sub associated_metaclass { (shift)->{'$!associated_metaclass'} }
46
47 ## cached values ...
48
49 sub meta_instance { 
50     my $self = shift;
51     $self->{'$!meta_instance'} ||= $self->associated_metaclass->get_meta_instance;
52 }
53
54 sub attributes { 
55     my $self = shift;
56     $self->{'@!attributes'} ||= [ $self->associated_metaclass->compute_all_applicable_attributes ]
57 }
58
59 ## method
60
61 sub initialize_body {
62     my $self        = shift;
63     my $method_name = 'generate_constructor_method';
64     
65     $method_name .= '_inline' if $self->is_inline;
66     
67     $self->{'&!body'} = $self->$method_name;
68 }
69
70 sub generate_constructor_method {
71     return sub { (shift)->meta->new_object(@_) }
72 }
73
74 sub generate_constructor_method_inline {
75     my $self = shift;
76
77     my $source = 'sub {';
78     $source .= "\n" . 'my ($class, %params) = @_;';
79     
80     $source .= "\n" . 'return $class->meta->new_object(%params)';
81     $source .= "\n" . '    if $class ne \'' . $self->associated_metaclass->name . '\';';    
82     
83     $source .= "\n" . 'my $instance = ' . $self->meta_instance->inline_create_instance('$class');
84     $source .= ";\n" . (join ";\n" => map { 
85         $self->_generate_slot_initializer($_) 
86     } 0 .. (@{$self->attributes} - 1));
87     $source .= ";\n" . 'return $instance';
88     $source .= ";\n" . '}'; 
89     warn $source if $self->options->{debug};   
90     
91     my $code;
92     {
93         # NOTE:
94         # create the nessecary lexicals
95         # to be picked up in the eval 
96         my $attrs = $self->attributes;
97         
98         $code = eval $source;
99         confess "Could not eval the constructor :\n\n$source\n\nbecause :\n\n$@" if $@;
100     }
101     return $code;
102 }
103
104 sub _generate_slot_initializer {
105     my $self  = shift;
106     my $index = shift;
107     
108     my $attr = $self->attributes->[$index];
109     
110     my $default;
111     if ($attr->has_default) {
112         # NOTE:
113         # default values can either be CODE refs
114         # in which case we need to call them. Or 
115         # they can be scalars (strings/numbers)
116         # in which case we can just deal with them
117         # in the code we eval.
118         if ($attr->is_default_a_coderef) {
119             $default = '$attrs->[' . $index . ']->default($instance)';
120         }
121         else {
122             $default = $attr->default;
123             # make sure to quote strings ...
124             unless (looks_like_number($default)) {
125                 $default = "'$default'";
126             }
127         }
128     }
129     $self->meta_instance->inline_set_slot_value(
130         '$instance', 
131         ("'" . $attr->name . "'"), 
132         ('$params{\'' . $attr->init_arg . '\'}' . (defined $default ? (' || ' . $default) : ''))
133     );   
134 }
135
136 1;
137
138 1;
139
140 __END__
141
142 =pod
143
144 =head1 NAME 
145
146 Class::MOP::Method::Constructor - Method Meta Object for constructors
147
148 =head1 SYNOPSIS
149
150   use Class::MOP::Method::Constructor;
151   
152   my $constructor = Class::MOP::Method::Constructor->new(
153       metaclass => $metaclass,       
154       options   => {
155           debug => 1, # this is all for now
156       },                        
157   );
158   
159   # calling the constructor ...
160   $constructor->body->($metaclass->name, %params);
161   
162 =head1 DESCRIPTION
163
164 This is a subclass of C<Class::MOP::Method> which deals with 
165 class constructors.  
166
167 =head1 METHODS
168
169 =over 4
170
171 =item B<new (metaclass => $meta, options => \%options)>
172
173 =item B<options>
174
175 This returns the options HASH which is passed into C<new>.
176
177 =item B<associated_metaclass>
178
179 This returns the metaclass which is passed into C<new>.
180
181 =item B<attributes>
182
183 This returns the list of attributes which are associated with the 
184 metaclass which is passed into C<new>.
185
186 =item B<meta_instance>
187
188 This returns the meta instance which is associated with the 
189 metaclass which is passed into C<new>.
190
191 =item B<is_inline>
192
193 This returns a boolean, but since constructors are very rarely 
194 not inlined, this always returns true for now.
195
196 =item B<initialize_body>
197
198 This creates the code reference for the constructor itself. 
199
200 =back
201
202 =head2 Method Generators
203
204 =over 4
205
206 =item B<generate_constructor_method>
207
208 =item B<generate_constructor_method_inline>
209
210 =back
211
212 =head1 AUTHORS
213
214 Stevan Little E<lt>stevan@iinteractive.comE<gt>
215
216 =head1 COPYRIGHT AND LICENSE
217
218 Copyright 2006, 2007 by Infinity Interactive, Inc.
219
220 L<http://www.iinteractive.com>
221
222 This library is free software; you can redistribute it and/or modify
223 it under the same terms as Perl itself. 
224
225 =cut
226