2 package Class::MOP::Class;
7 use Class::MOP::Immutable;
8 use Class::MOP::Instance;
9 use Class::MOP::Method::Wrapped;
12 use Scalar::Util 'blessed', 'reftype', 'weaken';
13 use Sub::Name 'subname';
15 our $VERSION = '0.30';
16 our $AUTHORITY = 'cpan:STEVAN';
18 use base 'Class::MOP::Module';
24 my $package_name = shift;
25 (defined $package_name && $package_name && !blessed($package_name))
26 || confess "You must pass a package name and it cannot be blessed";
27 if (defined(my $meta = Class::MOP::get_metaclass_by_name($package_name))) {
30 $class->construct_class_instance('package' => $package_name, @_);
35 my $package_name = shift;
36 (defined $package_name && $package_name && !blessed($package_name))
37 || confess "You must pass a package name and it cannot be blessed";
38 Class::MOP::remove_metaclass_by_name($package_name);
39 $class->construct_class_instance('package' => $package_name, @_);
42 # NOTE: (meta-circularity)
43 # this is a special form of &construct_instance
44 # (see below), which is used to construct class
45 # meta-object instances for any Class::MOP::*
46 # class. All other classes will use the more
47 # normal &construct_instance.
48 sub construct_class_instance {
51 my $package_name = $options{'package'};
52 (defined $package_name && $package_name)
53 || confess "You must pass a package name";
55 # return the metaclass if we have it cached,
56 # and it is still defined (it has not been
57 # reaped by DESTROY yet, which can happen
58 # annoyingly enough during global destruction)
60 if (defined(my $meta = Class::MOP::get_metaclass_by_name($package_name))) {
65 # we need to deal with the possibility
66 # of class immutability here, and then
67 # get the name of the class appropriately
68 $class = (blessed($class)
69 ? ($class->is_immutable
70 ? $class->get_mutable_metaclass_name()
74 # now create the metaclass
76 if ($class eq 'Class::MOP::Class') {
79 # inherited from Class::MOP::Package
80 '$!package' => $package_name,
83 # since the following attributes will
84 # actually be loaded from the symbol
85 # table, and actually bypass the instance
86 # entirely, we can just leave these things
87 # listed here for reference, because they
88 # should not actually have a value associated
90 '%!namespace' => \undef,
91 # inherited from Class::MOP::Module
92 '$!version' => \undef,
93 '$!authority' => \undef,
94 # defined in Class::MOP::Class
95 '@!superclasses' => \undef,
99 '$!attribute_metaclass' => $options{'attribute_metaclass'} || 'Class::MOP::Attribute',
100 '$!method_metaclass' => $options{'method_metaclass'} || 'Class::MOP::Method',
101 '$!instance_metaclass' => $options{'instance_metaclass'} || 'Class::MOP::Instance',
103 ## uber-private variables
105 # this starts out as undef so that
106 # we can tell the first time the
107 # methods are fetched
109 '$!_package_cache_flag' => undef,
114 # it is safe to use meta here because
115 # class will always be a subclass of
116 # Class::MOP::Class, which defines meta
117 $meta = $class->meta->construct_instance(%options)
120 # and check the metaclass compatibility
121 $meta->check_metaclass_compatability();
123 Class::MOP::store_metaclass_by_name($package_name, $meta);
126 # we need to weaken any anon classes
127 # so that they can call DESTROY properly
128 Class::MOP::weaken_metaclass($package_name) if $meta->is_anon_class;
133 sub reset_package_cache_flag { (shift)->{'$!_package_cache_flag'} = undef }
134 sub update_package_cache_flag {
137 # we can manually update the cache number
138 # since we are actually adding the method
139 # to our cache as well. This avoids us
140 # having to regenerate the method_map.
142 $self->{'$!_package_cache_flag'} = Class::MOP::check_package_cache_flag($self->name);
145 sub check_metaclass_compatability {
148 # this is always okay ...
149 return if blessed($self) eq 'Class::MOP::Class' &&
150 $self->instance_metaclass eq 'Class::MOP::Instance';
152 my @class_list = $self->linearized_isa;
153 shift @class_list; # shift off $self->name
155 foreach my $class_name (@class_list) {
156 my $meta = Class::MOP::get_metaclass_by_name($class_name) || next;
159 # we need to deal with the possibility
160 # of class immutability here, and then
161 # get the name of the class appropriately
162 my $meta_type = ($meta->is_immutable
163 ? $meta->get_mutable_metaclass_name()
166 ($self->isa($meta_type))
167 || confess $self->name . "->meta => (" . (blessed($self)) . ")" .
168 " is not compatible with the " .
169 $class_name . "->meta => (" . ($meta_type) . ")";
171 # we also need to check that instance metaclasses
172 # are compatabile in the same the class.
173 ($self->instance_metaclass->isa($meta->instance_metaclass))
174 || confess $self->name . "->meta => (" . ($self->instance_metaclass) . ")" .
175 " is not compatible with the " .
176 $class_name . "->meta => (" . ($meta->instance_metaclass) . ")";
184 # this should be sufficient, if you have a
185 # use case where it is not, write a test and
187 my $ANON_CLASS_SERIAL = 0;
190 # we need a sufficiently annoying prefix
191 # this should suffice for now, this is
192 # used in a couple of places below, so
193 # need to put it up here for now.
194 my $ANON_CLASS_PREFIX = 'Class::MOP::Class::__ANON__::SERIAL::';
198 no warnings 'uninitialized';
199 $self->name =~ /^$ANON_CLASS_PREFIX/ ? 1 : 0;
202 sub create_anon_class {
203 my ($class, %options) = @_;
204 my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
205 return $class->create($package_name, %options);
209 # this will only get called for
210 # anon-classes, all other calls
211 # are assumed to occur during
212 # global destruction and so don't
213 # really need to be handled explicitly
216 no warnings 'uninitialized';
217 return unless $self->name =~ /^$ANON_CLASS_PREFIX/;
218 my ($serial_id) = ($self->name =~ /^$ANON_CLASS_PREFIX(\d+)/);
220 foreach my $key (keys %{$ANON_CLASS_PREFIX . $serial_id}) {
221 delete ${$ANON_CLASS_PREFIX . $serial_id}{$key};
223 delete ${'main::' . $ANON_CLASS_PREFIX}{$serial_id . '::'};
228 # creating classes with MOP ...
232 my $package_name = shift;
234 (defined $package_name && $package_name)
235 || confess "You must pass a package name";
238 || confess "You much pass all parameters as name => value pairs " .
239 "(I found an uneven number of params in \@_)";
243 (ref $options{superclasses} eq 'ARRAY')
244 || confess "You must pass an ARRAY ref of superclasses"
245 if exists $options{superclasses};
247 (ref $options{attributes} eq 'ARRAY')
248 || confess "You must pass an ARRAY ref of attributes"
249 if exists $options{attributes};
251 (ref $options{methods} eq 'HASH')
252 || confess "You must pass an HASH ref of methods"
253 if exists $options{methods};
255 my $code = "package $package_name;";
256 $code .= "\$$package_name\:\:VERSION = '" . $options{version} . "';"
257 if exists $options{version};
258 $code .= "\$$package_name\:\:AUTHORITY = '" . $options{authority} . "';"
259 if exists $options{authority};
262 confess "creation of $package_name failed : $@" if $@;
264 my $meta = $class->initialize($package_name);
266 $meta->add_method('meta' => sub {
267 $class->initialize(blessed($_[0]) || $_[0]);
270 $meta->superclasses(@{$options{superclasses}})
271 if exists $options{superclasses};
273 # process attributes first, so that they can
274 # install accessors, but locally defined methods
275 # can then overwrite them. It is maybe a little odd, but
276 # I think this should be the order of things.
277 if (exists $options{attributes}) {
278 foreach my $attr (@{$options{attributes}}) {
279 $meta->add_attribute($attr);
282 if (exists $options{methods}) {
283 foreach my $method_name (keys %{$options{methods}}) {
284 $meta->add_method($method_name, $options{methods}->{$method_name});
293 # all these attribute readers will be bootstrapped
294 # away in the Class::MOP bootstrap section
296 sub get_attribute_map { $_[0]->{'%!attributes'} }
297 sub attribute_metaclass { $_[0]->{'$!attribute_metaclass'} }
298 sub method_metaclass { $_[0]->{'$!method_metaclass'} }
299 sub instance_metaclass { $_[0]->{'$!instance_metaclass'} }
302 # this is a prime canidate for conversion to XS
306 if (defined $self->{'$!_package_cache_flag'} &&
307 $self->{'$!_package_cache_flag'} == Class::MOP::check_package_cache_flag($self->name)) {
308 return $self->{'%!methods'};
311 my $map = $self->{'%!methods'};
313 my $class_name = $self->name;
314 my $method_metaclass = $self->method_metaclass;
316 foreach my $symbol ($self->list_all_package_symbols('CODE')) {
317 my $code = $self->get_package_symbol('&' . $symbol);
319 next if exists $map->{$symbol} &&
320 defined $map->{$symbol} &&
321 $map->{$symbol}->body == $code;
323 my ($pkg, $name) = Class::MOP::get_code_info($code);
324 next if ($pkg || '') ne $class_name &&
325 ($name || '') ne '__ANON__';
327 $map->{$symbol} = $method_metaclass->wrap($code);
333 # Instance Construction & Cloning
338 # we need to protect the integrity of the
339 # Class::MOP::Class singletons here, so we
340 # delegate this to &construct_class_instance
341 # which will deal with the singletons
342 return $class->construct_class_instance(@_)
343 if $class->name->isa('Class::MOP::Class');
344 return $class->construct_instance(@_);
347 sub construct_instance {
348 my ($class, %params) = @_;
349 my $meta_instance = $class->get_meta_instance();
350 my $instance = $meta_instance->create_instance();
351 foreach my $attr ($class->compute_all_applicable_attributes()) {
352 $attr->initialize_instance_slot($meta_instance, $instance, \%params);
355 # this will only work for a HASH instance type
356 if ($class->is_anon_class) {
357 (reftype($instance) eq 'HASH')
358 || confess "Currently only HASH based instances are supported with instance of anon-classes";
360 # At some point we should make this official
361 # as a reserved slot name, but right now I am
362 # going to keep it here.
363 # my $RESERVED_MOP_SLOT = '__MOP__';
364 $instance->{'__MOP__'} = $class;
369 sub get_meta_instance {
371 return $class->instance_metaclass->new(
373 $class->compute_all_applicable_attributes()
379 my $instance = shift;
380 (blessed($instance) && $instance->isa($class->name))
381 || confess "You must pass an instance ($instance) of the metaclass (" . $class->name . ")";
383 # we need to protect the integrity of the
384 # Class::MOP::Class singletons here, they
385 # should not be cloned.
386 return $instance if $instance->isa('Class::MOP::Class');
387 $class->clone_instance($instance, @_);
391 my ($class, $instance, %params) = @_;
393 || confess "You can only clone instances, \$self is not a blessed instance";
394 my $meta_instance = $class->get_meta_instance();
395 my $clone = $meta_instance->clone_instance($instance);
396 foreach my $attr ($class->compute_all_applicable_attributes()) {
397 if ( defined( my $init_arg = $attr->init_arg ) ) {
398 if (exists $params{$init_arg}) {
399 $attr->set_value($clone, $params{$init_arg});
406 sub rebless_instance {
407 my ($self, $instance, %params) = @_;
410 if ($instance->can('meta')) {
411 ($instance->meta->isa('Class::MOP::Class'))
412 || confess 'Cannot rebless instance if ->meta is not an instance of Class::MOP::Class';
413 $old_metaclass = $instance->meta;
416 $old_metaclass = $self->initialize(blessed($instance));
419 my $meta_instance = $self->get_meta_instance();
421 $self->name->isa($old_metaclass->name)
422 || confess "You may rebless only into a subclass of (". $old_metaclass->name ."), of which (". $self->name .") isn't.";
425 $meta_instance->rebless_instance_structure($instance, $self);
427 foreach my $attr ( $self->compute_all_applicable_attributes ) {
428 if ( $attr->has_value($instance) ) {
429 if ( defined( my $init_arg = $attr->init_arg ) ) {
430 $params{$init_arg} = $attr->get_value($instance)
431 unless exists $params{$init_arg};
434 $attr->set_value($instance, $attr->get_value($instance));
439 foreach my $attr ($self->compute_all_applicable_attributes) {
440 $attr->initialize_instance_slot($meta_instance, $instance, \%params);
452 @{$self->get_package_symbol('@ISA')} = @supers;
454 # we need to check the metaclass
455 # compatibility here so that we can
456 # be sure that the superclass is
457 # not potentially creating an issues
458 # we don't know about
459 $self->check_metaclass_compatability();
461 @{$self->get_package_symbol('@ISA')};
467 my $super_class = $self->name;
470 my $find_derived_classes;
471 $find_derived_classes = sub {
472 my ($outer_class) = @_;
474 my $symbol_table_hashref = do { no strict 'refs'; \%{"${outer_class}::"} };
477 for my $symbol ( keys %$symbol_table_hashref ) {
478 next SYMBOL if $symbol !~ /\A (\w+):: \z/x;
479 my $inner_class = $1;
481 next SYMBOL if $inner_class eq 'SUPER'; # skip '*::SUPER'
485 ? "${outer_class}::$inner_class"
488 if ( $class->isa($super_class) and $class ne $super_class ) {
489 push @derived_classes, $class;
492 next SYMBOL if $class eq 'main'; # skip 'main::*'
494 $find_derived_classes->($class);
498 my $root_class = q{};
499 $find_derived_classes->($root_class);
501 undef $find_derived_classes;
503 @derived_classes = sort { $a->isa($b) ? 1 : $b->isa($a) ? -1 : 0 } @derived_classes;
505 return @derived_classes;
510 return @{ mro::get_linear_isa( (shift)->name ) };
513 sub class_precedence_list {
516 unless (Class::MOP::IS_RUNNING_ON_5_10()) {
518 # We need to check for circular inheritance here
519 # if we are are not on 5.10, cause 5.8 detects it
520 # late. This will do nothing if all is well, and
521 # blow up otherwise. Yes, it's an ugly hack, better
522 # suggestions are welcome.
524 ($self->name || return)->isa('This is a test for circular inheritance')
530 $self->initialize($_)->class_precedence_list()
531 } $self->superclasses()
538 my ($self, $method_name, $method) = @_;
539 (defined $method_name && $method_name)
540 || confess "You must define a method name";
543 if (blessed($method)) {
544 $body = $method->body;
548 ('CODE' eq (reftype($body) || ''))
549 || confess "Your code block must be a CODE reference";
550 $method = $self->method_metaclass->wrap($body);
552 $self->get_method_map->{$method_name} = $method;
554 my $full_method_name = ($self->name . '::' . $method_name);
555 $self->add_package_symbol("&${method_name}" => subname $full_method_name => $body);
556 $self->update_package_cache_flag;
560 my $fetch_and_prepare_method = sub {
561 my ($self, $method_name) = @_;
563 my $method = $self->get_method($method_name);
564 # if we dont have local ...
566 # try to find the next method
567 $method = $self->find_next_method_by_name($method_name);
568 # die if it does not exist
570 || confess "The method '$method_name' is not found in the inheritance hierarchy for class " . $self->name;
571 # and now make sure to wrap it
572 # even if it is already wrapped
573 # because we need a new sub ref
574 $method = Class::MOP::Method::Wrapped->wrap($method);
577 # now make sure we wrap it properly
578 $method = Class::MOP::Method::Wrapped->wrap($method)
579 unless $method->isa('Class::MOP::Method::Wrapped');
581 $self->add_method($method_name => $method);
585 sub add_before_method_modifier {
586 my ($self, $method_name, $method_modifier) = @_;
587 (defined $method_name && $method_name)
588 || confess "You must pass in a method name";
589 my $method = $fetch_and_prepare_method->($self, $method_name);
590 $method->add_before_modifier(subname ':before' => $method_modifier);
593 sub add_after_method_modifier {
594 my ($self, $method_name, $method_modifier) = @_;
595 (defined $method_name && $method_name)
596 || confess "You must pass in a method name";
597 my $method = $fetch_and_prepare_method->($self, $method_name);
598 $method->add_after_modifier(subname ':after' => $method_modifier);
601 sub add_around_method_modifier {
602 my ($self, $method_name, $method_modifier) = @_;
603 (defined $method_name && $method_name)
604 || confess "You must pass in a method name";
605 my $method = $fetch_and_prepare_method->($self, $method_name);
606 $method->add_around_modifier(subname ':around' => $method_modifier);
610 # the methods above used to be named like this:
611 # ${pkg}::${method}:(before|after|around)
612 # but this proved problematic when using one modifier
613 # to wrap multiple methods (something which is likely
614 # to happen pretty regularly IMO). So instead of naming
615 # it like this, I have chosen to just name them purely
616 # with their modifier names, like so:
617 # :(before|after|around)
618 # The fact is that in a stack trace, it will be fairly
619 # evident from the context what method they are attached
620 # to, and so don't need the fully qualified name.
624 my ($self, $method_name, $method) = @_;
625 (defined $method_name && $method_name)
626 || confess "You must define a method name";
628 my $body = (blessed($method) ? $method->body : $method);
629 ('CODE' eq (reftype($body) || ''))
630 || confess "Your code block must be a CODE reference";
632 $self->add_package_symbol("&${method_name}" => $body);
633 $self->update_package_cache_flag;
637 my ($self, $method_name) = @_;
638 (defined $method_name && $method_name)
639 || confess "You must define a method name";
641 return 0 unless exists $self->get_method_map->{$method_name};
646 my ($self, $method_name) = @_;
647 (defined $method_name && $method_name)
648 || confess "You must define a method name";
651 # I don't really need this here, because
652 # if the method_map is missing a key it
653 # will just return undef for me now
654 # return unless $self->has_method($method_name);
656 return $self->get_method_map->{$method_name};
660 my ($self, $method_name) = @_;
661 (defined $method_name && $method_name)
662 || confess "You must define a method name";
664 my $removed_method = delete $self->get_method_map->{$method_name};
666 $self->remove_package_symbol("&${method_name}");
668 $self->update_package_cache_flag;
670 return $removed_method;
673 sub get_method_list {
675 keys %{$self->get_method_map};
678 sub find_method_by_name {
679 my ($self, $method_name) = @_;
680 (defined $method_name && $method_name)
681 || confess "You must define a method name to find";
682 foreach my $class ($self->linearized_isa) {
683 # fetch the meta-class ...
684 my $meta = $self->initialize($class);
685 return $meta->get_method($method_name)
686 if $meta->has_method($method_name);
691 sub compute_all_applicable_methods {
693 my (@methods, %seen_method);
694 foreach my $class ($self->linearized_isa) {
695 # fetch the meta-class ...
696 my $meta = $self->initialize($class);
697 foreach my $method_name ($meta->get_method_list()) {
698 next if exists $seen_method{$method_name};
699 $seen_method{$method_name}++;
701 name => $method_name,
703 code => $meta->get_method($method_name)
710 sub find_all_methods_by_name {
711 my ($self, $method_name) = @_;
712 (defined $method_name && $method_name)
713 || confess "You must define a method name to find";
715 foreach my $class ($self->linearized_isa) {
716 # fetch the meta-class ...
717 my $meta = $self->initialize($class);
719 name => $method_name,
721 code => $meta->get_method($method_name)
722 } if $meta->has_method($method_name);
727 sub find_next_method_by_name {
728 my ($self, $method_name) = @_;
729 (defined $method_name && $method_name)
730 || confess "You must define a method name to find";
731 my @cpl = $self->linearized_isa;
732 shift @cpl; # discard ourselves
733 foreach my $class (@cpl) {
734 # fetch the meta-class ...
735 my $meta = $self->initialize($class);
736 return $meta->get_method($method_name)
737 if $meta->has_method($method_name);
746 # either we have an attribute object already
747 # or we need to create one from the args provided
748 my $attribute = blessed($_[0]) ? $_[0] : $self->attribute_metaclass->new(@_);
749 # make sure it is derived from the correct type though
750 ($attribute->isa('Class::MOP::Attribute'))
751 || confess "Your attribute must be an instance of Class::MOP::Attribute (or a subclass)";
753 # first we attach our new attribute
754 # because it might need certain information
755 # about the class which it is attached to
756 $attribute->attach_to_class($self);
758 # then we remove attributes of a conflicting
759 # name here so that we can properly detach
760 # the old attr object, and remove any
761 # accessors it would have generated
762 $self->remove_attribute($attribute->name)
763 if $self->has_attribute($attribute->name);
765 # then onto installing the new accessors
766 $attribute->install_accessors();
767 $self->get_attribute_map->{$attribute->name} = $attribute;
771 my ($self, $attribute_name) = @_;
772 (defined $attribute_name && $attribute_name)
773 || confess "You must define an attribute name";
774 exists $self->get_attribute_map->{$attribute_name} ? 1 : 0;
778 my ($self, $attribute_name) = @_;
779 (defined $attribute_name && $attribute_name)
780 || confess "You must define an attribute name";
781 return $self->get_attribute_map->{$attribute_name}
783 # this will return undef anyway, so no need ...
784 # if $self->has_attribute($attribute_name);
788 sub remove_attribute {
789 my ($self, $attribute_name) = @_;
790 (defined $attribute_name && $attribute_name)
791 || confess "You must define an attribute name";
792 my $removed_attribute = $self->get_attribute_map->{$attribute_name};
793 return unless defined $removed_attribute;
794 delete $self->get_attribute_map->{$attribute_name};
795 $removed_attribute->remove_accessors();
796 $removed_attribute->detach_from_class();
797 return $removed_attribute;
800 sub get_attribute_list {
802 keys %{$self->get_attribute_map};
805 sub compute_all_applicable_attributes {
807 my (@attrs, %seen_attr);
808 foreach my $class ($self->linearized_isa) {
809 # fetch the meta-class ...
810 my $meta = $self->initialize($class);
811 foreach my $attr_name ($meta->get_attribute_list()) {
812 next if exists $seen_attr{$attr_name};
813 $seen_attr{$attr_name}++;
814 push @attrs => $meta->get_attribute($attr_name);
820 sub find_attribute_by_name {
821 my ($self, $attr_name) = @_;
822 foreach my $class ($self->linearized_isa) {
823 # fetch the meta-class ...
824 my $meta = $self->initialize($class);
825 return $meta->get_attribute($attr_name)
826 if $meta->has_attribute($attr_name);
834 sub is_immutable { 0 }
837 # Why I changed this (groditi)
838 # - One Metaclass may have many Classes through many Metaclass instances
839 # - One Metaclass should only have one Immutable Transformer instance
840 # - Each Class may have different Immutabilizing options
841 # - Therefore each Metaclass instance may have different Immutabilizing options
842 # - We need to store one Immutable Transformer instance per Metaclass
843 # - We need to store one set of Immutable Transformer options per Class
844 # - Upon make_mutable we may delete the Immutabilizing options
845 # - We could clean the immutable Transformer instance when there is no more
846 # immutable Classes of that type, but we can also keep it in case
847 # another class with this same Metaclass becomes immutable. It is a case
848 # of trading of storing an instance to avoid unnecessary instantiations of
849 # Immutable Transformers. You may view this as a memory leak, however
850 # Because we have few Metaclasses, in practice it seems acceptable
851 # - To allow Immutable Transformers instances to be cleaned up we could weaken
852 # the reference stored in $IMMUTABLE_TRANSFORMERS{$class} and ||= should DWIM
855 my %IMMUTABLE_TRANSFORMERS;
856 my %IMMUTABLE_OPTIONS;
860 my $class = blessed $self || $self;
862 $IMMUTABLE_TRANSFORMERS{$class} ||= $self->create_immutable_transformer;
863 my $transformer = $IMMUTABLE_TRANSFORMERS{$class};
865 $transformer->make_metaclass_immutable($self, \%options);
866 $IMMUTABLE_OPTIONS{$self->name} =
867 { %options, IMMUTABLE_TRANSFORMER => $transformer };
869 if( exists $options{debug} && $options{debug} ){
870 print STDERR "# of Metaclass options: ", keys %IMMUTABLE_OPTIONS;
871 print STDERR "# of Immutable transformers: ", keys %IMMUTABLE_TRANSFORMERS;
879 return if $self->is_mutable;
880 my $options = delete $IMMUTABLE_OPTIONS{$self->name};
881 confess "unable to find immutabilizing options" unless ref $options;
882 my $transformer = delete $options->{IMMUTABLE_TRANSFORMER};
883 $transformer->make_metaclass_mutable($self, $options);
888 sub create_immutable_transformer {
890 my $class = Class::MOP::Immutable->new($self, {
891 read_only => [qw/superclasses/],
899 remove_package_symbol
902 class_precedence_list => 'ARRAY',
903 linearized_isa => 'ARRAY',
904 compute_all_applicable_attributes => 'ARRAY',
905 get_meta_instance => 'SCALAR',
906 get_method_map => 'SCALAR',
920 Class::MOP::Class - Class Meta Object
924 # assuming that class Foo
925 # has been defined, you can
927 # use this for introspection ...
929 # add a method to Foo ...
930 Foo->meta->add_method('bar' => sub { ... })
932 # get a list of all the classes searched
933 # the method dispatcher in the correct order
934 Foo->meta->class_precedence_list()
936 # remove a method from Foo
937 Foo->meta->remove_method('bar');
939 # or use this to actually create classes ...
941 Class::MOP::Class->create('Bar' => (
943 superclasses => [ 'Foo' ],
945 Class::MOP:::Attribute->new('$bar'),
946 Class::MOP:::Attribute->new('$baz'),
949 calculate_bar => sub { ... },
950 construct_baz => sub { ... }
956 This is the largest and currently most complex part of the Perl 5
957 meta-object protocol. It controls the introspection and
958 manipulation of Perl 5 classes (and it can create them too). The
959 best way to understand what this module can do, is to read the
960 documentation for each of it's methods.
964 =head2 Self Introspection
970 This will return a B<Class::MOP::Class> instance which is related
971 to this class. Thereby allowing B<Class::MOP::Class> to actually
974 As with B<Class::MOP::Attribute>, B<Class::MOP> will actually
975 bootstrap this module by installing a number of attribute meta-objects
976 into it's metaclass. This will allow this class to reap all the benifits
977 of the MOP when subclassing it.
981 =head2 Class construction
983 These methods will handle creating B<Class::MOP::Class> objects,
984 which can be used to both create new classes, and analyze
985 pre-existing classes.
987 This module will internally store references to all the instances
988 you create with these methods, so that they do not need to be
989 created any more than nessecary. Basically, they are singletons.
993 =item B<create ($package_name,
994 version =E<gt> ?$version,
995 authority =E<gt> ?$authority,
996 superclasses =E<gt> ?@superclasses,
997 methods =E<gt> ?%methods,
998 attributes =E<gt> ?%attributes)>
1000 This returns a B<Class::MOP::Class> object, bringing the specified
1001 C<$package_name> into existence and adding any of the C<$version>,
1002 C<$authority>, C<@superclasses>, C<%methods> and C<%attributes> to
1005 =item B<create_anon_class (superclasses =E<gt> ?@superclasses,
1006 methods =E<gt> ?%methods,
1007 attributes =E<gt> ?%attributes)>
1009 This will create an anonymous class, it works much like C<create> but
1010 it does not need a C<$package_name>. Instead it will create a suitably
1011 unique package name for you to stash things into.
1013 On very important distinction is that anon classes are destroyed once
1014 the metaclass they are attached to goes out of scope. In the DESTROY
1015 method, the created package will be removed from the symbol table.
1017 It is also worth noting that any instances created with an anon-class
1018 will keep a special reference to the anon-meta which will prevent the
1019 anon-class from going out of scope until all instances of it have also
1020 been destroyed. This however only works for HASH based instance types,
1021 as we use a special reserved slot (C<__MOP__>) to store this.
1023 =item B<initialize ($package_name, %options)>
1025 This initializes and returns returns a B<Class::MOP::Class> object
1026 for a given a C<$package_name>.
1028 =item B<reinitialize ($package_name, %options)>
1030 This removes the old metaclass, and creates a new one in it's place.
1031 Do B<not> use this unless you really know what you are doing, it could
1032 very easily make a very large mess of your program.
1034 =item B<construct_class_instance (%options)>
1036 This will construct an instance of B<Class::MOP::Class>, it is
1037 here so that we can actually "tie the knot" for B<Class::MOP::Class>
1038 to use C<construct_instance> once all the bootstrapping is done. This
1039 method is used internally by C<initialize> and should never be called
1040 from outside of that method really.
1042 =item B<check_metaclass_compatability>
1044 This method is called as the very last thing in the
1045 C<construct_class_instance> method. This will check that the
1046 metaclass you are creating is compatible with the metaclasses of all
1047 your ancestors. For more inforamtion about metaclass compatibility
1048 see the C<About Metaclass compatibility> section in L<Class::MOP>.
1050 =item B<update_package_cache_flag>
1052 This will reset the package cache flag for this particular metaclass
1053 it is basically the value of the C<Class::MOP::get_package_cache_flag>
1054 function. This is very rarely needed from outside of C<Class::MOP::Class>
1055 but in some cases you might want to use it, so it is here.
1057 =item B<reset_package_cache_flag>
1059 Clears the package cache flag to announce to the internals that we need
1060 to rebuild the method map.
1064 =head2 Object instance construction and cloning
1066 These methods are B<entirely optional>, it is up to you whether you want
1071 =item B<instance_metaclass>
1073 Returns the class name of the instance metaclass, see L<Class::MOP::Instance>
1074 for more information on the instance metaclasses.
1076 =item B<get_meta_instance>
1078 Returns an instance of L<Class::MOP::Instance> to be used in the construction
1079 of a new instance of the class.
1081 =item B<new_object (%params)>
1083 This is a convience method for creating a new object of the class, and
1084 blessing it into the appropriate package as well. Ideally your class
1085 would call a C<new> this method like so:
1088 my ($class, %param) = @_;
1089 $class->meta->new_object(%params);
1092 =item B<construct_instance (%params)>
1094 This method is used to construct an instance structure suitable for
1095 C<bless>-ing into your package of choice. It works in conjunction
1096 with the Attribute protocol to collect all applicable attributes.
1098 This will construct and instance using a HASH ref as storage
1099 (currently only HASH references are supported). This will collect all
1100 the applicable attributes and layout out the fields in the HASH ref,
1101 it will then initialize them using either use the corresponding key
1102 in C<%params> or any default value or initializer found in the
1103 attribute meta-object.
1105 =item B<clone_object ($instance, %params)>
1107 This is a convience method for cloning an object instance, then
1108 blessing it into the appropriate package. This method will call
1109 C<clone_instance>, which performs a shallow copy of the object,
1110 see that methods documentation for more details. Ideally your
1111 class would call a C<clone> this method like so:
1113 sub MyClass::clone {
1114 my ($self, %param) = @_;
1115 $self->meta->clone_object($self, %params);
1118 =item B<clone_instance($instance, %params)>
1120 This method is a compliment of C<construct_instance> (which means if
1121 you override C<construct_instance>, you need to override this one too),
1122 and clones the instance shallowly.
1124 The cloned structure returned is (like with C<construct_instance>) an
1125 unC<bless>ed HASH reference, it is your responsibility to then bless
1126 this cloned structure into the right class (which C<clone_object> will
1129 As of 0.11, this method will clone the C<$instance> structure shallowly,
1130 as opposed to the deep cloning implemented in prior versions. After much
1131 thought, research and discussion, I have decided that anything but basic
1132 shallow cloning is outside the scope of the meta-object protocol. I
1133 think Yuval "nothingmuch" Kogman put it best when he said that cloning
1134 is too I<context-specific> to be part of the MOP.
1136 =item B<rebless_instance($instance, ?%params)>
1138 This will change the class of C<$instance> to the class of the invoking
1139 C<Class::MOP::Class>. You may only rebless the instance to a subclass of
1140 itself. You may pass in optional C<%params> which are like constructor
1141 params and will override anything already defined in the instance.
1145 =head2 Informational
1147 These are a few predicate methods for asking information about the class.
1151 =item B<is_anon_class>
1153 This returns true if the class is a C<Class::MOP::Class> created anon class.
1157 This returns true if the class is still mutable.
1159 =item B<is_immutable>
1161 This returns true if the class has been made immutable.
1165 =head2 Inheritance Relationships
1169 =item B<superclasses (?@superclasses)>
1171 This is a read-write attribute which represents the superclass
1172 relationships of the class the B<Class::MOP::Class> instance is
1173 associated with. Basically, it can get and set the C<@ISA> for you.
1175 =item B<class_precedence_list>
1177 This computes the a list of all the class's ancestors in the same order
1178 in which method dispatch will be done. This is similair to what
1179 B<Class::ISA::super_path> does, but we don't remove duplicate names.
1181 =item B<linearized_isa>
1183 This returns a list based on C<class_precedence_list> but with all
1188 This returns a list of subclasses for this class.
1196 =item B<get_method_map>
1198 Returns a HASH ref of name to CODE reference mapping for this class.
1200 =item B<method_metaclass>
1202 Returns the class name of the method metaclass, see L<Class::MOP::Method>
1203 for more information on the method metaclasses.
1205 =item B<add_method ($method_name, $method)>
1207 This will take a C<$method_name> and CODE reference to that
1208 C<$method> and install it into the class's package.
1211 This does absolutely nothing special to C<$method>
1212 other than use B<Sub::Name> to make sure it is tagged with the
1213 correct name, and therefore show up correctly in stack traces and
1216 =item B<alias_method ($method_name, $method)>
1218 This will take a C<$method_name> and CODE reference to that
1219 C<$method> and alias the method into the class's package.
1222 Unlike C<add_method>, this will B<not> try to name the
1223 C<$method> using B<Sub::Name>, it only aliases the method in
1224 the class's package.
1226 =item B<has_method ($method_name)>
1228 This just provides a simple way to check if the class implements
1229 a specific C<$method_name>. It will I<not> however, attempt to check
1230 if the class inherits the method (use C<UNIVERSAL::can> for that).
1232 This will correctly handle functions defined outside of the package
1233 that use a fully qualified name (C<sub Package::name { ... }>).
1235 This will correctly handle functions renamed with B<Sub::Name> and
1236 installed using the symbol tables. However, if you are naming the
1237 subroutine outside of the package scope, you must use the fully
1238 qualified name, including the package name, for C<has_method> to
1239 correctly identify it.
1241 This will attempt to correctly ignore functions imported from other
1242 packages using B<Exporter>. It breaks down if the function imported
1243 is an C<__ANON__> sub (such as with C<use constant>), which very well
1244 may be a valid method being applied to the class.
1246 In short, this method cannot always be trusted to determine if the
1247 C<$method_name> is actually a method. However, it will DWIM about
1248 90% of the time, so it's a small trade off I think.
1250 =item B<get_method ($method_name)>
1252 This will return a Class::MOP::Method instance related to the specified
1253 C<$method_name>, or return undef if that method does not exist.
1255 The Class::MOP::Method is codifiable, so you can use it like a normal
1256 CODE reference, see L<Class::MOP::Method> for more information.
1258 =item B<find_method_by_name ($method_name>
1260 This will return a CODE reference of the specified C<$method_name>,
1261 or return undef if that method does not exist.
1263 Unlike C<get_method> this will also look in the superclasses.
1265 =item B<remove_method ($method_name)>
1267 This will attempt to remove a given C<$method_name> from the class.
1268 It will return the CODE reference that it has removed, and will
1269 attempt to use B<Sub::Name> to clear the methods associated name.
1271 =item B<get_method_list>
1273 This will return a list of method names for all I<locally> defined
1274 methods. It does B<not> provide a list of all applicable methods,
1275 including any inherited ones. If you want a list of all applicable
1276 methods, use the C<compute_all_applicable_methods> method.
1278 =item B<compute_all_applicable_methods>
1280 This will return a list of all the methods names this class will
1281 respond to, taking into account inheritance. The list will be a list of
1282 HASH references, each one containing the following information; method
1283 name, the name of the class in which the method lives and a CODE
1284 reference for the actual method.
1286 =item B<find_all_methods_by_name ($method_name)>
1288 This will traverse the inheritence hierarchy and locate all methods
1289 with a given C<$method_name>. Similar to
1290 C<compute_all_applicable_methods> it returns a list of HASH references
1291 with the following information; method name (which will always be the
1292 same as C<$method_name>), the name of the class in which the method
1293 lives and a CODE reference for the actual method.
1295 The list of methods produced is a distinct list, meaning there are no
1296 duplicates in it. This is especially useful for things like object
1297 initialization and destruction where you only want the method called
1298 once, and in the correct order.
1300 =item B<find_next_method_by_name ($method_name)>
1302 This will return the first method to match a given C<$method_name> in
1303 the superclasses, this is basically equivalent to calling
1304 C<SUPER::$method_name>, but it can be dispatched at runtime.
1308 =head2 Method Modifiers
1310 Method modifiers are a concept borrowed from CLOS, in which a method
1311 can be wrapped with I<before>, I<after> and I<around> method modifiers
1312 that will be called everytime the method is called.
1314 =head3 How method modifiers work?
1316 Method modifiers work by wrapping the original method and then replacing
1317 it in the classes symbol table. The wrappers will handle calling all the
1318 modifiers in the appropariate orders and preserving the calling context
1319 for the original method.
1321 Each method modifier serves a particular purpose, which may not be
1322 obvious to users of other method wrapping modules. To start with, the
1323 return values of I<before> and I<after> modifiers are ignored. This is
1324 because thier purpose is B<not> to filter the input and output of the
1325 primary method (this is done with an I<around> modifier). This may seem
1326 like an odd restriction to some, but doing this allows for simple code
1327 to be added at the begining or end of a method call without jeapordizing
1328 the normal functioning of the primary method or placing any extra
1329 responsibility on the code of the modifier. Of course if you have more
1330 complex needs, then use the I<around> modifier, which uses a variation
1331 of continutation passing style to allow for a high degree of flexibility.
1333 Before and around modifiers are called in last-defined-first-called order,
1334 while after modifiers are called in first-defined-first-called order. So
1335 the call tree might looks something like this:
1345 To see examples of using method modifiers, see the following examples
1346 included in the distribution; F<InstanceCountingClass>, F<Perl6Attribute>,
1347 F<AttributesWithHistory> and F<C3MethodDispatchOrder>. There is also a
1348 classic CLOS usage example in the test F<017_add_method_modifier.t>.
1350 =head3 What is the performance impact?
1352 Of course there is a performance cost associated with method modifiers,
1353 but we have made every effort to make that cost be directly proportional
1354 to the amount of modifier features you utilize.
1356 The wrapping method does it's best to B<only> do as much work as it
1357 absolutely needs to. In order to do this we have moved some of the
1358 performance costs to set-up time, where they are easier to amortize.
1360 All this said, my benchmarks have indicated the following:
1362 simple wrapper with no modifiers 100% slower
1363 simple wrapper with simple before modifier 400% slower
1364 simple wrapper with simple after modifier 450% slower
1365 simple wrapper with simple around modifier 500-550% slower
1366 simple wrapper with all 3 modifiers 1100% slower
1368 These numbers may seem daunting, but you must remember, every feature
1369 comes with some cost. To put things in perspective, just doing a simple
1370 C<AUTOLOAD> which does nothing but extract the name of the method called
1371 and return it costs about 400% over a normal method call.
1375 =item B<add_before_method_modifier ($method_name, $code)>
1377 This will wrap the method at C<$method_name> and the supplied C<$code>
1378 will be passed the C<@_> arguments, and called before the original
1379 method is called. As specified above, the return value of the I<before>
1380 method modifiers is ignored, and it's ability to modify C<@_> is
1381 fairly limited. If you need to do either of these things, use an
1382 C<around> method modifier.
1384 =item B<add_after_method_modifier ($method_name, $code)>
1386 This will wrap the method at C<$method_name> so that the original
1387 method will be called, it's return values stashed, and then the
1388 supplied C<$code> will be passed the C<@_> arguments, and called.
1389 As specified above, the return value of the I<after> method
1390 modifiers is ignored, and it cannot modify the return values of
1391 the original method. If you need to do either of these things, use an
1392 C<around> method modifier.
1394 =item B<add_around_method_modifier ($method_name, $code)>
1396 This will wrap the method at C<$method_name> so that C<$code>
1397 will be called and passed the original method as an extra argument
1398 at the begining of the C<@_> argument list. This is a variation of
1399 continuation passing style, where the function prepended to C<@_>
1400 can be considered a continuation. It is up to C<$code> if it calls
1401 the original method or not, there is no restriction on what the
1402 C<$code> can or cannot do.
1408 It should be noted that since there is no one consistent way to define
1409 the attributes of a class in Perl 5. These methods can only work with
1410 the information given, and can not easily discover information on
1411 their own. See L<Class::MOP::Attribute> for more details.
1415 =item B<attribute_metaclass>
1417 Returns the class name of the attribute metaclass, see L<Class::MOP::Attribute>
1418 for more information on the attribute metaclasses.
1420 =item B<get_attribute_map>
1422 This returns a HASH ref of name to attribute meta-object mapping.
1424 =item B<add_attribute ($attribute_meta_object | ($attribute_name, %attribute_spec))>
1426 This stores the C<$attribute_meta_object> (or creates one from the
1427 C<$attribute_name> and C<%attribute_spec>) in the B<Class::MOP::Class>
1428 instance associated with the given class. Unlike methods, attributes
1429 within the MOP are stored as meta-information only. They will be used
1430 later to construct instances from (see C<construct_instance> above).
1431 More details about the attribute meta-objects can be found in the
1432 L<Class::MOP::Attribute> or the L<Class::MOP/The Attribute protocol>
1435 It should be noted that any accessor, reader/writer or predicate
1436 methods which the C<$attribute_meta_object> has will be installed
1437 into the class at this time.
1440 If an attribute already exists for C<$attribute_name>, the old one
1441 will be removed (as well as removing all it's accessors), and then
1444 =item B<has_attribute ($attribute_name)>
1446 Checks to see if this class has an attribute by the name of
1447 C<$attribute_name> and returns a boolean.
1449 =item B<get_attribute ($attribute_name)>
1451 Returns the attribute meta-object associated with C<$attribute_name>,
1452 if none is found, it will return undef.
1454 =item B<remove_attribute ($attribute_name)>
1456 This will remove the attribute meta-object stored at
1457 C<$attribute_name>, then return the removed attribute meta-object.
1460 Removing an attribute will only affect future instances of
1461 the class, it will not make any attempt to remove the attribute from
1462 any existing instances of the class.
1464 It should be noted that any accessor, reader/writer or predicate
1465 methods which the attribute meta-object stored at C<$attribute_name>
1466 has will be removed from the class at this time. This B<will> make
1467 these attributes somewhat inaccessable in previously created
1468 instances. But if you are crazy enough to do this at runtime, then
1469 you are crazy enough to deal with something like this :).
1471 =item B<get_attribute_list>
1473 This returns a list of attribute names which are defined in the local
1474 class. If you want a list of all applicable attributes for a class,
1475 use the C<compute_all_applicable_attributes> method.
1477 =item B<compute_all_applicable_attributes>
1479 This will traverse the inheritance heirachy and return a list of all
1480 the applicable attributes for this class. It does not construct a
1481 HASH reference like C<compute_all_applicable_methods> because all
1482 that same information is discoverable through the attribute
1485 =item B<find_attribute_by_name ($attr_name)>
1487 This method will traverse the inheritance heirachy and find the
1488 first attribute whose name matches C<$attr_name>, then return it.
1489 It will return undef if nothing is found.
1493 =head2 Class Immutability
1497 =item B<make_immutable (%options)>
1499 This method will invoke a tranforamtion upon the class which will
1500 make it immutable. Details of this transformation can be found in
1501 the L<Class::MOP::Immutable> documentation.
1503 =item B<make_mutable>
1505 This method will reverse tranforamtion upon the class which
1508 =item B<create_immutable_transformer>
1510 Create a transformer suitable for making this class immutable
1516 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1518 =head1 COPYRIGHT AND LICENSE
1520 Copyright 2006-2008 by Infinity Interactive, Inc.
1522 L<http://www.iinteractive.com>
1524 This library is free software; you can redistribute it and/or modify
1525 it under the same terms as Perl itself.