2 package Class::MOP::Class;
8 use Scalar::Util 'blessed', 'reftype', 'weaken';
9 use Sub::Name 'subname';
10 use B 'svref_2object';
12 our $VERSION = '0.15';
14 use base 'Class::MOP::Module';
16 use Class::MOP::Instance;
20 sub meta { Class::MOP::Class->initialize(blessed($_[0]) || $_[0]) }
25 # we need a sufficiently annoying prefix
26 # this should suffice for now, this is
27 # used in a couple of places below, so
28 # need to put it up here for now.
29 my $ANON_CLASS_PREFIX = 'Class::MOP::Class::__ANON__::SERIAL::';
34 # Metaclasses are singletons, so we cache them here.
35 # there is no need to worry about destruction though
36 # because they should die only when the program dies.
37 # After all, do package definitions even get reaped?
40 # means of accessing all the metaclasses that have
41 # been initialized thus far (for mugwumps obj browser)
42 sub get_all_metaclasses { %METAS }
43 sub get_all_metaclass_instances { values %METAS }
44 sub get_all_metaclass_names { keys %METAS }
48 my $package_name = shift;
49 (defined $package_name && $package_name && !blessed($package_name))
50 || confess "You must pass a package name and it cannot be blessed";
51 $class->construct_class_instance(':package' => $package_name, @_);
56 my $package_name = shift;
57 (defined $package_name && $package_name && !blessed($package_name))
58 || confess "You must pass a package name and it cannot be blessed";
59 $METAS{$package_name} = undef;
60 $class->construct_class_instance(':package' => $package_name, @_);
63 # NOTE: (meta-circularity)
64 # this is a special form of &construct_instance
65 # (see below), which is used to construct class
66 # meta-object instances for any Class::MOP::*
67 # class. All other classes will use the more
68 # normal &construct_instance.
69 sub construct_class_instance {
72 my $package_name = $options{':package'};
73 (defined $package_name && $package_name)
74 || confess "You must pass a package name";
76 # return the metaclass if we have it cached,
77 # and it is still defined (it has not been
78 # reaped by DESTROY yet, which can happen
79 # annoyingly enough during global destruction)
80 return $METAS{$package_name}
81 if exists $METAS{$package_name} && defined $METAS{$package_name};
82 $class = blessed($class) || $class;
83 # now create the metaclass
85 if ($class =~ /^Class::MOP::/) {
87 '$:package' => $package_name,
89 '$:attribute_metaclass' => $options{':attribute_metaclass'} || 'Class::MOP::Attribute',
90 '$:method_metaclass' => $options{':method_metaclass'} || 'Class::MOP::Method',
91 '$:instance_metaclass' => $options{':instance_metaclass'} || 'Class::MOP::Instance',
96 # it is safe to use meta here because
97 # class will always be a subclass of
98 # Class::MOP::Class, which defines meta
99 $meta = $class->meta->construct_instance(%options)
101 # and check the metaclass compatibility
102 $meta->check_metaclass_compatability();
103 $METAS{$package_name} = $meta;
105 # we need to weaken any anon classes
106 # so that they can call DESTROY properly
107 weaken($METAS{$package_name})
108 if $package_name =~ /^$ANON_CLASS_PREFIX/;
112 sub check_metaclass_compatability {
115 # this is always okay ...
116 return if blessed($self) eq 'Class::MOP::Class' &&
117 $self->instance_metaclass eq 'Class::MOP::Instance';
119 my @class_list = $self->class_precedence_list;
120 shift @class_list; # shift off $self->name
122 foreach my $class_name (@class_list) {
123 my $meta = $METAS{$class_name} || next;
124 ($self->isa(blessed($meta)))
125 || confess $self->name . "->meta => (" . (blessed($self)) . ")" .
126 " is not compatible with the " .
127 $class_name . "->meta => (" . (blessed($meta)) . ")";
129 # we also need to check that instance metaclasses
130 # are compatabile in the same the class.
131 ($self->instance_metaclass->isa($meta->instance_metaclass))
132 || confess $self->name . "->meta => (" . ($self->instance_metaclass) . ")" .
133 " is not compatible with the " .
134 $class_name . "->meta => (" . ($meta->instance_metaclass) . ")";
143 # this should be sufficient, if you have a
144 # use case where it is not, write a test and
146 my $ANON_CLASS_SERIAL = 0;
148 sub create_anon_class {
149 my ($class, %options) = @_;
150 my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
151 return $class->create($package_name, '0.00', %options);
156 # this will only get called for
157 # anon-classes, all other calls
158 # are assumed to occur during
159 # global destruction and so don't
160 # really need to be handled explicitly
163 return unless $self->name =~ /^$ANON_CLASS_PREFIX/;
164 my ($serial_id) = ($self->name =~ /^$ANON_CLASS_PREFIX(\d+)/);
166 foreach my $key (keys %{$ANON_CLASS_PREFIX . $serial_id}) {
167 delete ${$ANON_CLASS_PREFIX . $serial_id}{$key};
169 delete ${'main::' . $ANON_CLASS_PREFIX}{$serial_id . '::'};
172 # creating classes with MOP ...
175 my ($class, $package_name, $package_version, %options) = @_;
176 (defined $package_name && $package_name)
177 || confess "You must pass a package name";
178 my $code = "package $package_name;";
179 $code .= "\$$package_name\:\:VERSION = '$package_version';"
180 if defined $package_version;
182 confess "creation of $package_name failed : $@" if $@;
183 my $meta = $class->initialize($package_name);
185 $meta->add_method('meta' => sub {
186 $class->initialize(blessed($_[0]) || $_[0]);
189 $meta->superclasses(@{$options{superclasses}})
190 if exists $options{superclasses};
192 # process attributes first, so that they can
193 # install accessors, but locally defined methods
194 # can then overwrite them. It is maybe a little odd, but
195 # I think this should be the order of things.
196 if (exists $options{attributes}) {
197 foreach my $attr (@{$options{attributes}}) {
198 $meta->add_attribute($attr);
201 if (exists $options{methods}) {
202 foreach my $method_name (keys %{$options{methods}}) {
203 $meta->add_method($method_name, $options{methods}->{$method_name});
212 # all these attribute readers will be bootstrapped
213 # away in the Class::MOP bootstrap section
215 sub get_attribute_map { $_[0]->{'%:attributes'} }
216 sub attribute_metaclass { $_[0]->{'$:attribute_metaclass'} }
217 sub method_metaclass { $_[0]->{'$:method_metaclass'} }
218 sub instance_metaclass { $_[0]->{'$:instance_metaclass'} }
220 # Instance Construction & Cloning
225 # we need to protect the integrity of the
226 # Class::MOP::Class singletons here, so we
227 # delegate this to &construct_class_instance
228 # which will deal with the singletons
229 return $class->construct_class_instance(@_)
230 if $class->name->isa('Class::MOP::Class');
231 return $class->construct_instance(@_);
234 sub construct_instance {
235 my ($class, %params) = @_;
236 my $meta_instance = $class->get_meta_instance();
237 my $instance = $meta_instance->create_instance();
238 foreach my $attr ($class->compute_all_applicable_attributes()) {
239 $attr->initialize_instance_slot($meta_instance, $instance, \%params);
244 sub get_meta_instance {
246 return $class->instance_metaclass->new(
248 $class->compute_all_applicable_attributes()
254 my $instance = shift;
255 (blessed($instance) && $instance->isa($class->name))
256 || confess "You must pass an instance ($instance) of the metaclass (" . $class->name . ")";
258 # we need to protect the integrity of the
259 # Class::MOP::Class singletons here, they
260 # should not be cloned.
261 return $instance if $instance->isa('Class::MOP::Class');
262 $class->clone_instance($instance, @_);
266 my ($class, $instance, %params) = @_;
268 || confess "You can only clone instances, \$self is not a blessed instance";
269 my $meta_instance = $class->get_meta_instance();
270 my $clone = $meta_instance->clone_instance($instance);
271 foreach my $key (keys %params) {
272 next unless $meta_instance->is_valid_slot($key);
273 $meta_instance->set_slot_value($clone, $key, $params{$key});
285 @{$self->name . '::ISA'} = @supers;
287 # we need to check the metaclass
288 # compatability here so that we can
289 # be sure that the superclass is
290 # not potentially creating an issues
291 # we don't know about
292 $self->check_metaclass_compatability();
294 @{$self->name . '::ISA'};
297 sub class_precedence_list {
300 # We need to check for ciruclar inheirtance here.
301 # This will do nothing if all is well, and blow
302 # up otherwise. Yes, it's an ugly hack, better
303 # suggestions are welcome.
304 { ($self->name || return)->isa('This is a test for circular inheritance') }
305 # ... and now back to our regularly scheduled program
309 $self->initialize($_)->class_precedence_list()
310 } $self->superclasses()
317 my ($self, $method_name, $method) = @_;
318 (defined $method_name && $method_name)
319 || confess "You must define a method name";
320 # use reftype here to allow for blessed subs ...
321 ('CODE' eq (reftype($method) || ''))
322 || confess "Your code block must be a CODE reference";
323 my $full_method_name = ($self->name . '::' . $method_name);
325 $method = $self->method_metaclass->wrap($method) unless blessed($method);
328 no warnings 'redefine';
329 *{$full_method_name} = subname $full_method_name => $method;
333 my $fetch_and_prepare_method = sub {
334 my ($self, $method_name) = @_;
336 my $method = $self->get_method($method_name);
337 # if we dont have local ...
339 # try to find the next method
340 $method = $self->find_next_method_by_name($method_name);
341 # die if it does not exist
343 || confess "The method '$method_name' is not found in the inherience hierarchy for this class";
344 # and now make sure to wrap it
345 # even if it is already wrapped
346 # because we need a new sub ref
347 $method = Class::MOP::Method::Wrapped->wrap($method);
350 # now make sure we wrap it properly
351 $method = Class::MOP::Method::Wrapped->wrap($method)
352 unless $method->isa('Class::MOP::Method::Wrapped');
354 $self->add_method($method_name => $method);
358 sub add_before_method_modifier {
359 my ($self, $method_name, $method_modifier) = @_;
360 (defined $method_name && $method_name)
361 || confess "You must pass in a method name";
362 my $method = $fetch_and_prepare_method->($self, $method_name);
363 $method->add_before_modifier(subname ':before' => $method_modifier);
366 sub add_after_method_modifier {
367 my ($self, $method_name, $method_modifier) = @_;
368 (defined $method_name && $method_name)
369 || confess "You must pass in a method name";
370 my $method = $fetch_and_prepare_method->($self, $method_name);
371 $method->add_after_modifier(subname ':after' => $method_modifier);
374 sub add_around_method_modifier {
375 my ($self, $method_name, $method_modifier) = @_;
376 (defined $method_name && $method_name)
377 || confess "You must pass in a method name";
378 my $method = $fetch_and_prepare_method->($self, $method_name);
379 $method->add_around_modifier(subname ':around' => $method_modifier);
383 # the methods above used to be named like this:
384 # ${pkg}::${method}:(before|after|around)
385 # but this proved problematic when using one modifier
386 # to wrap multiple methods (something which is likely
387 # to happen pretty regularly IMO). So instead of naming
388 # it like this, I have chosen to just name them purely
389 # with their modifier names, like so:
390 # :(before|after|around)
391 # The fact is that in a stack trace, it will be fairly
392 # evident from the context what method they are attached
393 # to, and so don't need the fully qualified name.
397 my ($self, $method_name, $method) = @_;
398 (defined $method_name && $method_name)
399 || confess "You must define a method name";
400 # use reftype here to allow for blessed subs ...
401 ('CODE' eq (reftype($method) || ''))
402 || confess "Your code block must be a CODE reference";
403 my $full_method_name = ($self->name . '::' . $method_name);
405 $method = $self->method_metaclass->wrap($method) unless blessed($method);
408 no warnings 'redefine';
409 *{$full_method_name} = $method;
413 my ($self, $method_name) = @_;
414 (defined $method_name && $method_name)
415 || confess "You must define a method name";
417 my $sub_name = ($self->name . '::' . $method_name);
420 return 0 if !defined(&{$sub_name});
421 my $method = \&{$sub_name};
422 return 0 if (svref_2object($method)->GV->STASH->NAME || '') ne $self->name &&
423 (svref_2object($method)->GV->NAME || '') ne '__ANON__';
425 # at this point we are relatively sure
426 # it is our method, so we bless/wrap it
427 $self->method_metaclass->wrap($method) unless blessed($method);
432 my ($self, $method_name) = @_;
433 (defined $method_name && $method_name)
434 || confess "You must define a method name";
436 return unless $self->has_method($method_name);
439 return \&{$self->name . '::' . $method_name};
443 my ($self, $method_name) = @_;
444 (defined $method_name && $method_name)
445 || confess "You must define a method name";
447 my $removed_method = $self->get_method($method_name);
450 delete ${$self->name . '::'}{$method_name}
451 if defined $removed_method;
453 return $removed_method;
456 sub get_method_list {
459 grep { $self->has_method($_) } keys %{$self->name . '::'};
462 sub compute_all_applicable_methods {
465 # keep a record of what we have seen
466 # here, this will handle all the
467 # inheritence issues because we are
468 # using the &class_precedence_list
469 my (%seen_class, %seen_method);
470 foreach my $class ($self->class_precedence_list()) {
471 next if $seen_class{$class};
472 $seen_class{$class}++;
473 # fetch the meta-class ...
474 my $meta = $self->initialize($class);
475 foreach my $method_name ($meta->get_method_list()) {
476 next if exists $seen_method{$method_name};
477 $seen_method{$method_name}++;
479 name => $method_name,
481 code => $meta->get_method($method_name)
488 sub find_all_methods_by_name {
489 my ($self, $method_name) = @_;
490 (defined $method_name && $method_name)
491 || confess "You must define a method name to find";
493 # keep a record of what we have seen
494 # here, this will handle all the
495 # inheritence issues because we are
496 # using the &class_precedence_list
498 foreach my $class ($self->class_precedence_list()) {
499 next if $seen_class{$class};
500 $seen_class{$class}++;
501 # fetch the meta-class ...
502 my $meta = $self->initialize($class);
504 name => $method_name,
506 code => $meta->get_method($method_name)
507 } if $meta->has_method($method_name);
512 sub find_next_method_by_name {
513 my ($self, $method_name) = @_;
514 (defined $method_name && $method_name)
515 || confess "You must define a method name to find";
516 # keep a record of what we have seen
517 # here, this will handle all the
518 # inheritence issues because we are
519 # using the &class_precedence_list
521 my @cpl = $self->class_precedence_list();
522 shift @cpl; # discard ourselves
523 foreach my $class (@cpl) {
524 next if $seen_class{$class};
525 $seen_class{$class}++;
526 # fetch the meta-class ...
527 my $meta = $self->initialize($class);
528 return $meta->get_method($method_name)
529 if $meta->has_method($method_name);
538 # either we have an attribute object already
539 # or we need to create one from the args provided
540 my $attribute = blessed($_[0]) ? $_[0] : $self->attribute_metaclass->new(@_);
541 # make sure it is derived from the correct type though
542 ($attribute->isa('Class::MOP::Attribute'))
543 || confess "Your attribute must be an instance of Class::MOP::Attribute (or a subclass)";
544 $attribute->attach_to_class($self);
545 $attribute->install_accessors();
546 $self->get_attribute_map->{$attribute->name} = $attribute;
549 # in theory we have to tell everyone the slot structure may have changed
553 my ($self, $attribute_name) = @_;
554 (defined $attribute_name && $attribute_name)
555 || confess "You must define an attribute name";
556 exists $self->get_attribute_map->{$attribute_name} ? 1 : 0;
560 my ($self, $attribute_name) = @_;
561 (defined $attribute_name && $attribute_name)
562 || confess "You must define an attribute name";
563 return $self->get_attribute_map->{$attribute_name}
564 if $self->has_attribute($attribute_name);
568 sub remove_attribute {
569 my ($self, $attribute_name) = @_;
570 (defined $attribute_name && $attribute_name)
571 || confess "You must define an attribute name";
572 my $removed_attribute = $self->get_attribute_map->{$attribute_name};
573 return unless defined $removed_attribute;
574 delete $self->get_attribute_map->{$attribute_name};
575 $removed_attribute->remove_accessors();
576 $removed_attribute->detach_from_class();
577 return $removed_attribute;
580 sub get_attribute_list {
582 keys %{$self->get_attribute_map};
585 sub compute_all_applicable_attributes {
588 # keep a record of what we have seen
589 # here, this will handle all the
590 # inheritence issues because we are
591 # using the &class_precedence_list
592 my (%seen_class, %seen_attr);
593 foreach my $class ($self->class_precedence_list()) {
594 next if $seen_class{$class};
595 $seen_class{$class}++;
596 # fetch the meta-class ...
597 my $meta = $self->initialize($class);
598 foreach my $attr_name ($meta->get_attribute_list()) {
599 next if exists $seen_attr{$attr_name};
600 $seen_attr{$attr_name}++;
601 push @attrs => $meta->get_attribute($attr_name);
607 sub find_attribute_by_name {
608 my ($self, $attr_name) = @_;
609 # keep a record of what we have seen
610 # here, this will handle all the
611 # inheritence issues because we are
612 # using the &class_precedence_list
614 foreach my $class ($self->class_precedence_list()) {
615 next if $seen_class{$class};
616 $seen_class{$class}++;
617 # fetch the meta-class ...
618 my $meta = $self->initialize($class);
619 return $meta->get_attribute($attr_name)
620 if $meta->has_attribute($attr_name);
628 sub is_immutable { 0 }
631 return Class::MOP::Class::Immutable->make_metaclass_immutable(@_);
642 Class::MOP::Class - Class Meta Object
646 # assuming that class Foo
647 # has been defined, you can
649 # use this for introspection ...
651 # add a method to Foo ...
652 Foo->meta->add_method('bar' => sub { ... })
654 # get a list of all the classes searched
655 # the method dispatcher in the correct order
656 Foo->meta->class_precedence_list()
658 # remove a method from Foo
659 Foo->meta->remove_method('bar');
661 # or use this to actually create classes ...
663 Class::MOP::Class->create('Bar' => '0.01' => (
664 superclasses => [ 'Foo' ],
666 Class::MOP:::Attribute->new('$bar'),
667 Class::MOP:::Attribute->new('$baz'),
670 calculate_bar => sub { ... },
671 construct_baz => sub { ... }
677 This is the largest and currently most complex part of the Perl 5
678 meta-object protocol. It controls the introspection and
679 manipulation of Perl 5 classes (and it can create them too). The
680 best way to understand what this module can do, is to read the
681 documentation for each of it's methods.
685 =head2 Self Introspection
691 This will return a B<Class::MOP::Class> instance which is related
692 to this class. Thereby allowing B<Class::MOP::Class> to actually
695 As with B<Class::MOP::Attribute>, B<Class::MOP> will actually
696 bootstrap this module by installing a number of attribute meta-objects
697 into it's metaclass. This will allow this class to reap all the benifits
698 of the MOP when subclassing it.
700 =item B<get_all_metaclasses>
702 This will return an hash of all the metaclass instances that have
703 been cached by B<Class::MOP::Class> keyed by the package name.
705 =item B<get_all_metaclass_instances>
707 This will return an array of all the metaclass instances that have
708 been cached by B<Class::MOP::Class>.
710 =item B<get_all_metaclass_names>
712 This will return an array of all the metaclass names that have
713 been cached by B<Class::MOP::Class>.
717 =head2 Class construction
719 These methods will handle creating B<Class::MOP::Class> objects,
720 which can be used to both create new classes, and analyze
721 pre-existing classes.
723 This module will internally store references to all the instances
724 you create with these methods, so that they do not need to be
725 created any more than nessecary. Basically, they are singletons.
729 =item B<create ($package_name, ?$package_version,
730 superclasses =E<gt> ?@superclasses,
731 methods =E<gt> ?%methods,
732 attributes =E<gt> ?%attributes)>
734 This returns a B<Class::MOP::Class> object, bringing the specified
735 C<$package_name> into existence and adding any of the
736 C<$package_version>, C<@superclasses>, C<%methods> and C<%attributes>
739 =item B<create_anon_class (superclasses =E<gt> ?@superclasses,
740 methods =E<gt> ?%methods,
741 attributes =E<gt> ?%attributes)>
743 This will create an anonymous class, it works much like C<create> but
744 it does not need a C<$package_name>. Instead it will create a suitably
745 unique package name for you to stash things into.
747 =item B<initialize ($package_name, %options)>
749 This initializes and returns returns a B<Class::MOP::Class> object
750 for a given a C<$package_name>.
752 =item B<reinitialize ($package_name, %options)>
754 This removes the old metaclass, and creates a new one in it's place.
755 Do B<not> use this unless you really know what you are doing, it could
756 very easily make a very large mess of your program.
758 =item B<construct_class_instance (%options)>
760 This will construct an instance of B<Class::MOP::Class>, it is
761 here so that we can actually "tie the knot" for B<Class::MOP::Class>
762 to use C<construct_instance> once all the bootstrapping is done. This
763 method is used internally by C<initialize> and should never be called
764 from outside of that method really.
766 =item B<check_metaclass_compatability>
768 This method is called as the very last thing in the
769 C<construct_class_instance> method. This will check that the
770 metaclass you are creating is compatible with the metaclasses of all
771 your ancestors. For more inforamtion about metaclass compatibility
772 see the C<About Metaclass compatibility> section in L<Class::MOP>.
776 =head2 Object instance construction and cloning
778 These methods are B<entirely optional>, it is up to you whether you want
783 =item B<instance_metaclass>
785 =item B<get_meta_instance>
787 =item B<new_object (%params)>
789 This is a convience method for creating a new object of the class, and
790 blessing it into the appropriate package as well. Ideally your class
791 would call a C<new> this method like so:
794 my ($class, %param) = @_;
795 $class->meta->new_object(%params);
798 Of course the ideal place for this would actually be in C<UNIVERSAL::>
799 but that is considered bad style, so we do not do that.
801 =item B<construct_instance (%params)>
803 This method is used to construct an instace structure suitable for
804 C<bless>-ing into your package of choice. It works in conjunction
805 with the Attribute protocol to collect all applicable attributes.
807 This will construct and instance using a HASH ref as storage
808 (currently only HASH references are supported). This will collect all
809 the applicable attributes and layout out the fields in the HASH ref,
810 it will then initialize them using either use the corresponding key
811 in C<%params> or any default value or initializer found in the
812 attribute meta-object.
814 =item B<clone_object ($instance, %params)>
816 This is a convience method for cloning an object instance, then
817 blessing it into the appropriate package. This method will call
818 C<clone_instance>, which performs a shallow copy of the object,
819 see that methods documentation for more details. Ideally your
820 class would call a C<clone> this method like so:
823 my ($self, %param) = @_;
824 $self->meta->clone_object($self, %params);
827 Of course the ideal place for this would actually be in C<UNIVERSAL::>
828 but that is considered bad style, so we do not do that.
830 =item B<clone_instance($instance, %params)>
832 This method is a compliment of C<construct_instance> (which means if
833 you override C<construct_instance>, you need to override this one too),
834 and clones the instance shallowly.
836 The cloned structure returned is (like with C<construct_instance>) an
837 unC<bless>ed HASH reference, it is your responsibility to then bless
838 this cloned structure into the right class (which C<clone_object> will
841 As of 0.11, this method will clone the C<$instance> structure shallowly,
842 as opposed to the deep cloning implemented in prior versions. After much
843 thought, research and discussion, I have decided that anything but basic
844 shallow cloning is outside the scope of the meta-object protocol. I
845 think Yuval "nothingmuch" Kogman put it best when he said that cloning
846 is too I<context-specific> to be part of the MOP.
856 This is a read-only attribute which returns the package name for the
857 given B<Class::MOP::Class> instance.
861 This is a read-only attribute which returns the C<$VERSION> of the
862 package for the given B<Class::MOP::Class> instance.
866 =head2 Inheritance Relationships
870 =item B<superclasses (?@superclasses)>
872 This is a read-write attribute which represents the superclass
873 relationships of the class the B<Class::MOP::Class> instance is
874 associated with. Basically, it can get and set the C<@ISA> for you.
877 Perl will occasionally perform some C<@ISA> and method caching, if
878 you decide to change your superclass relationship at runtime (which
879 is quite insane and very much not recommened), then you should be
880 aware of this and the fact that this module does not make any
881 attempt to address this issue.
883 =item B<class_precedence_list>
885 This computes the a list of all the class's ancestors in the same order
886 in which method dispatch will be done. This is similair to
887 what B<Class::ISA::super_path> does, but we don't remove duplicate names.
895 =item B<method_metaclass>
897 =item B<add_method ($method_name, $method)>
899 This will take a C<$method_name> and CODE reference to that
900 C<$method> and install it into the class's package.
903 This does absolutely nothing special to C<$method>
904 other than use B<Sub::Name> to make sure it is tagged with the
905 correct name, and therefore show up correctly in stack traces and
908 =item B<alias_method ($method_name, $method)>
910 This will take a C<$method_name> and CODE reference to that
911 C<$method> and alias the method into the class's package.
914 Unlike C<add_method>, this will B<not> try to name the
915 C<$method> using B<Sub::Name>, it only aliases the method in
918 =item B<has_method ($method_name)>
920 This just provides a simple way to check if the class implements
921 a specific C<$method_name>. It will I<not> however, attempt to check
922 if the class inherits the method (use C<UNIVERSAL::can> for that).
924 This will correctly handle functions defined outside of the package
925 that use a fully qualified name (C<sub Package::name { ... }>).
927 This will correctly handle functions renamed with B<Sub::Name> and
928 installed using the symbol tables. However, if you are naming the
929 subroutine outside of the package scope, you must use the fully
930 qualified name, including the package name, for C<has_method> to
931 correctly identify it.
933 This will attempt to correctly ignore functions imported from other
934 packages using B<Exporter>. It breaks down if the function imported
935 is an C<__ANON__> sub (such as with C<use constant>), which very well
936 may be a valid method being applied to the class.
938 In short, this method cannot always be trusted to determine if the
939 C<$method_name> is actually a method. However, it will DWIM about
940 90% of the time, so it's a small trade off I think.
942 =item B<get_method ($method_name)>
944 This will return a CODE reference of the specified C<$method_name>,
945 or return undef if that method does not exist.
947 =item B<remove_method ($method_name)>
949 This will attempt to remove a given C<$method_name> from the class.
950 It will return the CODE reference that it has removed, and will
951 attempt to use B<Sub::Name> to clear the methods associated name.
953 =item B<get_method_list>
955 This will return a list of method names for all I<locally> defined
956 methods. It does B<not> provide a list of all applicable methods,
957 including any inherited ones. If you want a list of all applicable
958 methods, use the C<compute_all_applicable_methods> method.
960 =item B<compute_all_applicable_methods>
962 This will return a list of all the methods names this class will
963 respond to, taking into account inheritance. The list will be a list of
964 HASH references, each one containing the following information; method
965 name, the name of the class in which the method lives and a CODE
966 reference for the actual method.
968 =item B<find_all_methods_by_name ($method_name)>
970 This will traverse the inheritence hierarchy and locate all methods
971 with a given C<$method_name>. Similar to
972 C<compute_all_applicable_methods> it returns a list of HASH references
973 with the following information; method name (which will always be the
974 same as C<$method_name>), the name of the class in which the method
975 lives and a CODE reference for the actual method.
977 The list of methods produced is a distinct list, meaning there are no
978 duplicates in it. This is especially useful for things like object
979 initialization and destruction where you only want the method called
980 once, and in the correct order.
982 =item B<find_next_method_by_name ($method_name)>
984 This will return the first method to match a given C<$method_name> in
985 the superclasses, this is basically equivalent to calling
986 C<SUPER::$method_name>, but it can be dispatched at runtime.
990 =head2 Method Modifiers
992 Method modifiers are a concept borrowed from CLOS, in which a method
993 can be wrapped with I<before>, I<after> and I<around> method modifiers
994 that will be called everytime the method is called.
996 =head3 How method modifiers work?
998 Method modifiers work by wrapping the original method and then replacing
999 it in the classes symbol table. The wrappers will handle calling all the
1000 modifiers in the appropariate orders and preserving the calling context
1001 for the original method.
1003 Each method modifier serves a particular purpose, which may not be
1004 obvious to users of other method wrapping modules. To start with, the
1005 return values of I<before> and I<after> modifiers are ignored. This is
1006 because thier purpose is B<not> to filter the input and output of the
1007 primary method (this is done with an I<around> modifier). This may seem
1008 like an odd restriction to some, but doing this allows for simple code
1009 to be added at the begining or end of a method call without jeapordizing
1010 the normal functioning of the primary method or placing any extra
1011 responsibility on the code of the modifier. Of course if you have more
1012 complex needs, then use the I<around> modifier, which uses a variation
1013 of continutation passing style to allow for a high degree of flexibility.
1015 Before and around modifiers are called in last-defined-first-called order,
1016 while after modifiers are called in first-defined-first-called order. So
1017 the call tree might looks something like this:
1027 To see examples of using method modifiers, see the following examples
1028 included in the distribution; F<InstanceCountingClass>, F<Perl6Attribute>,
1029 F<AttributesWithHistory> and F<C3MethodDispatchOrder>. There is also a
1030 classic CLOS usage example in the test F<017_add_method_modifier.t>.
1032 =head3 What is the performance impact?
1034 Of course there is a performance cost associated with method modifiers,
1035 but we have made every effort to make that cost be directly proportional
1036 to the amount of modifier features you utilize.
1038 The wrapping method does it's best to B<only> do as much work as it
1039 absolutely needs to. In order to do this we have moved some of the
1040 performance costs to set-up time, where they are easier to amortize.
1042 All this said, my benchmarks have indicated the following:
1044 simple wrapper with no modifiers 100% slower
1045 simple wrapper with simple before modifier 400% slower
1046 simple wrapper with simple after modifier 450% slower
1047 simple wrapper with simple around modifier 500-550% slower
1048 simple wrapper with all 3 modifiers 1100% slower
1050 These numbers may seem daunting, but you must remember, every feature
1051 comes with some cost. To put things in perspective, just doing a simple
1052 C<AUTOLOAD> which does nothing but extract the name of the method called
1053 and return it costs about 400% over a normal method call.
1057 =item B<add_before_method_modifier ($method_name, $code)>
1059 This will wrap the method at C<$method_name> and the supplied C<$code>
1060 will be passed the C<@_> arguments, and called before the original
1061 method is called. As specified above, the return value of the I<before>
1062 method modifiers is ignored, and it's ability to modify C<@_> is
1063 fairly limited. If you need to do either of these things, use an
1064 C<around> method modifier.
1066 =item B<add_after_method_modifier ($method_name, $code)>
1068 This will wrap the method at C<$method_name> so that the original
1069 method will be called, it's return values stashed, and then the
1070 supplied C<$code> will be passed the C<@_> arguments, and called.
1071 As specified above, the return value of the I<after> method
1072 modifiers is ignored, and it cannot modify the return values of
1073 the original method. If you need to do either of these things, use an
1074 C<around> method modifier.
1076 =item B<add_around_method_modifier ($method_name, $code)>
1078 This will wrap the method at C<$method_name> so that C<$code>
1079 will be called and passed the original method as an extra argument
1080 at the begining of the C<@_> argument list. This is a variation of
1081 continuation passing style, where the function prepended to C<@_>
1082 can be considered a continuation. It is up to C<$code> if it calls
1083 the original method or not, there is no restriction on what the
1084 C<$code> can or cannot do.
1090 It should be noted that since there is no one consistent way to define
1091 the attributes of a class in Perl 5. These methods can only work with
1092 the information given, and can not easily discover information on
1093 their own. See L<Class::MOP::Attribute> for more details.
1097 =item B<attribute_metaclass>
1099 =item B<get_attribute_map>
1101 =item B<add_attribute ($attribute_name, $attribute_meta_object)>
1103 This stores a C<$attribute_meta_object> in the B<Class::MOP::Class>
1104 instance associated with the given class, and associates it with
1105 the C<$attribute_name>. Unlike methods, attributes within the MOP
1106 are stored as meta-information only. They will be used later to
1107 construct instances from (see C<construct_instance> above).
1108 More details about the attribute meta-objects can be found in the
1109 L<Class::MOP::Attribute> or the L<Class::MOP/The Attribute protocol>
1112 It should be noted that any accessor, reader/writer or predicate
1113 methods which the C<$attribute_meta_object> has will be installed
1114 into the class at this time.
1116 =item B<has_attribute ($attribute_name)>
1118 Checks to see if this class has an attribute by the name of
1119 C<$attribute_name> and returns a boolean.
1121 =item B<get_attribute ($attribute_name)>
1123 Returns the attribute meta-object associated with C<$attribute_name>,
1124 if none is found, it will return undef.
1126 =item B<remove_attribute ($attribute_name)>
1128 This will remove the attribute meta-object stored at
1129 C<$attribute_name>, then return the removed attribute meta-object.
1132 Removing an attribute will only affect future instances of
1133 the class, it will not make any attempt to remove the attribute from
1134 any existing instances of the class.
1136 It should be noted that any accessor, reader/writer or predicate
1137 methods which the attribute meta-object stored at C<$attribute_name>
1138 has will be removed from the class at this time. This B<will> make
1139 these attributes somewhat inaccessable in previously created
1140 instances. But if you are crazy enough to do this at runtime, then
1141 you are crazy enough to deal with something like this :).
1143 =item B<get_attribute_list>
1145 This returns a list of attribute names which are defined in the local
1146 class. If you want a list of all applicable attributes for a class,
1147 use the C<compute_all_applicable_attributes> method.
1149 =item B<compute_all_applicable_attributes>
1151 This will traverse the inheritance heirachy and return a list of all
1152 the applicable attributes for this class. It does not construct a
1153 HASH reference like C<compute_all_applicable_methods> because all
1154 that same information is discoverable through the attribute
1157 =item B<find_attribute_by_name ($attr_name)>
1159 This method will traverse the inheritance heirachy and find the
1160 first attribute whose name matches C<$attr_name>, then return it.
1161 It will return undef if nothing is found.
1165 =head2 Package Variables
1167 Since Perl's classes are built atop the Perl package system, it is
1168 fairly common to use package scoped variables for things like static
1169 class variables. The following methods are convience methods for
1170 the creation and inspection of package scoped variables.
1174 =item B<add_package_symbol ($variable_name, ?$initial_value)>
1176 Given a C<$variable_name>, which must contain a leading sigil, this
1177 method will create that variable within the package which houses the
1178 class. It also takes an optional C<$initial_value>, which must be a
1179 reference of the same type as the sigil of the C<$variable_name>
1182 =item B<get_package_symbol ($variable_name)>
1184 This will return a reference to the package variable in
1187 =item B<has_package_symbol ($variable_name)>
1189 Returns true (C<1>) if there is a package variable defined for
1190 C<$variable_name>, and false (C<0>) otherwise.
1192 =item B<remove_package_symbol ($variable_name)>
1194 This will attempt to remove the package variable at C<$variable_name>.
1198 =head2 Class closing
1204 =item B<is_immutable>
1206 =item B<make_immutable>
1212 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1214 =head1 COPYRIGHT AND LICENSE
1216 Copyright 2006 by Infinity Interactive, Inc.
1218 L<http://www.iinteractive.com>
1220 This library is free software; you can redistribute it and/or modify
1221 it under the same terms as Perl itself.