lib/Class/MOP/Method/Constructor.pm

   1
   2 package Class::MOP::Method::Constructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed', 'weaken', 'looks_like_number';
   9
  10 our $VERSION   = '0.92';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use base 'Class::MOP::Method::Inlined';
  15
  16 sub new {
  17     my $class   = shift;
  18     my %options = @_;
  19
  20     (blessed $options{metaclass} && $options{metaclass}->isa('Class::MOP::Class'))
  21         || confess "You must pass a metaclass instance if you want to inline"
  22             if $options{is_inline};
  23
  24     ($options{package_name} && $options{name})
  25         || confess "You must supply the package_name and name parameters $Class::MOP::Method::UPGRADE_ERROR_TEXT";
  26
  27     my $self = $class->_new(\%options);
  28
  29     # we don't want this creating
  30     # a cycle in the code, if not
  31     # needed
  32     weaken($self->{'associated_metaclass'});
  33
  34     $self->_initialize_body;
  35
  36     return $self;
  37 }
  38
  39 sub _new {
  40     my $class = shift;
  41
  42     return Class::MOP::Class->initialize($class)->new_object(@_)
  43         if $class ne __PACKAGE__;
  44
  45     my $params = @_ == 1 ? $_[0] : {@_};
  46
  47     return bless {
  48         # inherited from Class::MOP::Method
  49         body                 => $params->{body},
  50         # associated_metaclass => $params->{associated_metaclass}, # overriden
  51         package_name         => $params->{package_name},
  52         name                 => $params->{name},
  53         original_method      => $params->{original_method},
  54
  55         # inherited from Class::MOP::Generated
  56         is_inline            => $params->{is_inline} || 0,
  57         definition_context   => $params->{definition_context},
  58
  59         # inherited from Class::MOP::Inlined
  60         _expected_method_class => $params->{_expected_method_class},
  61
  62         # defined in this subclass
  63         options              => $params->{options} || {},
  64         associated_metaclass => $params->{metaclass},
  65     }, $class;
  66 }
  67
  68 ## cached values ...
  69
  70 sub meta_instance {
  71     Carp::cluck('The meta_instance method has been made private.'
  72         . " The public version is deprecated and will be removed in a future release.\n");
  73     shift->_meta_instance;
  74 }
  75
  76 sub _meta_instance {
  77     my $self = shift;
  78     $self->{'meta_instance'} ||= $self->associated_metaclass->get_meta_instance;
  79 }
  80
  81 sub attributes {
  82     Carp::cluck('The attributes method has been made private.'
  83         . " The public version is deprecated and will be removed in a future release.\n");
  84
  85     return shift->_attributes;
  86 }
  87
  88 sub _attributes {
  89     my $self = shift;
  90     $self->{'attributes'} ||= [ $self->associated_metaclass->get_all_attributes ]
  91 }
  92
  93 ## method
  94
  95 sub initialize_body {
  96     Carp::cluck('The initialize_body method has been made private.'
  97         . " The public version is deprecated and will be removed in a future release.\n");
  98     shift->_initialize_body;
  99 }
 100
 101 sub _initialize_body {
 102     my $self        = shift;
 103     my $method_name = '_generate_constructor_method';
 104
 105     $method_name .= '_inline' if $self->is_inline;
 106
 107     $self->{'body'} = $self->$method_name;
 108 }
 109
 110 sub generate_constructor_method {
 111     Carp::cluck('The generate_constructor_method method has been made private.'
 112         . " The public version is deprecated and will be removed in a future release.\n");
 113     shift->_generate_constructor_method;
 114 }
 115
 116 sub _generate_constructor_method {
 117     return sub { Class::MOP::Class->initialize(shift)->new_object(@_) }
 118 }
 119
 120 sub generate_constructor_method_inline {
 121     Carp::cluck('The generate_constructor_method_inline method has been made private.'
 122         . " The public version is deprecated and will be removed in a future release.\n");
 123     shift->_generate_constructor_method_inline;
 124 }
 125
 126 sub _generate_constructor_method_inline {
 127     my $self = shift;
 128
 129     my $close_over = {};
 130
 131     my $source = 'sub {';
 132     $source .= "\n" . 'my $class = shift;';
 133
 134     $source .= "\n" . 'return Class::MOP::Class->initialize($class)->new_object(@_)';
 135     $source .= "\n" . '    if $class ne \'' . $self->associated_metaclass->name . '\';';
 136
 137     $source .= "\n" . 'my $params = @_ == 1 ? $_[0] : {@_};';
 138
 139     $source .= "\n" . 'my $instance = ' . $self->_meta_instance->inline_create_instance('$class');
 140     $source .= ";\n" . (join ";\n" => map {
 141         $self->_generate_slot_initializer($_, $close_over)
 142     } @{ $self->_attributes });
 143     $source .= ";\n" . 'return $instance';
 144     $source .= ";\n" . '}';
 145     warn $source if $self->options->{debug};
 146
 147     my ( $code, $e ) = $self->_eval_closure(
 148         $close_over,
 149         $source
 150     );
 151     confess "Could not eval the constructor :\n\n$source\n\nbecause :\n\n$e" if $e;
 152
 153     return $code;
 154 }
 155
 156 sub _generate_slot_initializer {
 157     my $self  = shift;
 158     my $attr  = shift;
 159     my $close = shift;
 160
 161     my $default;
 162     if ($attr->has_default) {
 163         # NOTE:
 164         # default values can either be CODE refs
 165         # in which case we need to call them. Or
 166         # they can be scalars (strings/numbers)
 167         # in which case we can just deal with them
 168         # in the code we eval.
 169         if ($attr->is_default_a_coderef) {
 170             my $idx = @{$close->{'@defaults'}||=[]};
 171             push(@{$close->{'@defaults'}}, $attr->default);
 172             $default = '$defaults[' . $idx . ']->($instance)';
 173         }
 174         else {
 175             $default = $attr->default;
 176             # make sure to quote strings ...
 177             unless (looks_like_number($default)) {
 178                 $default = "'$default'";
 179             }
 180         }
 181     } elsif( $attr->has_builder ) {
 182         $default = '$instance->'.$attr->builder;
 183     }
 184
 185     if ( defined(my $init_arg = $attr->init_arg) ) {
 186       return (
 187           'if(exists $params->{\'' . $init_arg . '\'}){' . "\n" .
 188                 $self->_meta_instance->inline_set_slot_value(
 189                     '$instance',
 190                     $attr->name,
 191                     '$params->{\'' . $init_arg . '\'}' ) . "\n" .
 192            '} ' . (!defined $default ? '' : 'else {' . "\n" .
 193                 $self->_meta_instance->inline_set_slot_value(
 194                     '$instance',
 195                     $attr->name,
 196                      $default ) . "\n" .
 197            '}')
 198         );
 199     } elsif ( defined $default ) {
 200         return (
 201             $self->_meta_instance->inline_set_slot_value(
 202                 '$instance',
 203                 $attr->name,
 204                  $default ) . "\n"
 205         );
 206     } else { return '' }
 207 }
 208
 209 1;
 210
 211 __END__
 212
 213 =pod
 214
 215 =head1 NAME
 216
 217 Class::MOP::Method::Constructor - Method Meta Object for constructors
 218
 219 =head1 SYNOPSIS
 220
 221   use Class::MOP::Method::Constructor;
 222
 223   my $constructor = Class::MOP::Method::Constructor->new(
 224       metaclass => $metaclass,
 225       options   => {
 226           debug => 1, # this is all for now
 227       },
 228   );
 229
 230   # calling the constructor ...
 231   $constructor->body->execute($metaclass->name, %params);
 232
 233 =head1 DESCRIPTION
 234
 235 This is a subclass of C<Class::MOP::Method> which generates
 236 constructor methods.
 237
 238 =head1 METHODS
 239
 240 =over 4
 241
 242 =item B<< Class::MOP::Method::Constructor->new(%options) >>
 243
 244 This creates a new constructor object. It accepts a hash reference of
 245 options.
 246
 247 =over 8
 248
 249 =item * metaclass
 250
 251 This should be a L<Class::MOP::Class> object. It is required.
 252
 253 =item * name
 254
 255 The method name (without a package name). This is required.
 256
 257 =item * package_name
 258
 259 The package name for the method. This is required.
 260
 261 =item * is_inline
 262
 263 This indicates whether or not the constructor should be inlined. This
 264 defaults to false.
 265
 266 =back
 267
 268 =item B<< $metamethod->is_inline >>
 269
 270 Returns a boolean indicating whether or not the constructor is
 271 inlined.
 272
 273 =item B<< $metamethod->associated_metaclass >>
 274
 275 This returns the L<Class::MOP::Class> object for the method.
 276
 277 =back
 278
 279 =head1 AUTHORS
 280
 281 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 282
 283 =head1 COPYRIGHT AND LICENSE
 284
 285 Copyright 2006-2009 by Infinity Interactive, Inc.
 286
 287 L<http://www.iinteractive.com>
 288
 289 This library is free software; you can redistribute it and/or modify
 290 it under the same terms as Perl itself.
 291
 292 =cut
 293