2 package Class::MOP::Class;
8 use Scalar::Util 'blessed', 'reftype', 'weaken';
9 use Sub::Name 'subname';
10 use B 'svref_2object';
12 our $VERSION = '0.16';
14 use base 'Class::MOP::Module';
16 use Class::MOP::Instance;
20 sub meta { Class::MOP::Class->initialize(blessed($_[0]) || $_[0]) }
25 # we need a sufficiently annoying prefix
26 # this should suffice for now, this is
27 # used in a couple of places below, so
28 # need to put it up here for now.
29 my $ANON_CLASS_PREFIX = 'Class::MOP::Class::__ANON__::SERIAL::';
34 # Metaclasses are singletons, so we cache them here.
35 # there is no need to worry about destruction though
36 # because they should die only when the program dies.
37 # After all, do package definitions even get reaped?
40 # means of accessing all the metaclasses that have
41 # been initialized thus far (for mugwumps obj browser)
42 sub get_all_metaclasses { %METAS }
43 sub get_all_metaclass_instances { values %METAS }
44 sub get_all_metaclass_names { keys %METAS }
48 my $package_name = shift;
49 (defined $package_name && $package_name && !blessed($package_name))
50 || confess "You must pass a package name and it cannot be blessed";
51 $class->construct_class_instance(':package' => $package_name, @_);
56 my $package_name = shift;
57 (defined $package_name && $package_name && !blessed($package_name))
58 || confess "You must pass a package name and it cannot be blessed";
59 $METAS{$package_name} = undef;
60 $class->construct_class_instance(':package' => $package_name, @_);
63 # NOTE: (meta-circularity)
64 # this is a special form of &construct_instance
65 # (see below), which is used to construct class
66 # meta-object instances for any Class::MOP::*
67 # class. All other classes will use the more
68 # normal &construct_instance.
69 sub construct_class_instance {
72 my $package_name = $options{':package'};
73 (defined $package_name && $package_name)
74 || confess "You must pass a package name";
76 # return the metaclass if we have it cached,
77 # and it is still defined (it has not been
78 # reaped by DESTROY yet, which can happen
79 # annoyingly enough during global destruction)
80 return $METAS{$package_name}
81 if exists $METAS{$package_name} && defined $METAS{$package_name};
84 # we need to deal with the possibility
85 # of class immutability here, and then
86 # get the name of the class appropriately
87 $class = (blessed($class)
88 ? ($class->is_immutable
89 ? $class->get_mutable_metaclass_name()
93 $class = blessed($class) || $class;
94 # now create the metaclass
96 if ($class =~ /^Class::MOP::/) {
98 '$:package' => $package_name,
100 '$:attribute_metaclass' => $options{':attribute_metaclass'} || 'Class::MOP::Attribute',
101 '$:method_metaclass' => $options{':method_metaclass'} || 'Class::MOP::Method',
102 '$:instance_metaclass' => $options{':instance_metaclass'} || 'Class::MOP::Instance',
107 # it is safe to use meta here because
108 # class will always be a subclass of
109 # Class::MOP::Class, which defines meta
110 $meta = $class->meta->construct_instance(%options)
112 # and check the metaclass compatibility
113 $meta->check_metaclass_compatability();
114 $METAS{$package_name} = $meta;
116 # we need to weaken any anon classes
117 # so that they can call DESTROY properly
118 weaken($METAS{$package_name})
119 if $package_name =~ /^$ANON_CLASS_PREFIX/;
123 sub check_metaclass_compatability {
126 # this is always okay ...
127 return if blessed($self) eq 'Class::MOP::Class' &&
128 $self->instance_metaclass eq 'Class::MOP::Instance';
130 my @class_list = $self->class_precedence_list;
131 shift @class_list; # shift off $self->name
133 foreach my $class_name (@class_list) {
134 my $meta = $METAS{$class_name} || next;
137 # we need to deal with the possibility
138 # of class immutability here, and then
139 # get the name of the class appropriately
140 my $meta_type = ($meta->is_immutable
141 ? $meta->get_mutable_metaclass_name()
144 ($self->isa($meta_type))
145 || confess $self->name . "->meta => (" . (blessed($self)) . ")" .
146 " is not compatible with the " .
147 $class_name . "->meta => (" . ($meta_type) . ")";
149 # we also need to check that instance metaclasses
150 # are compatabile in the same the class.
151 ($self->instance_metaclass->isa($meta->instance_metaclass))
152 || confess $self->name . "->meta => (" . ($self->instance_metaclass) . ")" .
153 " is not compatible with the " .
154 $class_name . "->meta => (" . ($meta->instance_metaclass) . ")";
163 # this should be sufficient, if you have a
164 # use case where it is not, write a test and
166 my $ANON_CLASS_SERIAL = 0;
168 sub create_anon_class {
169 my ($class, %options) = @_;
170 my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
171 return $class->create($package_name, '0.00', %options);
176 # this will only get called for
177 # anon-classes, all other calls
178 # are assumed to occur during
179 # global destruction and so don't
180 # really need to be handled explicitly
183 return unless $self->name =~ /^$ANON_CLASS_PREFIX/;
184 my ($serial_id) = ($self->name =~ /^$ANON_CLASS_PREFIX(\d+)/);
186 foreach my $key (keys %{$ANON_CLASS_PREFIX . $serial_id}) {
187 delete ${$ANON_CLASS_PREFIX . $serial_id}{$key};
189 delete ${'main::' . $ANON_CLASS_PREFIX}{$serial_id . '::'};
192 # creating classes with MOP ...
195 my ($class, $package_name, $package_version, %options) = @_;
196 (defined $package_name && $package_name)
197 || confess "You must pass a package name";
198 my $code = "package $package_name;";
199 $code .= "\$$package_name\:\:VERSION = '$package_version';"
200 if defined $package_version;
202 confess "creation of $package_name failed : $@" if $@;
203 my $meta = $class->initialize($package_name);
205 $meta->add_method('meta' => sub {
206 $class->initialize(blessed($_[0]) || $_[0]);
209 $meta->superclasses(@{$options{superclasses}})
210 if exists $options{superclasses};
212 # process attributes first, so that they can
213 # install accessors, but locally defined methods
214 # can then overwrite them. It is maybe a little odd, but
215 # I think this should be the order of things.
216 if (exists $options{attributes}) {
217 foreach my $attr (@{$options{attributes}}) {
218 $meta->add_attribute($attr);
221 if (exists $options{methods}) {
222 foreach my $method_name (keys %{$options{methods}}) {
223 $meta->add_method($method_name, $options{methods}->{$method_name});
232 # all these attribute readers will be bootstrapped
233 # away in the Class::MOP bootstrap section
235 sub get_attribute_map { $_[0]->{'%:attributes'} }
236 sub attribute_metaclass { $_[0]->{'$:attribute_metaclass'} }
237 sub method_metaclass { $_[0]->{'$:method_metaclass'} }
238 sub instance_metaclass { $_[0]->{'$:instance_metaclass'} }
240 # Instance Construction & Cloning
245 # we need to protect the integrity of the
246 # Class::MOP::Class singletons here, so we
247 # delegate this to &construct_class_instance
248 # which will deal with the singletons
249 return $class->construct_class_instance(@_)
250 if $class->name->isa('Class::MOP::Class');
251 return $class->construct_instance(@_);
254 sub construct_instance {
255 my ($class, %params) = @_;
256 my $meta_instance = $class->get_meta_instance();
257 my $instance = $meta_instance->create_instance();
258 foreach my $attr ($class->compute_all_applicable_attributes()) {
259 $attr->initialize_instance_slot($meta_instance, $instance, \%params);
264 sub get_meta_instance {
266 return $class->instance_metaclass->new(
268 $class->compute_all_applicable_attributes()
274 my $instance = shift;
275 (blessed($instance) && $instance->isa($class->name))
276 || confess "You must pass an instance ($instance) of the metaclass (" . $class->name . ")";
278 # we need to protect the integrity of the
279 # Class::MOP::Class singletons here, they
280 # should not be cloned.
281 return $instance if $instance->isa('Class::MOP::Class');
282 $class->clone_instance($instance, @_);
286 my ($class, $instance, %params) = @_;
288 || confess "You can only clone instances, \$self is not a blessed instance";
289 my $meta_instance = $class->get_meta_instance();
290 my $clone = $meta_instance->clone_instance($instance);
291 foreach my $key (keys %params) {
292 next unless $meta_instance->is_valid_slot($key);
293 $meta_instance->set_slot_value($clone, $key, $params{$key});
305 @{$self->name . '::ISA'} = @supers;
307 # we need to check the metaclass
308 # compatability here so that we can
309 # be sure that the superclass is
310 # not potentially creating an issues
311 # we don't know about
312 $self->check_metaclass_compatability();
314 @{$self->name . '::ISA'};
317 sub class_precedence_list {
320 # We need to check for ciruclar inheirtance here.
321 # This will do nothing if all is well, and blow
322 # up otherwise. Yes, it's an ugly hack, better
323 # suggestions are welcome.
324 { ($self->name || return)->isa('This is a test for circular inheritance') }
325 # ... and now back to our regularly scheduled program
329 $self->initialize($_)->class_precedence_list()
330 } $self->superclasses()
337 my ($self, $method_name, $method) = @_;
338 (defined $method_name && $method_name)
339 || confess "You must define a method name";
340 # use reftype here to allow for blessed subs ...
341 ('CODE' eq (reftype($method) || ''))
342 || confess "Your code block must be a CODE reference";
343 my $full_method_name = ($self->name . '::' . $method_name);
345 $method = $self->method_metaclass->wrap($method) unless blessed($method);
348 no warnings 'redefine';
349 *{$full_method_name} = subname $full_method_name => $method;
353 my $fetch_and_prepare_method = sub {
354 my ($self, $method_name) = @_;
356 my $method = $self->get_method($method_name);
357 # if we dont have local ...
359 # try to find the next method
360 $method = $self->find_next_method_by_name($method_name);
361 # die if it does not exist
363 || confess "The method '$method_name' is not found in the inherience hierarchy for this class";
364 # and now make sure to wrap it
365 # even if it is already wrapped
366 # because we need a new sub ref
367 $method = Class::MOP::Method::Wrapped->wrap($method);
370 # now make sure we wrap it properly
371 $method = Class::MOP::Method::Wrapped->wrap($method)
372 unless $method->isa('Class::MOP::Method::Wrapped');
374 $self->add_method($method_name => $method);
378 sub add_before_method_modifier {
379 my ($self, $method_name, $method_modifier) = @_;
380 (defined $method_name && $method_name)
381 || confess "You must pass in a method name";
382 my $method = $fetch_and_prepare_method->($self, $method_name);
383 $method->add_before_modifier(subname ':before' => $method_modifier);
386 sub add_after_method_modifier {
387 my ($self, $method_name, $method_modifier) = @_;
388 (defined $method_name && $method_name)
389 || confess "You must pass in a method name";
390 my $method = $fetch_and_prepare_method->($self, $method_name);
391 $method->add_after_modifier(subname ':after' => $method_modifier);
394 sub add_around_method_modifier {
395 my ($self, $method_name, $method_modifier) = @_;
396 (defined $method_name && $method_name)
397 || confess "You must pass in a method name";
398 my $method = $fetch_and_prepare_method->($self, $method_name);
399 $method->add_around_modifier(subname ':around' => $method_modifier);
403 # the methods above used to be named like this:
404 # ${pkg}::${method}:(before|after|around)
405 # but this proved problematic when using one modifier
406 # to wrap multiple methods (something which is likely
407 # to happen pretty regularly IMO). So instead of naming
408 # it like this, I have chosen to just name them purely
409 # with their modifier names, like so:
410 # :(before|after|around)
411 # The fact is that in a stack trace, it will be fairly
412 # evident from the context what method they are attached
413 # to, and so don't need the fully qualified name.
417 my ($self, $method_name, $method) = @_;
418 (defined $method_name && $method_name)
419 || confess "You must define a method name";
420 # use reftype here to allow for blessed subs ...
421 ('CODE' eq (reftype($method) || ''))
422 || confess "Your code block must be a CODE reference";
423 my $full_method_name = ($self->name . '::' . $method_name);
425 $method = $self->method_metaclass->wrap($method) unless blessed($method);
428 no warnings 'redefine';
429 *{$full_method_name} = $method;
432 sub find_method_by_name {
433 my ( $self, $method_name ) = @_;
435 return $self->name->can( $method_name );
439 my ($self, $method_name) = @_;
440 (defined $method_name && $method_name)
441 || confess "You must define a method name";
443 my $sub_name = ($self->name . '::' . $method_name);
446 return 0 if !defined(&{$sub_name});
447 my $method = \&{$sub_name};
448 return 0 if (svref_2object($method)->GV->STASH->NAME || '') ne $self->name &&
449 (svref_2object($method)->GV->NAME || '') ne '__ANON__';
451 #if ( $self->name->can("meta") ) {
452 # don't bless (destructive operation) classes that didn't ask for it
454 # at this point we are relatively sure
455 # it is our method, so we bless/wrap it
456 $self->method_metaclass->wrap($method) unless blessed($method);
462 my ($self, $method_name) = @_;
463 (defined $method_name && $method_name)
464 || confess "You must define a method name";
466 return unless $self->has_method($method_name);
469 return \&{$self->name . '::' . $method_name};
473 my ($self, $method_name) = @_;
474 (defined $method_name && $method_name)
475 || confess "You must define a method name";
477 my $removed_method = $self->get_method($method_name);
480 delete ${$self->name . '::'}{$method_name}
481 if defined $removed_method;
483 return $removed_method;
486 sub get_method_list {
489 grep { $self->has_method($_) } keys %{$self->name . '::'};
492 sub compute_all_applicable_methods {
495 # keep a record of what we have seen
496 # here, this will handle all the
497 # inheritence issues because we are
498 # using the &class_precedence_list
499 my (%seen_class, %seen_method);
500 foreach my $class ($self->class_precedence_list()) {
501 next if $seen_class{$class};
502 $seen_class{$class}++;
503 # fetch the meta-class ...
504 my $meta = $self->initialize($class);
505 foreach my $method_name ($meta->get_method_list()) {
506 next if exists $seen_method{$method_name};
507 $seen_method{$method_name}++;
509 name => $method_name,
511 code => $meta->get_method($method_name)
518 sub find_all_methods_by_name {
519 my ($self, $method_name) = @_;
520 (defined $method_name && $method_name)
521 || confess "You must define a method name to find";
523 # keep a record of what we have seen
524 # here, this will handle all the
525 # inheritence issues because we are
526 # using the &class_precedence_list
528 foreach my $class ($self->class_precedence_list()) {
529 next if $seen_class{$class};
530 $seen_class{$class}++;
531 # fetch the meta-class ...
532 my $meta = $self->initialize($class);
534 name => $method_name,
536 code => $meta->get_method($method_name)
537 } if $meta->has_method($method_name);
542 sub find_next_method_by_name {
543 my ($self, $method_name) = @_;
544 (defined $method_name && $method_name)
545 || confess "You must define a method name to find";
546 # keep a record of what we have seen
547 # here, this will handle all the
548 # inheritence issues because we are
549 # using the &class_precedence_list
551 my @cpl = $self->class_precedence_list();
552 shift @cpl; # discard ourselves
553 foreach my $class (@cpl) {
554 next if $seen_class{$class};
555 $seen_class{$class}++;
556 # fetch the meta-class ...
557 my $meta = $self->initialize($class);
558 return $meta->get_method($method_name)
559 if $meta->has_method($method_name);
568 # either we have an attribute object already
569 # or we need to create one from the args provided
570 my $attribute = blessed($_[0]) ? $_[0] : $self->attribute_metaclass->new(@_);
571 # make sure it is derived from the correct type though
572 ($attribute->isa('Class::MOP::Attribute'))
573 || confess "Your attribute must be an instance of Class::MOP::Attribute (or a subclass)";
574 $attribute->attach_to_class($self);
575 $attribute->install_accessors();
576 $self->get_attribute_map->{$attribute->name} = $attribute;
579 # in theory we have to tell everyone the slot structure may have changed
583 my ($self, $attribute_name) = @_;
584 (defined $attribute_name && $attribute_name)
585 || confess "You must define an attribute name";
586 exists $self->get_attribute_map->{$attribute_name} ? 1 : 0;
590 my ($self, $attribute_name) = @_;
591 (defined $attribute_name && $attribute_name)
592 || confess "You must define an attribute name";
593 return $self->get_attribute_map->{$attribute_name}
594 if $self->has_attribute($attribute_name);
598 sub remove_attribute {
599 my ($self, $attribute_name) = @_;
600 (defined $attribute_name && $attribute_name)
601 || confess "You must define an attribute name";
602 my $removed_attribute = $self->get_attribute_map->{$attribute_name};
603 return unless defined $removed_attribute;
604 delete $self->get_attribute_map->{$attribute_name};
605 $removed_attribute->remove_accessors();
606 $removed_attribute->detach_from_class();
607 return $removed_attribute;
610 sub get_attribute_list {
612 keys %{$self->get_attribute_map};
615 sub compute_all_applicable_attributes {
618 # keep a record of what we have seen
619 # here, this will handle all the
620 # inheritence issues because we are
621 # using the &class_precedence_list
622 my (%seen_class, %seen_attr);
623 foreach my $class ($self->class_precedence_list()) {
624 next if $seen_class{$class};
625 $seen_class{$class}++;
626 # fetch the meta-class ...
627 my $meta = $self->initialize($class);
628 foreach my $attr_name ($meta->get_attribute_list()) {
629 next if exists $seen_attr{$attr_name};
630 $seen_attr{$attr_name}++;
631 push @attrs => $meta->get_attribute($attr_name);
637 sub find_attribute_by_name {
638 my ($self, $attr_name) = @_;
639 # keep a record of what we have seen
640 # here, this will handle all the
641 # inheritence issues because we are
642 # using the &class_precedence_list
644 foreach my $class ($self->class_precedence_list()) {
645 next if $seen_class{$class};
646 $seen_class{$class}++;
647 # fetch the meta-class ...
648 my $meta = $self->initialize($class);
649 return $meta->get_attribute($attr_name)
650 if $meta->has_attribute($attr_name);
658 sub is_immutable { 0 }
661 return Class::MOP::Class::Immutable->make_metaclass_immutable(@_);
672 Class::MOP::Class - Class Meta Object
676 # assuming that class Foo
677 # has been defined, you can
679 # use this for introspection ...
681 # add a method to Foo ...
682 Foo->meta->add_method('bar' => sub { ... })
684 # get a list of all the classes searched
685 # the method dispatcher in the correct order
686 Foo->meta->class_precedence_list()
688 # remove a method from Foo
689 Foo->meta->remove_method('bar');
691 # or use this to actually create classes ...
693 Class::MOP::Class->create('Bar' => '0.01' => (
694 superclasses => [ 'Foo' ],
696 Class::MOP:::Attribute->new('$bar'),
697 Class::MOP:::Attribute->new('$baz'),
700 calculate_bar => sub { ... },
701 construct_baz => sub { ... }
707 This is the largest and currently most complex part of the Perl 5
708 meta-object protocol. It controls the introspection and
709 manipulation of Perl 5 classes (and it can create them too). The
710 best way to understand what this module can do, is to read the
711 documentation for each of it's methods.
715 =head2 Self Introspection
721 This will return a B<Class::MOP::Class> instance which is related
722 to this class. Thereby allowing B<Class::MOP::Class> to actually
725 As with B<Class::MOP::Attribute>, B<Class::MOP> will actually
726 bootstrap this module by installing a number of attribute meta-objects
727 into it's metaclass. This will allow this class to reap all the benifits
728 of the MOP when subclassing it.
730 =item B<get_all_metaclasses>
732 This will return an hash of all the metaclass instances that have
733 been cached by B<Class::MOP::Class> keyed by the package name.
735 =item B<get_all_metaclass_instances>
737 This will return an array of all the metaclass instances that have
738 been cached by B<Class::MOP::Class>.
740 =item B<get_all_metaclass_names>
742 This will return an array of all the metaclass names that have
743 been cached by B<Class::MOP::Class>.
747 =head2 Class construction
749 These methods will handle creating B<Class::MOP::Class> objects,
750 which can be used to both create new classes, and analyze
751 pre-existing classes.
753 This module will internally store references to all the instances
754 you create with these methods, so that they do not need to be
755 created any more than nessecary. Basically, they are singletons.
759 =item B<create ($package_name, ?$package_version,
760 superclasses =E<gt> ?@superclasses,
761 methods =E<gt> ?%methods,
762 attributes =E<gt> ?%attributes)>
764 This returns a B<Class::MOP::Class> object, bringing the specified
765 C<$package_name> into existence and adding any of the
766 C<$package_version>, C<@superclasses>, C<%methods> and C<%attributes>
769 =item B<create_anon_class (superclasses =E<gt> ?@superclasses,
770 methods =E<gt> ?%methods,
771 attributes =E<gt> ?%attributes)>
773 This will create an anonymous class, it works much like C<create> but
774 it does not need a C<$package_name>. Instead it will create a suitably
775 unique package name for you to stash things into.
777 =item B<initialize ($package_name, %options)>
779 This initializes and returns returns a B<Class::MOP::Class> object
780 for a given a C<$package_name>.
782 =item B<reinitialize ($package_name, %options)>
784 This removes the old metaclass, and creates a new one in it's place.
785 Do B<not> use this unless you really know what you are doing, it could
786 very easily make a very large mess of your program.
788 =item B<construct_class_instance (%options)>
790 This will construct an instance of B<Class::MOP::Class>, it is
791 here so that we can actually "tie the knot" for B<Class::MOP::Class>
792 to use C<construct_instance> once all the bootstrapping is done. This
793 method is used internally by C<initialize> and should never be called
794 from outside of that method really.
796 =item B<check_metaclass_compatability>
798 This method is called as the very last thing in the
799 C<construct_class_instance> method. This will check that the
800 metaclass you are creating is compatible with the metaclasses of all
801 your ancestors. For more inforamtion about metaclass compatibility
802 see the C<About Metaclass compatibility> section in L<Class::MOP>.
806 =head2 Object instance construction and cloning
808 These methods are B<entirely optional>, it is up to you whether you want
813 =item B<instance_metaclass>
815 =item B<get_meta_instance>
817 =item B<new_object (%params)>
819 This is a convience method for creating a new object of the class, and
820 blessing it into the appropriate package as well. Ideally your class
821 would call a C<new> this method like so:
824 my ($class, %param) = @_;
825 $class->meta->new_object(%params);
828 Of course the ideal place for this would actually be in C<UNIVERSAL::>
829 but that is considered bad style, so we do not do that.
831 =item B<construct_instance (%params)>
833 This method is used to construct an instace structure suitable for
834 C<bless>-ing into your package of choice. It works in conjunction
835 with the Attribute protocol to collect all applicable attributes.
837 This will construct and instance using a HASH ref as storage
838 (currently only HASH references are supported). This will collect all
839 the applicable attributes and layout out the fields in the HASH ref,
840 it will then initialize them using either use the corresponding key
841 in C<%params> or any default value or initializer found in the
842 attribute meta-object.
844 =item B<clone_object ($instance, %params)>
846 This is a convience method for cloning an object instance, then
847 blessing it into the appropriate package. This method will call
848 C<clone_instance>, which performs a shallow copy of the object,
849 see that methods documentation for more details. Ideally your
850 class would call a C<clone> this method like so:
853 my ($self, %param) = @_;
854 $self->meta->clone_object($self, %params);
857 Of course the ideal place for this would actually be in C<UNIVERSAL::>
858 but that is considered bad style, so we do not do that.
860 =item B<clone_instance($instance, %params)>
862 This method is a compliment of C<construct_instance> (which means if
863 you override C<construct_instance>, you need to override this one too),
864 and clones the instance shallowly.
866 The cloned structure returned is (like with C<construct_instance>) an
867 unC<bless>ed HASH reference, it is your responsibility to then bless
868 this cloned structure into the right class (which C<clone_object> will
871 As of 0.11, this method will clone the C<$instance> structure shallowly,
872 as opposed to the deep cloning implemented in prior versions. After much
873 thought, research and discussion, I have decided that anything but basic
874 shallow cloning is outside the scope of the meta-object protocol. I
875 think Yuval "nothingmuch" Kogman put it best when he said that cloning
876 is too I<context-specific> to be part of the MOP.
886 This is a read-only attribute which returns the package name for the
887 given B<Class::MOP::Class> instance.
891 This is a read-only attribute which returns the C<$VERSION> of the
892 package for the given B<Class::MOP::Class> instance.
896 =head2 Inheritance Relationships
900 =item B<superclasses (?@superclasses)>
902 This is a read-write attribute which represents the superclass
903 relationships of the class the B<Class::MOP::Class> instance is
904 associated with. Basically, it can get and set the C<@ISA> for you.
907 Perl will occasionally perform some C<@ISA> and method caching, if
908 you decide to change your superclass relationship at runtime (which
909 is quite insane and very much not recommened), then you should be
910 aware of this and the fact that this module does not make any
911 attempt to address this issue.
913 =item B<class_precedence_list>
915 This computes the a list of all the class's ancestors in the same order
916 in which method dispatch will be done. This is similair to
917 what B<Class::ISA::super_path> does, but we don't remove duplicate names.
925 =item B<method_metaclass>
927 =item B<add_method ($method_name, $method)>
929 This will take a C<$method_name> and CODE reference to that
930 C<$method> and install it into the class's package.
933 This does absolutely nothing special to C<$method>
934 other than use B<Sub::Name> to make sure it is tagged with the
935 correct name, and therefore show up correctly in stack traces and
938 =item B<alias_method ($method_name, $method)>
940 This will take a C<$method_name> and CODE reference to that
941 C<$method> and alias the method into the class's package.
944 Unlike C<add_method>, this will B<not> try to name the
945 C<$method> using B<Sub::Name>, it only aliases the method in
948 =item B<has_method ($method_name)>
950 This just provides a simple way to check if the class implements
951 a specific C<$method_name>. It will I<not> however, attempt to check
952 if the class inherits the method (use C<UNIVERSAL::can> for that).
954 This will correctly handle functions defined outside of the package
955 that use a fully qualified name (C<sub Package::name { ... }>).
957 This will correctly handle functions renamed with B<Sub::Name> and
958 installed using the symbol tables. However, if you are naming the
959 subroutine outside of the package scope, you must use the fully
960 qualified name, including the package name, for C<has_method> to
961 correctly identify it.
963 This will attempt to correctly ignore functions imported from other
964 packages using B<Exporter>. It breaks down if the function imported
965 is an C<__ANON__> sub (such as with C<use constant>), which very well
966 may be a valid method being applied to the class.
968 In short, this method cannot always be trusted to determine if the
969 C<$method_name> is actually a method. However, it will DWIM about
970 90% of the time, so it's a small trade off I think.
972 =item B<get_method ($method_name)>
974 This will return a CODE reference of the specified C<$method_name>,
975 or return undef if that method does not exist.
977 =item B<find_method_by_name ($method_name>
979 This will return a CODE reference of the specified C<$method_name>,
980 or return undef if that method does not exist.
982 Unlike C<get_method> this will also look in the superclasses.
984 =item B<remove_method ($method_name)>
986 This will attempt to remove a given C<$method_name> from the class.
987 It will return the CODE reference that it has removed, and will
988 attempt to use B<Sub::Name> to clear the methods associated name.
990 =item B<get_method_list>
992 This will return a list of method names for all I<locally> defined
993 methods. It does B<not> provide a list of all applicable methods,
994 including any inherited ones. If you want a list of all applicable
995 methods, use the C<compute_all_applicable_methods> method.
997 =item B<compute_all_applicable_methods>
999 This will return a list of all the methods names this class will
1000 respond to, taking into account inheritance. The list will be a list of
1001 HASH references, each one containing the following information; method
1002 name, the name of the class in which the method lives and a CODE
1003 reference for the actual method.
1005 =item B<find_all_methods_by_name ($method_name)>
1007 This will traverse the inheritence hierarchy and locate all methods
1008 with a given C<$method_name>. Similar to
1009 C<compute_all_applicable_methods> it returns a list of HASH references
1010 with the following information; method name (which will always be the
1011 same as C<$method_name>), the name of the class in which the method
1012 lives and a CODE reference for the actual method.
1014 The list of methods produced is a distinct list, meaning there are no
1015 duplicates in it. This is especially useful for things like object
1016 initialization and destruction where you only want the method called
1017 once, and in the correct order.
1019 =item B<find_next_method_by_name ($method_name)>
1021 This will return the first method to match a given C<$method_name> in
1022 the superclasses, this is basically equivalent to calling
1023 C<SUPER::$method_name>, but it can be dispatched at runtime.
1027 =head2 Method Modifiers
1029 Method modifiers are a concept borrowed from CLOS, in which a method
1030 can be wrapped with I<before>, I<after> and I<around> method modifiers
1031 that will be called everytime the method is called.
1033 =head3 How method modifiers work?
1035 Method modifiers work by wrapping the original method and then replacing
1036 it in the classes symbol table. The wrappers will handle calling all the
1037 modifiers in the appropariate orders and preserving the calling context
1038 for the original method.
1040 Each method modifier serves a particular purpose, which may not be
1041 obvious to users of other method wrapping modules. To start with, the
1042 return values of I<before> and I<after> modifiers are ignored. This is
1043 because thier purpose is B<not> to filter the input and output of the
1044 primary method (this is done with an I<around> modifier). This may seem
1045 like an odd restriction to some, but doing this allows for simple code
1046 to be added at the begining or end of a method call without jeapordizing
1047 the normal functioning of the primary method or placing any extra
1048 responsibility on the code of the modifier. Of course if you have more
1049 complex needs, then use the I<around> modifier, which uses a variation
1050 of continutation passing style to allow for a high degree of flexibility.
1052 Before and around modifiers are called in last-defined-first-called order,
1053 while after modifiers are called in first-defined-first-called order. So
1054 the call tree might looks something like this:
1064 To see examples of using method modifiers, see the following examples
1065 included in the distribution; F<InstanceCountingClass>, F<Perl6Attribute>,
1066 F<AttributesWithHistory> and F<C3MethodDispatchOrder>. There is also a
1067 classic CLOS usage example in the test F<017_add_method_modifier.t>.
1069 =head3 What is the performance impact?
1071 Of course there is a performance cost associated with method modifiers,
1072 but we have made every effort to make that cost be directly proportional
1073 to the amount of modifier features you utilize.
1075 The wrapping method does it's best to B<only> do as much work as it
1076 absolutely needs to. In order to do this we have moved some of the
1077 performance costs to set-up time, where they are easier to amortize.
1079 All this said, my benchmarks have indicated the following:
1081 simple wrapper with no modifiers 100% slower
1082 simple wrapper with simple before modifier 400% slower
1083 simple wrapper with simple after modifier 450% slower
1084 simple wrapper with simple around modifier 500-550% slower
1085 simple wrapper with all 3 modifiers 1100% slower
1087 These numbers may seem daunting, but you must remember, every feature
1088 comes with some cost. To put things in perspective, just doing a simple
1089 C<AUTOLOAD> which does nothing but extract the name of the method called
1090 and return it costs about 400% over a normal method call.
1094 =item B<add_before_method_modifier ($method_name, $code)>
1096 This will wrap the method at C<$method_name> and the supplied C<$code>
1097 will be passed the C<@_> arguments, and called before the original
1098 method is called. As specified above, the return value of the I<before>
1099 method modifiers is ignored, and it's ability to modify C<@_> is
1100 fairly limited. If you need to do either of these things, use an
1101 C<around> method modifier.
1103 =item B<add_after_method_modifier ($method_name, $code)>
1105 This will wrap the method at C<$method_name> so that the original
1106 method will be called, it's return values stashed, and then the
1107 supplied C<$code> will be passed the C<@_> arguments, and called.
1108 As specified above, the return value of the I<after> method
1109 modifiers is ignored, and it cannot modify the return values of
1110 the original method. If you need to do either of these things, use an
1111 C<around> method modifier.
1113 =item B<add_around_method_modifier ($method_name, $code)>
1115 This will wrap the method at C<$method_name> so that C<$code>
1116 will be called and passed the original method as an extra argument
1117 at the begining of the C<@_> argument list. This is a variation of
1118 continuation passing style, where the function prepended to C<@_>
1119 can be considered a continuation. It is up to C<$code> if it calls
1120 the original method or not, there is no restriction on what the
1121 C<$code> can or cannot do.
1127 It should be noted that since there is no one consistent way to define
1128 the attributes of a class in Perl 5. These methods can only work with
1129 the information given, and can not easily discover information on
1130 their own. See L<Class::MOP::Attribute> for more details.
1134 =item B<attribute_metaclass>
1136 =item B<get_attribute_map>
1138 =item B<add_attribute ($attribute_name, $attribute_meta_object)>
1140 This stores a C<$attribute_meta_object> in the B<Class::MOP::Class>
1141 instance associated with the given class, and associates it with
1142 the C<$attribute_name>. Unlike methods, attributes within the MOP
1143 are stored as meta-information only. They will be used later to
1144 construct instances from (see C<construct_instance> above).
1145 More details about the attribute meta-objects can be found in the
1146 L<Class::MOP::Attribute> or the L<Class::MOP/The Attribute protocol>
1149 It should be noted that any accessor, reader/writer or predicate
1150 methods which the C<$attribute_meta_object> has will be installed
1151 into the class at this time.
1153 =item B<has_attribute ($attribute_name)>
1155 Checks to see if this class has an attribute by the name of
1156 C<$attribute_name> and returns a boolean.
1158 =item B<get_attribute ($attribute_name)>
1160 Returns the attribute meta-object associated with C<$attribute_name>,
1161 if none is found, it will return undef.
1163 =item B<remove_attribute ($attribute_name)>
1165 This will remove the attribute meta-object stored at
1166 C<$attribute_name>, then return the removed attribute meta-object.
1169 Removing an attribute will only affect future instances of
1170 the class, it will not make any attempt to remove the attribute from
1171 any existing instances of the class.
1173 It should be noted that any accessor, reader/writer or predicate
1174 methods which the attribute meta-object stored at C<$attribute_name>
1175 has will be removed from the class at this time. This B<will> make
1176 these attributes somewhat inaccessable in previously created
1177 instances. But if you are crazy enough to do this at runtime, then
1178 you are crazy enough to deal with something like this :).
1180 =item B<get_attribute_list>
1182 This returns a list of attribute names which are defined in the local
1183 class. If you want a list of all applicable attributes for a class,
1184 use the C<compute_all_applicable_attributes> method.
1186 =item B<compute_all_applicable_attributes>
1188 This will traverse the inheritance heirachy and return a list of all
1189 the applicable attributes for this class. It does not construct a
1190 HASH reference like C<compute_all_applicable_methods> because all
1191 that same information is discoverable through the attribute
1194 =item B<find_attribute_by_name ($attr_name)>
1196 This method will traverse the inheritance heirachy and find the
1197 first attribute whose name matches C<$attr_name>, then return it.
1198 It will return undef if nothing is found.
1202 =head2 Package Variables
1204 Since Perl's classes are built atop the Perl package system, it is
1205 fairly common to use package scoped variables for things like static
1206 class variables. The following methods are convience methods for
1207 the creation and inspection of package scoped variables.
1211 =item B<add_package_symbol ($variable_name, ?$initial_value)>
1213 Given a C<$variable_name>, which must contain a leading sigil, this
1214 method will create that variable within the package which houses the
1215 class. It also takes an optional C<$initial_value>, which must be a
1216 reference of the same type as the sigil of the C<$variable_name>
1219 =item B<get_package_symbol ($variable_name)>
1221 This will return a reference to the package variable in
1224 =item B<has_package_symbol ($variable_name)>
1226 Returns true (C<1>) if there is a package variable defined for
1227 C<$variable_name>, and false (C<0>) otherwise.
1229 =item B<remove_package_symbol ($variable_name)>
1231 This will attempt to remove the package variable at C<$variable_name>.
1235 =head2 Class closing
1241 =item B<is_immutable>
1243 =item B<make_immutable>
1249 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1251 =head1 COPYRIGHT AND LICENSE
1253 Copyright 2006 by Infinity Interactive, Inc.
1255 L<http://www.iinteractive.com>
1257 This library is free software; you can redistribute it and/or modify
1258 it under the same terms as Perl itself.