2 package Class::MOP::Class;
8 use Scalar::Util 'blessed', 'reftype', 'weaken';
9 use Sub::Name 'subname';
10 use B 'svref_2object';
12 our $VERSION = '0.15';
14 use base 'Class::MOP::Module';
16 use Class::MOP::Instance;
20 sub meta { Class::MOP::Class->initialize(blessed($_[0]) || $_[0]) }
25 # we need a sufficiently annoying prefix
26 # this should suffice for now, this is
27 # used in a couple of places below, so
28 # need to put it up here for now.
29 my $ANON_CLASS_PREFIX = 'Class::MOP::Class::__ANON__::SERIAL::';
34 # Metaclasses are singletons, so we cache them here.
35 # there is no need to worry about destruction though
36 # because they should die only when the program dies.
37 # After all, do package definitions even get reaped?
40 # means of accessing all the metaclasses that have
41 # been initialized thus far (for mugwumps obj browser)
42 sub get_all_metaclasses { %METAS }
43 sub get_all_metaclass_instances { values %METAS }
44 sub get_all_metaclass_names { keys %METAS }
48 my $package_name = shift;
49 (defined $package_name && $package_name && !blessed($package_name))
50 || confess "You must pass a package name and it cannot be blessed";
51 $class->construct_class_instance(':package' => $package_name, @_);
56 my $package_name = shift;
57 (defined $package_name && $package_name && !blessed($package_name))
58 || confess "You must pass a package name and it cannot be blessed";
59 $METAS{$package_name} = undef;
60 $class->construct_class_instance(':package' => $package_name, @_);
63 # NOTE: (meta-circularity)
64 # this is a special form of &construct_instance
65 # (see below), which is used to construct class
66 # meta-object instances for any Class::MOP::*
67 # class. All other classes will use the more
68 # normal &construct_instance.
69 sub construct_class_instance {
72 my $package_name = $options{':package'};
73 (defined $package_name && $package_name)
74 || confess "You must pass a package name";
76 # return the metaclass if we have it cached,
77 # and it is still defined (it has not been
78 # reaped by DESTROY yet, which can happen
79 # annoyingly enough during global destruction)
80 return $METAS{$package_name}
81 if exists $METAS{$package_name} && defined $METAS{$package_name};
82 $class = blessed($class) || $class;
83 # now create the metaclass
85 if ($class =~ /^Class::MOP::/) {
87 '$:package' => $package_name,
89 '$:attribute_metaclass' => $options{':attribute_metaclass'} || 'Class::MOP::Attribute',
90 '$:method_metaclass' => $options{':method_metaclass'} || 'Class::MOP::Method',
91 '$:instance_metaclass' => $options{':instance_metaclass'} || 'Class::MOP::Instance',
96 # it is safe to use meta here because
97 # class will always be a subclass of
98 # Class::MOP::Class, which defines meta
99 $meta = $class->meta->construct_instance(%options)
101 # and check the metaclass compatibility
102 $meta->check_metaclass_compatability();
103 $METAS{$package_name} = $meta;
105 # we need to weaken any anon classes
106 # so that they can call DESTROY properly
107 weaken($METAS{$package_name})
108 if $package_name =~ /^$ANON_CLASS_PREFIX/;
112 sub check_metaclass_compatability {
115 # this is always okay ...
116 return if blessed($self) eq 'Class::MOP::Class' &&
117 $self->instance_metaclass eq 'Class::MOP::Instance';
119 my @class_list = $self->class_precedence_list;
120 shift @class_list; # shift off $self->name
122 foreach my $class_name (@class_list) {
123 my $meta = $METAS{$class_name} || next;
124 ($self->isa(blessed($meta)))
125 || confess $self->name . "->meta => (" . (blessed($self)) . ")" .
126 " is not compatible with the " .
127 $class_name . "->meta => (" . (blessed($meta)) . ")";
129 # we also need to check that instance metaclasses
130 # are compatabile in the same the class.
131 ($self->instance_metaclass->isa($meta->instance_metaclass))
132 || confess $self->name . "->meta => (" . ($self->instance_metaclass) . ")" .
133 " is not compatible with the " .
134 $class_name . "->meta => (" . ($meta->instance_metaclass) . ")";
143 # this should be sufficient, if you have a
144 # use case where it is not, write a test and
146 my $ANON_CLASS_SERIAL = 0;
148 sub create_anon_class {
149 my ($class, %options) = @_;
150 my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
151 return $class->create($package_name, '0.00', %options);
156 # this will only get called for
157 # anon-classes, all other calls
158 # are assumed to occur during
159 # global destruction and so don't
160 # really need to be handled explicitly
163 return unless $self->name =~ /^$ANON_CLASS_PREFIX/;
164 my ($serial_id) = ($self->name =~ /^$ANON_CLASS_PREFIX(\d+)/);
166 foreach my $key (keys %{$ANON_CLASS_PREFIX . $serial_id}) {
167 delete ${$ANON_CLASS_PREFIX . $serial_id}{$key};
169 delete ${'main::' . $ANON_CLASS_PREFIX}{$serial_id . '::'};
172 # creating classes with MOP ...
175 my ($class, $package_name, $package_version, %options) = @_;
176 (defined $package_name && $package_name)
177 || confess "You must pass a package name";
178 my $code = "package $package_name;";
179 $code .= "\$$package_name\:\:VERSION = '$package_version';"
180 if defined $package_version;
182 confess "creation of $package_name failed : $@" if $@;
183 my $meta = $class->initialize($package_name);
185 $meta->add_method('meta' => sub {
186 $class->initialize(blessed($_[0]) || $_[0]);
189 $meta->superclasses(@{$options{superclasses}})
190 if exists $options{superclasses};
192 # process attributes first, so that they can
193 # install accessors, but locally defined methods
194 # can then overwrite them. It is maybe a little odd, but
195 # I think this should be the order of things.
196 if (exists $options{attributes}) {
197 foreach my $attr (@{$options{attributes}}) {
198 $meta->add_attribute($attr);
201 if (exists $options{methods}) {
202 foreach my $method_name (keys %{$options{methods}}) {
203 $meta->add_method($method_name, $options{methods}->{$method_name});
212 # all these attribute readers will be bootstrapped
213 # away in the Class::MOP bootstrap section
215 sub get_attribute_map { $_[0]->{'%:attributes'} }
216 sub attribute_metaclass { $_[0]->{'$:attribute_metaclass'} }
217 sub method_metaclass { $_[0]->{'$:method_metaclass'} }
218 sub instance_metaclass { $_[0]->{'$:instance_metaclass'} }
220 # Instance Construction & Cloning
225 # we need to protect the integrity of the
226 # Class::MOP::Class singletons here, so we
227 # delegate this to &construct_class_instance
228 # which will deal with the singletons
229 return $class->construct_class_instance(@_)
230 if $class->name->isa('Class::MOP::Class');
231 return $class->construct_instance(@_);
234 sub construct_instance {
235 my ($class, %params) = @_;
236 my $meta_instance = $class->get_meta_instance();
237 my $instance = $meta_instance->create_instance();
238 foreach my $attr ($class->compute_all_applicable_attributes()) {
239 $attr->initialize_instance_slot($meta_instance, $instance, \%params);
244 sub get_meta_instance {
246 return $class->instance_metaclass->new(
248 $class->compute_all_applicable_attributes()
254 my $instance = shift;
255 (blessed($instance) && $instance->isa($class->name))
256 || confess "You must pass an instance ($instance) of the metaclass (" . $class->name . ")";
258 # we need to protect the integrity of the
259 # Class::MOP::Class singletons here, they
260 # should not be cloned.
261 return $instance if $instance->isa('Class::MOP::Class');
262 $class->clone_instance($instance, @_);
266 my ($class, $instance, %params) = @_;
268 || confess "You can only clone instances, \$self is not a blessed instance";
269 my $meta_instance = $class->get_meta_instance();
270 my $clone = $meta_instance->clone_instance($instance);
271 foreach my $key (keys %params) {
272 next unless $meta_instance->is_valid_slot($key);
273 $meta_instance->set_slot_value($clone, $key, $params{$key});
280 # &name should be here too, but it is above
281 # because it gets bootstrapped away
285 ${$self->get_package_variable('$VERSION')};
295 @{$self->name . '::ISA'} = @supers;
297 # we need to check the metaclass
298 # compatability here so that we can
299 # be sure that the superclass is
300 # not potentially creating an issues
301 # we don't know about
302 $self->check_metaclass_compatability();
304 @{$self->name . '::ISA'};
307 sub class_precedence_list {
310 # We need to check for ciruclar inheirtance here.
311 # This will do nothing if all is well, and blow
312 # up otherwise. Yes, it's an ugly hack, better
313 # suggestions are welcome.
314 { ($self->name || return)->isa('This is a test for circular inheritance') }
315 # ... and now back to our regularly scheduled program
319 $self->initialize($_)->class_precedence_list()
320 } $self->superclasses()
327 my ($self, $method_name, $method) = @_;
328 (defined $method_name && $method_name)
329 || confess "You must define a method name";
330 # use reftype here to allow for blessed subs ...
331 ('CODE' eq (reftype($method) || ''))
332 || confess "Your code block must be a CODE reference";
333 my $full_method_name = ($self->name . '::' . $method_name);
335 $method = $self->method_metaclass->wrap($method) unless blessed($method);
338 no warnings 'redefine';
339 *{$full_method_name} = subname $full_method_name => $method;
343 my $fetch_and_prepare_method = sub {
344 my ($self, $method_name) = @_;
346 my $method = $self->get_method($method_name);
347 # if we dont have local ...
349 # try to find the next method
350 $method = $self->find_next_method_by_name($method_name);
351 # die if it does not exist
353 || confess "The method '$method_name' is not found in the inherience hierarchy for this class";
354 # and now make sure to wrap it
355 # even if it is already wrapped
356 # because we need a new sub ref
357 $method = Class::MOP::Method::Wrapped->wrap($method);
360 # now make sure we wrap it properly
361 $method = Class::MOP::Method::Wrapped->wrap($method)
362 unless $method->isa('Class::MOP::Method::Wrapped');
364 $self->add_method($method_name => $method);
368 sub add_before_method_modifier {
369 my ($self, $method_name, $method_modifier) = @_;
370 (defined $method_name && $method_name)
371 || confess "You must pass in a method name";
372 my $method = $fetch_and_prepare_method->($self, $method_name);
373 $method->add_before_modifier(subname ':before' => $method_modifier);
376 sub add_after_method_modifier {
377 my ($self, $method_name, $method_modifier) = @_;
378 (defined $method_name && $method_name)
379 || confess "You must pass in a method name";
380 my $method = $fetch_and_prepare_method->($self, $method_name);
381 $method->add_after_modifier(subname ':after' => $method_modifier);
384 sub add_around_method_modifier {
385 my ($self, $method_name, $method_modifier) = @_;
386 (defined $method_name && $method_name)
387 || confess "You must pass in a method name";
388 my $method = $fetch_and_prepare_method->($self, $method_name);
389 $method->add_around_modifier(subname ':around' => $method_modifier);
393 # the methods above used to be named like this:
394 # ${pkg}::${method}:(before|after|around)
395 # but this proved problematic when using one modifier
396 # to wrap multiple methods (something which is likely
397 # to happen pretty regularly IMO). So instead of naming
398 # it like this, I have chosen to just name them purely
399 # with their modifier names, like so:
400 # :(before|after|around)
401 # The fact is that in a stack trace, it will be fairly
402 # evident from the context what method they are attached
403 # to, and so don't need the fully qualified name.
407 my ($self, $method_name, $method) = @_;
408 (defined $method_name && $method_name)
409 || confess "You must define a method name";
410 # use reftype here to allow for blessed subs ...
411 ('CODE' eq (reftype($method) || ''))
412 || confess "Your code block must be a CODE reference";
413 my $full_method_name = ($self->name . '::' . $method_name);
415 $method = $self->method_metaclass->wrap($method) unless blessed($method);
418 no warnings 'redefine';
419 *{$full_method_name} = $method;
423 my ($self, $method_name) = @_;
424 (defined $method_name && $method_name)
425 || confess "You must define a method name";
427 my $sub_name = ($self->name . '::' . $method_name);
430 return 0 if !defined(&{$sub_name});
431 my $method = \&{$sub_name};
432 return 0 if (svref_2object($method)->GV->STASH->NAME || '') ne $self->name &&
433 (svref_2object($method)->GV->NAME || '') ne '__ANON__';
435 # at this point we are relatively sure
436 # it is our method, so we bless/wrap it
437 $self->method_metaclass->wrap($method) unless blessed($method);
442 my ($self, $method_name) = @_;
443 (defined $method_name && $method_name)
444 || confess "You must define a method name";
446 return unless $self->has_method($method_name);
449 return \&{$self->name . '::' . $method_name};
453 my ($self, $method_name) = @_;
454 (defined $method_name && $method_name)
455 || confess "You must define a method name";
457 my $removed_method = $self->get_method($method_name);
460 delete ${$self->name . '::'}{$method_name}
461 if defined $removed_method;
463 return $removed_method;
466 sub get_method_list {
469 grep { $self->has_method($_) } keys %{$self->name . '::'};
472 sub compute_all_applicable_methods {
475 # keep a record of what we have seen
476 # here, this will handle all the
477 # inheritence issues because we are
478 # using the &class_precedence_list
479 my (%seen_class, %seen_method);
480 foreach my $class ($self->class_precedence_list()) {
481 next if $seen_class{$class};
482 $seen_class{$class}++;
483 # fetch the meta-class ...
484 my $meta = $self->initialize($class);
485 foreach my $method_name ($meta->get_method_list()) {
486 next if exists $seen_method{$method_name};
487 $seen_method{$method_name}++;
489 name => $method_name,
491 code => $meta->get_method($method_name)
498 sub find_all_methods_by_name {
499 my ($self, $method_name) = @_;
500 (defined $method_name && $method_name)
501 || confess "You must define a method name to find";
503 # keep a record of what we have seen
504 # here, this will handle all the
505 # inheritence issues because we are
506 # using the &class_precedence_list
508 foreach my $class ($self->class_precedence_list()) {
509 next if $seen_class{$class};
510 $seen_class{$class}++;
511 # fetch the meta-class ...
512 my $meta = $self->initialize($class);
514 name => $method_name,
516 code => $meta->get_method($method_name)
517 } if $meta->has_method($method_name);
522 sub find_next_method_by_name {
523 my ($self, $method_name) = @_;
524 (defined $method_name && $method_name)
525 || confess "You must define a method name to find";
526 # keep a record of what we have seen
527 # here, this will handle all the
528 # inheritence issues because we are
529 # using the &class_precedence_list
531 my @cpl = $self->class_precedence_list();
532 shift @cpl; # discard ourselves
533 foreach my $class (@cpl) {
534 next if $seen_class{$class};
535 $seen_class{$class}++;
536 # fetch the meta-class ...
537 my $meta = $self->initialize($class);
538 return $meta->get_method($method_name)
539 if $meta->has_method($method_name);
548 # either we have an attribute object already
549 # or we need to create one from the args provided
550 my $attribute = blessed($_[0]) ? $_[0] : $self->attribute_metaclass->new(@_);
551 # make sure it is derived from the correct type though
552 ($attribute->isa('Class::MOP::Attribute'))
553 || confess "Your attribute must be an instance of Class::MOP::Attribute (or a subclass)";
554 $attribute->attach_to_class($self);
555 $attribute->install_accessors();
556 $self->get_attribute_map->{$attribute->name} = $attribute;
559 # in theory we have to tell everyone the slot structure may have changed
563 my ($self, $attribute_name) = @_;
564 (defined $attribute_name && $attribute_name)
565 || confess "You must define an attribute name";
566 exists $self->get_attribute_map->{$attribute_name} ? 1 : 0;
570 my ($self, $attribute_name) = @_;
571 (defined $attribute_name && $attribute_name)
572 || confess "You must define an attribute name";
573 return $self->get_attribute_map->{$attribute_name}
574 if $self->has_attribute($attribute_name);
578 sub remove_attribute {
579 my ($self, $attribute_name) = @_;
580 (defined $attribute_name && $attribute_name)
581 || confess "You must define an attribute name";
582 my $removed_attribute = $self->get_attribute_map->{$attribute_name};
583 return unless defined $removed_attribute;
584 delete $self->get_attribute_map->{$attribute_name};
585 $removed_attribute->remove_accessors();
586 $removed_attribute->detach_from_class();
587 return $removed_attribute;
590 sub get_attribute_list {
592 keys %{$self->get_attribute_map};
595 sub compute_all_applicable_attributes {
598 # keep a record of what we have seen
599 # here, this will handle all the
600 # inheritence issues because we are
601 # using the &class_precedence_list
602 my (%seen_class, %seen_attr);
603 foreach my $class ($self->class_precedence_list()) {
604 next if $seen_class{$class};
605 $seen_class{$class}++;
606 # fetch the meta-class ...
607 my $meta = $self->initialize($class);
608 foreach my $attr_name ($meta->get_attribute_list()) {
609 next if exists $seen_attr{$attr_name};
610 $seen_attr{$attr_name}++;
611 push @attrs => $meta->get_attribute($attr_name);
617 sub find_attribute_by_name {
618 my ($self, $attr_name) = @_;
619 # keep a record of what we have seen
620 # here, this will handle all the
621 # inheritence issues because we are
622 # using the &class_precedence_list
624 foreach my $class ($self->class_precedence_list()) {
625 next if $seen_class{$class};
626 $seen_class{$class}++;
627 # fetch the meta-class ...
628 my $meta = $self->initialize($class);
629 return $meta->get_attribute($attr_name)
630 if $meta->has_attribute($attr_name);
638 sub is_immutable { 0 }
642 return Class::MOP::Class::Immutable->make_metaclass_immutable($class);
653 Class::MOP::Class - Class Meta Object
657 # assuming that class Foo
658 # has been defined, you can
660 # use this for introspection ...
662 # add a method to Foo ...
663 Foo->meta->add_method('bar' => sub { ... })
665 # get a list of all the classes searched
666 # the method dispatcher in the correct order
667 Foo->meta->class_precedence_list()
669 # remove a method from Foo
670 Foo->meta->remove_method('bar');
672 # or use this to actually create classes ...
674 Class::MOP::Class->create('Bar' => '0.01' => (
675 superclasses => [ 'Foo' ],
677 Class::MOP:::Attribute->new('$bar'),
678 Class::MOP:::Attribute->new('$baz'),
681 calculate_bar => sub { ... },
682 construct_baz => sub { ... }
688 This is the largest and currently most complex part of the Perl 5
689 meta-object protocol. It controls the introspection and
690 manipulation of Perl 5 classes (and it can create them too). The
691 best way to understand what this module can do, is to read the
692 documentation for each of it's methods.
696 =head2 Self Introspection
702 This will return a B<Class::MOP::Class> instance which is related
703 to this class. Thereby allowing B<Class::MOP::Class> to actually
706 As with B<Class::MOP::Attribute>, B<Class::MOP> will actually
707 bootstrap this module by installing a number of attribute meta-objects
708 into it's metaclass. This will allow this class to reap all the benifits
709 of the MOP when subclassing it.
711 =item B<get_all_metaclasses>
713 This will return an hash of all the metaclass instances that have
714 been cached by B<Class::MOP::Class> keyed by the package name.
716 =item B<get_all_metaclass_instances>
718 This will return an array of all the metaclass instances that have
719 been cached by B<Class::MOP::Class>.
721 =item B<get_all_metaclass_names>
723 This will return an array of all the metaclass names that have
724 been cached by B<Class::MOP::Class>.
728 =head2 Class construction
730 These methods will handle creating B<Class::MOP::Class> objects,
731 which can be used to both create new classes, and analyze
732 pre-existing classes.
734 This module will internally store references to all the instances
735 you create with these methods, so that they do not need to be
736 created any more than nessecary. Basically, they are singletons.
740 =item B<create ($package_name, ?$package_version,
741 superclasses =E<gt> ?@superclasses,
742 methods =E<gt> ?%methods,
743 attributes =E<gt> ?%attributes)>
745 This returns a B<Class::MOP::Class> object, bringing the specified
746 C<$package_name> into existence and adding any of the
747 C<$package_version>, C<@superclasses>, C<%methods> and C<%attributes>
750 =item B<create_anon_class (superclasses =E<gt> ?@superclasses,
751 methods =E<gt> ?%methods,
752 attributes =E<gt> ?%attributes)>
754 This will create an anonymous class, it works much like C<create> but
755 it does not need a C<$package_name>. Instead it will create a suitably
756 unique package name for you to stash things into.
758 =item B<initialize ($package_name, %options)>
760 This initializes and returns returns a B<Class::MOP::Class> object
761 for a given a C<$package_name>.
763 =item B<reinitialize ($package_name, %options)>
765 This removes the old metaclass, and creates a new one in it's place.
766 Do B<not> use this unless you really know what you are doing, it could
767 very easily make a very large mess of your program.
769 =item B<construct_class_instance (%options)>
771 This will construct an instance of B<Class::MOP::Class>, it is
772 here so that we can actually "tie the knot" for B<Class::MOP::Class>
773 to use C<construct_instance> once all the bootstrapping is done. This
774 method is used internally by C<initialize> and should never be called
775 from outside of that method really.
777 =item B<check_metaclass_compatability>
779 This method is called as the very last thing in the
780 C<construct_class_instance> method. This will check that the
781 metaclass you are creating is compatible with the metaclasses of all
782 your ancestors. For more inforamtion about metaclass compatibility
783 see the C<About Metaclass compatibility> section in L<Class::MOP>.
787 =head2 Object instance construction and cloning
789 These methods are B<entirely optional>, it is up to you whether you want
794 =item B<instance_metaclass>
796 =item B<get_meta_instance>
798 =item B<new_object (%params)>
800 This is a convience method for creating a new object of the class, and
801 blessing it into the appropriate package as well. Ideally your class
802 would call a C<new> this method like so:
805 my ($class, %param) = @_;
806 $class->meta->new_object(%params);
809 Of course the ideal place for this would actually be in C<UNIVERSAL::>
810 but that is considered bad style, so we do not do that.
812 =item B<construct_instance (%params)>
814 This method is used to construct an instace structure suitable for
815 C<bless>-ing into your package of choice. It works in conjunction
816 with the Attribute protocol to collect all applicable attributes.
818 This will construct and instance using a HASH ref as storage
819 (currently only HASH references are supported). This will collect all
820 the applicable attributes and layout out the fields in the HASH ref,
821 it will then initialize them using either use the corresponding key
822 in C<%params> or any default value or initializer found in the
823 attribute meta-object.
825 =item B<clone_object ($instance, %params)>
827 This is a convience method for cloning an object instance, then
828 blessing it into the appropriate package. This method will call
829 C<clone_instance>, which performs a shallow copy of the object,
830 see that methods documentation for more details. Ideally your
831 class would call a C<clone> this method like so:
834 my ($self, %param) = @_;
835 $self->meta->clone_object($self, %params);
838 Of course the ideal place for this would actually be in C<UNIVERSAL::>
839 but that is considered bad style, so we do not do that.
841 =item B<clone_instance($instance, %params)>
843 This method is a compliment of C<construct_instance> (which means if
844 you override C<construct_instance>, you need to override this one too),
845 and clones the instance shallowly.
847 The cloned structure returned is (like with C<construct_instance>) an
848 unC<bless>ed HASH reference, it is your responsibility to then bless
849 this cloned structure into the right class (which C<clone_object> will
852 As of 0.11, this method will clone the C<$instance> structure shallowly,
853 as opposed to the deep cloning implemented in prior versions. After much
854 thought, research and discussion, I have decided that anything but basic
855 shallow cloning is outside the scope of the meta-object protocol. I
856 think Yuval "nothingmuch" Kogman put it best when he said that cloning
857 is too I<context-specific> to be part of the MOP.
867 This is a read-only attribute which returns the package name for the
868 given B<Class::MOP::Class> instance.
872 This is a read-only attribute which returns the C<$VERSION> of the
873 package for the given B<Class::MOP::Class> instance.
877 =head2 Inheritance Relationships
881 =item B<superclasses (?@superclasses)>
883 This is a read-write attribute which represents the superclass
884 relationships of the class the B<Class::MOP::Class> instance is
885 associated with. Basically, it can get and set the C<@ISA> for you.
888 Perl will occasionally perform some C<@ISA> and method caching, if
889 you decide to change your superclass relationship at runtime (which
890 is quite insane and very much not recommened), then you should be
891 aware of this and the fact that this module does not make any
892 attempt to address this issue.
894 =item B<class_precedence_list>
896 This computes the a list of all the class's ancestors in the same order
897 in which method dispatch will be done. This is similair to
898 what B<Class::ISA::super_path> does, but we don't remove duplicate names.
906 =item B<method_metaclass>
908 =item B<add_method ($method_name, $method)>
910 This will take a C<$method_name> and CODE reference to that
911 C<$method> and install it into the class's package.
914 This does absolutely nothing special to C<$method>
915 other than use B<Sub::Name> to make sure it is tagged with the
916 correct name, and therefore show up correctly in stack traces and
919 =item B<alias_method ($method_name, $method)>
921 This will take a C<$method_name> and CODE reference to that
922 C<$method> and alias the method into the class's package.
925 Unlike C<add_method>, this will B<not> try to name the
926 C<$method> using B<Sub::Name>, it only aliases the method in
929 =item B<has_method ($method_name)>
931 This just provides a simple way to check if the class implements
932 a specific C<$method_name>. It will I<not> however, attempt to check
933 if the class inherits the method (use C<UNIVERSAL::can> for that).
935 This will correctly handle functions defined outside of the package
936 that use a fully qualified name (C<sub Package::name { ... }>).
938 This will correctly handle functions renamed with B<Sub::Name> and
939 installed using the symbol tables. However, if you are naming the
940 subroutine outside of the package scope, you must use the fully
941 qualified name, including the package name, for C<has_method> to
942 correctly identify it.
944 This will attempt to correctly ignore functions imported from other
945 packages using B<Exporter>. It breaks down if the function imported
946 is an C<__ANON__> sub (such as with C<use constant>), which very well
947 may be a valid method being applied to the class.
949 In short, this method cannot always be trusted to determine if the
950 C<$method_name> is actually a method. However, it will DWIM about
951 90% of the time, so it's a small trade off I think.
953 =item B<get_method ($method_name)>
955 This will return a CODE reference of the specified C<$method_name>,
956 or return undef if that method does not exist.
958 =item B<remove_method ($method_name)>
960 This will attempt to remove a given C<$method_name> from the class.
961 It will return the CODE reference that it has removed, and will
962 attempt to use B<Sub::Name> to clear the methods associated name.
964 =item B<get_method_list>
966 This will return a list of method names for all I<locally> defined
967 methods. It does B<not> provide a list of all applicable methods,
968 including any inherited ones. If you want a list of all applicable
969 methods, use the C<compute_all_applicable_methods> method.
971 =item B<compute_all_applicable_methods>
973 This will return a list of all the methods names this class will
974 respond to, taking into account inheritance. The list will be a list of
975 HASH references, each one containing the following information; method
976 name, the name of the class in which the method lives and a CODE
977 reference for the actual method.
979 =item B<find_all_methods_by_name ($method_name)>
981 This will traverse the inheritence hierarchy and locate all methods
982 with a given C<$method_name>. Similar to
983 C<compute_all_applicable_methods> it returns a list of HASH references
984 with the following information; method name (which will always be the
985 same as C<$method_name>), the name of the class in which the method
986 lives and a CODE reference for the actual method.
988 The list of methods produced is a distinct list, meaning there are no
989 duplicates in it. This is especially useful for things like object
990 initialization and destruction where you only want the method called
991 once, and in the correct order.
993 =item B<find_next_method_by_name ($method_name)>
995 This will return the first method to match a given C<$method_name> in
996 the superclasses, this is basically equivalent to calling
997 C<SUPER::$method_name>, but it can be dispatched at runtime.
1001 =head2 Method Modifiers
1003 Method modifiers are a concept borrowed from CLOS, in which a method
1004 can be wrapped with I<before>, I<after> and I<around> method modifiers
1005 that will be called everytime the method is called.
1007 =head3 How method modifiers work?
1009 Method modifiers work by wrapping the original method and then replacing
1010 it in the classes symbol table. The wrappers will handle calling all the
1011 modifiers in the appropariate orders and preserving the calling context
1012 for the original method.
1014 Each method modifier serves a particular purpose, which may not be
1015 obvious to users of other method wrapping modules. To start with, the
1016 return values of I<before> and I<after> modifiers are ignored. This is
1017 because thier purpose is B<not> to filter the input and output of the
1018 primary method (this is done with an I<around> modifier). This may seem
1019 like an odd restriction to some, but doing this allows for simple code
1020 to be added at the begining or end of a method call without jeapordizing
1021 the normal functioning of the primary method or placing any extra
1022 responsibility on the code of the modifier. Of course if you have more
1023 complex needs, then use the I<around> modifier, which uses a variation
1024 of continutation passing style to allow for a high degree of flexibility.
1026 Before and around modifiers are called in last-defined-first-called order,
1027 while after modifiers are called in first-defined-first-called order. So
1028 the call tree might looks something like this:
1038 To see examples of using method modifiers, see the following examples
1039 included in the distribution; F<InstanceCountingClass>, F<Perl6Attribute>,
1040 F<AttributesWithHistory> and F<C3MethodDispatchOrder>. There is also a
1041 classic CLOS usage example in the test F<017_add_method_modifier.t>.
1043 =head3 What is the performance impact?
1045 Of course there is a performance cost associated with method modifiers,
1046 but we have made every effort to make that cost be directly proportional
1047 to the amount of modifier features you utilize.
1049 The wrapping method does it's best to B<only> do as much work as it
1050 absolutely needs to. In order to do this we have moved some of the
1051 performance costs to set-up time, where they are easier to amortize.
1053 All this said, my benchmarks have indicated the following:
1055 simple wrapper with no modifiers 100% slower
1056 simple wrapper with simple before modifier 400% slower
1057 simple wrapper with simple after modifier 450% slower
1058 simple wrapper with simple around modifier 500-550% slower
1059 simple wrapper with all 3 modifiers 1100% slower
1061 These numbers may seem daunting, but you must remember, every feature
1062 comes with some cost. To put things in perspective, just doing a simple
1063 C<AUTOLOAD> which does nothing but extract the name of the method called
1064 and return it costs about 400% over a normal method call.
1068 =item B<add_before_method_modifier ($method_name, $code)>
1070 This will wrap the method at C<$method_name> and the supplied C<$code>
1071 will be passed the C<@_> arguments, and called before the original
1072 method is called. As specified above, the return value of the I<before>
1073 method modifiers is ignored, and it's ability to modify C<@_> is
1074 fairly limited. If you need to do either of these things, use an
1075 C<around> method modifier.
1077 =item B<add_after_method_modifier ($method_name, $code)>
1079 This will wrap the method at C<$method_name> so that the original
1080 method will be called, it's return values stashed, and then the
1081 supplied C<$code> will be passed the C<@_> arguments, and called.
1082 As specified above, the return value of the I<after> method
1083 modifiers is ignored, and it cannot modify the return values of
1084 the original method. If you need to do either of these things, use an
1085 C<around> method modifier.
1087 =item B<add_around_method_modifier ($method_name, $code)>
1089 This will wrap the method at C<$method_name> so that C<$code>
1090 will be called and passed the original method as an extra argument
1091 at the begining of the C<@_> argument list. This is a variation of
1092 continuation passing style, where the function prepended to C<@_>
1093 can be considered a continuation. It is up to C<$code> if it calls
1094 the original method or not, there is no restriction on what the
1095 C<$code> can or cannot do.
1101 It should be noted that since there is no one consistent way to define
1102 the attributes of a class in Perl 5. These methods can only work with
1103 the information given, and can not easily discover information on
1104 their own. See L<Class::MOP::Attribute> for more details.
1108 =item B<attribute_metaclass>
1110 =item B<get_attribute_map>
1112 =item B<add_attribute ($attribute_name, $attribute_meta_object)>
1114 This stores a C<$attribute_meta_object> in the B<Class::MOP::Class>
1115 instance associated with the given class, and associates it with
1116 the C<$attribute_name>. Unlike methods, attributes within the MOP
1117 are stored as meta-information only. They will be used later to
1118 construct instances from (see C<construct_instance> above).
1119 More details about the attribute meta-objects can be found in the
1120 L<Class::MOP::Attribute> or the L<Class::MOP/The Attribute protocol>
1123 It should be noted that any accessor, reader/writer or predicate
1124 methods which the C<$attribute_meta_object> has will be installed
1125 into the class at this time.
1127 =item B<has_attribute ($attribute_name)>
1129 Checks to see if this class has an attribute by the name of
1130 C<$attribute_name> and returns a boolean.
1132 =item B<get_attribute ($attribute_name)>
1134 Returns the attribute meta-object associated with C<$attribute_name>,
1135 if none is found, it will return undef.
1137 =item B<remove_attribute ($attribute_name)>
1139 This will remove the attribute meta-object stored at
1140 C<$attribute_name>, then return the removed attribute meta-object.
1143 Removing an attribute will only affect future instances of
1144 the class, it will not make any attempt to remove the attribute from
1145 any existing instances of the class.
1147 It should be noted that any accessor, reader/writer or predicate
1148 methods which the attribute meta-object stored at C<$attribute_name>
1149 has will be removed from the class at this time. This B<will> make
1150 these attributes somewhat inaccessable in previously created
1151 instances. But if you are crazy enough to do this at runtime, then
1152 you are crazy enough to deal with something like this :).
1154 =item B<get_attribute_list>
1156 This returns a list of attribute names which are defined in the local
1157 class. If you want a list of all applicable attributes for a class,
1158 use the C<compute_all_applicable_attributes> method.
1160 =item B<compute_all_applicable_attributes>
1162 This will traverse the inheritance heirachy and return a list of all
1163 the applicable attributes for this class. It does not construct a
1164 HASH reference like C<compute_all_applicable_methods> because all
1165 that same information is discoverable through the attribute
1168 =item B<find_attribute_by_name ($attr_name)>
1170 This method will traverse the inheritance heirachy and find the
1171 first attribute whose name matches C<$attr_name>, then return it.
1172 It will return undef if nothing is found.
1176 =head2 Package Variables
1178 Since Perl's classes are built atop the Perl package system, it is
1179 fairly common to use package scoped variables for things like static
1180 class variables. The following methods are convience methods for
1181 the creation and inspection of package scoped variables.
1185 =item B<add_package_variable ($variable_name, ?$initial_value)>
1187 Given a C<$variable_name>, which must contain a leading sigil, this
1188 method will create that variable within the package which houses the
1189 class. It also takes an optional C<$initial_value>, which must be a
1190 reference of the same type as the sigil of the C<$variable_name>
1193 =item B<get_package_variable ($variable_name)>
1195 This will return a reference to the package variable in
1198 =item B<has_package_variable ($variable_name)>
1200 Returns true (C<1>) if there is a package variable defined for
1201 C<$variable_name>, and false (C<0>) otherwise.
1203 =item B<remove_package_variable ($variable_name)>
1205 This will attempt to remove the package variable at C<$variable_name>.
1209 =head2 Class closing
1215 =item B<is_immutable>
1217 =item B<make_immutable>
1223 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1225 =head1 COPYRIGHT AND LICENSE
1227 Copyright 2006 by Infinity Interactive, Inc.
1229 L<http://www.iinteractive.com>
1231 This library is free software; you can redistribute it and/or modify
1232 it under the same terms as Perl itself.