2 package Class::MOP::Class;
8 use Scalar::Util 'blessed', 'reftype', 'weaken';
9 use Sub::Name 'subname';
10 use B 'svref_2object';
12 our $VERSION = '0.15';
14 use Class::MOP::Instance;
18 sub meta { Class::MOP::Class->initialize(blessed($_[0]) || $_[0]) }
23 # Metaclasses are singletons, so we cache them here.
24 # there is no need to worry about destruction though
25 # because they should die only when the program dies.
26 # After all, do package definitions even get reaped?
29 # means of accessing all the metaclasses that have
30 # been initialized thus far (for mugwumps obj browser)
31 sub get_all_metaclasses { %METAS }
32 sub get_all_metaclass_instances { values %METAS }
33 sub get_all_metaclass_names { keys %METAS }
37 my $package_name = shift;
38 (defined $package_name && $package_name && !blessed($package_name))
39 || confess "You must pass a package name and it cannot be blessed";
40 $class->construct_class_instance(':package' => $package_name, @_);
45 my $package_name = shift;
46 (defined $package_name && $package_name && !blessed($package_name))
47 || confess "You must pass a package name and it cannot be blessed";
48 $METAS{$package_name} = undef;
49 $class->construct_class_instance(':package' => $package_name, @_);
53 # we need a sufficiently annoying prefix
54 # this should suffice for now
55 my $ANON_CLASS_PREFIX = 'Class::MOP::Class::__ANON__::SERIAL::';
59 # this should be sufficient, if you have a
60 # use case where it is not, write a test and
62 my $ANON_CLASS_SERIAL = 0;
64 sub create_anon_class {
65 my ($class, %options) = @_;
66 my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
67 return $class->create($package_name, '0.00', %options);
71 # NOTE: (meta-circularity)
72 # this is a special form of &construct_instance
73 # (see below), which is used to construct class
74 # meta-object instances for any Class::MOP::*
75 # class. All other classes will use the more
76 # normal &construct_instance.
77 sub construct_class_instance {
80 my $package_name = $options{':package'};
81 (defined $package_name && $package_name)
82 || confess "You must pass a package name";
84 # return the metaclass if we have it cached,
85 # and it is still defined (it has not been
86 # reaped by DESTROY yet, which can happen
87 # annoyingly enough during global destruction)
88 return $METAS{$package_name}
89 if exists $METAS{$package_name} && defined $METAS{$package_name};
90 $class = blessed($class) || $class;
91 # now create the metaclass
93 if ($class =~ /^Class::MOP::/) {
95 '$:package' => $package_name,
97 '$:attribute_metaclass' => $options{':attribute_metaclass'} || 'Class::MOP::Attribute',
98 '$:method_metaclass' => $options{':method_metaclass'} || 'Class::MOP::Method',
99 '$:instance_metaclass' => $options{':instance_metaclass'} || 'Class::MOP::Instance',
104 # it is safe to use meta here because
105 # class will always be a subclass of
106 # Class::MOP::Class, which defines meta
107 $meta = $class->meta->construct_instance(%options)
109 # and check the metaclass compatibility
110 $meta->check_metaclass_compatability();
111 $METAS{$package_name} = $meta;
113 # we need to weaken any anon classes
114 # so that they can call DESTROY properly
115 weaken($METAS{$package_name})
116 if $package_name =~ /^$ANON_CLASS_PREFIX/;
121 # this will only get called for
122 # anon-classes, all other calls
123 # are assumed to occur during
124 # global destruction and so don't
125 # really need to be handled explicitly
128 return unless $self->name =~ /^$ANON_CLASS_PREFIX/;
129 my ($serial_id) = ($self->name =~ /^$ANON_CLASS_PREFIX(\d+)/);
131 foreach my $key (keys %{$ANON_CLASS_PREFIX . $serial_id}) {
132 delete ${$ANON_CLASS_PREFIX . $serial_id}{$key};
134 delete ${'main::' . $ANON_CLASS_PREFIX}{$serial_id . '::'};
137 sub check_metaclass_compatability {
140 # this is always okay ...
141 return if blessed($self) eq 'Class::MOP::Class' &&
142 $self->instance_metaclass eq 'Class::MOP::Instance';
144 my @class_list = $self->class_precedence_list;
145 shift @class_list; # shift off $self->name
147 foreach my $class_name (@class_list) {
148 my $meta = $METAS{$class_name} || next;
149 ($self->isa(blessed($meta)))
150 || confess $self->name . "->meta => (" . (blessed($self)) . ")" .
151 " is not compatible with the " .
152 $class_name . "->meta => (" . (blessed($meta)) . ")";
154 # we also need to check that instance metaclasses
155 # are compatabile in the same the class.
156 ($self->instance_metaclass->isa($meta->instance_metaclass))
157 || confess $self->name . "->meta => (" . ($self->instance_metaclass) . ")" .
158 " is not compatible with the " .
159 $class_name . "->meta => (" . ($meta->instance_metaclass) . ")";
165 my ($class, $package_name, $package_version, %options) = @_;
166 (defined $package_name && $package_name)
167 || confess "You must pass a package name";
168 my $code = "package $package_name;";
169 $code .= "\$$package_name\:\:VERSION = '$package_version';"
170 if defined $package_version;
172 confess "creation of $package_name failed : $@" if $@;
173 my $meta = $class->initialize($package_name);
175 $meta->add_method('meta' => sub {
176 $class->initialize(blessed($_[0]) || $_[0]);
179 $meta->superclasses(@{$options{superclasses}})
180 if exists $options{superclasses};
182 # process attributes first, so that they can
183 # install accessors, but locally defined methods
184 # can then overwrite them. It is maybe a little odd, but
185 # I think this should be the order of things.
186 if (exists $options{attributes}) {
187 foreach my $attr (@{$options{attributes}}) {
188 $meta->add_attribute($attr);
191 if (exists $options{methods}) {
192 foreach my $method_name (keys %{$options{methods}}) {
193 $meta->add_method($method_name, $options{methods}->{$method_name});
202 # all these attribute readers will be bootstrapped
203 # away in the Class::MOP bootstrap section
205 sub name { $_[0]->{'$:package'} }
206 sub get_attribute_map { $_[0]->{'%:attributes'} }
207 sub attribute_metaclass { $_[0]->{'$:attribute_metaclass'} }
208 sub method_metaclass { $_[0]->{'$:method_metaclass'} }
209 sub instance_metaclass { $_[0]->{'$:instance_metaclass'} }
211 # Instance Construction & Cloning
216 # we need to protect the integrity of the
217 # Class::MOP::Class singletons here, so we
218 # delegate this to &construct_class_instance
219 # which will deal with the singletons
220 return $class->construct_class_instance(@_)
221 if $class->name->isa('Class::MOP::Class');
222 return $class->construct_instance(@_);
225 sub construct_instance {
226 my ($class, %params) = @_;
227 my $meta_instance = $class->get_meta_instance();
228 my $instance = $meta_instance->create_instance();
229 foreach my $attr ($class->compute_all_applicable_attributes()) {
230 $attr->initialize_instance_slot($meta_instance, $instance, \%params);
235 sub get_meta_instance {
237 return $class->instance_metaclass->new(
239 $class->compute_all_applicable_attributes()
245 my $instance = shift;
246 (blessed($instance) && $instance->isa($class->name))
247 || confess "You must pass an instance ($instance) of the metaclass (" . $class->name . ")";
249 # we need to protect the integrity of the
250 # Class::MOP::Class singletons here, they
251 # should not be cloned.
252 return $instance if $instance->isa('Class::MOP::Class');
253 $class->clone_instance($instance, @_);
257 my ($class, $instance, %params) = @_;
259 || confess "You can only clone instances, \$self is not a blessed instance";
260 my $meta_instance = $class->get_meta_instance();
261 my $clone = $meta_instance->clone_instance($instance);
262 foreach my $key (keys %params) {
263 next unless $meta_instance->is_valid_slot($key);
264 $meta_instance->set_slot_value($clone, $key, $params{$key});
271 # &name should be here too, but it is above
272 # because it gets bootstrapped away
276 ${$self->get_package_variable('$VERSION')};
286 @{$self->name . '::ISA'} = @supers;
288 # we need to check the metaclass
289 # compatability here so that we can
290 # be sure that the superclass is
291 # not potentially creating an issues
292 # we don't know about
293 $self->check_metaclass_compatability();
295 @{$self->name . '::ISA'};
298 sub class_precedence_list {
301 # We need to check for ciruclar inheirtance here.
302 # This will do nothing if all is well, and blow
303 # up otherwise. Yes, it's an ugly hack, better
304 # suggestions are welcome.
305 { ($self->name || return)->isa('This is a test for circular inheritance') }
306 # ... and now back to our regularly scheduled program
310 $self->initialize($_)->class_precedence_list()
311 } $self->superclasses()
318 my ($self, $method_name, $method) = @_;
319 (defined $method_name && $method_name)
320 || confess "You must define a method name";
321 # use reftype here to allow for blessed subs ...
322 ('CODE' eq (reftype($method) || ''))
323 || confess "Your code block must be a CODE reference";
324 my $full_method_name = ($self->name . '::' . $method_name);
326 $method = $self->method_metaclass->wrap($method) unless blessed($method);
329 no warnings 'redefine';
330 *{$full_method_name} = subname $full_method_name => $method;
334 my $fetch_and_prepare_method = sub {
335 my ($self, $method_name) = @_;
337 my $method = $self->get_method($method_name);
338 # if we dont have local ...
340 # try to find the next method
341 $method = $self->find_next_method_by_name($method_name);
342 # die if it does not exist
344 || confess "The method '$method_name' is not found in the inherience hierarchy for this class";
345 # and now make sure to wrap it
346 # even if it is already wrapped
347 # because we need a new sub ref
348 $method = Class::MOP::Method::Wrapped->wrap($method);
351 # now make sure we wrap it properly
352 $method = Class::MOP::Method::Wrapped->wrap($method)
353 unless $method->isa('Class::MOP::Method::Wrapped');
355 $self->add_method($method_name => $method);
359 sub add_before_method_modifier {
360 my ($self, $method_name, $method_modifier) = @_;
361 (defined $method_name && $method_name)
362 || confess "You must pass in a method name";
363 my $method = $fetch_and_prepare_method->($self, $method_name);
364 $method->add_before_modifier(subname ':before' => $method_modifier);
367 sub add_after_method_modifier {
368 my ($self, $method_name, $method_modifier) = @_;
369 (defined $method_name && $method_name)
370 || confess "You must pass in a method name";
371 my $method = $fetch_and_prepare_method->($self, $method_name);
372 $method->add_after_modifier(subname ':after' => $method_modifier);
375 sub add_around_method_modifier {
376 my ($self, $method_name, $method_modifier) = @_;
377 (defined $method_name && $method_name)
378 || confess "You must pass in a method name";
379 my $method = $fetch_and_prepare_method->($self, $method_name);
380 $method->add_around_modifier(subname ':around' => $method_modifier);
384 # the methods above used to be named like this:
385 # ${pkg}::${method}:(before|after|around)
386 # but this proved problematic when using one modifier
387 # to wrap multiple methods (something which is likely
388 # to happen pretty regularly IMO). So instead of naming
389 # it like this, I have chosen to just name them purely
390 # with their modifier names, like so:
391 # :(before|after|around)
392 # The fact is that in a stack trace, it will be fairly
393 # evident from the context what method they are attached
394 # to, and so don't need the fully qualified name.
398 my ($self, $method_name, $method) = @_;
399 (defined $method_name && $method_name)
400 || confess "You must define a method name";
401 # use reftype here to allow for blessed subs ...
402 ('CODE' eq (reftype($method) || ''))
403 || confess "Your code block must be a CODE reference";
404 my $full_method_name = ($self->name . '::' . $method_name);
406 $method = $self->method_metaclass->wrap($method) unless blessed($method);
409 no warnings 'redefine';
410 *{$full_method_name} = $method;
414 my ($self, $method_name) = @_;
415 (defined $method_name && $method_name)
416 || confess "You must define a method name";
418 my $sub_name = ($self->name . '::' . $method_name);
421 return 0 if !defined(&{$sub_name});
422 my $method = \&{$sub_name};
423 return 0 if (svref_2object($method)->GV->STASH->NAME || '') ne $self->name &&
424 (svref_2object($method)->GV->NAME || '') ne '__ANON__';
426 # at this point we are relatively sure
427 # it is our method, so we bless/wrap it
428 $self->method_metaclass->wrap($method) unless blessed($method);
433 my ($self, $method_name) = @_;
434 (defined $method_name && $method_name)
435 || confess "You must define a method name";
437 return unless $self->has_method($method_name);
440 return \&{$self->name . '::' . $method_name};
444 my ($self, $method_name) = @_;
445 (defined $method_name && $method_name)
446 || confess "You must define a method name";
448 my $removed_method = $self->get_method($method_name);
451 delete ${$self->name . '::'}{$method_name}
452 if defined $removed_method;
454 return $removed_method;
457 sub get_method_list {
460 grep { $self->has_method($_) } keys %{$self->name . '::'};
463 sub compute_all_applicable_methods {
466 # keep a record of what we have seen
467 # here, this will handle all the
468 # inheritence issues because we are
469 # using the &class_precedence_list
470 my (%seen_class, %seen_method);
471 foreach my $class ($self->class_precedence_list()) {
472 next if $seen_class{$class};
473 $seen_class{$class}++;
474 # fetch the meta-class ...
475 my $meta = $self->initialize($class);
476 foreach my $method_name ($meta->get_method_list()) {
477 next if exists $seen_method{$method_name};
478 $seen_method{$method_name}++;
480 name => $method_name,
482 code => $meta->get_method($method_name)
489 sub find_all_methods_by_name {
490 my ($self, $method_name) = @_;
491 (defined $method_name && $method_name)
492 || confess "You must define a method name to find";
494 # keep a record of what we have seen
495 # here, this will handle all the
496 # inheritence issues because we are
497 # using the &class_precedence_list
499 foreach my $class ($self->class_precedence_list()) {
500 next if $seen_class{$class};
501 $seen_class{$class}++;
502 # fetch the meta-class ...
503 my $meta = $self->initialize($class);
505 name => $method_name,
507 code => $meta->get_method($method_name)
508 } if $meta->has_method($method_name);
513 sub find_next_method_by_name {
514 my ($self, $method_name) = @_;
515 (defined $method_name && $method_name)
516 || confess "You must define a method name to find";
517 # keep a record of what we have seen
518 # here, this will handle all the
519 # inheritence issues because we are
520 # using the &class_precedence_list
522 my @cpl = $self->class_precedence_list();
523 shift @cpl; # discard ourselves
524 foreach my $class (@cpl) {
525 next if $seen_class{$class};
526 $seen_class{$class}++;
527 # fetch the meta-class ...
528 my $meta = $self->initialize($class);
529 return $meta->get_method($method_name)
530 if $meta->has_method($method_name);
539 # either we have an attribute object already
540 # or we need to create one from the args provided
541 my $attribute = blessed($_[0]) ? $_[0] : $self->attribute_metaclass->new(@_);
542 # make sure it is derived from the correct type though
543 ($attribute->isa('Class::MOP::Attribute'))
544 || confess "Your attribute must be an instance of Class::MOP::Attribute (or a subclass)";
545 $attribute->attach_to_class($self);
546 $attribute->install_accessors();
547 $self->get_attribute_map->{$attribute->name} = $attribute;
550 # in theory we have to tell everyone the slot structure may have changed
554 my ($self, $attribute_name) = @_;
555 (defined $attribute_name && $attribute_name)
556 || confess "You must define an attribute name";
557 exists $self->get_attribute_map->{$attribute_name} ? 1 : 0;
561 my ($self, $attribute_name) = @_;
562 (defined $attribute_name && $attribute_name)
563 || confess "You must define an attribute name";
564 return $self->get_attribute_map->{$attribute_name}
565 if $self->has_attribute($attribute_name);
569 sub remove_attribute {
570 my ($self, $attribute_name) = @_;
571 (defined $attribute_name && $attribute_name)
572 || confess "You must define an attribute name";
573 my $removed_attribute = $self->get_attribute_map->{$attribute_name};
574 return unless defined $removed_attribute;
575 delete $self->get_attribute_map->{$attribute_name};
576 $removed_attribute->remove_accessors();
577 $removed_attribute->detach_from_class();
578 return $removed_attribute;
581 sub get_attribute_list {
583 keys %{$self->get_attribute_map};
586 sub compute_all_applicable_attributes {
589 # keep a record of what we have seen
590 # here, this will handle all the
591 # inheritence issues because we are
592 # using the &class_precedence_list
593 my (%seen_class, %seen_attr);
594 foreach my $class ($self->class_precedence_list()) {
595 next if $seen_class{$class};
596 $seen_class{$class}++;
597 # fetch the meta-class ...
598 my $meta = $self->initialize($class);
599 foreach my $attr_name ($meta->get_attribute_list()) {
600 next if exists $seen_attr{$attr_name};
601 $seen_attr{$attr_name}++;
602 push @attrs => $meta->get_attribute($attr_name);
608 sub find_attribute_by_name {
609 my ($self, $attr_name) = @_;
610 # keep a record of what we have seen
611 # here, this will handle all the
612 # inheritence issues because we are
613 # using the &class_precedence_list
615 foreach my $class ($self->class_precedence_list()) {
616 next if $seen_class{$class};
617 $seen_class{$class}++;
618 # fetch the meta-class ...
619 my $meta = $self->initialize($class);
620 return $meta->get_attribute($attr_name)
621 if $meta->has_attribute($attr_name);
628 sub add_package_variable {
629 my ($self, $variable, $initial_value) = @_;
630 (defined $variable && $variable =~ /^[\$\@\%]/)
631 || confess "variable name does not have a sigil";
633 my ($sigil, $name) = ($variable =~ /^(.)(.*)$/);
634 if (defined $initial_value) {
636 *{$self->name . '::' . $name} = $initial_value;
642 # We HAVE to localize $@ or all
643 # hell breaks loose. It is not
644 # good, believe me, not good.
646 eval $sigil . $self->name . '::' . $name;
649 confess "Could not create package variable ($variable) because : $e" if $e;
653 sub has_package_variable {
654 my ($self, $variable) = @_;
655 (defined $variable && $variable =~ /^[\$\@\%]/)
656 || confess "variable name does not have a sigil";
657 my ($sigil, $name) = ($variable =~ /^(.)(.*)$/);
659 defined ${$self->name . '::'}{$name} ? 1 : 0;
662 sub get_package_variable {
663 my ($self, $variable) = @_;
664 (defined $variable && $variable =~ /^[\$\@\%]/)
665 || confess "variable name does not have a sigil";
666 my ($sigil, $name) = ($variable =~ /^(.)(.*)$/);
670 # We HAVE to localize $@ or all
671 # hell breaks loose. It is not
672 # good, believe me, not good.
674 $ref = eval '\\' . $sigil . $self->name . '::' . $name;
677 confess "Could not get the package variable ($variable) because : $e" if $e;
678 # if we didn't die, then we can return it
682 sub remove_package_variable {
683 my ($self, $variable) = @_;
684 (defined $variable && $variable =~ /^[\$\@\%]/)
685 || confess "variable name does not have a sigil";
686 my ($sigil, $name) = ($variable =~ /^(.)(.*)$/);
688 delete ${$self->name . '::'}{$name};
694 sub is_immutable { 0 }
698 return Class::MOP::Class::Immutable->make_metaclass_immutable($class);
709 Class::MOP::Class - Class Meta Object
713 # assuming that class Foo
714 # has been defined, you can
716 # use this for introspection ...
718 # add a method to Foo ...
719 Foo->meta->add_method('bar' => sub { ... })
721 # get a list of all the classes searched
722 # the method dispatcher in the correct order
723 Foo->meta->class_precedence_list()
725 # remove a method from Foo
726 Foo->meta->remove_method('bar');
728 # or use this to actually create classes ...
730 Class::MOP::Class->create('Bar' => '0.01' => (
731 superclasses => [ 'Foo' ],
733 Class::MOP:::Attribute->new('$bar'),
734 Class::MOP:::Attribute->new('$baz'),
737 calculate_bar => sub { ... },
738 construct_baz => sub { ... }
744 This is the largest and currently most complex part of the Perl 5
745 meta-object protocol. It controls the introspection and
746 manipulation of Perl 5 classes (and it can create them too). The
747 best way to understand what this module can do, is to read the
748 documentation for each of it's methods.
752 =head2 Self Introspection
758 This will return a B<Class::MOP::Class> instance which is related
759 to this class. Thereby allowing B<Class::MOP::Class> to actually
762 As with B<Class::MOP::Attribute>, B<Class::MOP> will actually
763 bootstrap this module by installing a number of attribute meta-objects
764 into it's metaclass. This will allow this class to reap all the benifits
765 of the MOP when subclassing it.
767 =item B<get_all_metaclasses>
769 This will return an hash of all the metaclass instances that have
770 been cached by B<Class::MOP::Class> keyed by the package name.
772 =item B<get_all_metaclass_instances>
774 This will return an array of all the metaclass instances that have
775 been cached by B<Class::MOP::Class>.
777 =item B<get_all_metaclass_names>
779 This will return an array of all the metaclass names that have
780 been cached by B<Class::MOP::Class>.
784 =head2 Class construction
786 These methods will handle creating B<Class::MOP::Class> objects,
787 which can be used to both create new classes, and analyze
788 pre-existing classes.
790 This module will internally store references to all the instances
791 you create with these methods, so that they do not need to be
792 created any more than nessecary. Basically, they are singletons.
796 =item B<create ($package_name, ?$package_version,
797 superclasses =E<gt> ?@superclasses,
798 methods =E<gt> ?%methods,
799 attributes =E<gt> ?%attributes)>
801 This returns a B<Class::MOP::Class> object, bringing the specified
802 C<$package_name> into existence and adding any of the
803 C<$package_version>, C<@superclasses>, C<%methods> and C<%attributes>
806 =item B<create_anon_class (superclasses =E<gt> ?@superclasses,
807 methods =E<gt> ?%methods,
808 attributes =E<gt> ?%attributes)>
810 This will create an anonymous class, it works much like C<create> but
811 it does not need a C<$package_name>. Instead it will create a suitably
812 unique package name for you to stash things into.
814 =item B<initialize ($package_name, %options)>
816 This initializes and returns returns a B<Class::MOP::Class> object
817 for a given a C<$package_name>.
819 =item B<reinitialize ($package_name, %options)>
821 This removes the old metaclass, and creates a new one in it's place.
822 Do B<not> use this unless you really know what you are doing, it could
823 very easily make a very large mess of your program.
825 =item B<construct_class_instance (%options)>
827 This will construct an instance of B<Class::MOP::Class>, it is
828 here so that we can actually "tie the knot" for B<Class::MOP::Class>
829 to use C<construct_instance> once all the bootstrapping is done. This
830 method is used internally by C<initialize> and should never be called
831 from outside of that method really.
833 =item B<check_metaclass_compatability>
835 This method is called as the very last thing in the
836 C<construct_class_instance> method. This will check that the
837 metaclass you are creating is compatible with the metaclasses of all
838 your ancestors. For more inforamtion about metaclass compatibility
839 see the C<About Metaclass compatibility> section in L<Class::MOP>.
843 =head2 Object instance construction and cloning
845 These methods are B<entirely optional>, it is up to you whether you want
850 =item B<instance_metaclass>
852 =item B<get_meta_instance>
854 =item B<new_object (%params)>
856 This is a convience method for creating a new object of the class, and
857 blessing it into the appropriate package as well. Ideally your class
858 would call a C<new> this method like so:
861 my ($class, %param) = @_;
862 $class->meta->new_object(%params);
865 Of course the ideal place for this would actually be in C<UNIVERSAL::>
866 but that is considered bad style, so we do not do that.
868 =item B<construct_instance (%params)>
870 This method is used to construct an instace structure suitable for
871 C<bless>-ing into your package of choice. It works in conjunction
872 with the Attribute protocol to collect all applicable attributes.
874 This will construct and instance using a HASH ref as storage
875 (currently only HASH references are supported). This will collect all
876 the applicable attributes and layout out the fields in the HASH ref,
877 it will then initialize them using either use the corresponding key
878 in C<%params> or any default value or initializer found in the
879 attribute meta-object.
881 =item B<clone_object ($instance, %params)>
883 This is a convience method for cloning an object instance, then
884 blessing it into the appropriate package. This method will call
885 C<clone_instance>, which performs a shallow copy of the object,
886 see that methods documentation for more details. Ideally your
887 class would call a C<clone> this method like so:
890 my ($self, %param) = @_;
891 $self->meta->clone_object($self, %params);
894 Of course the ideal place for this would actually be in C<UNIVERSAL::>
895 but that is considered bad style, so we do not do that.
897 =item B<clone_instance($instance, %params)>
899 This method is a compliment of C<construct_instance> (which means if
900 you override C<construct_instance>, you need to override this one too),
901 and clones the instance shallowly.
903 The cloned structure returned is (like with C<construct_instance>) an
904 unC<bless>ed HASH reference, it is your responsibility to then bless
905 this cloned structure into the right class (which C<clone_object> will
908 As of 0.11, this method will clone the C<$instance> structure shallowly,
909 as opposed to the deep cloning implemented in prior versions. After much
910 thought, research and discussion, I have decided that anything but basic
911 shallow cloning is outside the scope of the meta-object protocol. I
912 think Yuval "nothingmuch" Kogman put it best when he said that cloning
913 is too I<context-specific> to be part of the MOP.
923 This is a read-only attribute which returns the package name for the
924 given B<Class::MOP::Class> instance.
928 This is a read-only attribute which returns the C<$VERSION> of the
929 package for the given B<Class::MOP::Class> instance.
933 =head2 Inheritance Relationships
937 =item B<superclasses (?@superclasses)>
939 This is a read-write attribute which represents the superclass
940 relationships of the class the B<Class::MOP::Class> instance is
941 associated with. Basically, it can get and set the C<@ISA> for you.
944 Perl will occasionally perform some C<@ISA> and method caching, if
945 you decide to change your superclass relationship at runtime (which
946 is quite insane and very much not recommened), then you should be
947 aware of this and the fact that this module does not make any
948 attempt to address this issue.
950 =item B<class_precedence_list>
952 This computes the a list of all the class's ancestors in the same order
953 in which method dispatch will be done. This is similair to
954 what B<Class::ISA::super_path> does, but we don't remove duplicate names.
962 =item B<method_metaclass>
964 =item B<add_method ($method_name, $method)>
966 This will take a C<$method_name> and CODE reference to that
967 C<$method> and install it into the class's package.
970 This does absolutely nothing special to C<$method>
971 other than use B<Sub::Name> to make sure it is tagged with the
972 correct name, and therefore show up correctly in stack traces and
975 =item B<alias_method ($method_name, $method)>
977 This will take a C<$method_name> and CODE reference to that
978 C<$method> and alias the method into the class's package.
981 Unlike C<add_method>, this will B<not> try to name the
982 C<$method> using B<Sub::Name>, it only aliases the method in
985 =item B<has_method ($method_name)>
987 This just provides a simple way to check if the class implements
988 a specific C<$method_name>. It will I<not> however, attempt to check
989 if the class inherits the method (use C<UNIVERSAL::can> for that).
991 This will correctly handle functions defined outside of the package
992 that use a fully qualified name (C<sub Package::name { ... }>).
994 This will correctly handle functions renamed with B<Sub::Name> and
995 installed using the symbol tables. However, if you are naming the
996 subroutine outside of the package scope, you must use the fully
997 qualified name, including the package name, for C<has_method> to
998 correctly identify it.
1000 This will attempt to correctly ignore functions imported from other
1001 packages using B<Exporter>. It breaks down if the function imported
1002 is an C<__ANON__> sub (such as with C<use constant>), which very well
1003 may be a valid method being applied to the class.
1005 In short, this method cannot always be trusted to determine if the
1006 C<$method_name> is actually a method. However, it will DWIM about
1007 90% of the time, so it's a small trade off I think.
1009 =item B<get_method ($method_name)>
1011 This will return a CODE reference of the specified C<$method_name>,
1012 or return undef if that method does not exist.
1014 =item B<remove_method ($method_name)>
1016 This will attempt to remove a given C<$method_name> from the class.
1017 It will return the CODE reference that it has removed, and will
1018 attempt to use B<Sub::Name> to clear the methods associated name.
1020 =item B<get_method_list>
1022 This will return a list of method names for all I<locally> defined
1023 methods. It does B<not> provide a list of all applicable methods,
1024 including any inherited ones. If you want a list of all applicable
1025 methods, use the C<compute_all_applicable_methods> method.
1027 =item B<compute_all_applicable_methods>
1029 This will return a list of all the methods names this class will
1030 respond to, taking into account inheritance. The list will be a list of
1031 HASH references, each one containing the following information; method
1032 name, the name of the class in which the method lives and a CODE
1033 reference for the actual method.
1035 =item B<find_all_methods_by_name ($method_name)>
1037 This will traverse the inheritence hierarchy and locate all methods
1038 with a given C<$method_name>. Similar to
1039 C<compute_all_applicable_methods> it returns a list of HASH references
1040 with the following information; method name (which will always be the
1041 same as C<$method_name>), the name of the class in which the method
1042 lives and a CODE reference for the actual method.
1044 The list of methods produced is a distinct list, meaning there are no
1045 duplicates in it. This is especially useful for things like object
1046 initialization and destruction where you only want the method called
1047 once, and in the correct order.
1049 =item B<find_next_method_by_name ($method_name)>
1051 This will return the first method to match a given C<$method_name> in
1052 the superclasses, this is basically equivalent to calling
1053 C<SUPER::$method_name>, but it can be dispatched at runtime.
1057 =head2 Method Modifiers
1059 Method modifiers are a concept borrowed from CLOS, in which a method
1060 can be wrapped with I<before>, I<after> and I<around> method modifiers
1061 that will be called everytime the method is called.
1063 =head3 How method modifiers work?
1065 Method modifiers work by wrapping the original method and then replacing
1066 it in the classes symbol table. The wrappers will handle calling all the
1067 modifiers in the appropariate orders and preserving the calling context
1068 for the original method.
1070 Each method modifier serves a particular purpose, which may not be
1071 obvious to users of other method wrapping modules. To start with, the
1072 return values of I<before> and I<after> modifiers are ignored. This is
1073 because thier purpose is B<not> to filter the input and output of the
1074 primary method (this is done with an I<around> modifier). This may seem
1075 like an odd restriction to some, but doing this allows for simple code
1076 to be added at the begining or end of a method call without jeapordizing
1077 the normal functioning of the primary method or placing any extra
1078 responsibility on the code of the modifier. Of course if you have more
1079 complex needs, then use the I<around> modifier, which uses a variation
1080 of continutation passing style to allow for a high degree of flexibility.
1082 Before and around modifiers are called in last-defined-first-called order,
1083 while after modifiers are called in first-defined-first-called order. So
1084 the call tree might looks something like this:
1094 To see examples of using method modifiers, see the following examples
1095 included in the distribution; F<InstanceCountingClass>, F<Perl6Attribute>,
1096 F<AttributesWithHistory> and F<C3MethodDispatchOrder>. There is also a
1097 classic CLOS usage example in the test F<017_add_method_modifier.t>.
1099 =head3 What is the performance impact?
1101 Of course there is a performance cost associated with method modifiers,
1102 but we have made every effort to make that cost be directly proportional
1103 to the amount of modifier features you utilize.
1105 The wrapping method does it's best to B<only> do as much work as it
1106 absolutely needs to. In order to do this we have moved some of the
1107 performance costs to set-up time, where they are easier to amortize.
1109 All this said, my benchmarks have indicated the following:
1111 simple wrapper with no modifiers 100% slower
1112 simple wrapper with simple before modifier 400% slower
1113 simple wrapper with simple after modifier 450% slower
1114 simple wrapper with simple around modifier 500-550% slower
1115 simple wrapper with all 3 modifiers 1100% slower
1117 These numbers may seem daunting, but you must remember, every feature
1118 comes with some cost. To put things in perspective, just doing a simple
1119 C<AUTOLOAD> which does nothing but extract the name of the method called
1120 and return it costs about 400% over a normal method call.
1124 =item B<add_before_method_modifier ($method_name, $code)>
1126 This will wrap the method at C<$method_name> and the supplied C<$code>
1127 will be passed the C<@_> arguments, and called before the original
1128 method is called. As specified above, the return value of the I<before>
1129 method modifiers is ignored, and it's ability to modify C<@_> is
1130 fairly limited. If you need to do either of these things, use an
1131 C<around> method modifier.
1133 =item B<add_after_method_modifier ($method_name, $code)>
1135 This will wrap the method at C<$method_name> so that the original
1136 method will be called, it's return values stashed, and then the
1137 supplied C<$code> will be passed the C<@_> arguments, and called.
1138 As specified above, the return value of the I<after> method
1139 modifiers is ignored, and it cannot modify the return values of
1140 the original method. If you need to do either of these things, use an
1141 C<around> method modifier.
1143 =item B<add_around_method_modifier ($method_name, $code)>
1145 This will wrap the method at C<$method_name> so that C<$code>
1146 will be called and passed the original method as an extra argument
1147 at the begining of the C<@_> argument list. This is a variation of
1148 continuation passing style, where the function prepended to C<@_>
1149 can be considered a continuation. It is up to C<$code> if it calls
1150 the original method or not, there is no restriction on what the
1151 C<$code> can or cannot do.
1157 It should be noted that since there is no one consistent way to define
1158 the attributes of a class in Perl 5. These methods can only work with
1159 the information given, and can not easily discover information on
1160 their own. See L<Class::MOP::Attribute> for more details.
1164 =item B<attribute_metaclass>
1166 =item B<get_attribute_map>
1168 =item B<add_attribute ($attribute_name, $attribute_meta_object)>
1170 This stores a C<$attribute_meta_object> in the B<Class::MOP::Class>
1171 instance associated with the given class, and associates it with
1172 the C<$attribute_name>. Unlike methods, attributes within the MOP
1173 are stored as meta-information only. They will be used later to
1174 construct instances from (see C<construct_instance> above).
1175 More details about the attribute meta-objects can be found in the
1176 L<Class::MOP::Attribute> or the L<Class::MOP/The Attribute protocol>
1179 It should be noted that any accessor, reader/writer or predicate
1180 methods which the C<$attribute_meta_object> has will be installed
1181 into the class at this time.
1183 =item B<has_attribute ($attribute_name)>
1185 Checks to see if this class has an attribute by the name of
1186 C<$attribute_name> and returns a boolean.
1188 =item B<get_attribute ($attribute_name)>
1190 Returns the attribute meta-object associated with C<$attribute_name>,
1191 if none is found, it will return undef.
1193 =item B<remove_attribute ($attribute_name)>
1195 This will remove the attribute meta-object stored at
1196 C<$attribute_name>, then return the removed attribute meta-object.
1199 Removing an attribute will only affect future instances of
1200 the class, it will not make any attempt to remove the attribute from
1201 any existing instances of the class.
1203 It should be noted that any accessor, reader/writer or predicate
1204 methods which the attribute meta-object stored at C<$attribute_name>
1205 has will be removed from the class at this time. This B<will> make
1206 these attributes somewhat inaccessable in previously created
1207 instances. But if you are crazy enough to do this at runtime, then
1208 you are crazy enough to deal with something like this :).
1210 =item B<get_attribute_list>
1212 This returns a list of attribute names which are defined in the local
1213 class. If you want a list of all applicable attributes for a class,
1214 use the C<compute_all_applicable_attributes> method.
1216 =item B<compute_all_applicable_attributes>
1218 This will traverse the inheritance heirachy and return a list of all
1219 the applicable attributes for this class. It does not construct a
1220 HASH reference like C<compute_all_applicable_methods> because all
1221 that same information is discoverable through the attribute
1224 =item B<find_attribute_by_name ($attr_name)>
1226 This method will traverse the inheritance heirachy and find the
1227 first attribute whose name matches C<$attr_name>, then return it.
1228 It will return undef if nothing is found.
1232 =head2 Package Variables
1234 Since Perl's classes are built atop the Perl package system, it is
1235 fairly common to use package scoped variables for things like static
1236 class variables. The following methods are convience methods for
1237 the creation and inspection of package scoped variables.
1241 =item B<add_package_variable ($variable_name, ?$initial_value)>
1243 Given a C<$variable_name>, which must contain a leading sigil, this
1244 method will create that variable within the package which houses the
1245 class. It also takes an optional C<$initial_value>, which must be a
1246 reference of the same type as the sigil of the C<$variable_name>
1249 =item B<get_package_variable ($variable_name)>
1251 This will return a reference to the package variable in
1254 =item B<has_package_variable ($variable_name)>
1256 Returns true (C<1>) if there is a package variable defined for
1257 C<$variable_name>, and false (C<0>) otherwise.
1259 =item B<remove_package_variable ($variable_name)>
1261 This will attempt to remove the package variable at C<$variable_name>.
1265 =head2 Class closing
1271 =item B<is_immutable>
1273 =item B<make_immutable>
1279 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1281 =head1 COPYRIGHT AND LICENSE
1283 Copyright 2006 by Infinity Interactive, Inc.
1285 L<http://www.iinteractive.com>
1287 This library is free software; you can redistribute it and/or modify
1288 it under the same terms as Perl itself.