lib/Class/MOP/Method/Constructor.pm

   1
   2 package Class::MOP::Method::Constructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed', 'weaken';
   9
  10 our $VERSION   = '1.04';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use base 'Class::MOP::Method::Inlined';
  15
  16 sub new {
  17     my $class   = shift;
  18     my %options = @_;
  19
  20     (blessed $options{metaclass} && $options{metaclass}->isa('Class::MOP::Class'))
  21         || confess "You must pass a metaclass instance if you want to inline"
  22             if $options{is_inline};
  23
  24     ($options{package_name} && $options{name})
  25         || confess "You must supply the package_name and name parameters $Class::MOP::Method::UPGRADE_ERROR_TEXT";
  26
  27     my $self = $class->_new(\%options);
  28
  29     # we don't want this creating
  30     # a cycle in the code, if not
  31     # needed
  32     weaken($self->{'associated_metaclass'});
  33
  34     $self->_initialize_body;
  35
  36     return $self;
  37 }
  38
  39 sub _new {
  40     my $class = shift;
  41
  42     return Class::MOP::Class->initialize($class)->new_object(@_)
  43         if $class ne __PACKAGE__;
  44
  45     my $params = @_ == 1 ? $_[0] : {@_};
  46
  47     return bless {
  48         # inherited from Class::MOP::Method
  49         body                 => $params->{body},
  50         # associated_metaclass => $params->{associated_metaclass}, # overriden
  51         package_name         => $params->{package_name},
  52         name                 => $params->{name},
  53         original_method      => $params->{original_method},
  54
  55         # inherited from Class::MOP::Generated
  56         is_inline            => $params->{is_inline} || 0,
  57         definition_context   => $params->{definition_context},
  58
  59         # inherited from Class::MOP::Inlined
  60         _expected_method_class => $params->{_expected_method_class},
  61
  62         # defined in this subclass
  63         options              => $params->{options} || {},
  64         associated_metaclass => $params->{metaclass},
  65     }, $class;
  66 }
  67
  68 ## accessors
  69
  70 sub options              { (shift)->{'options'}              }
  71 sub associated_metaclass { (shift)->{'associated_metaclass'} }
  72
  73 ## cached values ...
  74
  75 sub _meta_instance {
  76     my $self = shift;
  77     $self->{'meta_instance'} ||= $self->associated_metaclass->get_meta_instance;
  78 }
  79
  80 sub _attributes {
  81     my $self = shift;
  82     $self->{'attributes'} ||= [ $self->associated_metaclass->get_all_attributes ]
  83 }
  84
  85 ## method
  86
  87 sub _initialize_body {
  88     my $self        = shift;
  89     my $method_name = '_generate_constructor_method';
  90
  91     $method_name .= '_inline' if $self->is_inline;
  92
  93     $self->{'body'} = $self->$method_name;
  94 }
  95
  96 sub _generate_constructor_method {
  97     return sub { Class::MOP::Class->initialize(shift)->new_object(@_) }
  98 }
  99
 100 sub _generate_constructor_method_inline {
 101     my $self = shift;
 102
 103     my $defaults = [map { $_->default } @{ $self->_attributes }];
 104
 105     my $close_over = {
 106         '$defaults' => \$defaults,
 107     };
 108
 109     my $source = 'sub {';
 110     $source .= "\n" . 'my $class = shift;';
 111
 112     $source .= "\n" . 'return Class::MOP::Class->initialize($class)->new_object(@_)';
 113     $source .= "\n" . '    if $class ne \'' . $self->associated_metaclass->name . '\';';
 114
 115     $source .= "\n" . 'my $params = @_ == 1 ? $_[0] : {@_};';
 116
 117     $source .= "\n" . 'my $instance = ' . $self->_meta_instance->inline_create_instance('$class');
 118     my $idx = 0;
 119     $source .= ";\n" . (join ";\n" => map {
 120         $self->_generate_slot_initializer($_, $idx++)
 121     } @{ $self->_attributes });
 122     $source .= ";\n" . 'return $instance';
 123     $source .= ";\n" . '}';
 124     warn $source if $self->options->{debug};
 125
 126     my ( $code, $e ) = $self->_eval_closure(
 127         $close_over,
 128         $source
 129     );
 130     confess "Could not eval the constructor :\n\n$source\n\nbecause :\n\n$e" if $e;
 131
 132     return $code;
 133 }
 134
 135 sub _generate_slot_initializer {
 136     my $self  = shift;
 137     my $attr  = shift;
 138     my $idx   = shift;
 139
 140     my $default;
 141     if ($attr->has_default) {
 142         $default = $self->_generate_default_value($attr, $idx);
 143     } elsif( $attr->has_builder ) {
 144         $default = '$instance->'.$attr->builder;
 145     }
 146
 147     if ( defined( my $init_arg = $attr->init_arg ) ) {
 148         return (
 149                   'if(exists $params->{\''
 150                 . $init_arg . '\'}){' . "\n"
 151                 . $self->_meta_instance->inline_set_slot_value(
 152                 '$instance',
 153                 $attr->name,
 154                 '$params->{\'' . $init_arg . '\'}'
 155                 )
 156                 . "\n" . '} '
 157                 . (
 158                 !defined $default ? '' : 'else {' . "\n"
 159                     . $self->_meta_instance->inline_set_slot_value(
 160                     '$instance',
 161                     $attr->name,
 162                     $default
 163                     )
 164                     . "\n" . '}'
 165                 )
 166         );
 167     }
 168     elsif ( defined $default ) {
 169         return (
 170             $self->_meta_instance->inline_set_slot_value(
 171                 '$instance',
 172                 $attr->name,
 173                 $default
 174                 )
 175                 . "\n"
 176         );
 177     }
 178     else {
 179         return '';
 180     }
 181 }
 182
 183 sub _generate_default_value {
 184     my ($self, $attr, $index) = @_;
 185     # NOTE:
 186     # default values can either be CODE refs
 187     # in which case we need to call them. Or
 188     # they can be scalars (strings/numbers)
 189     # in which case we can just deal with them
 190     # in the code we eval.
 191     if ($attr->is_default_a_coderef) {
 192         return '$defaults->[' . $index . ']->($instance)';
 193     }
 194     else {
 195         return '$defaults->[' . $index . ']';
 196     }
 197 }
 198
 199 1;
 200
 201 __END__
 202
 203 =pod
 204
 205 =head1 NAME
 206
 207 Class::MOP::Method::Constructor - Method Meta Object for constructors
 208
 209 =head1 SYNOPSIS
 210
 211   use Class::MOP::Method::Constructor;
 212
 213   my $constructor = Class::MOP::Method::Constructor->new(
 214       metaclass => $metaclass,
 215       options   => {
 216           debug => 1, # this is all for now
 217       },
 218   );
 219
 220   # calling the constructor ...
 221   $constructor->body->execute($metaclass->name, %params);
 222
 223 =head1 DESCRIPTION
 224
 225 This is a subclass of C<Class::MOP::Method> which generates
 226 constructor methods.
 227
 228 =head1 METHODS
 229
 230 =over 4
 231
 232 =item B<< Class::MOP::Method::Constructor->new(%options) >>
 233
 234 This creates a new constructor object. It accepts a hash reference of
 235 options.
 236
 237 =over 8
 238
 239 =item * metaclass
 240
 241 This should be a L<Class::MOP::Class> object. It is required.
 242
 243 =item * name
 244
 245 The method name (without a package name). This is required.
 246
 247 =item * package_name
 248
 249 The package name for the method. This is required.
 250
 251 =item * is_inline
 252
 253 This indicates whether or not the constructor should be inlined. This
 254 defaults to false.
 255
 256 =back
 257
 258 =item B<< $metamethod->is_inline >>
 259
 260 Returns a boolean indicating whether or not the constructor is
 261 inlined.
 262
 263 =item B<< $metamethod->associated_metaclass >>
 264
 265 This returns the L<Class::MOP::Class> object for the method.
 266
 267 =back
 268
 269 =head1 AUTHORS
 270
 271 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 272
 273 =head1 COPYRIGHT AND LICENSE
 274
 275 Copyright 2006-2010 by Infinity Interactive, Inc.
 276
 277 L<http://www.iinteractive.com>
 278
 279 This library is free software; you can redistribute it and/or modify
 280 it under the same terms as Perl itself.
 281
 282 =cut
 283