lib/Class/MOP/Attribute.pm

   1
   2 package Class::MOP::Attribute;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Class::MOP::Method::Accessor;
   8
   9 use Carp         'confess';
  10 use Scalar::Util 'blessed', 'reftype', 'weaken';
  11
  12 our $VERSION   = '0.24';
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 use base 'Class::MOP::Object';
  16
  17 # NOTE: (meta-circularity)
  18 # This method will be replaced in the
  19 # boostrap section of Class::MOP, by
  20 # a new version which uses the
  21 # &Class::MOP::Class::construct_instance
  22 # method to build an attribute meta-object
  23 # which itself is described with attribute
  24 # meta-objects.
  25 #     - Ain't meta-circularity grand? :)
  26 sub new {
  27     my $class   = shift;
  28     my $name    = shift;
  29     my %options = @_;
  30
  31     (defined $name && $name)
  32         || confess "You must provide a name for the attribute";
  33
  34     $options{init_arg} = $name
  35         if not exists $options{init_arg};
  36     if(exists $options{builder}){
  37         confess("builder must be a defined scalar value which is a method name")
  38             if ref $options{builder} || !(defined $options{builder});
  39         confess("Setting both default and builder is not allowed.")
  40             if exists $options{default};
  41     } else {
  42         (is_default_a_coderef(\%options))
  43             || confess("References are not allowed as default values, you must ".
  44                        "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])")
  45                 if exists $options{default} && ref $options{default};
  46     }
  47     if( $options{required} and not( defined($options{builder}) || defined($options{init_arg}) || exists $options{default} ) ) {
  48         confess("A required attribute must have either 'init_arg', 'builder', or 'default'");
  49     }
  50     bless {
  51         '$!name'      => $name,
  52         '$!accessor'  => $options{accessor},
  53         '$!reader'    => $options{reader},
  54         '$!writer'      => $options{writer},
  55         '$!predicate'   => $options{predicate},
  56         '$!clearer'     => $options{clearer},
  57         '$!builder'     => $options{builder},
  58         '$!init_arg'    => $options{init_arg},
  59         '$!default'     => $options{default},
  60         '$!initializer' => $options{initializer},
  61         # keep a weakened link to the
  62         # class we are associated with
  63         '$!associated_class' => undef,
  64         # and a list of the methods
  65         # associated with this attr
  66         '@!associated_methods' => [],
  67         # NOTE:
  68         # protect this from silliness
  69         init_arg => undef,
  70     } => $class;
  71 }
  72
  73 # NOTE:
  74 # this is a primative (and kludgy) clone operation
  75 # for now, it will be replaced in the Class::MOP
  76 # bootstrap with a proper one, however we know
  77 # that this one will work fine for now.
  78 sub clone {
  79     my $self    = shift;
  80     my %options = @_;
  81     (blessed($self))
  82         || confess "Can only clone an instance";
  83     return bless { %{$self}, %options } => blessed($self);
  84 }
  85
  86 sub initialize_instance_slot {
  87     my ($self, $meta_instance, $instance, $params) = @_;
  88     my $init_arg = $self->{'$!init_arg'};
  89     # try to fetch the init arg from the %params ...
  90
  91     # if nothing was in the %params, we can use the
  92     # attribute's default value (if it has one)
  93     if(defined $init_arg and exists $params->{$init_arg}){
  94         $self->_set_initial_slot_value(
  95             $meta_instance,
  96             $instance,
  97             $params->{$init_arg},
  98         );
  99     }
 100     elsif (defined $self->{'$!default'}) {
 101         $self->_set_initial_slot_value(
 102             $meta_instance,
 103             $instance,
 104             $self->default($instance),
 105         );
 106     }
 107     elsif (defined( my $builder = $self->{'$!builder'})) {
 108         if ($builder = $instance->can($builder)) {
 109             $self->_set_initial_slot_value(
 110                 $meta_instance,
 111                 $instance,
 112                 $instance->$builder,
 113             );
 114         }
 115         else {
 116             confess(blessed($instance)." does not support builder method '". $self->{'$!builder'} ."' for attribute '" . $self->name . "'");
 117         }
 118     }
 119 }
 120
 121 sub _set_initial_slot_value {
 122     my ($self, $meta_instance, $instance, $value) = @_;
 123
 124     my $slot_name = $self->name;
 125
 126     return $meta_instance->set_slot_value($instance, $slot_name, $value)
 127         unless $self->has_initializer;
 128
 129     my $callback = sub {
 130         $meta_instance->set_slot_value($instance, $slot_name, $_[0]);
 131     };
 132
 133     my $initializer = $self->initializer;
 134
 135     # most things will just want to set a value, so make it first arg
 136     $instance->$initializer($value, $callback, $self);
 137 }
 138
 139 # NOTE:
 140 # the next bunch of methods will get bootstrapped
 141 # away in the Class::MOP bootstrapping section
 142
 143 sub name { $_[0]->{'$!name'} }
 144
 145 sub associated_class   { $_[0]->{'$!associated_class'}   }
 146 sub associated_methods { $_[0]->{'@!associated_methods'} }
 147
 148 sub has_accessor    { defined($_[0]->{'$!accessor'})     ? 1 : 0 }
 149 sub has_reader      { defined($_[0]->{'$!reader'})       ? 1 : 0 }
 150 sub has_writer      { defined($_[0]->{'$!writer'})       ? 1 : 0 }
 151 sub has_predicate   { defined($_[0]->{'$!predicate'})    ? 1 : 0 }
 152 sub has_clearer     { defined($_[0]->{'$!clearer'})      ? 1 : 0 }
 153 sub has_builder     { defined($_[0]->{'$!builder'})      ? 1 : 0 }
 154 sub has_init_arg    { defined($_[0]->{'$!init_arg'})     ? 1 : 0 }
 155 sub has_default     { defined($_[0]->{'$!default'})      ? 1 : 0 }
 156 sub has_initializer { defined($_[0]->{'$!initializer'})  ? 1 : 0 }
 157
 158 sub accessor    { $_[0]->{'$!accessor'}    }
 159 sub reader      { $_[0]->{'$!reader'}      }
 160 sub writer      { $_[0]->{'$!writer'}      }
 161 sub predicate   { $_[0]->{'$!predicate'}   }
 162 sub clearer     { $_[0]->{'$!clearer'}     }
 163 sub builder     { $_[0]->{'$!builder'}     }
 164 sub init_arg    { $_[0]->{'$!init_arg'}    }
 165 sub initializer { $_[0]->{'$!initializer'} }
 166
 167 # end bootstrapped away method section.
 168 # (all methods below here are kept intact)
 169
 170 sub has_read_method  { $_[0]->has_reader || $_[0]->has_accessor }
 171 sub has_write_method { $_[0]->has_writer || $_[0]->has_accessor }
 172
 173 sub get_read_method  {
 174     my $self   = shift;
 175     my $reader = $self->reader || $self->accessor;
 176     # normal case ...
 177     return $reader unless ref $reader;
 178     # the HASH ref case
 179     my ($name) = %$reader;
 180     return $name;
 181 }
 182
 183 sub get_write_method {
 184     my $self   = shift;
 185     my $writer = $self->writer || $self->accessor;
 186     # normal case ...
 187     return $writer unless ref $writer;
 188     # the HASH ref case
 189     my ($name) = %$writer;
 190     return $name;
 191 }
 192
 193 sub get_read_method_ref {
 194     my $self = shift;
 195     if ((my $reader = $self->get_read_method) && $self->associated_class) {
 196         return $self->associated_class->get_method($reader);
 197     }
 198     else {
 199         return sub { $self->get_value(@_) };
 200     }
 201 }
 202
 203 sub get_write_method_ref {
 204     my $self = shift;
 205     if ((my $writer = $self->get_write_method) && $self->associated_class) {
 206         return $self->associated_class->get_method($writer);
 207     }
 208     else {
 209         return sub { $self->set_value(@_) };
 210     }
 211 }
 212
 213 sub is_default_a_coderef {
 214     ('CODE' eq (reftype($_[0]->{'$!default'} || $_[0]->{default}) || ''))
 215 }
 216
 217 sub default {
 218     my ($self, $instance) = @_;
 219     if (defined $instance && $self->is_default_a_coderef) {
 220         # if the default is a CODE ref, then
 221         # we pass in the instance and default
 222         # can return a value based on that
 223         # instance. Somewhat crude, but works.
 224         return $self->{'$!default'}->($instance);
 225     }
 226     $self->{'$!default'};
 227 }
 228
 229 # slots
 230
 231 sub slots { (shift)->name }
 232
 233 # class association
 234
 235 sub attach_to_class {
 236     my ($self, $class) = @_;
 237     (blessed($class) && $class->isa('Class::MOP::Class'))
 238         || confess "You must pass a Class::MOP::Class instance (or a subclass)";
 239     weaken($self->{'$!associated_class'} = $class);
 240 }
 241
 242 sub detach_from_class {
 243     my $self = shift;
 244     $self->{'$!associated_class'} = undef;
 245 }
 246
 247 # method association
 248
 249 sub associate_method {
 250     my ($self, $method) = @_;
 251     push @{$self->{'@!associated_methods'}} => $method;
 252 }
 253
 254 ## Slot management
 255
 256 sub set_initial_value {
 257     my ($self, $instance, $value) = @_;
 258     $self->_set_initial_slot_value(
 259         Class::MOP::Class->initialize(blessed($instance))->get_meta_instance,
 260         $instance,
 261         $value
 262     );
 263 }
 264
 265 sub set_value {
 266     my ($self, $instance, $value) = @_;
 267
 268     Class::MOP::Class->initialize(blessed($instance))
 269                      ->get_meta_instance
 270                      ->set_slot_value($instance, $self->name, $value);
 271 }
 272
 273 sub get_value {
 274     my ($self, $instance) = @_;
 275
 276     Class::MOP::Class->initialize(blessed($instance))
 277                      ->get_meta_instance
 278                      ->get_slot_value($instance, $self->name);
 279 }
 280
 281 sub has_value {
 282     my ($self, $instance) = @_;
 283
 284     Class::MOP::Class->initialize(blessed($instance))
 285                      ->get_meta_instance
 286                      ->is_slot_initialized($instance, $self->name);
 287 }
 288
 289 sub clear_value {
 290     my ($self, $instance) = @_;
 291
 292     Class::MOP::Class->initialize(blessed($instance))
 293                      ->get_meta_instance
 294                      ->deinitialize_slot($instance, $self->name);
 295 }
 296
 297 ## load em up ...
 298
 299 sub accessor_metaclass { 'Class::MOP::Method::Accessor' }
 300
 301 sub process_accessors {
 302     my ($self, $type, $accessor, $generate_as_inline_methods) = @_;
 303     if (reftype($accessor)) {
 304         (reftype($accessor) eq 'HASH')
 305             || confess "bad accessor/reader/writer/predicate/clearer format, must be a HASH ref";
 306         my ($name, $method) = %{$accessor};
 307         $method = $self->accessor_metaclass->wrap(
 308             $method,
 309             package_name => $self->associated_class->name,
 310             name         => $name,
 311         );
 312         $self->associate_method($method);
 313         return ($name, $method);
 314     }
 315     else {
 316         my $inline_me = ($generate_as_inline_methods && $self->associated_class->instance_metaclass->is_inlinable);
 317         my $method;
 318         eval {
 319             $method = $self->accessor_metaclass->new(
 320                 attribute     => $self,
 321                 is_inline     => $inline_me,
 322                 accessor_type => $type,
 323                 package_name  => $self->associated_class->name,
 324                 name          => $accessor,
 325             );
 326         };
 327         confess "Could not create the '$type' method for " . $self->name . " because : $@" if $@;
 328         $self->associate_method($method);
 329         return ($accessor, $method);
 330     }
 331 }
 332
 333 sub install_accessors {
 334     my $self   = shift;
 335     my $inline = shift;
 336     my $class  = $self->associated_class;
 337
 338     $class->add_method(
 339         $self->process_accessors('accessor' => $self->accessor(), $inline)
 340     ) if $self->has_accessor();
 341
 342     $class->add_method(
 343         $self->process_accessors('reader' => $self->reader(), $inline)
 344     ) if $self->has_reader();
 345
 346     $class->add_method(
 347         $self->process_accessors('writer' => $self->writer(), $inline)
 348     ) if $self->has_writer();
 349
 350     $class->add_method(
 351         $self->process_accessors('predicate' => $self->predicate(), $inline)
 352     ) if $self->has_predicate();
 353
 354     $class->add_method(
 355         $self->process_accessors('clearer' => $self->clearer(), $inline)
 356     ) if $self->has_clearer();
 357
 358     return;
 359 }
 360
 361 {
 362     my $_remove_accessor = sub {
 363         my ($accessor, $class) = @_;
 364         if (reftype($accessor) && reftype($accessor) eq 'HASH') {
 365             ($accessor) = keys %{$accessor};
 366         }
 367         my $method = $class->get_method($accessor);
 368         $class->remove_method($accessor)
 369             if (blessed($method) && $method->isa('Class::MOP::Method::Accessor'));
 370     };
 371
 372     sub remove_accessors {
 373         my $self = shift;
 374         # TODO:
 375         # we really need to make sure to remove from the
 376         # associates methods here as well. But this is
 377         # such a slimly used method, I am not worried
 378         # about it right now.
 379         $_remove_accessor->($self->accessor(),  $self->associated_class()) if $self->has_accessor();
 380         $_remove_accessor->($self->reader(),    $self->associated_class()) if $self->has_reader();
 381         $_remove_accessor->($self->writer(),    $self->associated_class()) if $self->has_writer();
 382         $_remove_accessor->($self->predicate(), $self->associated_class()) if $self->has_predicate();
 383         $_remove_accessor->($self->clearer(),   $self->associated_class()) if $self->has_clearer();
 384         return;
 385     }
 386
 387 }
 388
 389 1;
 390
 391 __END__
 392
 393 =pod
 394
 395 =head1 NAME
 396
 397 Class::MOP::Attribute - Attribute Meta Object
 398
 399 =head1 SYNOPSIS
 400
 401   Class::MOP::Attribute->new('$foo' => (
 402       accessor  => 'foo',        # dual purpose get/set accessor
 403       predicate => 'has_foo'     # predicate check for defined-ness
 404       init_arg  => '-foo',       # class->new will look for a -foo key
 405       default   => 'BAR IS BAZ!' # if no -foo key is provided, use this
 406   ));
 407
 408   Class::MOP::Attribute->new('$.bar' => (
 409       reader    => 'bar',        # getter
 410       writer    => 'set_bar',    # setter
 411       predicate => 'has_bar'     # predicate check for defined-ness
 412       init_arg  => ':bar',       # class->new will look for a :bar key
 413       # no default value means it is undef
 414   ));
 415
 416 =head1 DESCRIPTION
 417
 418 The Attribute Protocol is almost entirely an invention of this module,
 419 and is completely optional to this MOP. This is because Perl 5 does not
 420 have consistent notion of what is an attribute of a class. There are
 421 so many ways in which this is done, and very few (if any) are
 422 easily discoverable by this module.
 423
 424 So, all that said, this module attempts to inject some order into this
 425 chaos, by introducing a consistent API which can be used to create
 426 object attributes.
 427
 428 =head1 METHODS
 429
 430 =head2 Creation
 431
 432 =over 4
 433
 434 =item B<new ($name, ?%options)>
 435
 436 An attribute must (at the very least), have a C<$name>. All other
 437 C<%options> are contained added as key-value pairs. Acceptable keys
 438 are as follows:
 439
 440 =over 4
 441
 442 =item I<init_arg>
 443
 444 This should be a string value representing the expected key in
 445 an initialization hash. For instance, if we have an I<init_arg>
 446 value of C<-foo>, then the following code will Just Work.
 447
 448   MyClass->meta->construct_instance(-foo => "Hello There");
 449
 450 In an init_arg is not assigned, it will automatically use the
 451 value of C<$name>.  If an explicit C<undef> is given for an init_arg,
 452 an attribute value can't be specified during initialization.
 453
 454 =item I<builder>
 455
 456 The value of this key is the name of the method that will be
 457 called to obtain the value used to initialize the attribute.
 458 This should be a method in the class associated with the attribute,
 459 not a method in the attribute class itself.
 460
 461 =item I<default>
 462
 463 The value of this key is the default value which
 464 C<Class::MOP::Class::construct_instance> will initialize the
 465 attribute to.
 466
 467 B<NOTE:>
 468 If the value is a simple scalar (string or number), then it can
 469 be just passed as is. However, if you wish to initialize it with
 470 a HASH or ARRAY ref, then you need to wrap that inside a CODE
 471 reference, like so:
 472
 473   Class::MOP::Attribute->new('@foo' => (
 474       default => sub { [] },
 475   ));
 476
 477   # or ...
 478
 479   Class::MOP::Attribute->new('%foo' => (
 480       default => sub { {} },
 481   ));
 482
 483 If you wish to initialize an attribute with a CODE reference
 484 itself, then you need to wrap that in a subroutine as well, like
 485 so:
 486
 487   Class::MOP::Attribute->new('&foo' => (
 488       default => sub { sub { print "Hello World" } },
 489   ));
 490
 491 And lastly, if the value of your attribute is dependent upon
 492 some other aspect of the instance structure, then you can take
 493 advantage of the fact that when the I<default> value is a CODE
 494 reference, it is passed the (as yet unfinished) instance structure
 495 as it's only argument. So you can do things like this:
 496
 497   Class::MOP::Attribute->new('$object_identity' => (
 498       default => sub { Scalar::Util::refaddr($_[0]) },
 499   ));
 500
 501 This last feature is fairly limited as there is no gurantee of
 502 the order of attribute initializations, so you cannot perform
 503 any kind of dependent initializations. However, if this is
 504 something you need, you could subclass B<Class::MOP::Class> and
 505 this class to acheive it. However, this is currently left as
 506 an exercise to the reader :).
 507
 508 =item I<initializer>
 509
 510 This may be a method name (referring to a method on the class with this
 511 attribute) or a CODE ref.  The initializer is used to set the attribute value
 512 on an instance when the attribute is set during instance initialization.  When
 513 called, it is passed the instance (as the invocant), the value to set, a
 514 slot-setting CODE ref, and the attribute meta-instance.  The slot-setting code
 515 is provided to make it easy to set the (possibly altered) value on the instance
 516 without going through several more method calls.
 517
 518 This contrived example shows an initializer that sets the attribute to twice
 519 the given value.
 520
 521   Class::MOP::Attribute->new('$doubled' => (
 522       initializer => sub {
 523           my ($instance, $value, $set) = @_;
 524           $set->($value * 2);
 525       },
 526   ));
 527
 528 As method names can be given as initializers, one can easily make
 529 attribute initialization use the writer:
 530
 531   Class::MOP::Attribute->new('$some_attr' => (
 532       writer      => 'some_attr',
 533       initializer => 'some_attr',
 534   ));
 535
 536 Your writer will simply need to examine it's C<@_> and determine under
 537 which context it is being called.
 538
 539 =back
 540
 541 The I<accessor>, I<reader>, I<writer>, I<predicate> and I<clearer> keys can
 542 contain either; the name of the method and an appropriate default one will be
 543 generated for you, B<or> a HASH ref containing exactly one key (which will be
 544 used as the name of the method) and one value, which should contain a CODE
 545 reference which will be installed as the method itself.
 546
 547 =over 4
 548
 549 =item I<accessor>
 550
 551 The I<accessor> is a standard perl-style read/write accessor. It will
 552 return the value of the attribute, and if a value is passed as an argument,
 553 it will assign that value to the attribute.
 554
 555 B<NOTE:>
 556 This method will properly handle the following code, by assigning an
 557 C<undef> value to the attribute.
 558
 559   $object->set_something(undef);
 560
 561 =item I<reader>
 562
 563 This is a basic read-only accessor, it will just return the value of
 564 the attribute.
 565
 566 =item I<writer>
 567
 568 This is a basic write accessor, it accepts a single argument, and
 569 assigns that value to the attribute. This method does not intentially
 570 return a value, however perl will return the result of the last
 571 expression in the subroutine, which returns in this returning the
 572 same value that it was passed.
 573
 574 B<NOTE:>
 575 This method will properly handle the following code, by assigning an
 576 C<undef> value to the attribute.
 577
 578   $object->set_something();
 579
 580 =item I<predicate>
 581
 582 This is a basic test to see if any value has been set for the
 583 attribute. It will return true (C<1>) if the attribute has been set
 584 to any value (even C<undef>), and false (C<0>) otherwise.
 585
 586 B<NOTE:>
 587 The predicate will return true even when you set an attribute's
 588 value to C<undef>. This behaviour has changed as of version 0.43. In
 589 older versions, the predicate (erroneously) checked for attribute
 590 value definedness, instead of presence as it is now.
 591
 592 If you really want to get rid of the value, you have to define and
 593 use a I<clearer> (see below).
 594
 595 =item I<clearer>
 596
 597 This is the a method that will uninitialize the attr, reverting lazy values
 598 back to their "unfulfilled" state.
 599
 600 =back
 601
 602 =item B<clone (%options)>
 603
 604 This will return a clone of the attribute instance, allowing the overriding
 605 of various attributes through the C<%options> supplied.
 606
 607 =item B<initialize_instance_slot ($instance, $params)>
 608
 609 This method is used internally to initialize the approriate slot for this
 610 attribute in a given C<$instance>, the C<$params> passed are those that were
 611 passed to the constructor.
 612
 613 =back
 614
 615 =head2 Value management
 616
 617 These methods are basically "backdoors" to the instance, which can be used
 618 to bypass the regular accessors, but still stay within the context of the MOP.
 619
 620 These methods are not for general use, and should only be used if you really
 621 know what you are doing.
 622
 623 =over 4
 624
 625 =item B<set_value ($instance, $value)>
 626
 627 Set the value without going through the accessor. Note that this may be done to
 628 even attributes with just read only accessors.
 629
 630 =item B<set_initial_value ($instance, $value)>
 631
 632 This method sets the value without going through the accessor -- but it is only
 633 called when the instance data is first initialized.
 634
 635 =item B<get_value ($instance)>
 636
 637 Return the value without going through the accessor. Note that this may be done
 638 even to attributes with just write only accessors.
 639
 640 =item B<has_value ($instance)>
 641
 642 Return a boolean indicating if the item in the C<$instance> has a value in it.
 643 This is basically what the default C<predicate> method calls.
 644
 645 =item B<clear_value ($instance)>
 646
 647 This will clear the value in the C<$instance>. This is basically what the default
 648 C<clearer> would call. Note that this may be done even if the attirbute does not
 649 have any associated read, write or clear methods.
 650
 651 =back
 652
 653 =head2 Informational
 654
 655 These are all basic read-only value accessors for the values
 656 passed into C<new>. I think they are pretty much self-explanitory.
 657
 658 =over 4
 659
 660 =item B<name>
 661
 662 =item B<accessor>
 663
 664 =item B<reader>
 665
 666 =item B<writer>
 667
 668 =item B<predicate>
 669
 670 =item B<clearer>
 671
 672 =item B<initializer>
 673
 674 =item B<init_arg>
 675
 676 =item B<is_default_a_coderef>
 677
 678 =item B<default (?$instance)>
 679
 680 Return the default value for the attribute.
 681
 682 If you pass in an C<$instance> argument to this accessor and the
 683 I<default> is a CODE reference, then the CODE reference will be
 684 executed with the C<$instance> as its argument.
 685
 686 =item B<slots>
 687
 688 Return a list of slots required by the attribute. This is usually
 689 just one, which is the name of the attribute.
 690
 691 =item B<get_read_method>
 692
 693 =item B<get_write_method>
 694
 695 Return the name of a method name suitable for reading / writing the value
 696 of the attribute in the associated class. Suitable for use whether
 697 C<reader> and C<writer> or C<accessor> was used.
 698
 699 =item B<get_read_method_ref>
 700
 701 =item B<get_write_method_ref>
 702
 703 Return the CODE reference of a method suitable for reading / writing the
 704 value of the attribute in the associated class. Suitable for use whether
 705 C<reader> and C<writer> or C<accessor> was specified or not.
 706
 707 NOTE: If no reader/writer/accessor was specified, this will use the
 708 attribute get_value/set_value methods, which can be very inefficient.
 709
 710 =item B<has_read_method>
 711
 712 =item B<has_write_method>
 713
 714 Return whether a method exists suitable for reading / writing the value
 715 of the attribute in the associated class. Suitable for use whether
 716 C<reader> and C<writer> or C<accessor> was used.
 717
 718 =back
 719
 720 =head2 Informational predicates
 721
 722 These are all basic predicate methods for the values passed into C<new>.
 723
 724 =over 4
 725
 726 =item B<has_accessor>
 727
 728 =item B<has_reader>
 729
 730 =item B<has_writer>
 731
 732 =item B<has_predicate>
 733
 734 =item B<has_clearer>
 735
 736 =item B<has_initializer>
 737
 738 =item B<has_init_arg>
 739
 740 =item B<has_default>
 741
 742 =item B<has_builder>
 743
 744 =back
 745
 746 =head2 Class association
 747
 748 These methods allow you to manage the attributes association with
 749 the class that contains it. These methods should not be used
 750 lightly, nor are they very magical, they are mostly used internally
 751 and by metaclass instances.
 752
 753 =over 4
 754
 755 =item B<associated_class>
 756
 757 This returns the metaclass this attribute is associated with.
 758
 759 =item B<attach_to_class ($class)>
 760
 761 This will store a weaken reference to C<$class> internally. You should
 762 note that just changing the class assocation will not remove the attribute
 763 from it's old class, and initialize it (and it's accessors) in the new
 764 C<$class>. It is up to you to do this manually.
 765
 766 =item B<detach_from_class>
 767
 768 This will remove the weakened reference to the class. It does B<not>
 769 remove the attribute itself from the class (or remove it's accessors),
 770 you must do that yourself if you want too. Actually if that is what
 771 you want to do, you should probably be looking at
 772 L<Class::MOP::Class::remove_attribute> instead.
 773
 774 =back
 775
 776 =head2 Attribute Accessor generation
 777
 778 =over 4
 779
 780 =item B<accessor_metaclass>
 781
 782 Accessors are generated by an accessor metaclass, which is usually
 783 a subclass of C<Class::MOP::Method::Accessor>. This method returns
 784 the name of the accessor metaclass that this attribute uses.
 785
 786 =item B<associate_method ($method)>
 787
 788 This will associate a C<$method> with the given attribute which is
 789 used internally by the accessor generator.
 790
 791 =item B<associated_methods>
 792
 793 This will return the list of methods which have been associated with
 794 the C<associate_method> methods. This is a good way of seeing what
 795 methods are used to manage a given attribute.
 796
 797 =item B<install_accessors>
 798
 799 This allows the attribute to generate and install code for it's own
 800 I<accessor/reader/writer/predicate> methods. This is called by
 801 C<Class::MOP::Class::add_attribute>.
 802
 803 This method will call C<process_accessors> for each of the possible
 804 method types (accessor, reader, writer & predicate).
 805
 806 =item B<process_accessors ($type, $value)>
 807
 808 This takes a C<$type> (accessor, reader, writer or predicate), and
 809 a C<$value> (the value passed into the constructor for each of the
 810 different types). It will then either generate the method itself
 811 (using the C<generate_*_method> methods listed below) or it will
 812 use the custom method passed through the constructor.
 813
 814 =item B<remove_accessors>
 815
 816 This allows the attribute to remove the method for it's own
 817 I<accessor/reader/writer/predicate/clearer>. This is called by
 818 C<Class::MOP::Class::remove_attribute>.
 819
 820 NOTE: This does not currently remove methods from the list returned
 821 by C<associated_methods>, that is on the TODO list.
 822
 823 =back
 824
 825 =head2 Introspection
 826
 827 =over 4
 828
 829 =item B<meta>
 830
 831 This will return a B<Class::MOP::Class> instance which is related
 832 to this class.
 833
 834 It should also be noted that B<Class::MOP> will actually bootstrap
 835 this module by installing a number of attribute meta-objects into
 836 it's metaclass. This will allow this class to reap all the benefits
 837 of the MOP when subclassing it.
 838
 839 =back
 840
 841 =head1 AUTHORS
 842
 843 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 844
 845 =head1 COPYRIGHT AND LICENSE
 846
 847 Copyright 2006-2008 by Infinity Interactive, Inc.
 848
 849 L<http://www.iinteractive.com>
 850
 851 This library is free software; you can redistribute it and/or modify
 852 it under the same terms as Perl itself.
 853
 854 =cut
 855
 856