lib/Class/MOP/Class.pm

   1
   2 package Class::MOP::Class;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed', 'reftype';
   9 use Sub::Name    'subname';
  10 use B            'svref_2object';
  11 use Clone         ();
  12
  13 our $VERSION = '0.04';
  14
  15 # Self-introspection
  16
  17 sub meta { Class::MOP::Class->initialize(blessed($_[0]) || $_[0]) }
  18
  19 # Creation
  20
  21 {
  22     # Metaclasses are singletons, so we cache them here.
  23     # there is no need to worry about destruction though
  24     # because they should die only when the program dies.
  25     # After all, do package definitions even get reaped?
  26     my %METAS;
  27
  28     sub initialize {
  29         my $class        = shift;
  30         my $package_name = shift;
  31         (defined $package_name && $package_name)
  32             || confess "You must pass a package name";
  33         # make sure the package name is not blessed
  34         $package_name = blessed($package_name) || $package_name;
  35         $class->construct_class_instance(':package' => $package_name, @_);
  36     }
  37
  38     # NOTE: (meta-circularity)
  39     # this is a special form of &construct_instance
  40     # (see below), which is used to construct class
  41     # meta-object instances for any Class::MOP::*
  42     # class. All other classes will use the more
  43     # normal &construct_instance.
  44     sub construct_class_instance {
  45         my $class        = shift;
  46         my %options      = @_;
  47         my $package_name = $options{':package'};
  48         (defined $package_name && $package_name)
  49             || confess "You must pass a package name";
  50         return $METAS{$package_name} if exists $METAS{$package_name};
  51         $class = blessed($class) || $class;
  52         # now create the metaclass
  53         my $meta;
  54         if ($class =~ /^Class::MOP::/) {
  55             $meta = bless {
  56                 '$:package'             => $package_name,
  57                 '%:attributes'          => {},
  58                 '$:attribute_metaclass' => $options{':attribute_metaclass'} || 'Class::MOP::Attribute',
  59                 '$:method_metaclass'    => $options{':method_metaclass'}    || 'Class::MOP::Method',
  60             } => $class;
  61         }
  62         else {
  63             # NOTE:
  64             # it is safe to use meta here because
  65             # class will always be a subclass of
  66             # Class::MOP::Class, which defines meta
  67             $meta = bless $class->meta->construct_instance(%options) => $class
  68         }
  69         # and check the metaclass compatibility
  70         $meta->check_metaclass_compatability();
  71         $METAS{$package_name} = $meta;
  72     }
  73
  74     sub check_metaclass_compatability {
  75         my $self = shift;
  76
  77         # this is always okay ...
  78         return if blessed($self) eq 'Class::MOP::Class';
  79
  80         my @class_list = $self->class_precedence_list;
  81         shift @class_list; # shift off $self->name
  82
  83         foreach my $class_name (@class_list) {
  84             my $meta = $METAS{$class_name};
  85             ($self->isa(blessed($meta)))
  86                 || confess $self->name . "->meta => (" . (blessed($self)) . ")" .
  87                            " is not compatible with the " .
  88                            $class_name . "->meta => (" . (blessed($meta)) . ")";
  89         }
  90     }
  91 }
  92
  93 sub create {
  94     my ($class, $package_name, $package_version, %options) = @_;
  95     (defined $package_name && $package_name)
  96         || confess "You must pass a package name";
  97     my $code = "package $package_name;";
  98     $code .= "\$$package_name\:\:VERSION = '$package_version';"
  99         if defined $package_version;
 100     eval $code;
 101     confess "creation of $package_name failed : $@" if $@;
 102     my $meta = $class->initialize($package_name);
 103
 104     $meta->add_method('meta' => sub {
 105         Class::MOP::Class->initialize(blessed($_[0]) || $_[0]);
 106     });
 107
 108     $meta->superclasses(@{$options{superclasses}})
 109         if exists $options{superclasses};
 110     # NOTE:
 111     # process attributes first, so that they can
 112     # install accessors, but locally defined methods
 113     # can then overwrite them. It is maybe a little odd, but
 114     # I think this should be the order of things.
 115     if (exists $options{attributes}) {
 116         foreach my $attr (@{$options{attributes}}) {
 117             $meta->add_attribute($attr);
 118         }
 119     }
 120     if (exists $options{methods}) {
 121         foreach my $method_name (keys %{$options{methods}}) {
 122             $meta->add_method($method_name, $options{methods}->{$method_name});
 123         }
 124     }
 125     return $meta;
 126 }
 127
 128 ## Attribute readers
 129
 130 # NOTE:
 131 # all these attribute readers will be bootstrapped
 132 # away in the Class::MOP bootstrap section
 133
 134 sub name                { $_[0]->{'$:package'}             }
 135 sub get_attribute_map   { $_[0]->{'%:attributes'}          }
 136 sub attribute_metaclass { $_[0]->{'$:attribute_metaclass'} }
 137 sub method_metaclass    { $_[0]->{'$:method_metaclass'}    }
 138
 139 # Instance Construction & Cloning
 140
 141 sub new_object {
 142     my $class = shift;
 143     # NOTE:
 144     # we need to protect the integrity of the
 145     # Class::MOP::Class singletons here, so we
 146     # delegate this to &construct_class_instance
 147     # which will deal with the singletons
 148     return $class->construct_class_instance(@_)
 149         if $class->name->isa('Class::MOP::Class');
 150     bless $class->construct_instance(@_) => $class->name;
 151 }
 152
 153 sub construct_instance {
 154     my ($class, %params) = @_;
 155     my $instance = {};
 156     foreach my $attr ($class->compute_all_applicable_attributes()) {
 157         my $init_arg = $attr->init_arg();
 158         # try to fetch the init arg from the %params ...
 159         my $val;
 160         $val = $params{$init_arg} if exists $params{$init_arg};
 161         # if nothing was in the %params, we can use the
 162         # attribute's default value (if it has one)
 163         $val ||= $attr->default($instance) if $attr->has_default();
 164         $instance->{$attr->name} = $val;
 165     }
 166     return $instance;
 167 }
 168
 169 sub clone_object {
 170     my $class    = shift;
 171     my $instance = shift;
 172     (blessed($instance) && $instance->isa($class->name))
 173         || confess "You must pass an instance ($instance) of the metaclass (" . $class->name . ")";
 174     # NOTE:
 175     # we need to protect the integrity of the
 176     # Class::MOP::Class singletons here, they
 177     # should not be cloned.
 178     return $instance if $instance->isa('Class::MOP::Class');
 179     bless $class->clone_instance($instance, @_) => blessed($instance);
 180 }
 181
 182 sub clone_instance {
 183     my ($class, $instance, %params) = @_;
 184     (blessed($instance))
 185         || confess "You can only clone instances, \$self is not a blessed instance";
 186     # NOTE:
 187     # This will deep clone, which might
 188     # not be what you always want. So
 189     # the best thing is to write a more
 190     # controled &clone method locally
 191     # in the class (see Class::MOP)
 192     my $clone = Clone::clone($instance);
 193     foreach my $attr ($class->compute_all_applicable_attributes()) {
 194         my $init_arg = $attr->init_arg();
 195         # try to fetch the init arg from the %params ...
 196         $clone->{$attr->name} = $params{$init_arg}
 197             if exists $params{$init_arg};
 198     }
 199     return $clone;
 200 }
 201
 202 # Informational
 203
 204 # &name should be here too, but it is above
 205 # because it gets bootstrapped away
 206
 207 sub version {
 208     my $self = shift;
 209     no strict 'refs';
 210     ${$self->name . '::VERSION'};
 211 }
 212
 213 # Inheritance
 214
 215 sub superclasses {
 216     my $self = shift;
 217     no strict 'refs';
 218     if (@_) {
 219         my @supers = @_;
 220         @{$self->name . '::ISA'} = @supers;
 221     }
 222     @{$self->name . '::ISA'};
 223 }
 224
 225 sub class_precedence_list {
 226     my $self = shift;
 227     # NOTE:
 228     # We need to check for ciruclar inheirtance here.
 229     # This will do nothing if all is well, and blow
 230     # up otherwise. Yes, it's an ugly hack, better
 231     # suggestions are welcome.
 232     { $self->name->isa('This is a test for circular inheritance') }
 233     # ... and no back to our regularly scheduled program
 234     (
 235         $self->name,
 236         map {
 237             $self->initialize($_)->class_precedence_list()
 238         } $self->superclasses()
 239     );
 240 }
 241
 242 ## Methods
 243
 244 sub add_method {
 245     my ($self, $method_name, $method) = @_;
 246     (defined $method_name && $method_name)
 247         || confess "You must define a method name";
 248     # use reftype here to allow for blessed subs ...
 249     (reftype($method) && reftype($method) eq 'CODE')
 250         || confess "Your code block must be a CODE reference";
 251     my $full_method_name = ($self->name . '::' . $method_name);
 252
 253     no strict 'refs';
 254     no warnings 'redefine';
 255     *{$full_method_name} = subname $full_method_name => $method;
 256 }
 257
 258 sub alias_method {
 259     my ($self, $method_name, $method) = @_;
 260     (defined $method_name && $method_name)
 261         || confess "You must define a method name";
 262     # use reftype here to allow for blessed subs ...
 263     (reftype($method) && reftype($method) eq 'CODE')
 264         || confess "Your code block must be a CODE reference";
 265     my $full_method_name = ($self->name . '::' . $method_name);
 266
 267     no strict 'refs';
 268     no warnings 'redefine';
 269     *{$full_method_name} = $method;
 270 }
 271
 272 {
 273
 274     ## private utility functions for has_method
 275     my $_find_subroutine_package_name = sub { eval { svref_2object($_[0])->GV->STASH->NAME } || '' };
 276     my $_find_subroutine_name         = sub { eval { svref_2object($_[0])->GV->NAME        } || '' };
 277
 278     sub has_method {
 279         my ($self, $method_name) = @_;
 280         (defined $method_name && $method_name)
 281             || confess "You must define a method name";
 282
 283         my $sub_name = ($self->name . '::' . $method_name);
 284
 285         no strict 'refs';
 286         return 0 if !defined(&{$sub_name});
 287         return 0 if $_find_subroutine_package_name->(\&{$sub_name}) ne $self->name &&
 288                     $_find_subroutine_name->(\&{$sub_name})         ne '__ANON__';
 289         return 1;
 290     }
 291
 292 }
 293
 294 sub get_method {
 295     my ($self, $method_name) = @_;
 296     (defined $method_name && $method_name)
 297         || confess "You must define a method name";
 298
 299     no strict 'refs';
 300     return \&{$self->name . '::' . $method_name}
 301         if $self->has_method($method_name);
 302     return; # <- make sure to return undef
 303 }
 304
 305 sub remove_method {
 306     my ($self, $method_name) = @_;
 307     (defined $method_name && $method_name)
 308         || confess "You must define a method name";
 309
 310     my $removed_method = $self->get_method($method_name);
 311
 312     no strict 'refs';
 313     delete ${$self->name . '::'}{$method_name}
 314         if defined $removed_method;
 315
 316     return $removed_method;
 317 }
 318
 319 sub get_method_list {
 320     my $self = shift;
 321     no strict 'refs';
 322     grep { $self->has_method($_) } %{$self->name . '::'};
 323 }
 324
 325 sub compute_all_applicable_methods {
 326     my $self = shift;
 327     my @methods;
 328     # keep a record of what we have seen
 329     # here, this will handle all the
 330     # inheritence issues because we are
 331     # using the &class_precedence_list
 332     my (%seen_class, %seen_method);
 333     foreach my $class ($self->class_precedence_list()) {
 334         next if $seen_class{$class};
 335         $seen_class{$class}++;
 336         # fetch the meta-class ...
 337         my $meta = $self->initialize($class);
 338         foreach my $method_name ($meta->get_method_list()) {
 339             next if exists $seen_method{$method_name};
 340             $seen_method{$method_name}++;
 341             push @methods => {
 342                 name  => $method_name,
 343                 class => $class,
 344                 code  => $meta->get_method($method_name)
 345             };
 346         }
 347     }
 348     return @methods;
 349 }
 350
 351 sub find_all_methods_by_name {
 352     my ($self, $method_name) = @_;
 353     (defined $method_name && $method_name)
 354         || confess "You must define a method name to find";
 355     my @methods;
 356     # keep a record of what we have seen
 357     # here, this will handle all the
 358     # inheritence issues because we are
 359     # using the &class_precedence_list
 360     my %seen_class;
 361     foreach my $class ($self->class_precedence_list()) {
 362         next if $seen_class{$class};
 363         $seen_class{$class}++;
 364         # fetch the meta-class ...
 365         my $meta = $self->initialize($class);;
 366         push @methods => {
 367             name  => $method_name,
 368             class => $class,
 369             code  => $meta->get_method($method_name)
 370         } if $meta->has_method($method_name);
 371     }
 372     return @methods;
 373
 374 }
 375
 376 ## Attributes
 377
 378 sub add_attribute {
 379     my $self      = shift;
 380     # either we have an attribute object already
 381     # or we need to create one from the args provided
 382     my $attribute = blessed($_[0]) ? $_[0] : $self->attribute_metaclass->new(@_);
 383     # make sure it is derived from the correct type though
 384     ($attribute->isa('Class::MOP::Attribute'))
 385         || confess "Your attribute must be an instance of Class::MOP::Attribute (or a subclass)";
 386     $attribute->attach_to_class($self);
 387     $attribute->install_accessors();
 388     $self->get_attribute_map->{$attribute->name} = $attribute;
 389 }
 390
 391 sub has_attribute {
 392     my ($self, $attribute_name) = @_;
 393     (defined $attribute_name && $attribute_name)
 394         || confess "You must define an attribute name";
 395     exists $self->get_attribute_map->{$attribute_name} ? 1 : 0;
 396 }
 397
 398 sub get_attribute {
 399     my ($self, $attribute_name) = @_;
 400     (defined $attribute_name && $attribute_name)
 401         || confess "You must define an attribute name";
 402     return $self->get_attribute_map->{$attribute_name}
 403         if $self->has_attribute($attribute_name);
 404 }
 405
 406 sub remove_attribute {
 407     my ($self, $attribute_name) = @_;
 408     (defined $attribute_name && $attribute_name)
 409         || confess "You must define an attribute name";
 410     my $removed_attribute = $self->get_attribute_map->{$attribute_name};
 411     delete $self->get_attribute_map->{$attribute_name}
 412         if defined $removed_attribute;
 413     $removed_attribute->remove_accessors();
 414     $removed_attribute->detach_from_class();
 415     return $removed_attribute;
 416 }
 417
 418 sub get_attribute_list {
 419     my $self = shift;
 420     keys %{$self->get_attribute_map};
 421 }
 422
 423 sub compute_all_applicable_attributes {
 424     my $self = shift;
 425     my @attrs;
 426     # keep a record of what we have seen
 427     # here, this will handle all the
 428     # inheritence issues because we are
 429     # using the &class_precedence_list
 430     my (%seen_class, %seen_attr);
 431     foreach my $class ($self->class_precedence_list()) {
 432         next if $seen_class{$class};
 433         $seen_class{$class}++;
 434         # fetch the meta-class ...
 435         my $meta = $self->initialize($class);
 436         foreach my $attr_name ($meta->get_attribute_list()) {
 437             next if exists $seen_attr{$attr_name};
 438             $seen_attr{$attr_name}++;
 439             push @attrs => $meta->get_attribute($attr_name);
 440         }
 441     }
 442     return @attrs;
 443 }
 444
 445 # Class attributes
 446
 447 sub add_package_variable {
 448     my ($self, $variable, $initial_value) = @_;
 449     (defined $variable && $variable =~ /^[\$\@\%]/)
 450         || confess "variable name does not have a sigil";
 451
 452     my ($sigil, $name) = ($variable =~ /^(.)(.*)$/);
 453     if (defined $initial_value) {
 454         no strict 'refs';
 455         *{$self->name . '::' . $name} = $initial_value;
 456     }
 457     else {
 458         eval $sigil . $self->name . '::' . $name;
 459         confess "Could not create package variable ($variable) because : $@" if $@;
 460     }
 461 }
 462
 463 sub has_package_variable {
 464     my ($self, $variable) = @_;
 465     (defined $variable && $variable =~ /^[\$\@\%]/)
 466         || confess "variable name does not have a sigil";
 467     my ($sigil, $name) = ($variable =~ /^(.)(.*)$/);
 468     no strict 'refs';
 469     defined ${$self->name . '::'}{$name} ? 1 : 0;
 470 }
 471
 472 sub get_package_variable {
 473     my ($self, $variable) = @_;
 474     (defined $variable && $variable =~ /^[\$\@\%]/)
 475         || confess "variable name does not have a sigil";
 476     my ($sigil, $name) = ($variable =~ /^(.)(.*)$/);
 477     no strict 'refs';
 478     # try to fetch it first,.. see what happens
 479     eval '\\' . $sigil . $self->name . '::' . $name;
 480     confess "Could not get the package variable ($variable) because : $@" if $@;
 481     # if we didn't die, then we can return it
 482     # NOTE:
 483     # this is not ideal, better suggestions are welcome
 484     eval '\\' . $sigil . $self->name . '::' . $name;
 485 }
 486
 487 sub remove_package_variable {
 488     my ($self, $variable) = @_;
 489     (defined $variable && $variable =~ /^[\$\@\%]/)
 490         || confess "variable name does not have a sigil";
 491     my ($sigil, $name) = ($variable =~ /^(.)(.*)$/);
 492     no strict 'refs';
 493     delete ${$self->name . '::'}{$name};
 494 }
 495
 496 1;
 497
 498 __END__
 499
 500 =pod
 501
 502 =head1 NAME
 503
 504 Class::MOP::Class - Class Meta Object
 505
 506 =head1 SYNOPSIS
 507
 508   # use this for introspection ...
 509
 510   # add a method to Foo ...
 511   Foo->meta->add_method('bar' => sub { ... })
 512
 513   # get a list of all the classes searched
 514   # the method dispatcher in the correct order
 515   Foo->meta->class_precedence_list()
 516
 517   # remove a method from Foo
 518   Foo->meta->remove_method('bar');
 519
 520   # or use this to actually create classes ...
 521
 522   Class::MOP::Class->create('Bar' => '0.01' => (
 523       superclasses => [ 'Foo' ],
 524       attributes => [
 525           Class::MOP:::Attribute->new('$bar'),
 526           Class::MOP:::Attribute->new('$baz'),
 527       ],
 528       methods => {
 529           calculate_bar => sub { ... },
 530           construct_baz => sub { ... }
 531       }
 532   ));
 533
 534 =head1 DESCRIPTION
 535
 536 This is the largest and currently most complex part of the Perl 5
 537 meta-object protocol. It controls the introspection and
 538 manipulation of Perl 5 classes (and it can create them too). The
 539 best way to understand what this module can do, is to read the
 540 documentation for each of it's methods.
 541
 542 =head1 METHODS
 543
 544 =head2 Self Introspection
 545
 546 =over 4
 547
 548 =item B<meta>
 549
 550 This will return a B<Class::MOP::Class> instance which is related
 551 to this class. Thereby allowing B<Class::MOP::Class> to actually
 552 introspect itself.
 553
 554 As with B<Class::MOP::Attribute>, B<Class::MOP> will actually
 555 bootstrap this module by installing a number of attribute meta-objects
 556 into it's metaclass. This will allow this class to reap all the benifits
 557 of the MOP when subclassing it.
 558
 559 =back
 560
 561 =head2 Class construction
 562
 563 These methods will handle creating B<Class::MOP::Class> objects,
 564 which can be used to both create new classes, and analyze
 565 pre-existing classes.
 566
 567 This module will internally store references to all the instances
 568 you create with these methods, so that they do not need to be
 569 created any more than nessecary. Basically, they are singletons.
 570
 571 =over 4
 572
 573 =item B<create ($package_name, ?$package_version,
 574                 superclasses =E<gt> ?@superclasses,
 575                 methods      =E<gt> ?%methods,
 576                 attributes   =E<gt> ?%attributes)>
 577
 578 This returns a B<Class::MOP::Class> object, bringing the specified
 579 C<$package_name> into existence and adding any of the
 580 C<$package_version>, C<@superclasses>, C<%methods> and C<%attributes>
 581 to it.
 582
 583 =item B<initialize ($package_name)>
 584
 585 This initializes and returns returns a B<Class::MOP::Class> object
 586 for a given a C<$package_name>.
 587
 588 =item B<construct_class_instance (%options)>
 589
 590 This will construct an instance of B<Class::MOP::Class>, it is
 591 here so that we can actually "tie the knot" for B<Class::MOP::Class>
 592 to use C<construct_instance> once all the bootstrapping is done. This
 593 method is used internally by C<initialize> and should never be called
 594 from outside of that method really.
 595
 596 =item B<check_metaclass_compatability>
 597
 598 This method is called as the very last thing in the
 599 C<construct_class_instance> method. This will check that the
 600 metaclass you are creating is compatible with the metaclasses of all
 601 your ancestors. For more inforamtion about metaclass compatibility
 602 see the C<About Metaclass compatibility> section in L<Class::MOP>.
 603
 604 =back
 605
 606 =head2 Object instance construction and cloning
 607
 608 These methods are B<entirely optional>, it is up to you whether you want
 609 to use them or not.
 610
 611 =over 4
 612
 613 =item B<new_object (%params)>
 614
 615 This is a convience method for creating a new object of the class, and
 616 blessing it into the appropriate package as well. Ideally your class
 617 would call a C<new> this method like so:
 618
 619   sub MyClass::new {
 620       my ($class, %param) = @_;
 621       $class->meta->new_object(%params);
 622   }
 623
 624 Of course the ideal place for this would actually be in C<UNIVERSAL::>
 625 but that is considered bad style, so we do not do that.
 626
 627 =item B<construct_instance (%params)>
 628
 629 This method is used to construct an instace structure suitable for
 630 C<bless>-ing into your package of choice. It works in conjunction
 631 with the Attribute protocol to collect all applicable attributes.
 632
 633 This will construct and instance using a HASH ref as storage
 634 (currently only HASH references are supported). This will collect all
 635 the applicable attributes and layout out the fields in the HASH ref,
 636 it will then initialize them using either use the corresponding key
 637 in C<%params> or any default value or initializer found in the
 638 attribute meta-object.
 639
 640 =item B<clone_object ($instance, %params)>
 641
 642 This is a convience method for cloning an object instance, then
 643 blessing it into the appropriate package. Ideally your class
 644 would call a C<clone> this method like so:
 645
 646   sub MyClass::clone {
 647       my ($self, %param) = @_;
 648       $self->meta->clone_object($self, %params);
 649   }
 650
 651 Of course the ideal place for this would actually be in C<UNIVERSAL::>
 652 but that is considered bad style, so we do not do that.
 653
 654 =item B<clone_instance($instance, %params)>
 655
 656 This method is a compliment of C<construct_instance> (which means if
 657 you override C<construct_instance>, you need to override this one too).
 658
 659 This method will clone the C<$instance> structure created by the
 660 C<construct_instance> method, and apply any C<%params> passed to it
 661 to change the attribute values. The structure returned is (like with
 662 C<construct_instance>) an unC<bless>ed HASH reference, it is your
 663 responsibility to then bless this cloned structure into the right
 664 class.
 665
 666 =back
 667
 668 =head2 Informational
 669
 670 =over 4
 671
 672 =item B<name>
 673
 674 This is a read-only attribute which returns the package name for the
 675 given B<Class::MOP::Class> instance.
 676
 677 =item B<version>
 678
 679 This is a read-only attribute which returns the C<$VERSION> of the
 680 package for the given B<Class::MOP::Class> instance.
 681
 682 =back
 683
 684 =head2 Inheritance Relationships
 685
 686 =over 4
 687
 688 =item B<superclasses (?@superclasses)>
 689
 690 This is a read-write attribute which represents the superclass
 691 relationships of the class the B<Class::MOP::Class> instance is
 692 associated with. Basically, it can get and set the C<@ISA> for you.
 693
 694 B<NOTE:>
 695 Perl will occasionally perform some C<@ISA> and method caching, if
 696 you decide to change your superclass relationship at runtime (which
 697 is quite insane and very much not recommened), then you should be
 698 aware of this and the fact that this module does not make any
 699 attempt to address this issue.
 700
 701 =item B<class_precedence_list>
 702
 703 This computes the a list of all the class's ancestors in the same order
 704 in which method dispatch will be done. This is similair to
 705 what B<Class::ISA::super_path> does, but we don't remove duplicate names.
 706
 707 =back
 708
 709 =head2 Methods
 710
 711 =over 4
 712
 713 =item B<method_metaclass>
 714
 715 =item B<add_method ($method_name, $method)>
 716
 717 This will take a C<$method_name> and CODE reference to that
 718 C<$method> and install it into the class's package.
 719
 720 B<NOTE>:
 721 This does absolutely nothing special to C<$method>
 722 other than use B<Sub::Name> to make sure it is tagged with the
 723 correct name, and therefore show up correctly in stack traces and
 724 such.
 725
 726 =item B<alias_method ($method_name, $method)>
 727
 728 This will take a C<$method_name> and CODE reference to that
 729 C<$method> and alias the method into the class's package.
 730
 731 B<NOTE>:
 732 Unlike C<add_method>, this will B<not> try to name the
 733 C<$method> using B<Sub::Name>, it only aliases the method in
 734 the class's package.
 735
 736 =item B<has_method ($method_name)>
 737
 738 This just provides a simple way to check if the class implements
 739 a specific C<$method_name>. It will I<not> however, attempt to check
 740 if the class inherits the method (use C<UNIVERSAL::can> for that).
 741
 742 This will correctly handle functions defined outside of the package
 743 that use a fully qualified name (C<sub Package::name { ... }>).
 744
 745 This will correctly handle functions renamed with B<Sub::Name> and
 746 installed using the symbol tables. However, if you are naming the
 747 subroutine outside of the package scope, you must use the fully
 748 qualified name, including the package name, for C<has_method> to
 749 correctly identify it.
 750
 751 This will attempt to correctly ignore functions imported from other
 752 packages using B<Exporter>. It breaks down if the function imported
 753 is an C<__ANON__> sub (such as with C<use constant>), which very well
 754 may be a valid method being applied to the class.
 755
 756 In short, this method cannot always be trusted to determine if the
 757 C<$method_name> is actually a method. However, it will DWIM about
 758 90% of the time, so it's a small trade off I think.
 759
 760 =item B<get_method ($method_name)>
 761
 762 This will return a CODE reference of the specified C<$method_name>,
 763 or return undef if that method does not exist.
 764
 765 =item B<remove_method ($method_name)>
 766
 767 This will attempt to remove a given C<$method_name> from the class.
 768 It will return the CODE reference that it has removed, and will
 769 attempt to use B<Sub::Name> to clear the methods associated name.
 770
 771 =item B<get_method_list>
 772
 773 This will return a list of method names for all I<locally> defined
 774 methods. It does B<not> provide a list of all applicable methods,
 775 including any inherited ones. If you want a list of all applicable
 776 methods, use the C<compute_all_applicable_methods> method.
 777
 778 =item B<compute_all_applicable_methods>
 779
 780 This will return a list of all the methods names this class will
 781 respond to, taking into account inheritance. The list will be a list of
 782 HASH references, each one containing the following information; method
 783 name, the name of the class in which the method lives and a CODE
 784 reference for the actual method.
 785
 786 =item B<find_all_methods_by_name ($method_name)>
 787
 788 This will traverse the inheritence hierarchy and locate all methods
 789 with a given C<$method_name>. Similar to
 790 C<compute_all_applicable_methods> it returns a list of HASH references
 791 with the following information; method name (which will always be the
 792 same as C<$method_name>), the name of the class in which the method
 793 lives and a CODE reference for the actual method.
 794
 795 The list of methods produced is a distinct list, meaning there are no
 796 duplicates in it. This is especially useful for things like object
 797 initialization and destruction where you only want the method called
 798 once, and in the correct order.
 799
 800 =back
 801
 802 =head2 Attributes
 803
 804 It should be noted that since there is no one consistent way to define
 805 the attributes of a class in Perl 5. These methods can only work with
 806 the information given, and can not easily discover information on
 807 their own. See L<Class::MOP::Attribute> for more details.
 808
 809 =over 4
 810
 811 =item B<attribute_metaclass>
 812
 813 =item B<get_attribute_map>
 814
 815 =item B<add_attribute ($attribute_name, $attribute_meta_object)>
 816
 817 This stores a C<$attribute_meta_object> in the B<Class::MOP::Class>
 818 instance associated with the given class, and associates it with
 819 the C<$attribute_name>. Unlike methods, attributes within the MOP
 820 are stored as meta-information only. They will be used later to
 821 construct instances from (see C<construct_instance> above).
 822 More details about the attribute meta-objects can be found in the
 823 L<Class::MOP::Attribute> or the L<Class::MOP/The Attribute protocol>
 824 section.
 825
 826 It should be noted that any accessor, reader/writer or predicate
 827 methods which the C<$attribute_meta_object> has will be installed
 828 into the class at this time.
 829
 830 =item B<has_attribute ($attribute_name)>
 831
 832 Checks to see if this class has an attribute by the name of
 833 C<$attribute_name> and returns a boolean.
 834
 835 =item B<get_attribute ($attribute_name)>
 836
 837 Returns the attribute meta-object associated with C<$attribute_name>,
 838 if none is found, it will return undef.
 839
 840 =item B<remove_attribute ($attribute_name)>
 841
 842 This will remove the attribute meta-object stored at
 843 C<$attribute_name>, then return the removed attribute meta-object.
 844
 845 B<NOTE:>
 846 Removing an attribute will only affect future instances of
 847 the class, it will not make any attempt to remove the attribute from
 848 any existing instances of the class.
 849
 850 It should be noted that any accessor, reader/writer or predicate
 851 methods which the attribute meta-object stored at C<$attribute_name>
 852 has will be removed from the class at this time. This B<will> make
 853 these attributes somewhat inaccessable in previously created
 854 instances. But if you are crazy enough to do this at runtime, then
 855 you are crazy enough to deal with something like this :).
 856
 857 =item B<get_attribute_list>
 858
 859 This returns a list of attribute names which are defined in the local
 860 class. If you want a list of all applicable attributes for a class,
 861 use the C<compute_all_applicable_attributes> method.
 862
 863 =item B<compute_all_applicable_attributes>
 864
 865 This will traverse the inheritance heirachy and return a list of all
 866 the applicable attributes for this class. It does not construct a
 867 HASH reference like C<compute_all_applicable_methods> because all
 868 that same information is discoverable through the attribute
 869 meta-object itself.
 870
 871 =back
 872
 873 =head2 Package Variables
 874
 875 Since Perl's classes are built atop the Perl package system, it is
 876 fairly common to use package scoped variables for things like static
 877 class variables. The following methods are convience methods for
 878 the creation and inspection of package scoped variables.
 879
 880 =over 4
 881
 882 =item B<add_package_variable ($variable_name, ?$initial_value)>
 883
 884 Given a C<$variable_name>, which must contain a leading sigil, this
 885 method will create that variable within the package which houses the
 886 class. It also takes an optional C<$initial_value>, which must be a
 887 reference of the same type as the sigil of the C<$variable_name>
 888 implies.
 889
 890 =item B<get_package_variable ($variable_name)>
 891
 892 This will return a reference to the package variable in
 893 C<$variable_name>.
 894
 895 =item B<has_package_variable ($variable_name)>
 896
 897 Returns true (C<1>) if there is a package variable defined for
 898 C<$variable_name>, and false (C<0>) otherwise.
 899
 900 =item B<remove_package_variable ($variable_name)>
 901
 902 This will attempt to remove the package variable at C<$variable_name>.
 903
 904 =back
 905
 906 =head1 AUTHOR
 907
 908 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 909
 910 =head1 COPYRIGHT AND LICENSE
 911
 912 Copyright 2006 by Infinity Interactive, Inc.
 913
 914 L<http://www.iinteractive.com>
 915
 916 This library is free software; you can redistribute it and/or modify
 917 it under the same terms as Perl itself.
 918
 919 =cut