Fix a bug where a class made immutable and then mutable would end up
[gitmo/Class-MOP.git] / lib / Class / MOP / Class.pm
1
2 package Class::MOP::Class;
3
4 use strict;
5 use warnings;
6
7 use Class::MOP::Immutable;
8 use Class::MOP::Instance;
9 use Class::MOP::Method::Wrapped;
10
11 use Carp         'confess';
12 use Scalar::Util 'blessed', 'weaken';
13
14 our $VERSION   = '0.74';
15 $VERSION = eval $VERSION;
16 our $AUTHORITY = 'cpan:STEVAN';
17
18 use base 'Class::MOP::Module';
19
20 # Creation
21
22 sub initialize {
23     my $class = shift;
24
25     my $package_name;
26     
27     if ( @_ % 2 ) {
28         $package_name = shift;
29     } else {
30         my %options = @_;
31         $package_name = $options{package};
32     }
33
34     (defined $package_name && $package_name && !ref($package_name))
35         || confess "You must pass a package name and it cannot be blessed";
36
37     return Class::MOP::get_metaclass_by_name($package_name)
38         || $class->construct_class_instance(package => $package_name, @_);
39 }
40
41 # NOTE: (meta-circularity)
42 # this is a special form of &construct_instance
43 # (see below), which is used to construct class
44 # meta-object instances for any Class::MOP::*
45 # class. All other classes will use the more
46 # normal &construct_instance.
47 sub construct_class_instance {
48     my $class        = shift;
49     my $options      = @_ == 1 ? $_[0] : {@_};
50     my $package_name = $options->{package};
51     (defined $package_name && $package_name)
52         || confess "You must pass a package name";
53     # NOTE:
54     # return the metaclass if we have it cached,
55     # and it is still defined (it has not been
56     # reaped by DESTROY yet, which can happen
57     # annoyingly enough during global destruction)
58
59     if (defined(my $meta = Class::MOP::get_metaclass_by_name($package_name))) {
60         return $meta;
61     }
62
63     # NOTE:
64     # we need to deal with the possibility
65     # of class immutability here, and then
66     # get the name of the class appropriately
67     $class = (ref($class)
68                     ? ($class->is_immutable
69                         ? $class->get_mutable_metaclass_name()
70                         : ref($class))
71                     : $class);
72
73     # now create the metaclass
74     my $meta;
75     if ($class eq 'Class::MOP::Class') {
76         no strict 'refs';
77         $meta = $class->_new($options)
78     }
79     else {
80         # NOTE:
81         # it is safe to use meta here because
82         # class will always be a subclass of
83         # Class::MOP::Class, which defines meta
84         $meta = $class->meta->construct_instance($options)
85     }
86
87     # and check the metaclass compatibility
88     $meta->check_metaclass_compatibility();  
89
90     Class::MOP::store_metaclass_by_name($package_name, $meta);
91
92     # NOTE:
93     # we need to weaken any anon classes
94     # so that they can call DESTROY properly
95     Class::MOP::weaken_metaclass($package_name) if $meta->is_anon_class;
96
97     $meta;
98 }
99
100 sub _new {
101     my $class = shift;
102     my $options = @_ == 1 ? $_[0] : {@_};
103
104     bless {
105         # inherited from Class::MOP::Package
106         'package'             => $options->{package},
107
108         # NOTE:
109         # since the following attributes will
110         # actually be loaded from the symbol
111         # table, and actually bypass the instance
112         # entirely, we can just leave these things
113         # listed here for reference, because they
114         # should not actually have a value associated
115         # with the slot.
116         'namespace'           => \undef,
117         # inherited from Class::MOP::Module
118         'version'             => \undef,
119         'authority'           => \undef,
120         # defined in Class::MOP::Class
121         'superclasses'        => \undef,
122
123         'methods'             => {},
124         'attributes'          => {},
125         'attribute_metaclass' => $options->{'attribute_metaclass'} || 'Class::MOP::Attribute',
126         'method_metaclass'    => $options->{'method_metaclass'}    || 'Class::MOP::Method',
127         'instance_metaclass'  => $options->{'instance_metaclass'}  || 'Class::MOP::Instance',
128     }, $class;
129 }
130
131 sub reset_package_cache_flag  { (shift)->{'_package_cache_flag'} = undef } 
132 sub update_package_cache_flag {
133     my $self = shift;
134     # NOTE:
135     # we can manually update the cache number 
136     # since we are actually adding the method
137     # to our cache as well. This avoids us 
138     # having to regenerate the method_map.
139     # - SL    
140     $self->{'_package_cache_flag'} = Class::MOP::check_package_cache_flag($self->name);    
141 }
142
143 sub check_metaclass_compatibility {
144     my $self = shift;
145
146     # this is always okay ...
147     return if ref($self)                eq 'Class::MOP::Class'   &&
148               $self->instance_metaclass eq 'Class::MOP::Instance';
149
150     my @class_list = $self->linearized_isa;
151     shift @class_list; # shift off $self->name
152
153     foreach my $class_name (@class_list) {
154         my $meta = Class::MOP::get_metaclass_by_name($class_name) || next;
155
156         # NOTE:
157         # we need to deal with the possibility
158         # of class immutability here, and then
159         # get the name of the class appropriately
160         my $meta_type = ($meta->is_immutable
161                             ? $meta->get_mutable_metaclass_name()
162                             : ref($meta));
163
164         ($self->isa($meta_type))
165             || confess $self->name . "->meta => (" . (ref($self)) . ")" .
166                        " is not compatible with the " .
167                        $class_name . "->meta => (" . ($meta_type)     . ")";
168         # NOTE:
169         # we also need to check that instance metaclasses
170         # are compatibile in the same the class.
171         ($self->instance_metaclass->isa($meta->instance_metaclass))
172             || confess $self->name . "->meta->instance_metaclass => (" . ($self->instance_metaclass) . ")" .
173                        " is not compatible with the " .
174                        $class_name . "->meta->instance_metaclass => (" . ($meta->instance_metaclass) . ")";
175     }
176 }
177
178 # backwards compat for stevan's inability to spell ;)
179 sub check_metaclass_compatability {
180     my $self = shift;
181     $self->check_metaclass_compatibility(@_);
182 }
183
184 ## ANON classes
185
186 {
187     # NOTE:
188     # this should be sufficient, if you have a
189     # use case where it is not, write a test and
190     # I will change it.
191     my $ANON_CLASS_SERIAL = 0;
192
193     # NOTE:
194     # we need a sufficiently annoying prefix
195     # this should suffice for now, this is
196     # used in a couple of places below, so
197     # need to put it up here for now.
198     my $ANON_CLASS_PREFIX = 'Class::MOP::Class::__ANON__::SERIAL::';
199
200     sub is_anon_class {
201         my $self = shift;
202         no warnings 'uninitialized';
203         $self->name =~ /^$ANON_CLASS_PREFIX/;
204     }
205
206     sub create_anon_class {
207         my ($class, %options) = @_;
208         my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
209         return $class->create($package_name, %options);
210     }
211
212     # NOTE:
213     # this will only get called for
214     # anon-classes, all other calls
215     # are assumed to occur during
216     # global destruction and so don't
217     # really need to be handled explicitly
218     sub DESTROY {
219         my $self = shift;
220
221         return if Class::MOP::in_global_destruction(); # it'll happen soon anyway and this just makes things more complicated
222
223         no warnings 'uninitialized';
224         return unless $self->name =~ /^$ANON_CLASS_PREFIX/;
225         # Moose does a weird thing where it replaces the metaclass for
226         # class when fixing metaclass incompatibility. In that case,
227         # we don't want to clean out the namespace now. We can detect
228         # that because Moose will explicitly update the singleton
229         # cache in Class::MOP.
230         my $current_meta = Class::MOP::get_metaclass_by_name($self->name);
231         return if $current_meta ne $self;
232
233         my ($serial_id) = ($self->name =~ /^$ANON_CLASS_PREFIX(\d+)/);
234         no strict 'refs';
235         foreach my $key (keys %{$ANON_CLASS_PREFIX . $serial_id}) {
236             delete ${$ANON_CLASS_PREFIX . $serial_id}{$key};
237         }
238         delete ${'main::' . $ANON_CLASS_PREFIX}{$serial_id . '::'};
239     }
240
241 }
242
243 # creating classes with MOP ...
244
245 sub create {
246     my ( $class, @args ) = @_;
247
248     unshift @args, 'package' if @args % 2 == 1;
249
250     my (%options) = @args;
251     my $package_name = $options{package};
252
253     (ref $options{superclasses} eq 'ARRAY')
254         || confess "You must pass an ARRAY ref of superclasses"
255             if exists $options{superclasses};
256             
257     (ref $options{attributes} eq 'ARRAY')
258         || confess "You must pass an ARRAY ref of attributes"
259             if exists $options{attributes};      
260             
261     (ref $options{methods} eq 'HASH')
262         || confess "You must pass a HASH ref of methods"
263             if exists $options{methods};                  
264
265     $class->SUPER::create(%options);
266
267     my (%initialize_options) = @args;
268     delete @initialize_options{qw(
269         package
270         superclasses
271         attributes
272         methods
273         version
274         authority
275     )};
276     my $meta = $class->initialize( $package_name => %initialize_options );
277
278     # FIXME totally lame
279     $meta->add_method('meta' => sub {
280         $class->initialize(ref($_[0]) || $_[0]);
281     });
282
283     $meta->superclasses(@{$options{superclasses}})
284         if exists $options{superclasses};
285     # NOTE:
286     # process attributes first, so that they can
287     # install accessors, but locally defined methods
288     # can then overwrite them. It is maybe a little odd, but
289     # I think this should be the order of things.
290     if (exists $options{attributes}) {
291         foreach my $attr (@{$options{attributes}}) {
292             $meta->add_attribute($attr);
293         }
294     }
295     if (exists $options{methods}) {
296         foreach my $method_name (keys %{$options{methods}}) {
297             $meta->add_method($method_name, $options{methods}->{$method_name});
298         }
299     }
300     return $meta;
301 }
302
303 ## Attribute readers
304
305 # NOTE:
306 # all these attribute readers will be bootstrapped
307 # away in the Class::MOP bootstrap section
308
309 sub get_attribute_map   { $_[0]->{'attributes'}          }
310 sub attribute_metaclass { $_[0]->{'attribute_metaclass'} }
311 sub method_metaclass    { $_[0]->{'method_metaclass'}    }
312 sub instance_metaclass  { $_[0]->{'instance_metaclass'}  }
313
314 sub get_method_map {
315     my $self = shift;
316
317     my $class_name = $self->name;
318
319     my $current = Class::MOP::check_package_cache_flag($class_name);
320
321     if (defined $self->{'_package_cache_flag'} && $self->{'_package_cache_flag'} == $current) {
322         return $self->{'methods'} ||= {};
323     }
324
325     $self->{_package_cache_flag} = $current;
326
327     my $map = $self->{'methods'} ||= {};
328
329     my $method_metaclass = $self->method_metaclass;
330
331     my $all_code = $self->get_all_package_symbols('CODE');
332
333     foreach my $symbol (keys %{ $all_code }) {
334         my $code = $all_code->{$symbol};
335
336         next if exists  $map->{$symbol} &&
337                 defined $map->{$symbol} &&
338                         $map->{$symbol}->body == $code;
339
340         my ($pkg, $name) = Class::MOP::get_code_info($code);
341         
342         # NOTE:
343         # in 5.10 constant.pm the constants show up 
344         # as being in the right package, but in pre-5.10
345         # they show up as constant::__ANON__ so we 
346         # make an exception here to be sure that things
347         # work as expected in both.
348         # - SL
349         unless ($pkg eq 'constant' && $name eq '__ANON__') {
350             next if ($pkg  || '') ne $class_name ||
351                     (($name || '') ne '__ANON__' && ($pkg  || '') ne $class_name);
352         }
353
354         $map->{$symbol} = $method_metaclass->wrap(
355             $code,
356             associated_metaclass => $self,
357             package_name         => $class_name,
358             name                 => $symbol,
359         );
360     }
361
362     return $map;
363 }
364
365 # Instance Construction & Cloning
366
367 sub new_object {
368     my $class = shift;
369
370     # NOTE:
371     # we need to protect the integrity of the
372     # Class::MOP::Class singletons here, so we
373     # delegate this to &construct_class_instance
374     # which will deal with the singletons
375     return $class->construct_class_instance(@_)
376         if $class->name->isa('Class::MOP::Class');
377     return $class->construct_instance(@_);
378 }
379
380 sub construct_instance {
381     my $class = shift;
382     my $params = @_ == 1 ? $_[0] : {@_};
383     my $meta_instance = $class->get_meta_instance();
384     my $instance = $meta_instance->create_instance();
385     foreach my $attr ($class->compute_all_applicable_attributes()) {
386         $attr->initialize_instance_slot($meta_instance, $instance, $params);
387     }
388     # NOTE:
389     # this will only work for a HASH instance type
390     if ($class->is_anon_class) {
391         (Scalar::Util::reftype($instance) eq 'HASH')
392             || confess "Currently only HASH based instances are supported with instance of anon-classes";
393         # NOTE:
394         # At some point we should make this official
395         # as a reserved slot name, but right now I am
396         # going to keep it here.
397         # my $RESERVED_MOP_SLOT = '__MOP__';
398         $instance->{'__MOP__'} = $class;
399     }
400     return $instance;
401 }
402
403
404 sub get_meta_instance {
405     my $self = shift;
406     $self->{'_meta_instance'} ||= $self->create_meta_instance();
407 }
408
409 sub create_meta_instance {
410     my $self = shift;
411     
412     my $instance = $self->instance_metaclass->new(
413         associated_metaclass => $self,
414         attributes => [ $self->compute_all_applicable_attributes() ],
415     );
416
417     $self->add_meta_instance_dependencies()
418         if $instance->is_dependent_on_superclasses();
419
420     return $instance;
421 }
422
423 sub clone_object {
424     my $class    = shift;
425     my $instance = shift;
426     (blessed($instance) && $instance->isa($class->name))
427         || confess "You must pass an instance of the metaclass (" . (ref $class ? $class->name : $class) . "), not ($instance)";
428
429     # NOTE:
430     # we need to protect the integrity of the
431     # Class::MOP::Class singletons here, they
432     # should not be cloned.
433     return $instance if $instance->isa('Class::MOP::Class');
434     $class->clone_instance($instance, @_);
435 }
436
437 sub clone_instance {
438     my ($class, $instance, %params) = @_;
439     (blessed($instance))
440         || confess "You can only clone instances, ($instance) is not a blessed instance";
441     my $meta_instance = $class->get_meta_instance();
442     my $clone = $meta_instance->clone_instance($instance);
443     foreach my $attr ($class->compute_all_applicable_attributes()) {
444         if ( defined( my $init_arg = $attr->init_arg ) ) {
445             if (exists $params{$init_arg}) {
446                 $attr->set_value($clone, $params{$init_arg});
447             }
448         }
449     }
450     return $clone;
451 }
452
453 sub rebless_instance {
454     my ($self, $instance, %params) = @_;
455
456     my $old_metaclass;
457     if ($instance->can('meta')) {
458         ($instance->meta->isa('Class::MOP::Class'))
459             || confess 'Cannot rebless instance if ->meta is not an instance of Class::MOP::Class';
460         $old_metaclass = $instance->meta;
461     }
462     else {
463         $old_metaclass = $self->initialize(ref($instance));
464     }
465
466     my $meta_instance = $self->get_meta_instance();
467
468     $self->name->isa($old_metaclass->name)
469         || confess "You may rebless only into a subclass of (". $old_metaclass->name ."), of which (". $self->name .") isn't.";
470
471     # rebless!
472     $meta_instance->rebless_instance_structure($instance, $self);
473
474     foreach my $attr ( $self->compute_all_applicable_attributes ) {
475         if ( $attr->has_value($instance) ) {
476             if ( defined( my $init_arg = $attr->init_arg ) ) {
477                 $params{$init_arg} = $attr->get_value($instance)
478                     unless exists $params{$init_arg};
479             } 
480             else {
481                 $attr->set_value($instance, $attr->get_value($instance));
482             }
483         }
484     }
485
486     foreach my $attr ($self->compute_all_applicable_attributes) {
487         $attr->initialize_instance_slot($meta_instance, $instance, \%params);
488     }
489     
490     $instance;
491 }
492
493 # Inheritance
494
495 sub superclasses {
496     my $self     = shift;
497     my $var_spec = { sigil => '@', type => 'ARRAY', name => 'ISA' };
498     if (@_) {
499         my @supers = @_;
500         @{$self->get_package_symbol($var_spec)} = @supers;
501
502         # NOTE:
503         # on 5.8 and below, we need to call
504         # a method to get Perl to detect
505         # a cycle in the class hierarchy
506         my $class = $self->name;
507         $class->isa($class);
508
509         # NOTE:
510         # we need to check the metaclass
511         # compatibility here so that we can
512         # be sure that the superclass is
513         # not potentially creating an issues
514         # we don't know about
515
516         $self->check_metaclass_compatibility();
517         $self->update_meta_instance_dependencies();
518     }
519     @{$self->get_package_symbol($var_spec)};
520 }
521
522 sub subclasses {
523     my $self = shift;
524
525     my $super_class = $self->name;
526
527     if ( Class::MOP::HAVE_ISAREV() ) {
528         return @{ $super_class->mro::get_isarev() };
529     } else {
530         my @derived_classes;
531
532         my $find_derived_classes;
533         $find_derived_classes = sub {
534             my ($outer_class) = @_;
535
536             my $symbol_table_hashref = do { no strict 'refs'; \%{"${outer_class}::"} };
537
538             SYMBOL:
539             for my $symbol ( keys %$symbol_table_hashref ) {
540                 next SYMBOL if $symbol !~ /\A (\w+):: \z/x;
541                 my $inner_class = $1;
542
543                 next SYMBOL if $inner_class eq 'SUPER';    # skip '*::SUPER'
544
545                 my $class =
546                 $outer_class
547                 ? "${outer_class}::$inner_class"
548                 : $inner_class;
549
550                 if ( $class->isa($super_class) and $class ne $super_class ) {
551                     push @derived_classes, $class;
552                 }
553
554                 next SYMBOL if $class eq 'main';           # skip 'main::*'
555
556                 $find_derived_classes->($class);
557             }
558         };
559
560         my $root_class = q{};
561         $find_derived_classes->($root_class);
562
563         undef $find_derived_classes;
564
565         @derived_classes = sort { $a->isa($b) ? 1 : $b->isa($a) ? -1 : 0 } @derived_classes;
566
567         return @derived_classes;
568     }
569 }
570
571
572 sub linearized_isa {
573     return @{ mro::get_linear_isa( (shift)->name ) };
574 }
575
576 sub class_precedence_list {
577     my $self = shift;
578     my $name = $self->name;
579
580     unless (Class::MOP::IS_RUNNING_ON_5_10()) { 
581         # NOTE:
582         # We need to check for circular inheritance here
583         # if we are are not on 5.10, cause 5.8 detects it 
584         # late. This will do nothing if all is well, and 
585         # blow up otherwise. Yes, it's an ugly hack, better
586         # suggestions are welcome.        
587         # - SL
588         ($name || return)->isa('This is a test for circular inheritance') 
589     }
590
591     # if our mro is c3, we can 
592     # just grab the linear_isa
593     if (mro::get_mro($name) eq 'c3') {
594         return @{ mro::get_linear_isa($name) }
595     }
596     else {
597         # NOTE:
598         # we can't grab the linear_isa for dfs
599         # since it has all the duplicates 
600         # already removed.
601         return (
602             $name,
603             map {
604                 $self->initialize($_)->class_precedence_list()
605             } $self->superclasses()
606         );
607     }
608 }
609
610 ## Methods
611
612 sub wrap_method_body {
613     my ( $self, %args ) = @_;
614
615     ('CODE' eq ref $args{body})
616         || confess "Your code block must be a CODE reference";
617
618     $self->method_metaclass->wrap(
619         package_name => $self->name,
620         %args,
621     );
622 }
623
624 sub add_method {
625     my ($self, $method_name, $method) = @_;
626     (defined $method_name && $method_name)
627         || confess "You must define a method name";
628
629     my $body;
630     if (blessed($method)) {
631         $body = $method->body;
632         if ($method->package_name ne $self->name) {
633             $method = $method->clone(
634                 package_name => $self->name,
635                 name         => $method_name            
636             ) if $method->can('clone');
637         }
638     }
639     else {
640         $body = $method;
641         $method = $self->wrap_method_body( body => $body, name => $method_name );
642     }
643
644     $method->attach_to_class($self);
645
646     # This used to call get_method_map, which meant we would build all
647     # the method objects for the class just because we added one
648     # method. This is hackier, but quicker too.
649     $self->{methods}{$method_name} = $method;
650     
651     my $full_method_name = ($self->name . '::' . $method_name);    
652     $self->add_package_symbol(
653         { sigil => '&', type => 'CODE', name => $method_name }, 
654         Class::MOP::subname($full_method_name => $body)
655     );
656 }
657
658 {
659     my $fetch_and_prepare_method = sub {
660         my ($self, $method_name) = @_;
661         # fetch it locally
662         my $method = $self->get_method($method_name);
663         # if we dont have local ...
664         unless ($method) {
665             # try to find the next method
666             $method = $self->find_next_method_by_name($method_name);
667             # die if it does not exist
668             (defined $method)
669                 || confess "The method '$method_name' is not found in the inheritance hierarchy for class " . $self->name;
670             # and now make sure to wrap it
671             # even if it is already wrapped
672             # because we need a new sub ref
673             $method = Class::MOP::Method::Wrapped->wrap($method);
674         }
675         else {
676             # now make sure we wrap it properly
677             $method = Class::MOP::Method::Wrapped->wrap($method)
678                 unless $method->isa('Class::MOP::Method::Wrapped');
679         }
680         $self->add_method($method_name => $method);
681         return $method;
682     };
683
684     sub add_before_method_modifier {
685         my ($self, $method_name, $method_modifier) = @_;
686         (defined $method_name && $method_name)
687             || confess "You must pass in a method name";
688         my $method = $fetch_and_prepare_method->($self, $method_name);
689         $method->add_before_modifier(
690             Class::MOP::subname(':before' => $method_modifier)
691         );
692     }
693
694     sub add_after_method_modifier {
695         my ($self, $method_name, $method_modifier) = @_;
696         (defined $method_name && $method_name)
697             || confess "You must pass in a method name";
698         my $method = $fetch_and_prepare_method->($self, $method_name);
699         $method->add_after_modifier(
700             Class::MOP::subname(':after' => $method_modifier)
701         );
702     }
703
704     sub add_around_method_modifier {
705         my ($self, $method_name, $method_modifier) = @_;
706         (defined $method_name && $method_name)
707             || confess "You must pass in a method name";
708         my $method = $fetch_and_prepare_method->($self, $method_name);
709         $method->add_around_modifier(
710             Class::MOP::subname(':around' => $method_modifier)
711         );
712     }
713
714     # NOTE:
715     # the methods above used to be named like this:
716     #    ${pkg}::${method}:(before|after|around)
717     # but this proved problematic when using one modifier
718     # to wrap multiple methods (something which is likely
719     # to happen pretty regularly IMO). So instead of naming
720     # it like this, I have chosen to just name them purely
721     # with their modifier names, like so:
722     #    :(before|after|around)
723     # The fact is that in a stack trace, it will be fairly
724     # evident from the context what method they are attached
725     # to, and so don't need the fully qualified name.
726 }
727
728 sub alias_method {
729     my $self = shift;
730
731     $self->add_method(@_);
732 }
733
734 sub has_method {
735     my ($self, $method_name) = @_;
736     (defined $method_name && $method_name)
737         || confess "You must define a method name";
738
739     exists $self->{methods}{$method_name} || exists $self->get_method_map->{$method_name};
740 }
741
742 sub get_method {
743     my ($self, $method_name) = @_;
744     (defined $method_name && $method_name)
745         || confess "You must define a method name";
746
747     # NOTE:
748     # I don't really need this here, because
749     # if the method_map is missing a key it
750     # will just return undef for me now
751     # return unless $self->has_method($method_name);
752
753     return $self->{methods}{$method_name} || $self->get_method_map->{$method_name};
754 }
755
756 sub remove_method {
757     my ($self, $method_name) = @_;
758     (defined $method_name && $method_name)
759         || confess "You must define a method name";
760
761     my $removed_method = delete $self->get_method_map->{$method_name};
762     
763     $self->remove_package_symbol(
764         { sigil => '&', type => 'CODE', name => $method_name }
765     );
766
767     $removed_method->detach_from_class if $removed_method;
768
769     $self->update_package_cache_flag; # still valid, since we just removed the method from the map
770
771     return $removed_method;
772 }
773
774 sub get_method_list {
775     my $self = shift;
776     keys %{$self->get_method_map};
777 }
778
779 sub find_method_by_name {
780     my ($self, $method_name) = @_;
781     (defined $method_name && $method_name)
782         || confess "You must define a method name to find";
783     foreach my $class ($self->linearized_isa) {
784         # fetch the meta-class ...
785         my $meta = $self->initialize($class);
786         return $meta->get_method($method_name)
787             if $meta->has_method($method_name);
788     }
789     return;
790 }
791
792 sub get_all_methods {
793     my $self = shift;
794     my %methods = map { %{ $self->initialize($_)->get_method_map } } reverse $self->linearized_isa;
795     return values %methods;
796 }
797
798 # compatibility
799 sub compute_all_applicable_methods {
800     return map {
801         {
802             name  => $_->name,
803             class => $_->package_name,
804             code  => $_, # sigh, overloading
805         },
806     } shift->get_all_methods(@_);
807 }
808
809 sub find_all_methods_by_name {
810     my ($self, $method_name) = @_;
811     (defined $method_name && $method_name)
812         || confess "You must define a method name to find";
813     my @methods;
814     foreach my $class ($self->linearized_isa) {
815         # fetch the meta-class ...
816         my $meta = $self->initialize($class);
817         push @methods => {
818             name  => $method_name,
819             class => $class,
820             code  => $meta->get_method($method_name)
821         } if $meta->has_method($method_name);
822     }
823     return @methods;
824 }
825
826 sub find_next_method_by_name {
827     my ($self, $method_name) = @_;
828     (defined $method_name && $method_name)
829         || confess "You must define a method name to find";
830     my @cpl = $self->linearized_isa;
831     shift @cpl; # discard ourselves
832     foreach my $class (@cpl) {
833         # fetch the meta-class ...
834         my $meta = $self->initialize($class);
835         return $meta->get_method($method_name)
836             if $meta->has_method($method_name);
837     }
838     return;
839 }
840
841 ## Attributes
842
843 sub add_attribute {
844     my $self      = shift;
845     # either we have an attribute object already
846     # or we need to create one from the args provided
847     my $attribute = blessed($_[0]) ? $_[0] : $self->attribute_metaclass->new(@_);
848     # make sure it is derived from the correct type though
849     ($attribute->isa('Class::MOP::Attribute'))
850         || confess "Your attribute must be an instance of Class::MOP::Attribute (or a subclass)";
851
852     # first we attach our new attribute
853     # because it might need certain information
854     # about the class which it is attached to
855     $attribute->attach_to_class($self);
856
857     # then we remove attributes of a conflicting
858     # name here so that we can properly detach
859     # the old attr object, and remove any
860     # accessors it would have generated
861     if ( $self->has_attribute($attribute->name) ) {
862         $self->remove_attribute($attribute->name);
863     } else {
864         $self->invalidate_meta_instances();
865     }
866
867     # then onto installing the new accessors
868     $self->get_attribute_map->{$attribute->name} = $attribute;
869
870     # invalidate package flag here
871     my $e = do { local $@; eval { $attribute->install_accessors() }; $@ };
872     if ( $e ) {
873         $self->remove_attribute($attribute->name);
874         die $e;
875     }
876
877     return $attribute;
878 }
879
880 sub update_meta_instance_dependencies {
881     my $self = shift;
882
883     if ( $self->{meta_instance_dependencies} ) {
884         return $self->add_meta_instance_dependencies;
885     }
886 }
887
888 sub add_meta_instance_dependencies {
889     my $self = shift;
890
891     $self->remove_meta_instance_depdendencies;
892
893     my @attrs = $self->compute_all_applicable_attributes();
894
895     my %seen;
896     my @classes = grep { not $seen{$_->name}++ } map { $_->associated_class } @attrs;
897
898     foreach my $class ( @classes ) { 
899         $class->add_dependent_meta_instance($self);
900     }
901
902     $self->{meta_instance_dependencies} = \@classes;
903 }
904
905 sub remove_meta_instance_depdendencies {
906     my $self = shift;
907
908     if ( my $classes = delete $self->{meta_instance_dependencies} ) {
909         foreach my $class ( @$classes ) {
910             $class->remove_dependent_meta_instance($self);
911         }
912
913         return $classes;
914     }
915
916     return;
917
918 }
919
920 sub add_dependent_meta_instance {
921     my ( $self, $metaclass ) = @_;
922     push @{ $self->{dependent_meta_instances} }, $metaclass;
923 }
924
925 sub remove_dependent_meta_instance {
926     my ( $self, $metaclass ) = @_;
927     my $name = $metaclass->name;
928     @$_ = grep { $_->name ne $name } @$_ for $self->{dependent_meta_instances};
929 }
930
931 sub invalidate_meta_instances {
932     my $self = shift;
933     $_->invalidate_meta_instance() for $self, @{ $self->{dependent_meta_instances} };
934 }
935
936 sub invalidate_meta_instance {
937     my $self = shift;
938     undef $self->{_meta_instance};
939 }
940
941 sub has_attribute {
942     my ($self, $attribute_name) = @_;
943     (defined $attribute_name && $attribute_name)
944         || confess "You must define an attribute name";
945     exists $self->get_attribute_map->{$attribute_name};
946 }
947
948 sub get_attribute {
949     my ($self, $attribute_name) = @_;
950     (defined $attribute_name && $attribute_name)
951         || confess "You must define an attribute name";
952     return $self->get_attribute_map->{$attribute_name}
953     # NOTE:
954     # this will return undef anyway, so no need ...
955     #    if $self->has_attribute($attribute_name);
956     #return;
957 }
958
959 sub remove_attribute {
960     my ($self, $attribute_name) = @_;
961     (defined $attribute_name && $attribute_name)
962         || confess "You must define an attribute name";
963     my $removed_attribute = $self->get_attribute_map->{$attribute_name};
964     return unless defined $removed_attribute;
965     delete $self->get_attribute_map->{$attribute_name};
966     $self->invalidate_meta_instances();
967     $removed_attribute->remove_accessors();
968     $removed_attribute->detach_from_class();
969     return $removed_attribute;
970 }
971
972 sub get_attribute_list {
973     my $self = shift;
974     keys %{$self->get_attribute_map};
975 }
976
977 sub get_all_attributes {
978     shift->compute_all_applicable_attributes(@_);
979 }
980
981 sub compute_all_applicable_attributes {
982     my $self = shift;
983     my %attrs = map { %{ $self->initialize($_)->get_attribute_map } } reverse $self->linearized_isa;
984     return values %attrs;
985 }
986
987 sub find_attribute_by_name {
988     my ($self, $attr_name) = @_;
989     foreach my $class ($self->linearized_isa) {
990         # fetch the meta-class ...
991         my $meta = $self->initialize($class);
992         return $meta->get_attribute($attr_name)
993             if $meta->has_attribute($attr_name);
994     }
995     return;
996 }
997
998 # check if we can reinitialize
999 sub is_pristine {
1000     my $self = shift;
1001
1002     # if any local attr is defined
1003     return if $self->get_attribute_list;
1004
1005     # or any non-declared methods
1006     if ( my @methods = values %{ $self->get_method_map } ) {
1007         my $metaclass = $self->method_metaclass;
1008         foreach my $method ( @methods ) {
1009             return if $method->isa("Class::MOP::Method::Generated");
1010             # FIXME do we need to enforce this too? return unless $method->isa($metaclass);
1011         }
1012     }
1013
1014     return 1;
1015 }
1016
1017 ## Class closing
1018
1019 sub is_mutable   { 1 }
1020 sub is_immutable { 0 }
1021
1022 # NOTE:
1023 # Why I changed this (groditi)
1024 #  - One Metaclass may have many Classes through many Metaclass instances
1025 #  - One Metaclass should only have one Immutable Transformer instance
1026 #  - Each Class may have different Immutabilizing options
1027 #  - Therefore each Metaclass instance may have different Immutabilizing options
1028 #  - We need to store one Immutable Transformer instance per Metaclass
1029 #  - We need to store one set of Immutable Transformer options per Class
1030 #  - Upon make_mutable we may delete the Immutabilizing options
1031 #  - We could clean the immutable Transformer instance when there is no more
1032 #      immutable Classes of that type, but we can also keep it in case
1033 #      another class with this same Metaclass becomes immutable. It is a case
1034 #      of trading of storing an instance to avoid unnecessary instantiations of
1035 #      Immutable Transformers. You may view this as a memory leak, however
1036 #      Because we have few Metaclasses, in practice it seems acceptable
1037 #  - To allow Immutable Transformers instances to be cleaned up we could weaken
1038 #      the reference stored in  $IMMUTABLE_TRANSFORMERS{$class} and ||= should DWIM
1039
1040 {
1041
1042     my %IMMUTABLE_TRANSFORMERS;
1043     my %IMMUTABLE_OPTIONS;
1044
1045     sub get_immutable_options {
1046         my $self = shift;
1047         return if $self->is_mutable;
1048         confess "unable to find immutabilizing options"
1049             unless exists $IMMUTABLE_OPTIONS{$self->name};
1050         my %options = %{$IMMUTABLE_OPTIONS{$self->name}};
1051         delete $options{IMMUTABLE_TRANSFORMER};
1052         return \%options;
1053     }
1054
1055     sub get_immutable_transformer {
1056         my $self = shift;
1057         if( $self->is_mutable ){
1058             return $IMMUTABLE_TRANSFORMERS{$self->name} ||= $self->create_immutable_transformer;
1059         }
1060         confess "unable to find transformer for immutable class"
1061             unless exists $IMMUTABLE_OPTIONS{$self->name};
1062         return $IMMUTABLE_OPTIONS{$self->name}->{IMMUTABLE_TRANSFORMER};
1063     }
1064
1065     sub make_immutable {
1066         my $self = shift;
1067         my %options = @_;
1068
1069         my $transformer = $self->get_immutable_transformer;
1070         $transformer->make_metaclass_immutable($self, \%options);
1071         $IMMUTABLE_OPTIONS{$self->name} =
1072             { %options,  IMMUTABLE_TRANSFORMER => $transformer };
1073
1074         if( exists $options{debug} && $options{debug} ){
1075             print STDERR "# of Metaclass options:      ", keys %IMMUTABLE_OPTIONS;
1076             print STDERR "# of Immutable transformers: ", keys %IMMUTABLE_TRANSFORMERS;
1077         }
1078
1079         1;
1080     }
1081
1082     sub make_mutable{
1083         my $self = shift;
1084         return if $self->is_mutable;
1085         my $options = delete $IMMUTABLE_OPTIONS{$self->name};
1086         confess "unable to find immutabilizing options" unless ref $options;
1087         my $transformer = delete $options->{IMMUTABLE_TRANSFORMER};
1088         $transformer->make_metaclass_mutable($self, $options);
1089         1;
1090     }
1091 }
1092
1093 sub create_immutable_transformer {
1094     my $self = shift;
1095     my $class = Class::MOP::Immutable->new($self, {
1096         read_only   => [qw/superclasses/],
1097         cannot_call => [qw/
1098            add_method
1099            alias_method
1100            remove_method
1101            add_attribute
1102            remove_attribute
1103            remove_package_symbol
1104         /],
1105         memoize     => {
1106            class_precedence_list             => 'ARRAY',
1107            linearized_isa                    => 'ARRAY', # FIXME perl 5.10 memoizes this on its own, no need?
1108            get_all_methods                   => 'ARRAY',
1109            #get_all_attributes               => 'ARRAY', # it's an alias, no need, but maybe in the future
1110            compute_all_applicable_attributes => 'ARRAY',
1111            get_meta_instance                 => 'SCALAR',
1112            get_method_map                    => 'SCALAR',
1113         },
1114         # NOTE:
1115         # this is ugly, but so are typeglobs, 
1116         # so whattayahgonnadoboutit
1117         # - SL
1118         wrapped => { 
1119             add_package_symbol => sub {
1120                 my $original = shift;
1121                 confess "Cannot add package symbols to an immutable metaclass" 
1122                     unless (caller(2))[3] eq 'Class::MOP::Package::get_package_symbol'; 
1123
1124                 # This is a workaround for a bug in 5.8.1 which thinks that
1125                 # goto $original->body
1126                 # is trying to go to a label
1127                 my $body = $original->body;
1128                 goto $body;
1129             },
1130         },
1131     });
1132     return $class;
1133 }
1134
1135 1;
1136
1137 __END__
1138
1139 =pod
1140
1141 =head1 NAME
1142
1143 Class::MOP::Class - Class Meta Object
1144
1145 =head1 SYNOPSIS
1146
1147   # assuming that class Foo
1148   # has been defined, you can
1149
1150   # use this for introspection ...
1151
1152   # add a method to Foo ...
1153   Foo->meta->add_method('bar' => sub { ... })
1154
1155   # get a list of all the classes searched
1156   # the method dispatcher in the correct order
1157   Foo->meta->class_precedence_list()
1158
1159   # remove a method from Foo
1160   Foo->meta->remove_method('bar');
1161
1162   # or use this to actually create classes ...
1163
1164   Class::MOP::Class->create('Bar' => (
1165       version      => '0.01',
1166       superclasses => [ 'Foo' ],
1167       attributes => [
1168           Class::MOP:::Attribute->new('$bar'),
1169           Class::MOP:::Attribute->new('$baz'),
1170       ],
1171       methods => {
1172           calculate_bar => sub { ... },
1173           construct_baz => sub { ... }
1174       }
1175   ));
1176
1177 =head1 DESCRIPTION
1178
1179 This is the largest and currently most complex part of the Perl 5
1180 meta-object protocol. It controls the introspection and
1181 manipulation of Perl 5 classes (and it can create them too). The
1182 best way to understand what this module can do, is to read the
1183 documentation for each of it's methods.
1184
1185 =head1 INHERITANCE
1186
1187 B<Class::MOP::Class> is a subclass of L<Class::MOP::Module>
1188
1189 =head1 METHODS
1190
1191 =head2 Self Introspection
1192
1193 =over 4
1194
1195 =item B<meta>
1196
1197 This will return a B<Class::MOP::Class> instance which is related
1198 to this class. Thereby allowing B<Class::MOP::Class> to actually
1199 introspect itself.
1200
1201 As with B<Class::MOP::Attribute>, B<Class::MOP> will actually
1202 bootstrap this module by installing a number of attribute meta-objects
1203 into it's metaclass. This will allow this class to reap all the benifits
1204 of the MOP when subclassing it.
1205
1206 =back
1207
1208 =head2 Class construction
1209
1210 These methods will handle creating B<Class::MOP::Class> objects,
1211 which can be used to both create new classes, and analyze
1212 pre-existing classes.
1213
1214 This module will internally store references to all the instances
1215 you create with these methods, so that they do not need to be
1216 created any more than nessecary. Basically, they are singletons.
1217
1218 =over 4
1219
1220 =item B<create ($package_name,
1221                 version      =E<gt> ?$version,
1222                 authority    =E<gt> ?$authority,
1223                 superclasses =E<gt> ?@superclasses,
1224                 methods      =E<gt> ?%methods,
1225                 attributes   =E<gt> ?%attributes)>
1226
1227 This returns a B<Class::MOP::Class> object, bringing the specified
1228 C<$package_name> into existence and adding any of the C<$version>,
1229 C<$authority>, C<@superclasses>, C<%methods> and C<%attributes> to
1230 it.
1231
1232 =item B<create_anon_class (superclasses =E<gt> ?@superclasses,
1233                            methods      =E<gt> ?%methods,
1234                            attributes   =E<gt> ?%attributes)>
1235
1236 This will create an anonymous class, it works much like C<create> but
1237 it does not need a C<$package_name>. Instead it will create a suitably
1238 unique package name for you to stash things into.
1239
1240 On very important distinction is that anon classes are destroyed once
1241 the metaclass they are attached to goes out of scope. In the DESTROY
1242 method, the created package will be removed from the symbol table.
1243
1244 It is also worth noting that any instances created with an anon-class
1245 will keep a special reference to the anon-meta which will prevent the
1246 anon-class from going out of scope until all instances of it have also
1247 been destroyed. This however only works for HASH based instance types,
1248 as we use a special reserved slot (C<__MOP__>) to store this.
1249
1250 =item B<initialize ($package_name, %options)>
1251
1252 This initializes and returns returns a B<Class::MOP::Class> object
1253 for a given a C<$package_name>.
1254
1255 =item B<construct_class_instance (%options)>
1256
1257 This will construct an instance of B<Class::MOP::Class>, it is
1258 here so that we can actually "tie the knot" for B<Class::MOP::Class>
1259 to use C<construct_instance> once all the bootstrapping is done. This
1260 method is used internally by C<initialize> and should never be called
1261 from outside of that method really.
1262
1263 =item B<check_metaclass_compatibility>
1264
1265 This method is called as the very last thing in the
1266 C<construct_class_instance> method. This will check that the
1267 metaclass you are creating is compatible with the metaclasses of all
1268 your ancestors. For more inforamtion about metaclass compatibility
1269 see the C<About Metaclass compatibility> section in L<Class::MOP>.
1270
1271 =item B<update_package_cache_flag>
1272
1273 This will reset the package cache flag for this particular metaclass
1274 it is basically the value of the C<Class::MOP::get_package_cache_flag> 
1275 function. This is very rarely needed from outside of C<Class::MOP::Class>
1276 but in some cases you might want to use it, so it is here.
1277
1278 =item B<reset_package_cache_flag>
1279
1280 Clears the package cache flag to announce to the internals that we need 
1281 to rebuild the method map.
1282
1283 =item B<add_meta_instance_dependencies>
1284
1285 Registers this class as dependent on its superclasses.
1286
1287 Only superclasses from which this class inherits attributes will be added.
1288
1289 =item B<remove_meta_instance_depdendencies>
1290
1291 Unregisters this class from its superclasses.
1292
1293 =item B<update_meta_instance_dependencies>
1294
1295 Reregisters if necessary.
1296
1297 =item B<add_dependent_meta_instance> $metaclass
1298
1299 Registers the class as having a meta instance dependent on this class.
1300
1301 =item B<remove_dependent_meta_instance> $metaclass
1302
1303 Remove the class from the list of dependent classes.
1304
1305 =item B<invalidate_meta_instances>
1306
1307 Clears the cached meta instance for this metaclass and all of the registered
1308 classes with dependent meta instances.
1309
1310 Called by C<add_attribute> and C<remove_attribute> to recalculate the attribute
1311 slots.
1312
1313 =item B<invalidate_meta_instance>
1314
1315 Used by C<invalidate_meta_instances>.
1316
1317 =back
1318
1319 =head2 Object instance construction and cloning
1320
1321 These methods are B<entirely optional>, it is up to you whether you want
1322 to use them or not.
1323
1324 =over 4
1325
1326 =item B<instance_metaclass>
1327
1328 Returns the class name of the instance metaclass, see L<Class::MOP::Instance> 
1329 for more information on the instance metaclasses.
1330
1331 =item B<get_meta_instance>
1332
1333 Returns an instance of L<Class::MOP::Instance> to be used in the construction 
1334 of a new instance of the class. 
1335
1336 =item B<create_meta_instance>
1337
1338 Called by C<get_meta_instance> if necessary.
1339
1340 =item B<new_object (%params)>
1341
1342 This is a convience method for creating a new object of the class, and
1343 blessing it into the appropriate package as well. Ideally your class
1344 would call a C<new> this method like so:
1345
1346   sub MyClass::new {
1347       my ($class, %param) = @_;
1348       $class->meta->new_object(%params);
1349   }
1350
1351 =item B<construct_instance (%params)>
1352
1353 This method is used to construct an instance structure suitable for
1354 C<bless>-ing into your package of choice. It works in conjunction
1355 with the Attribute protocol to collect all applicable attributes.
1356
1357 This will construct an instance using a HASH ref as storage
1358 (currently only HASH references are supported). This will collect all
1359 the applicable attributes and layout out the fields in the HASH ref,
1360 it will then initialize them using either use the corresponding key
1361 in C<%params> or any default value or initializer found in the
1362 attribute meta-object.
1363
1364 =item B<clone_object ($instance, %params)>
1365
1366 This is a convience method for cloning an object instance, then
1367 blessing it into the appropriate package. This method will call
1368 C<clone_instance>, which performs a shallow copy of the object,
1369 see that methods documentation for more details. Ideally your
1370 class would call a C<clone> this method like so:
1371
1372   sub MyClass::clone {
1373       my ($self, %param) = @_;
1374       $self->meta->clone_object($self, %params);
1375   }
1376
1377 =item B<clone_instance($instance, %params)>
1378
1379 This method is a compliment of C<construct_instance> (which means if
1380 you override C<construct_instance>, you need to override this one too),
1381 and clones the instance shallowly.
1382
1383 The cloned structure returned is (like with C<construct_instance>) an
1384 unC<bless>ed HASH reference, it is your responsibility to then bless
1385 this cloned structure into the right class (which C<clone_object> will
1386 do for you).
1387
1388 As of 0.11, this method will clone the C<$instance> structure shallowly,
1389 as opposed to the deep cloning implemented in prior versions. After much
1390 thought, research and discussion, I have decided that anything but basic
1391 shallow cloning is outside the scope of the meta-object protocol. I
1392 think Yuval "nothingmuch" Kogman put it best when he said that cloning
1393 is too I<context-specific> to be part of the MOP.
1394
1395 =item B<rebless_instance($instance, ?%params)>
1396
1397 This will change the class of C<$instance> to the class of the invoking
1398 C<Class::MOP::Class>. You may only rebless the instance to a subclass of
1399 itself. You may pass in optional C<%params> which are like constructor 
1400 params and will override anything already defined in the instance.
1401
1402 =back
1403
1404 =head2 Informational
1405
1406 These are a few predicate methods for asking information about the class.
1407
1408 =over 4
1409
1410 =item B<is_anon_class>
1411
1412 This returns true if the class is a C<Class::MOP::Class> created anon class.
1413
1414 =item B<is_mutable>
1415
1416 This returns true if the class is still mutable.
1417
1418 =item B<is_immutable>
1419
1420 This returns true if the class has been made immutable.
1421
1422 =item B<is_pristine>
1423
1424 Checks whether the class has any data that will be lost if C<reinitialize> is
1425 called.
1426
1427 =back
1428
1429 =head2 Inheritance Relationships
1430
1431 =over 4
1432
1433 =item B<superclasses (?@superclasses)>
1434
1435 This is a read-write attribute which represents the superclass
1436 relationships of the class the B<Class::MOP::Class> instance is
1437 associated with. Basically, it can get and set the C<@ISA> for you.
1438
1439 =item B<class_precedence_list>
1440
1441 This computes the a list of all the class's ancestors in the same order
1442 in which method dispatch will be done. This is similair to what 
1443 B<Class::ISA::super_path> does, but we don't remove duplicate names.
1444
1445 =item B<linearized_isa>
1446
1447 This returns a list based on C<class_precedence_list> but with all 
1448 duplicates removed.
1449
1450 =item B<subclasses>
1451
1452 This returns a list of subclasses for this class. 
1453
1454 =back
1455
1456 =head2 Methods
1457
1458 =over 4
1459
1460 =item B<get_method_map>
1461
1462 Returns a HASH ref of name to CODE reference mapping for this class.
1463
1464 =item B<method_metaclass>
1465
1466 Returns the class name of the method metaclass, see L<Class::MOP::Method> 
1467 for more information on the method metaclasses.
1468
1469 =item B<wrap_method_body(%attrs)>
1470
1471 Wrap a code ref (C<$attrs{body>) with C<method_metaclass>.
1472
1473 =item B<add_method ($method_name, $method)>
1474
1475 This will take a C<$method_name> and CODE reference or meta method
1476 objectand install it into the class's package.
1477
1478 You are strongly encouraged to pass a meta method object instead of a
1479 code reference. If you do so, that object gets stored as part of the
1480 class's method map, providing more useful information about the method
1481 for introspection.
1482
1483 When you provide a method object, this method will clone that object
1484 if the object's package name does not match the class name. This lets
1485 us track the original source of any methods added from other classes
1486 (notably Moose roles).
1487
1488 B<NOTE>:
1489 This does absolutely nothing special to C<$method>
1490 other than use B<Sub::Name> to make sure it is tagged with the
1491 correct name, and therefore show up correctly in stack traces and
1492 such.
1493
1494 =item B<has_method ($method_name)>
1495
1496 This just provides a simple way to check if the class implements
1497 a specific C<$method_name>. It will I<not> however, attempt to check
1498 if the class inherits the method (use C<UNIVERSAL::can> for that).
1499
1500 This will correctly handle functions defined outside of the package
1501 that use a fully qualified name (C<sub Package::name { ... }>).
1502
1503 This will correctly handle functions renamed with B<Sub::Name> and
1504 installed using the symbol tables. However, if you are naming the
1505 subroutine outside of the package scope, you must use the fully
1506 qualified name, including the package name, for C<has_method> to
1507 correctly identify it.
1508
1509 This will attempt to correctly ignore functions imported from other
1510 packages using B<Exporter>. It breaks down if the function imported
1511 is an C<__ANON__> sub (such as with C<use constant>), which very well
1512 may be a valid method being applied to the class.
1513
1514 In short, this method cannot always be trusted to determine if the
1515 C<$method_name> is actually a method. However, it will DWIM about
1516 90% of the time, so it's a small trade off I think.
1517
1518 =item B<get_method ($method_name)>
1519
1520 This will return a Class::MOP::Method instance related to the specified
1521 C<$method_name>, or return undef if that method does not exist.
1522
1523 The Class::MOP::Method is codifiable, so you can use it like a normal
1524 CODE reference, see L<Class::MOP::Method> for more information.
1525
1526 =item B<find_method_by_name ($method_name)>
1527
1528 This will return a CODE reference of the specified C<$method_name>,
1529 or return undef if that method does not exist.
1530
1531 Unlike C<get_method> this will also look in the superclasses.
1532
1533 =item B<remove_method ($method_name)>
1534
1535 This will attempt to remove a given C<$method_name> from the class.
1536 It will return the CODE reference that it has removed, and will
1537 attempt to use B<Sub::Name> to clear the methods associated name.
1538
1539 =item B<get_method_list>
1540
1541 This will return a list of method names for all I<locally> defined
1542 methods. It does B<not> provide a list of all applicable methods,
1543 including any inherited ones. If you want a list of all applicable
1544 methods, use the C<compute_all_applicable_methods> method.
1545
1546 =item B<get_all_methods>
1547
1548 This will traverse the inheritance heirachy and return a list of all
1549 the applicable L<Class::MOP::Method> objects for this class.
1550
1551 =item B<compute_all_applicable_methods>
1552
1553 Deprecated.
1554
1555 This method returns a list of hashes describing the all the methods of the
1556 class.
1557
1558 Use L<get_all_methods>, which is easier/better/faster. This method predates
1559 L<Class::MOP::Method>.
1560
1561 =item B<find_all_methods_by_name ($method_name)>
1562
1563 This will traverse the inheritence hierarchy and locate all methods
1564 with a given C<$method_name>. Similar to
1565 C<compute_all_applicable_methods> it returns a list of HASH references
1566 with the following information; method name (which will always be the
1567 same as C<$method_name>), the name of the class in which the method
1568 lives and a CODE reference for the actual method.
1569
1570 The list of methods produced is a distinct list, meaning there are no
1571 duplicates in it. This is especially useful for things like object
1572 initialization and destruction where you only want the method called
1573 once, and in the correct order.
1574
1575 =item B<find_next_method_by_name ($method_name)>
1576
1577 This will return the first method to match a given C<$method_name> in
1578 the superclasses, this is basically equivalent to calling
1579 C<SUPER::$method_name>, but it can be dispatched at runtime.
1580
1581 =item B<alias_method ($method_name, $method)>
1582
1583 B<NOTE>: This method is now deprecated. Just use C<add_method>
1584 instead.
1585
1586 =back
1587
1588 =head2 Method Modifiers
1589
1590 Method modifiers are a concept borrowed from CLOS, in which a method
1591 can be wrapped with I<before>, I<after> and I<around> method modifiers
1592 that will be called everytime the method is called.
1593
1594 =head3 How method modifiers work?
1595
1596 Method modifiers work by wrapping the original method and then replacing
1597 it in the classes symbol table. The wrappers will handle calling all the
1598 modifiers in the appropariate orders and preserving the calling context
1599 for the original method.
1600
1601 Each method modifier serves a particular purpose, which may not be
1602 obvious to users of other method wrapping modules. To start with, the
1603 return values of I<before> and I<after> modifiers are ignored. This is
1604 because thier purpose is B<not> to filter the input and output of the
1605 primary method (this is done with an I<around> modifier). This may seem
1606 like an odd restriction to some, but doing this allows for simple code
1607 to be added at the begining or end of a method call without jeapordizing
1608 the normal functioning of the primary method or placing any extra
1609 responsibility on the code of the modifier. Of course if you have more
1610 complex needs, then use the I<around> modifier, which uses a variation
1611 of continutation passing style to allow for a high degree of flexibility.
1612
1613 Before and around modifiers are called in last-defined-first-called order,
1614 while after modifiers are called in first-defined-first-called order. So
1615 the call tree might looks something like this:
1616
1617   before 2
1618    before 1
1619     around 2
1620      around 1
1621       primary
1622      around 1
1623     around 2
1624    after 1
1625   after 2
1626
1627 To see examples of using method modifiers, see the following examples
1628 included in the distribution; F<InstanceCountingClass>, F<Perl6Attribute>,
1629 F<AttributesWithHistory> and F<C3MethodDispatchOrder>. There is also a
1630 classic CLOS usage example in the test F<017_add_method_modifier.t>.
1631
1632 =head3 What is the performance impact?
1633
1634 Of course there is a performance cost associated with method modifiers,
1635 but we have made every effort to make that cost be directly proportional
1636 to the amount of modifier features you utilize.
1637
1638 The wrapping method does it's best to B<only> do as much work as it
1639 absolutely needs to. In order to do this we have moved some of the
1640 performance costs to set-up time, where they are easier to amortize.
1641
1642 All this said, my benchmarks have indicated the following:
1643
1644   simple wrapper with no modifiers             100% slower
1645   simple wrapper with simple before modifier   400% slower
1646   simple wrapper with simple after modifier    450% slower
1647   simple wrapper with simple around modifier   500-550% slower
1648   simple wrapper with all 3 modifiers          1100% slower
1649
1650 These numbers may seem daunting, but you must remember, every feature
1651 comes with some cost. To put things in perspective, just doing a simple
1652 C<AUTOLOAD> which does nothing but extract the name of the method called
1653 and return it costs about 400% over a normal method call.
1654
1655 =over 4
1656
1657 =item B<add_before_method_modifier ($method_name, $code)>
1658
1659 This will wrap the method at C<$method_name> and the supplied C<$code>
1660 will be passed the C<@_> arguments, and called before the original
1661 method is called. As specified above, the return value of the I<before>
1662 method modifiers is ignored, and it's ability to modify C<@_> is
1663 fairly limited. If you need to do either of these things, use an
1664 C<around> method modifier.
1665
1666 =item B<add_after_method_modifier ($method_name, $code)>
1667
1668 This will wrap the method at C<$method_name> so that the original
1669 method will be called, it's return values stashed, and then the
1670 supplied C<$code> will be passed the C<@_> arguments, and called.
1671 As specified above, the return value of the I<after> method
1672 modifiers is ignored, and it cannot modify the return values of
1673 the original method. If you need to do either of these things, use an
1674 C<around> method modifier.
1675
1676 =item B<add_around_method_modifier ($method_name, $code)>
1677
1678 This will wrap the method at C<$method_name> so that C<$code>
1679 will be called and passed the original method as an extra argument
1680 at the begining of the C<@_> argument list. This is a variation of
1681 continuation passing style, where the function prepended to C<@_>
1682 can be considered a continuation. It is up to C<$code> if it calls
1683 the original method or not, there is no restriction on what the
1684 C<$code> can or cannot do.
1685
1686 =back
1687
1688 =head2 Attributes
1689
1690 It should be noted that since there is no one consistent way to define
1691 the attributes of a class in Perl 5. These methods can only work with
1692 the information given, and can not easily discover information on
1693 their own. See L<Class::MOP::Attribute> for more details.
1694
1695 =over 4
1696
1697 =item B<attribute_metaclass>
1698
1699 Returns the class name of the attribute metaclass, see L<Class::MOP::Attribute> 
1700 for more information on the attribute metaclasses.
1701
1702 =item B<get_attribute_map>
1703
1704 This returns a HASH ref of name to attribute meta-object mapping.
1705
1706 =item B<add_attribute ($attribute_meta_object | ($attribute_name, %attribute_spec))>
1707
1708 This stores the C<$attribute_meta_object> (or creates one from the
1709 C<$attribute_name> and C<%attribute_spec>) in the B<Class::MOP::Class>
1710 instance associated with the given class. Unlike methods, attributes
1711 within the MOP are stored as meta-information only. They will be used
1712 later to construct instances from (see C<construct_instance> above).
1713 More details about the attribute meta-objects can be found in the
1714 L<Class::MOP::Attribute> or the L<Class::MOP/The Attribute protocol>
1715 section.
1716
1717 It should be noted that any accessor, reader/writer or predicate
1718 methods which the C<$attribute_meta_object> has will be installed
1719 into the class at this time.
1720
1721 B<NOTE>
1722 If an attribute already exists for C<$attribute_name>, the old one
1723 will be removed (as well as removing all it's accessors), and then
1724 the new one added.
1725
1726 =item B<has_attribute ($attribute_name)>
1727
1728 Checks to see if this class has an attribute by the name of
1729 C<$attribute_name> and returns a boolean.
1730
1731 =item B<get_attribute ($attribute_name)>
1732
1733 Returns the attribute meta-object associated with C<$attribute_name>,
1734 if none is found, it will return undef.
1735
1736 =item B<remove_attribute ($attribute_name)>
1737
1738 This will remove the attribute meta-object stored at
1739 C<$attribute_name>, then return the removed attribute meta-object.
1740
1741 B<NOTE:>
1742 Removing an attribute will only affect future instances of
1743 the class, it will not make any attempt to remove the attribute from
1744 any existing instances of the class.
1745
1746 It should be noted that any accessor, reader/writer or predicate
1747 methods which the attribute meta-object stored at C<$attribute_name>
1748 has will be removed from the class at this time. This B<will> make
1749 these attributes somewhat inaccessable in previously created
1750 instances. But if you are crazy enough to do this at runtime, then
1751 you are crazy enough to deal with something like this :).
1752
1753 =item B<get_attribute_list>
1754
1755 This returns a list of attribute names which are defined in the local
1756 class. If you want a list of all applicable attributes for a class,
1757 use the C<compute_all_applicable_attributes> method.
1758
1759 =item B<compute_all_applicable_attributes>
1760
1761 =item B<get_all_attributes>
1762
1763 This will traverse the inheritance heirachy and return a list of all
1764 the applicable L<Class::MOP::Attribute> objects for this class.
1765
1766 C<get_all_attributes> is an alias for consistency with C<get_all_methods>.
1767
1768 =item B<find_attribute_by_name ($attr_name)>
1769
1770 This method will traverse the inheritance heirachy and find the
1771 first attribute whose name matches C<$attr_name>, then return it.
1772 It will return undef if nothing is found.
1773
1774 =back
1775
1776 =head2 Class Immutability
1777
1778 =over 4
1779
1780 =item B<make_immutable (%options)>
1781
1782 This method will invoke a tranforamtion upon the class which will
1783 make it immutable. Details of this transformation can be found in
1784 the L<Class::MOP::Immutable> documentation.
1785
1786 =item B<make_mutable>
1787
1788 This method will reverse tranforamtion upon the class which
1789 made it immutable.
1790
1791 =item B<get_immutable_transformer>
1792
1793 Return a transformer suitable for making this class immutable or, if this
1794 class is immutable, the transformer used to make it immutable.
1795
1796 =item B<get_immutable_options>
1797
1798 If the class is immutable, return the options used to make it immutable.
1799
1800 =item B<create_immutable_transformer>
1801
1802 Create a transformer suitable for making this class immutable
1803
1804 =back
1805
1806 =head1 AUTHORS
1807
1808 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1809
1810 =head1 COPYRIGHT AND LICENSE
1811
1812 Copyright 2006-2008 by Infinity Interactive, Inc.
1813
1814 L<http://www.iinteractive.com>
1815
1816 This library is free software; you can redistribute it and/or modify
1817 it under the same terms as Perl itself.
1818
1819 =cut