2 package Class::MOP::Class;
8 use Scalar::Util 'blessed', 'reftype';
9 use Sub::Name 'subname';
10 use B 'svref_2object';
12 our $VERSION = '0.14';
14 use Class::MOP::Instance;
18 sub meta { Class::MOP::Class->initialize(blessed($_[0]) || $_[0]) }
23 # Metaclasses are singletons, so we cache them here.
24 # there is no need to worry about destruction though
25 # because they should die only when the program dies.
26 # After all, do package definitions even get reaped?
29 # means of accessing all the metaclasses that have
30 # been initialized thus far (for mugwumps obj browser)
31 sub get_all_metaclasses { %METAS }
32 sub get_all_metaclass_instances { values %METAS }
33 sub get_all_metaclass_names { keys %METAS }
37 my $package_name = shift;
38 (defined $package_name && $package_name && !blessed($package_name))
39 || confess "You must pass a package name and it cannot be blessed";
40 $class->construct_class_instance(':package' => $package_name, @_);
43 # NOTE: (meta-circularity)
44 # this is a special form of &construct_instance
45 # (see below), which is used to construct class
46 # meta-object instances for any Class::MOP::*
47 # class. All other classes will use the more
48 # normal &construct_instance.
49 sub construct_class_instance {
52 my $package_name = $options{':package'};
53 (defined $package_name && $package_name)
54 || confess "You must pass a package name";
56 # return the metaclass if we have it cached,
57 # and it is still defined (it has not been
58 # reaped by DESTROY yet, which can happen
59 # annoyingly enough during global destruction)
60 return $METAS{$package_name}
61 if exists $METAS{$package_name} && defined $METAS{$package_name};
62 $class = blessed($class) || $class;
63 # now create the metaclass
65 if ($class =~ /^Class::MOP::/) {
67 '$:package' => $package_name,
69 '$:attribute_metaclass' => $options{':attribute_metaclass'} || 'Class::MOP::Attribute',
70 '$:method_metaclass' => $options{':method_metaclass'} || 'Class::MOP::Method',
71 '$:instance_metaclass' => $options{':instance_metaclass'} || 'Class::MOP::Instance',
76 # it is safe to use meta here because
77 # class will always be a subclass of
78 # Class::MOP::Class, which defines meta
79 $meta = bless $class->meta->construct_instance(%options) => $class
81 # and check the metaclass compatibility
82 $meta->check_metaclass_compatability();
83 $METAS{$package_name} = $meta;
86 sub check_metaclass_compatability {
89 # this is always okay ...
90 return if blessed($self) eq 'Class::MOP::Class';
92 my @class_list = $self->class_precedence_list;
93 shift @class_list; # shift off $self->name
95 foreach my $class_name (@class_list) {
96 my $meta = $METAS{$class_name} || next;
97 ($self->isa(blessed($meta)))
98 || confess $self->name . "->meta => (" . (blessed($self)) . ")" .
99 " is not compatible with the " .
100 $class_name . "->meta => (" . (blessed($meta)) . ")";
106 my ($class, $package_name, $package_version, %options) = @_;
107 (defined $package_name && $package_name)
108 || confess "You must pass a package name";
109 my $code = "package $package_name;";
110 $code .= "\$$package_name\:\:VERSION = '$package_version';"
111 if defined $package_version;
113 confess "creation of $package_name failed : $@" if $@;
114 my $meta = $class->initialize($package_name);
116 $meta->add_method('meta' => sub {
117 Class::MOP::Class->initialize(blessed($_[0]) || $_[0]);
120 $meta->superclasses(@{$options{superclasses}})
121 if exists $options{superclasses};
123 # process attributes first, so that they can
124 # install accessors, but locally defined methods
125 # can then overwrite them. It is maybe a little odd, but
126 # I think this should be the order of things.
127 if (exists $options{attributes}) {
128 foreach my $attr (@{$options{attributes}}) {
129 $meta->add_attribute($attr);
132 if (exists $options{methods}) {
133 foreach my $method_name (keys %{$options{methods}}) {
134 $meta->add_method($method_name, $options{methods}->{$method_name});
142 # this should be sufficient, if you have a
143 # use case where it is not, write a test and
145 my $ANON_CLASS_SERIAL = 0;
147 sub create_anon_class {
148 my ($class, %options) = @_;
149 my $package_name = 'Class::MOP::Class::__ANON__::SERIAL::' . ++$ANON_CLASS_SERIAL;
150 return $class->create($package_name, '0.00', %options);
157 # all these attribute readers will be bootstrapped
158 # away in the Class::MOP bootstrap section
160 sub name { $_[0]->{'$:package'} }
161 sub get_attribute_map { $_[0]->{'%:attributes'} }
162 sub attribute_metaclass { $_[0]->{'$:attribute_metaclass'} }
163 sub method_metaclass { $_[0]->{'$:method_metaclass'} }
164 sub instance_metaclass { $_[0]->{'$:instance_metaclass'} }
166 # Instance Construction & Cloning
171 # we need to protect the integrity of the
172 # Class::MOP::Class singletons here, so we
173 # delegate this to &construct_class_instance
174 # which will deal with the singletons
175 return $class->construct_class_instance(@_)
176 if $class->name->isa('Class::MOP::Class');
177 return $class->construct_instance(@_);
180 sub construct_instance {
181 my ($class, %params) = @_;
182 my $meta_instance = $class->instance_metaclass->new($class);
183 foreach my $attr ($class->compute_all_applicable_attributes()) {
184 $attr->initialize_instance_slot($class, $meta_instance, \%params);
186 return $meta_instance->get_instance;
191 my $instance = shift;
192 (blessed($instance) && $instance->isa($class->name))
193 || confess "You must pass an instance ($instance) of the metaclass (" . $class->name . ")";
195 # we need to protect the integrity of the
196 # Class::MOP::Class singletons here, they
197 # should not be cloned.
198 return $instance if $instance->isa('Class::MOP::Class');
199 bless $class->clone_instance($instance, @_) => blessed($instance);
203 my ($class, $instance, %params) = @_;
205 || confess "You can only clone instances, \$self is not a blessed instance";
206 my $clone = { %$instance, %params };
212 # &name should be here too, but it is above
213 # because it gets bootstrapped away
217 ${$self->get_package_variable('$VERSION')};
227 @{$self->name . '::ISA'} = @supers;
229 @{$self->name . '::ISA'};
232 sub class_precedence_list {
235 # We need to check for ciruclar inheirtance here.
236 # This will do nothing if all is well, and blow
237 # up otherwise. Yes, it's an ugly hack, better
238 # suggestions are welcome.
239 { ($self->name || return)->isa('This is a test for circular inheritance') }
240 # ... and now back to our regularly scheduled program
245 # we grab the metaclass from the %METAS
246 # hash here to save the initialize() call
247 # if we can, but it is not always possible
248 ($METAS{$_} || $self->initialize($_))->class_precedence_list()
249 } $self->superclasses()
256 my ($self, $method_name, $method) = @_;
257 (defined $method_name && $method_name)
258 || confess "You must define a method name";
259 # use reftype here to allow for blessed subs ...
260 ('CODE' eq (reftype($method) || ''))
261 || confess "Your code block must be a CODE reference";
262 my $full_method_name = ($self->name . '::' . $method_name);
264 $method = $self->method_metaclass->wrap($method) unless blessed($method);
267 no warnings 'redefine';
268 *{$full_method_name} = subname $full_method_name => $method;
272 my $fetch_and_prepare_method = sub {
273 my ($self, $method_name) = @_;
275 my $method = $self->get_method($method_name);
276 # if we dont have local ...
278 # make sure this method even exists ...
279 ($self->find_next_method_by_name($method_name))
280 || confess "The method '$method_name' is not found in the inherience hierarchy for this class";
281 # if so, then create a local which just
282 # calls the next applicable method ...
283 $self->add_method($method_name => sub {
284 $self->find_next_method_by_name($method_name)->(@_);
286 $method = $self->get_method($method_name);
289 # now make sure we wrap it properly
290 # (if it isnt already)
291 unless ($method->isa('Class::MOP::Method::Wrapped')) {
292 $method = Class::MOP::Method::Wrapped->wrap($method);
293 $self->add_method($method_name => $method);
298 sub add_before_method_modifier {
299 my ($self, $method_name, $method_modifier) = @_;
300 (defined $method_name && $method_name)
301 || confess "You must pass in a method name";
302 my $method = $fetch_and_prepare_method->($self, $method_name);
303 $method->add_before_modifier(subname ':before' => $method_modifier);
306 sub add_after_method_modifier {
307 my ($self, $method_name, $method_modifier) = @_;
308 (defined $method_name && $method_name)
309 || confess "You must pass in a method name";
310 my $method = $fetch_and_prepare_method->($self, $method_name);
311 $method->add_after_modifier(subname ':after' => $method_modifier);
314 sub add_around_method_modifier {
315 my ($self, $method_name, $method_modifier) = @_;
316 (defined $method_name && $method_name)
317 || confess "You must pass in a method name";
318 my $method = $fetch_and_prepare_method->($self, $method_name);
319 $method->add_around_modifier(subname ':around' => $method_modifier);
323 # the methods above used to be named like this:
324 # ${pkg}::${method}:(before|after|around)
325 # but this proved problematic when using one modifier
326 # to wrap multiple methods (something which is likely
327 # to happen pretty regularly IMO). So instead of naming
328 # it like this, I have chosen to just name them purely
329 # with their modifier names, like so:
330 # :(before|after|around)
331 # The fact is that in a stack trace, it will be fairly
332 # evident from the context what method they are attached
333 # to, and so don't need the fully qualified name.
337 my ($self, $method_name, $method) = @_;
338 (defined $method_name && $method_name)
339 || confess "You must define a method name";
340 # use reftype here to allow for blessed subs ...
341 ('CODE' eq (reftype($method) || ''))
342 || confess "Your code block must be a CODE reference";
343 my $full_method_name = ($self->name . '::' . $method_name);
345 $method = $self->method_metaclass->wrap($method) unless blessed($method);
348 no warnings 'redefine';
349 *{$full_method_name} = $method;
353 my ($self, $method_name) = @_;
354 (defined $method_name && $method_name)
355 || confess "You must define a method name";
357 my $sub_name = ($self->name . '::' . $method_name);
360 return 0 if !defined(&{$sub_name});
361 my $method = \&{$sub_name};
362 return 0 if (svref_2object($method)->GV->STASH->NAME || '') ne $self->name &&
363 (svref_2object($method)->GV->NAME || '') ne '__ANON__';
365 # at this point we are relatively sure
366 # it is our method, so we bless/wrap it
367 $self->method_metaclass->wrap($method) unless blessed($method);
372 my ($self, $method_name) = @_;
373 (defined $method_name && $method_name)
374 || confess "You must define a method name";
376 return unless $self->has_method($method_name);
379 return \&{$self->name . '::' . $method_name};
383 my ($self, $method_name) = @_;
384 (defined $method_name && $method_name)
385 || confess "You must define a method name";
387 my $removed_method = $self->get_method($method_name);
390 delete ${$self->name . '::'}{$method_name}
391 if defined $removed_method;
393 return $removed_method;
396 sub get_method_list {
399 grep { $self->has_method($_) } %{$self->name . '::'};
402 sub compute_all_applicable_methods {
405 # keep a record of what we have seen
406 # here, this will handle all the
407 # inheritence issues because we are
408 # using the &class_precedence_list
409 my (%seen_class, %seen_method);
410 foreach my $class ($self->class_precedence_list()) {
411 next if $seen_class{$class};
412 $seen_class{$class}++;
413 # fetch the meta-class ...
414 my $meta = $self->initialize($class);
415 foreach my $method_name ($meta->get_method_list()) {
416 next if exists $seen_method{$method_name};
417 $seen_method{$method_name}++;
419 name => $method_name,
421 code => $meta->get_method($method_name)
428 sub find_all_methods_by_name {
429 my ($self, $method_name) = @_;
430 (defined $method_name && $method_name)
431 || confess "You must define a method name to find";
433 # keep a record of what we have seen
434 # here, this will handle all the
435 # inheritence issues because we are
436 # using the &class_precedence_list
438 foreach my $class ($self->class_precedence_list()) {
439 next if $seen_class{$class};
440 $seen_class{$class}++;
441 # fetch the meta-class ...
442 my $meta = $self->initialize($class);
444 name => $method_name,
446 code => $meta->get_method($method_name)
447 } if $meta->has_method($method_name);
452 sub find_next_method_by_name {
453 my ($self, $method_name) = @_;
454 (defined $method_name && $method_name)
455 || confess "You must define a method name to find";
456 # keep a record of what we have seen
457 # here, this will handle all the
458 # inheritence issues because we are
459 # using the &class_precedence_list
461 my @cpl = $self->class_precedence_list();
462 shift @cpl; # discard ourselves
463 foreach my $class (@cpl) {
464 next if $seen_class{$class};
465 $seen_class{$class}++;
466 # fetch the meta-class ...
467 my $meta = $self->initialize($class);
468 return $meta->get_method($method_name)
469 if $meta->has_method($method_name);
478 # either we have an attribute object already
479 # or we need to create one from the args provided
480 my $attribute = blessed($_[0]) ? $_[0] : $self->attribute_metaclass->new(@_);
481 # make sure it is derived from the correct type though
482 ($attribute->isa('Class::MOP::Attribute'))
483 || confess "Your attribute must be an instance of Class::MOP::Attribute (or a subclass)";
484 $attribute->attach_to_class($self);
485 $attribute->install_accessors();
486 $self->get_attribute_map->{$attribute->name} = $attribute;
490 my ($self, $attribute_name) = @_;
491 (defined $attribute_name && $attribute_name)
492 || confess "You must define an attribute name";
493 exists $self->get_attribute_map->{$attribute_name} ? 1 : 0;
497 my ($self, $attribute_name) = @_;
498 (defined $attribute_name && $attribute_name)
499 || confess "You must define an attribute name";
501 # we used to say `if $self->has_attribute($attribute_name)`
502 # here, but since get_attribute is called so often, we
503 # eliminate the function call here
504 return $self->{'%:attributes'}->{$attribute_name}
505 if exists $self->{'%:attributes'}->{$attribute_name};
509 sub remove_attribute {
510 my ($self, $attribute_name) = @_;
511 (defined $attribute_name && $attribute_name)
512 || confess "You must define an attribute name";
513 my $removed_attribute = $self->get_attribute_map->{$attribute_name};
514 return unless defined $removed_attribute;
515 delete $self->get_attribute_map->{$attribute_name};
516 $removed_attribute->remove_accessors();
517 $removed_attribute->detach_from_class();
518 return $removed_attribute;
521 sub get_attribute_list {
524 # We don't use get_attribute_map here because
525 # we ask for the attribute list quite often
526 # in compute_all_applicable_attributes, so
527 # eliminating the function call helps
528 keys %{$self->{'%:attributes'}};
531 sub compute_all_applicable_attributes {
534 # keep a record of what we have seen
535 # here, this will handle all the
536 # inheritence issues because we are
537 # using the &class_precedence_list
538 my (%seen_class, %seen_attr);
539 foreach my $class ($self->class_precedence_list()) {
540 next if $seen_class{$class};
541 $seen_class{$class}++;
542 # fetch the meta-class ...
544 # we grab the metaclass from the %METAS
545 # hash here to save the initialize() call
546 my $meta = $METAS{$class};
547 foreach my $attr_name ($meta->get_attribute_list()) {
548 next if exists $seen_attr{$attr_name};
549 $seen_attr{$attr_name}++;
550 push @attrs => $meta->get_attribute($attr_name);
556 sub find_attribute_by_name {
557 my ($self, $attr_name) = @_;
558 # keep a record of what we have seen
559 # here, this will handle all the
560 # inheritence issues because we are
561 # using the &class_precedence_list
563 foreach my $class ($self->class_precedence_list()) {
564 next if $seen_class{$class};
565 $seen_class{$class}++;
566 # fetch the meta-class ...
567 my $meta = $self->initialize($class);
568 return $meta->get_attribute($attr_name)
569 if $meta->has_attribute($attr_name);
576 sub add_package_variable {
577 my ($self, $variable, $initial_value) = @_;
578 (defined $variable && $variable =~ /^[\$\@\%]/)
579 || confess "variable name does not have a sigil";
581 my ($sigil, $name) = ($variable =~ /^(.)(.*)$/);
582 if (defined $initial_value) {
584 *{$self->name . '::' . $name} = $initial_value;
590 # We HAVE to localize $@ or all
591 # hell breaks loose. It is not
592 # good, believe me, not good.
594 eval $sigil . $self->name . '::' . $name;
597 confess "Could not create package variable ($variable) because : $e" if $e;
601 sub has_package_variable {
602 my ($self, $variable) = @_;
603 (defined $variable && $variable =~ /^[\$\@\%]/)
604 || confess "variable name does not have a sigil";
605 my ($sigil, $name) = ($variable =~ /^(.)(.*)$/);
607 defined ${$self->name . '::'}{$name} ? 1 : 0;
610 sub get_package_variable {
611 my ($self, $variable) = @_;
612 (defined $variable && $variable =~ /^[\$\@\%]/)
613 || confess "variable name does not have a sigil";
614 my ($sigil, $name) = ($variable =~ /^(.)(.*)$/);
618 # We HAVE to localize $@ or all
619 # hell breaks loose. It is not
620 # good, believe me, not good.
622 $ref = eval '\\' . $sigil . $self->name . '::' . $name;
625 confess "Could not get the package variable ($variable) because : $e" if $e;
626 # if we didn't die, then we can return it
630 sub remove_package_variable {
631 my ($self, $variable) = @_;
632 (defined $variable && $variable =~ /^[\$\@\%]/)
633 || confess "variable name does not have a sigil";
634 my ($sigil, $name) = ($variable =~ /^(.)(.*)$/);
636 delete ${$self->name . '::'}{$name};
647 Class::MOP::Class - Class Meta Object
651 # assuming that class Foo
652 # has been defined, you can
654 # use this for introspection ...
656 # add a method to Foo ...
657 Foo->meta->add_method('bar' => sub { ... })
659 # get a list of all the classes searched
660 # the method dispatcher in the correct order
661 Foo->meta->class_precedence_list()
663 # remove a method from Foo
664 Foo->meta->remove_method('bar');
666 # or use this to actually create classes ...
668 Class::MOP::Class->create('Bar' => '0.01' => (
669 superclasses => [ 'Foo' ],
671 Class::MOP:::Attribute->new('$bar'),
672 Class::MOP:::Attribute->new('$baz'),
675 calculate_bar => sub { ... },
676 construct_baz => sub { ... }
682 This is the largest and currently most complex part of the Perl 5
683 meta-object protocol. It controls the introspection and
684 manipulation of Perl 5 classes (and it can create them too). The
685 best way to understand what this module can do, is to read the
686 documentation for each of it's methods.
690 =head2 Self Introspection
696 This will return a B<Class::MOP::Class> instance which is related
697 to this class. Thereby allowing B<Class::MOP::Class> to actually
700 As with B<Class::MOP::Attribute>, B<Class::MOP> will actually
701 bootstrap this module by installing a number of attribute meta-objects
702 into it's metaclass. This will allow this class to reap all the benifits
703 of the MOP when subclassing it.
705 =item B<get_all_metaclasses>
707 This will return an hash of all the metaclass instances that have
708 been cached by B<Class::MOP::Class> keyed by the package name.
710 =item B<get_all_metaclass_instances>
712 This will return an array of all the metaclass instances that have
713 been cached by B<Class::MOP::Class>.
715 =item B<get_all_metaclass_names>
717 This will return an array of all the metaclass names that have
718 been cached by B<Class::MOP::Class>.
722 =head2 Class construction
724 These methods will handle creating B<Class::MOP::Class> objects,
725 which can be used to both create new classes, and analyze
726 pre-existing classes.
728 This module will internally store references to all the instances
729 you create with these methods, so that they do not need to be
730 created any more than nessecary. Basically, they are singletons.
734 =item B<create ($package_name, ?$package_version,
735 superclasses =E<gt> ?@superclasses,
736 methods =E<gt> ?%methods,
737 attributes =E<gt> ?%attributes)>
739 This returns a B<Class::MOP::Class> object, bringing the specified
740 C<$package_name> into existence and adding any of the
741 C<$package_version>, C<@superclasses>, C<%methods> and C<%attributes>
744 =item B<create_anon_class (superclasses =E<gt> ?@superclasses,
745 methods =E<gt> ?%methods,
746 attributes =E<gt> ?%attributes)>
748 This will create an anonymous class, it works much like C<create> but
749 it does not need a C<$package_name>. Instead it will create a suitably
750 unique package name for you to stash things into.
752 =item B<initialize ($package_name)>
754 This initializes and returns returns a B<Class::MOP::Class> object
755 for a given a C<$package_name>.
757 =item B<construct_class_instance (%options)>
759 This will construct an instance of B<Class::MOP::Class>, it is
760 here so that we can actually "tie the knot" for B<Class::MOP::Class>
761 to use C<construct_instance> once all the bootstrapping is done. This
762 method is used internally by C<initialize> and should never be called
763 from outside of that method really.
765 =item B<check_metaclass_compatability>
767 This method is called as the very last thing in the
768 C<construct_class_instance> method. This will check that the
769 metaclass you are creating is compatible with the metaclasses of all
770 your ancestors. For more inforamtion about metaclass compatibility
771 see the C<About Metaclass compatibility> section in L<Class::MOP>.
775 =head2 Object instance construction and cloning
777 These methods are B<entirely optional>, it is up to you whether you want
782 =item B<instance_metaclass>
784 =item B<new_object (%params)>
786 This is a convience method for creating a new object of the class, and
787 blessing it into the appropriate package as well. Ideally your class
788 would call a C<new> this method like so:
791 my ($class, %param) = @_;
792 $class->meta->new_object(%params);
795 Of course the ideal place for this would actually be in C<UNIVERSAL::>
796 but that is considered bad style, so we do not do that.
798 =item B<construct_instance (%params)>
800 This method is used to construct an instace structure suitable for
801 C<bless>-ing into your package of choice. It works in conjunction
802 with the Attribute protocol to collect all applicable attributes.
804 This will construct and instance using a HASH ref as storage
805 (currently only HASH references are supported). This will collect all
806 the applicable attributes and layout out the fields in the HASH ref,
807 it will then initialize them using either use the corresponding key
808 in C<%params> or any default value or initializer found in the
809 attribute meta-object.
811 =item B<clone_object ($instance, %params)>
813 This is a convience method for cloning an object instance, then
814 blessing it into the appropriate package. This method will call
815 C<clone_instance>, which performs a shallow copy of the object,
816 see that methods documentation for more details. Ideally your
817 class would call a C<clone> this method like so:
820 my ($self, %param) = @_;
821 $self->meta->clone_object($self, %params);
824 Of course the ideal place for this would actually be in C<UNIVERSAL::>
825 but that is considered bad style, so we do not do that.
827 =item B<clone_instance($instance, %params)>
829 This method is a compliment of C<construct_instance> (which means if
830 you override C<construct_instance>, you need to override this one too),
831 and clones the instance shallowly.
833 The cloned structure returned is (like with C<construct_instance>) an
834 unC<bless>ed HASH reference, it is your responsibility to then bless
835 this cloned structure into the right class (which C<clone_object> will
838 As of 0.11, this method will clone the C<$instance> structure shallowly,
839 as opposed to the deep cloning implemented in prior versions. After much
840 thought, research and discussion, I have decided that anything but basic
841 shallow cloning is outside the scope of the meta-object protocol. I
842 think Yuval "nothingmuch" Kogman put it best when he said that cloning
843 is too I<context-specific> to be part of the MOP.
853 This is a read-only attribute which returns the package name for the
854 given B<Class::MOP::Class> instance.
858 This is a read-only attribute which returns the C<$VERSION> of the
859 package for the given B<Class::MOP::Class> instance.
863 =head2 Inheritance Relationships
867 =item B<superclasses (?@superclasses)>
869 This is a read-write attribute which represents the superclass
870 relationships of the class the B<Class::MOP::Class> instance is
871 associated with. Basically, it can get and set the C<@ISA> for you.
874 Perl will occasionally perform some C<@ISA> and method caching, if
875 you decide to change your superclass relationship at runtime (which
876 is quite insane and very much not recommened), then you should be
877 aware of this and the fact that this module does not make any
878 attempt to address this issue.
880 =item B<class_precedence_list>
882 This computes the a list of all the class's ancestors in the same order
883 in which method dispatch will be done. This is similair to
884 what B<Class::ISA::super_path> does, but we don't remove duplicate names.
892 =item B<method_metaclass>
894 =item B<add_method ($method_name, $method)>
896 This will take a C<$method_name> and CODE reference to that
897 C<$method> and install it into the class's package.
900 This does absolutely nothing special to C<$method>
901 other than use B<Sub::Name> to make sure it is tagged with the
902 correct name, and therefore show up correctly in stack traces and
905 =item B<alias_method ($method_name, $method)>
907 This will take a C<$method_name> and CODE reference to that
908 C<$method> and alias the method into the class's package.
911 Unlike C<add_method>, this will B<not> try to name the
912 C<$method> using B<Sub::Name>, it only aliases the method in
915 =item B<has_method ($method_name)>
917 This just provides a simple way to check if the class implements
918 a specific C<$method_name>. It will I<not> however, attempt to check
919 if the class inherits the method (use C<UNIVERSAL::can> for that).
921 This will correctly handle functions defined outside of the package
922 that use a fully qualified name (C<sub Package::name { ... }>).
924 This will correctly handle functions renamed with B<Sub::Name> and
925 installed using the symbol tables. However, if you are naming the
926 subroutine outside of the package scope, you must use the fully
927 qualified name, including the package name, for C<has_method> to
928 correctly identify it.
930 This will attempt to correctly ignore functions imported from other
931 packages using B<Exporter>. It breaks down if the function imported
932 is an C<__ANON__> sub (such as with C<use constant>), which very well
933 may be a valid method being applied to the class.
935 In short, this method cannot always be trusted to determine if the
936 C<$method_name> is actually a method. However, it will DWIM about
937 90% of the time, so it's a small trade off I think.
939 =item B<get_method ($method_name)>
941 This will return a CODE reference of the specified C<$method_name>,
942 or return undef if that method does not exist.
944 =item B<remove_method ($method_name)>
946 This will attempt to remove a given C<$method_name> from the class.
947 It will return the CODE reference that it has removed, and will
948 attempt to use B<Sub::Name> to clear the methods associated name.
950 =item B<get_method_list>
952 This will return a list of method names for all I<locally> defined
953 methods. It does B<not> provide a list of all applicable methods,
954 including any inherited ones. If you want a list of all applicable
955 methods, use the C<compute_all_applicable_methods> method.
957 =item B<compute_all_applicable_methods>
959 This will return a list of all the methods names this class will
960 respond to, taking into account inheritance. The list will be a list of
961 HASH references, each one containing the following information; method
962 name, the name of the class in which the method lives and a CODE
963 reference for the actual method.
965 =item B<find_all_methods_by_name ($method_name)>
967 This will traverse the inheritence hierarchy and locate all methods
968 with a given C<$method_name>. Similar to
969 C<compute_all_applicable_methods> it returns a list of HASH references
970 with the following information; method name (which will always be the
971 same as C<$method_name>), the name of the class in which the method
972 lives and a CODE reference for the actual method.
974 The list of methods produced is a distinct list, meaning there are no
975 duplicates in it. This is especially useful for things like object
976 initialization and destruction where you only want the method called
977 once, and in the correct order.
979 =item B<find_next_method_by_name ($method_name)>
981 This will return the first method to match a given C<$method_name> in
982 the superclasses, this is basically equivalent to calling
983 C<SUPER::$method_name>, but it can be dispatched at runtime.
987 =head2 Method Modifiers
989 Method modifiers are a concept borrowed from CLOS, in which a method
990 can be wrapped with I<before>, I<after> and I<around> method modifiers
991 that will be called everytime the method is called.
993 =head3 How method modifiers work?
995 Method modifiers work by wrapping the original method and then replacing
996 it in the classes symbol table. The wrappers will handle calling all the
997 modifiers in the appropariate orders and preserving the calling context
998 for the original method.
1000 Each method modifier serves a particular purpose, which may not be
1001 obvious to users of other method wrapping modules. To start with, the
1002 return values of I<before> and I<after> modifiers are ignored. This is
1003 because thier purpose is B<not> to filter the input and output of the
1004 primary method (this is done with an I<around> modifier). This may seem
1005 like an odd restriction to some, but doing this allows for simple code
1006 to be added at the begining or end of a method call without jeapordizing
1007 the normal functioning of the primary method or placing any extra
1008 responsibility on the code of the modifier. Of course if you have more
1009 complex needs, then use the I<around> modifier, which uses a variation
1010 of continutation passing style to allow for a high degree of flexibility.
1012 Before and around modifiers are called in last-defined-first-called order,
1013 while after modifiers are called in first-defined-first-called order. So
1014 the call tree might looks something like this:
1024 To see examples of using method modifiers, see the following examples
1025 included in the distribution; F<InstanceCountingClass>, F<Perl6Attribute>,
1026 F<AttributesWithHistory> and F<C3MethodDispatchOrder>. There is also a
1027 classic CLOS usage example in the test F<017_add_method_modifier.t>.
1029 =head3 What is the performance impact?
1031 Of course there is a performance cost associated with method modifiers,
1032 but we have made every effort to make that cost be directly proportional
1033 to the amount of modifier features you utilize.
1035 The wrapping method does it's best to B<only> do as much work as it
1036 absolutely needs to. In order to do this we have moved some of the
1037 performance costs to set-up time, where they are easier to amortize.
1039 All this said, my benchmarks have indicated the following:
1041 simple wrapper with no modifiers 100% slower
1042 simple wrapper with simple before modifier 400% slower
1043 simple wrapper with simple after modifier 450% slower
1044 simple wrapper with simple around modifier 500-550% slower
1045 simple wrapper with all 3 modifiers 1100% slower
1047 These numbers may seem daunting, but you must remember, every feature
1048 comes with some cost. To put things in perspective, just doing a simple
1049 C<AUTOLOAD> which does nothing but extract the name of the method called
1050 and return it costs about 400% over a normal method call.
1054 =item B<add_before_method_modifier ($method_name, $code)>
1056 This will wrap the method at C<$method_name> and the supplied C<$code>
1057 will be passed the C<@_> arguments, and called before the original
1058 method is called. As specified above, the return value of the I<before>
1059 method modifiers is ignored, and it's ability to modify C<@_> is
1060 fairly limited. If you need to do either of these things, use an
1061 C<around> method modifier.
1063 =item B<add_after_method_modifier ($method_name, $code)>
1065 This will wrap the method at C<$method_name> so that the original
1066 method will be called, it's return values stashed, and then the
1067 supplied C<$code> will be passed the C<@_> arguments, and called.
1068 As specified above, the return value of the I<after> method
1069 modifiers is ignored, and it cannot modify the return values of
1070 the original method. If you need to do either of these things, use an
1071 C<around> method modifier.
1073 =item B<add_around_method_modifier ($method_name, $code)>
1075 This will wrap the method at C<$method_name> so that C<$code>
1076 will be called and passed the original method as an extra argument
1077 at the begining of the C<@_> argument list. This is a variation of
1078 continuation passing style, where the function prepended to C<@_>
1079 can be considered a continuation. It is up to C<$code> if it calls
1080 the original method or not, there is no restriction on what the
1081 C<$code> can or cannot do.
1087 It should be noted that since there is no one consistent way to define
1088 the attributes of a class in Perl 5. These methods can only work with
1089 the information given, and can not easily discover information on
1090 their own. See L<Class::MOP::Attribute> for more details.
1094 =item B<attribute_metaclass>
1096 =item B<get_attribute_map>
1098 =item B<add_attribute ($attribute_name, $attribute_meta_object)>
1100 This stores a C<$attribute_meta_object> in the B<Class::MOP::Class>
1101 instance associated with the given class, and associates it with
1102 the C<$attribute_name>. Unlike methods, attributes within the MOP
1103 are stored as meta-information only. They will be used later to
1104 construct instances from (see C<construct_instance> above).
1105 More details about the attribute meta-objects can be found in the
1106 L<Class::MOP::Attribute> or the L<Class::MOP/The Attribute protocol>
1109 It should be noted that any accessor, reader/writer or predicate
1110 methods which the C<$attribute_meta_object> has will be installed
1111 into the class at this time.
1113 =item B<has_attribute ($attribute_name)>
1115 Checks to see if this class has an attribute by the name of
1116 C<$attribute_name> and returns a boolean.
1118 =item B<get_attribute ($attribute_name)>
1120 Returns the attribute meta-object associated with C<$attribute_name>,
1121 if none is found, it will return undef.
1123 =item B<remove_attribute ($attribute_name)>
1125 This will remove the attribute meta-object stored at
1126 C<$attribute_name>, then return the removed attribute meta-object.
1129 Removing an attribute will only affect future instances of
1130 the class, it will not make any attempt to remove the attribute from
1131 any existing instances of the class.
1133 It should be noted that any accessor, reader/writer or predicate
1134 methods which the attribute meta-object stored at C<$attribute_name>
1135 has will be removed from the class at this time. This B<will> make
1136 these attributes somewhat inaccessable in previously created
1137 instances. But if you are crazy enough to do this at runtime, then
1138 you are crazy enough to deal with something like this :).
1140 =item B<get_attribute_list>
1142 This returns a list of attribute names which are defined in the local
1143 class. If you want a list of all applicable attributes for a class,
1144 use the C<compute_all_applicable_attributes> method.
1146 =item B<compute_all_applicable_attributes>
1148 This will traverse the inheritance heirachy and return a list of all
1149 the applicable attributes for this class. It does not construct a
1150 HASH reference like C<compute_all_applicable_methods> because all
1151 that same information is discoverable through the attribute
1154 =item B<find_attribute_by_name ($attr_name)>
1156 This method will traverse the inheritance heirachy and find the
1157 first attribute whose name matches C<$attr_name>, then return it.
1158 It will return undef if nothing is found.
1162 =head2 Package Variables
1164 Since Perl's classes are built atop the Perl package system, it is
1165 fairly common to use package scoped variables for things like static
1166 class variables. The following methods are convience methods for
1167 the creation and inspection of package scoped variables.
1171 =item B<add_package_variable ($variable_name, ?$initial_value)>
1173 Given a C<$variable_name>, which must contain a leading sigil, this
1174 method will create that variable within the package which houses the
1175 class. It also takes an optional C<$initial_value>, which must be a
1176 reference of the same type as the sigil of the C<$variable_name>
1179 =item B<get_package_variable ($variable_name)>
1181 This will return a reference to the package variable in
1184 =item B<has_package_variable ($variable_name)>
1186 Returns true (C<1>) if there is a package variable defined for
1187 C<$variable_name>, and false (C<0>) otherwise.
1189 =item B<remove_package_variable ($variable_name)>
1191 This will attempt to remove the package variable at C<$variable_name>.
1197 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1199 =head1 COPYRIGHT AND LICENSE
1201 Copyright 2006 by Infinity Interactive, Inc.
1203 L<http://www.iinteractive.com>
1205 This library is free software; you can redistribute it and/or modify
1206 it under the same terms as Perl itself.