lib/Class/MOP/Attribute.pm

   1
   2 package Class::MOP::Attribute;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Class::MOP::Method::Accessor;
   8
   9 use Carp         'confess';
  10 use Scalar::Util 'blessed', 'reftype', 'weaken';
  11
  12 our $VERSION   = '0.23';
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 use base 'Class::MOP::Object';
  16
  17 sub meta {
  18     require Class::MOP::Class;
  19     Class::MOP::Class->initialize(blessed($_[0]) || $_[0]);
  20 }
  21
  22 # NOTE: (meta-circularity)
  23 # This method will be replaced in the
  24 # boostrap section of Class::MOP, by
  25 # a new version which uses the
  26 # &Class::MOP::Class::construct_instance
  27 # method to build an attribute meta-object
  28 # which itself is described with attribute
  29 # meta-objects.
  30 #     - Ain't meta-circularity grand? :)
  31 sub new {
  32     my $class   = shift;
  33     my $name    = shift;
  34     my %options = @_;
  35
  36     (defined $name && $name)
  37         || confess "You must provide a name for the attribute";
  38
  39     $options{init_arg} = $name
  40         if not exists $options{init_arg};
  41     if(exists $options{builder}){
  42         confess("builder must be a defined scalar value which is a method name")
  43             if ref $options{builder} || !(defined $options{builder});
  44         confess("Setting both default and builder is not allowed.")
  45             if exists $options{default};
  46     } else {
  47         (is_default_a_coderef(\%options))
  48             || confess("References are not allowed as default values, you must ".
  49                        "wrap then in a CODE reference (ex: sub { [] } and not [])")
  50                 if exists $options{default} && ref $options{default};
  51     }
  52     if( $options{required} and not( defined($options{builder}) || defined($options{init_arg}) || exists $options{default} ) ) {
  53         confess("A required attribute must have either 'init_arg', 'builder', or 'default'");
  54     }
  55     bless {
  56         '$!name'      => $name,
  57         '$!accessor'  => $options{accessor},
  58         '$!reader'    => $options{reader},
  59         # NOTE:
  60         # protect this from silliness
  61         init_arg => '!............( DO NOT DO THIS )............!',
  62         '$!writer'    => $options{writer},
  63         '$!predicate' => $options{predicate},
  64         '$!clearer'   => $options{clearer},
  65         '$!builder'   => $options{builder},
  66         '$!init_arg'  => $options{init_arg},
  67         '$!default'   => $options{default},
  68         # keep a weakened link to the
  69         # class we are associated with
  70         '$!associated_class' => undef,
  71         '$!initializer'      => $options{initializer},
  72         # and a list of the methods
  73         # associated with this attr
  74         '@!associated_methods' => [],
  75     } => $class;
  76 }
  77
  78 # NOTE:
  79 # this is a primative (and kludgy) clone operation
  80 # for now, it will be replaced in the Class::MOP
  81 # bootstrap with a proper one, however we know
  82 # that this one will work fine for now.
  83 sub clone {
  84     my $self    = shift;
  85     my %options = @_;
  86     (blessed($self))
  87         || confess "Can only clone an instance";
  88     return bless { %{$self}, %options } => blessed($self);
  89 }
  90
  91 sub initialize_instance_slot {
  92     my ($self, $meta_instance, $instance, $params) = @_;
  93     my $init_arg = $self->{'$!init_arg'};
  94     # try to fetch the init arg from the %params ...
  95
  96     # if nothing was in the %params, we can use the
  97     # attribute's default value (if it has one)
  98     if(defined $init_arg and exists $params->{$init_arg}){
  99         $meta_instance->_set_initial_slot_value(
 100             $instance,
 101             $self->name,
 102             $params->{$init_arg},
 103             $self->initializer,
 104         );
 105     }
 106     elsif (defined $self->{'$!default'}) {
 107         $meta_instance->_set_initial_slot_value(
 108             $instance,
 109             $self->name,
 110             $self->default($instance),
 111             $self->initializer,
 112         );
 113     }
 114     elsif (defined( my $builder = $self->{'$!builder'})) {
 115         if ($builder = $instance->can($builder)) {
 116             $meta_instance->_set_initial_slot_value(
 117                 $instance,
 118                 $self->name,
 119                 $instance->$builder,
 120                 $self->initializer,
 121             );
 122         }
 123         else {
 124             confess(blessed($instance)." does not support builder method '". $self->{'$!builder'} ."' for attribute '" . $self->name . "'");
 125         }
 126     }
 127 }
 128
 129 # NOTE:
 130 # the next bunch of methods will get bootstrapped
 131 # away in the Class::MOP bootstrapping section
 132
 133 sub name { $_[0]->{'$!name'} }
 134
 135 sub associated_class   { $_[0]->{'$!associated_class'}   }
 136 sub associated_methods { $_[0]->{'@!associated_methods'} }
 137
 138 sub has_accessor  { defined($_[0]->{'$!accessor'})  ? 1 : 0 }
 139 sub has_reader    { defined($_[0]->{'$!reader'})    ? 1 : 0 }
 140 sub has_writer    { defined($_[0]->{'$!writer'})    ? 1 : 0 }
 141 sub has_predicate { defined($_[0]->{'$!predicate'}) ? 1 : 0 }
 142 sub has_clearer   { defined($_[0]->{'$!clearer'})   ? 1 : 0 }
 143 sub has_builder   { defined($_[0]->{'$!builder'})   ? 1 : 0 }
 144 sub has_init_arg  { defined($_[0]->{'$!init_arg'})  ? 1 : 0 }
 145 sub has_default   { defined($_[0]->{'$!default'})   ? 1 : 0 }
 146 sub has_initializer { defined($_[0]->{'$!initializer'})  ? 1 : 0 }
 147
 148 sub accessor  { $_[0]->{'$!accessor'}  }
 149 sub reader    { $_[0]->{'$!reader'}    }
 150 sub writer    { $_[0]->{'$!writer'}    }
 151 sub predicate { $_[0]->{'$!predicate'} }
 152 sub clearer   { $_[0]->{'$!clearer'}   }
 153 sub builder   { $_[0]->{'$!builder'}   }
 154 sub init_arg  { $_[0]->{'$!init_arg'}  }
 155 sub initializer { $_[0]->{'$!initializer'} }
 156
 157 # end bootstrapped away method section.
 158 # (all methods below here are kept intact)
 159
 160 sub get_read_method  {
 161     my $self   = shift;
 162     my $reader = $self->reader || $self->accessor;
 163     # normal case ...
 164     return $reader unless ref $reader;
 165     # the HASH ref case
 166     my ($name) = %$reader;
 167     return $name;
 168 }
 169
 170 sub get_write_method {
 171     my $self   = shift;
 172     my $writer = $self->writer || $self->accessor;
 173     # normal case ...
 174     return $writer unless ref $writer;
 175     # the HASH ref case
 176     my ($name) = %$writer;
 177     return $name;
 178 }
 179
 180 sub get_read_method_ref {
 181     my $self = shift;
 182     if ((my $reader = $self->get_read_method) && $self->associated_class) {
 183         return $self->associated_class->get_method($reader);
 184     }
 185     else {
 186         return sub { $self->get_value(@_) };
 187     }
 188 }
 189
 190 sub get_write_method_ref {
 191     my $self = shift;
 192     if ((my $writer = $self->get_write_method) && $self->associated_class) {
 193         return $self->associated_class->get_method($writer);
 194     }
 195     else {
 196         return sub { $self->set_value(@_) };
 197     }
 198 }
 199
 200 sub is_default_a_coderef {
 201     ('CODE' eq (reftype($_[0]->{'$!default'} || $_[0]->{default}) || ''))
 202 }
 203
 204 sub default {
 205     my ($self, $instance) = @_;
 206     if (defined $instance && $self->is_default_a_coderef) {
 207         # if the default is a CODE ref, then
 208         # we pass in the instance and default
 209         # can return a value based on that
 210         # instance. Somewhat crude, but works.
 211         return $self->{'$!default'}->($instance);
 212     }
 213     $self->{'$!default'};
 214 }
 215
 216 # slots
 217
 218 sub slots { (shift)->name }
 219
 220 # class association
 221
 222 sub attach_to_class {
 223     my ($self, $class) = @_;
 224     (blessed($class) && $class->isa('Class::MOP::Class'))
 225         || confess "You must pass a Class::MOP::Class instance (or a subclass)";
 226     weaken($self->{'$!associated_class'} = $class);
 227 }
 228
 229 sub detach_from_class {
 230     my $self = shift;
 231     $self->{'$!associated_class'} = undef;
 232 }
 233
 234 # method association
 235
 236 sub associate_method {
 237     my ($self, $method) = @_;
 238     push @{$self->{'@!associated_methods'}} => $method;
 239 }
 240
 241 ## Slot management
 242
 243 sub set_value {
 244     my ($self, $instance, $value) = @_;
 245
 246     Class::MOP::Class->initialize(blessed($instance))
 247                      ->get_meta_instance
 248                      ->set_slot_value($instance, $self->name, $value);
 249 }
 250
 251 sub get_value {
 252     my ($self, $instance) = @_;
 253
 254     Class::MOP::Class->initialize(blessed($instance))
 255                      ->get_meta_instance
 256                      ->get_slot_value($instance, $self->name);
 257 }
 258
 259 sub has_value {
 260     my ($self, $instance) = @_;
 261
 262     Class::MOP::Class->initialize(blessed($instance))
 263                      ->get_meta_instance
 264                      ->is_slot_initialized($instance, $self->name);
 265 }
 266
 267 sub clear_value {
 268     my ($self, $instance) = @_;
 269
 270     Class::MOP::Class->initialize(blessed($instance))
 271                      ->get_meta_instance
 272                      ->deinitialize_slot($instance, $self->name);
 273 }
 274
 275 ## load em up ...
 276
 277 sub accessor_metaclass { 'Class::MOP::Method::Accessor' }
 278
 279 sub process_accessors {
 280     my ($self, $type, $accessor, $generate_as_inline_methods) = @_;
 281     if (reftype($accessor)) {
 282         (reftype($accessor) eq 'HASH')
 283             || confess "bad accessor/reader/writer/predicate/clearer format, must be a HASH ref";
 284         my ($name, $method) = %{$accessor};
 285         $method = $self->accessor_metaclass->wrap($method);
 286         $self->associate_method($method);
 287         return ($name, $method);
 288     }
 289     else {
 290         my $inline_me = ($generate_as_inline_methods && $self->associated_class->instance_metaclass->is_inlinable);
 291         my $method;
 292         eval {
 293             $method = $self->accessor_metaclass->new(
 294                 attribute     => $self,
 295                 is_inline     => $inline_me,
 296                 accessor_type => $type,
 297             );
 298         };
 299         confess "Could not create the '$type' method for " . $self->name . " because : $@" if $@;
 300         $self->associate_method($method);
 301         return ($accessor, $method);
 302     }
 303 }
 304
 305 sub install_accessors {
 306     my $self   = shift;
 307     my $inline = shift;
 308     my $class  = $self->associated_class;
 309
 310     $class->add_method(
 311         $self->process_accessors('accessor' => $self->accessor(), $inline)
 312     ) if $self->has_accessor();
 313
 314     $class->add_method(
 315         $self->process_accessors('reader' => $self->reader(), $inline)
 316     ) if $self->has_reader();
 317
 318     $class->add_method(
 319         $self->process_accessors('writer' => $self->writer(), $inline)
 320     ) if $self->has_writer();
 321
 322     $class->add_method(
 323         $self->process_accessors('predicate' => $self->predicate(), $inline)
 324     ) if $self->has_predicate();
 325
 326     $class->add_method(
 327         $self->process_accessors('clearer' => $self->clearer(), $inline)
 328     ) if $self->has_clearer();
 329
 330     return;
 331 }
 332
 333 {
 334     my $_remove_accessor = sub {
 335         my ($accessor, $class) = @_;
 336         if (reftype($accessor) && reftype($accessor) eq 'HASH') {
 337             ($accessor) = keys %{$accessor};
 338         }
 339         my $method = $class->get_method($accessor);
 340         $class->remove_method($accessor)
 341             if (blessed($method) && $method->isa('Class::MOP::Method::Accessor'));
 342     };
 343
 344     sub remove_accessors {
 345         my $self = shift;
 346         # TODO:
 347         # we really need to make sure to remove from the
 348         # associates methods here as well. But this is
 349         # such a slimly used method, I am not worried
 350         # about it right now.
 351         $_remove_accessor->($self->accessor(),  $self->associated_class()) if $self->has_accessor();
 352         $_remove_accessor->($self->reader(),    $self->associated_class()) if $self->has_reader();
 353         $_remove_accessor->($self->writer(),    $self->associated_class()) if $self->has_writer();
 354         $_remove_accessor->($self->predicate(), $self->associated_class()) if $self->has_predicate();
 355         $_remove_accessor->($self->clearer(),   $self->associated_class()) if $self->has_clearer();
 356         return;
 357     }
 358
 359 }
 360
 361 1;
 362
 363 __END__
 364
 365 =pod
 366
 367 =head1 NAME
 368
 369 Class::MOP::Attribute - Attribute Meta Object
 370
 371 =head1 SYNOPSIS
 372
 373   Class::MOP::Attribute->new('$foo' => (
 374       accessor  => 'foo',        # dual purpose get/set accessor
 375       predicate => 'has_foo'     # predicate check for defined-ness
 376       init_arg  => '-foo',       # class->new will look for a -foo key
 377       default   => 'BAR IS BAZ!' # if no -foo key is provided, use this
 378   ));
 379
 380   Class::MOP::Attribute->new('$.bar' => (
 381       reader    => 'bar',        # getter
 382       writer    => 'set_bar',    # setter
 383       predicate => 'has_bar'     # predicate check for defined-ness
 384       init_arg  => ':bar',       # class->new will look for a :bar key
 385       # no default value means it is undef
 386   ));
 387
 388 =head1 DESCRIPTION
 389
 390 The Attribute Protocol is almost entirely an invention of this module,
 391 and is completely optional to this MOP. This is because Perl 5 does not
 392 have consistent notion of what is an attribute of a class. There are
 393 so many ways in which this is done, and very few (if any) are
 394 easily discoverable by this module.
 395
 396 So, all that said, this module attempts to inject some order into this
 397 chaos, by introducing a consistent API which can be used to create
 398 object attributes.
 399
 400 =head1 METHODS
 401
 402 =head2 Creation
 403
 404 =over 4
 405
 406 =item B<new ($name, ?%options)>
 407
 408 An attribute must (at the very least), have a C<$name>. All other
 409 C<%options> are contained added as key-value pairs. Acceptable keys
 410 are as follows:
 411
 412 =over 4
 413
 414 =item I<init_arg>
 415
 416 This should be a string value representing the expected key in
 417 an initialization hash. For instance, if we have an I<init_arg>
 418 value of C<-foo>, then the following code will Just Work.
 419
 420   MyClass->meta->construct_instance(-foo => "Hello There");
 421
 422 In an init_arg is not assigned, it will automatically use the
 423 value of C<$name>.
 424
 425 =item I<builder>
 426
 427 The value of this key is the name of the method that will be
 428 called to obtain the value used to initialize the attribute.
 429 This should be a method in the class associated with the attribute,
 430 not a method in the attribute class itself.
 431
 432 =item I<default>
 433
 434 The value of this key is the default value which
 435 C<Class::MOP::Class::construct_instance> will initialize the
 436 attribute to.
 437
 438 B<NOTE:>
 439 If the value is a simple scalar (string or number), then it can
 440 be just passed as is. However, if you wish to initialize it with
 441 a HASH or ARRAY ref, then you need to wrap that inside a CODE
 442 reference, like so:
 443
 444   Class::MOP::Attribute->new('@foo' => (
 445       default => sub { [] },
 446   ));
 447
 448   # or ...
 449
 450   Class::MOP::Attribute->new('%foo' => (
 451       default => sub { {} },
 452   ));
 453
 454 If you wish to initialize an attribute with a CODE reference
 455 itself, then you need to wrap that in a subroutine as well, like
 456 so:
 457
 458   Class::MOP::Attribute->new('&foo' => (
 459       default => sub { sub { print "Hello World" } },
 460   ));
 461
 462 And lastly, if the value of your attribute is dependent upon
 463 some other aspect of the instance structure, then you can take
 464 advantage of the fact that when the I<default> value is a CODE
 465 reference, it is passed the raw (unblessed) instance structure
 466 as it's only argument. So you can do things like this:
 467
 468   Class::MOP::Attribute->new('$object_identity' => (
 469       default => sub { Scalar::Util::refaddr($_[0]) },
 470   ));
 471
 472 This last feature is fairly limited as there is no gurantee of
 473 the order of attribute initializations, so you cannot perform
 474 any kind of dependent initializations. However, if this is
 475 something you need, you could subclass B<Class::MOP::Class> and
 476 this class to acheive it. However, this is currently left as
 477 an exercise to the reader :).
 478
 479 =back
 480
 481 The I<accessor>, I<reader>, I<writer>, I<predicate> and I<clearer> keys can
 482 contain either; the name of the method and an appropriate default one will be
 483 generated for you, B<or> a HASH ref containing exactly one key (which will be
 484 used as the name of the method) and one value, which should contain a CODE
 485 reference which will be installed as the method itself.
 486
 487 =over 4
 488
 489 =item I<accessor>
 490
 491 The I<accessor> is a standard perl-style read/write accessor. It will
 492 return the value of the attribute, and if a value is passed as an argument,
 493 it will assign that value to the attribute.
 494
 495 B<NOTE:>
 496 This method will properly handle the following code, by assigning an
 497 C<undef> value to the attribute.
 498
 499   $object->set_something(undef);
 500
 501 =item I<reader>
 502
 503 This is a basic read-only accessor, it will just return the value of
 504 the attribute.
 505
 506 =item I<writer>
 507
 508 This is a basic write accessor, it accepts a single argument, and
 509 assigns that value to the attribute. This method does not intentially
 510 return a value, however perl will return the result of the last
 511 expression in the subroutine, which returns in this returning the
 512 same value that it was passed.
 513
 514 B<NOTE:>
 515 This method will properly handle the following code, by assigning an
 516 C<undef> value to the attribute.
 517
 518   $object->set_something();
 519
 520 =item I<predicate>
 521
 522 This is a basic test to see if any value has been set for the
 523 attribute. It will return true (C<1>) if the attribute has been set
 524 to any value (even C<undef>), and false (C<0>) otherwise.
 525
 526 B<NOTE:>
 527 The predicate will return true even when you set an attribute's
 528 value to C<undef>. This behaviour has changed as of version 0.43. In
 529 older versions, the predicate (erroneously) checked for attribute
 530 value definedness, instead of presence as it is now.
 531
 532 If you really want to get rid of the value, you have to define and
 533 use a I<clearer> (see below).
 534
 535
 536 =item I<clearer>
 537
 538 This is the a method that will uninitialize the attr, reverting lazy values
 539 back to their "unfulfilled" state.
 540
 541 =back
 542
 543 =item B<clone (%options)>
 544
 545 =item B<initialize_instance_slot ($instance, $params)>
 546
 547 =back
 548
 549 =head2 Value management
 550
 551 These methods are basically "backdoors" to the instance, which can be used
 552 to bypass the regular accessors, but still stay within the context of the MOP.
 553
 554 These methods are not for general use, and should only be used if you really
 555 know what you are doing.
 556
 557 =over 4
 558
 559 =item B<set_value ($instance, $value)>
 560
 561 Set the value without going through the accessor. Note that this may be done to
 562 even attributes with just read only accessors.
 563
 564 =item B<get_value ($instance)>
 565
 566 Return the value without going through the accessor. Note that this may be done
 567 even to attributes with just write only accessors.
 568
 569 =item B<has_value ($instance)>
 570
 571 Return a boolean indicating if the item in the C<$instance> has a value in it.
 572 This is basically what the default C<predicate> method calls.
 573
 574 =item B<clear_value ($instance)>
 575
 576 This will clear the value in the C<$instance>. This is basically what the default
 577 C<clearer> would call. Note that this may be done even if the attirbute does not
 578 have any associated read, write or clear methods.
 579
 580 =back
 581
 582 =head2 Informational
 583
 584 These are all basic read-only value accessors for the values
 585 passed into C<new>. I think they are pretty much self-explanitory.
 586
 587 =over 4
 588
 589 =item B<name>
 590
 591 =item B<accessor>
 592
 593 =item B<reader>
 594
 595 =item B<writer>
 596
 597 =item B<predicate>
 598
 599 =item B<clearer>
 600
 601 =item B<initializer>
 602
 603 =item B<init_arg>
 604
 605 =item B<is_default_a_coderef>
 606
 607 =item B<default (?$instance)>
 608
 609 Return the default value for the attribute.
 610
 611 If you pass in an C<$instance> argument to this accessor and the
 612 I<default> is a CODE reference, then the CODE reference will be
 613 executed with the C<$instance> as its argument.
 614
 615 =item B<slots>
 616
 617 Return a list of slots required by the attribute. This is usually
 618 just one, which is the name of the attribute.
 619
 620 =item B<get_read_method>
 621
 622 =item B<get_write_method>
 623
 624 Return the name of a method name suitable for reading / writing the value
 625 of the attribute in the associated class. Suitable for use whether
 626 C<reader> and C<writer> or C<accessor> was used.
 627
 628 =item B<get_read_method_ref>
 629
 630 =item B<get_write_method_ref>
 631
 632 Return the CODE reference of a method suitable for reading / writing the
 633 value of the attribute in the associated class. Suitable for use whether
 634 C<reader> and C<writer> or C<accessor> was specified or not.
 635
 636 NOTE: If not reader/writer/accessor was specified, this will use the
 637 attribute get_value/set_value methods, which can be very inefficient.
 638
 639 =back
 640
 641 =head2 Informational predicates
 642
 643 These are all basic predicate methods for the values passed into C<new>.
 644
 645 =over 4
 646
 647 =item B<has_accessor>
 648
 649 =item B<has_reader>
 650
 651 =item B<has_writer>
 652
 653 =item B<has_predicate>
 654
 655 =item B<has_clearer>
 656
 657 =item B<has_initializer>
 658
 659 =item B<has_init_arg>
 660
 661 =item B<has_default>
 662
 663 =item B<has_builder>
 664
 665 =back
 666
 667 =head2 Class association
 668
 669 These methods allow you to manage the attributes association with
 670 the class that contains it. These methods should not be used
 671 lightly, nor are they very magical, they are mostly used internally
 672 and by metaclass instances.
 673
 674 =over 4
 675
 676 =item B<associated_class>
 677
 678 This returns the metaclass this attribute is associated with.
 679
 680 =item B<attach_to_class ($class)>
 681
 682 This will store a weaken reference to C<$class> internally. You should
 683 note that just changing the class assocation will not remove the attribute
 684 from it's old class, and initialize it (and it's accessors) in the new
 685 C<$class>. It is up to you to do this manually.
 686
 687 =item B<detach_from_class>
 688
 689 This will remove the weakened reference to the class. It does B<not>
 690 remove the attribute itself from the class (or remove it's accessors),
 691 you must do that yourself if you want too. Actually if that is what
 692 you want to do, you should probably be looking at
 693 L<Class::MOP::Class::remove_attribute> instead.
 694
 695 =back
 696
 697 =head2 Attribute Accessor generation
 698
 699 =over 4
 700
 701 =item B<accessor_metaclass>
 702
 703 Accessors are generated by an accessor metaclass, which is usually
 704 a subclass of C<Class::MOP::Method::Accessor>. This method returns
 705 the name of the accessor metaclass that this attribute uses.
 706
 707 =item B<associate_method ($method)>
 708
 709 This will associate a C<$method> with the given attribute which is
 710 used internally by the accessor generator.
 711
 712 =item B<associated_methods>
 713
 714 This will return the list of methods which have been associated with
 715 the C<associate_method> methods.
 716
 717 =item B<install_accessors>
 718
 719 This allows the attribute to generate and install code for it's own
 720 I<accessor/reader/writer/predicate> methods. This is called by
 721 C<Class::MOP::Class::add_attribute>.
 722
 723 This method will call C<process_accessors> for each of the possible
 724 method types (accessor, reader, writer & predicate).
 725
 726 =item B<process_accessors ($type, $value)>
 727
 728 This takes a C<$type> (accessor, reader, writer or predicate), and
 729 a C<$value> (the value passed into the constructor for each of the
 730 different types). It will then either generate the method itself
 731 (using the C<generate_*_method> methods listed below) or it will
 732 use the custom method passed through the constructor.
 733
 734 =item B<remove_accessors>
 735
 736 This allows the attribute to remove the method for it's own
 737 I<accessor/reader/writer/predicate/clearer>. This is called by
 738 C<Class::MOP::Class::remove_attribute>.
 739
 740 NOTE: This does not currently remove methods from the list returned
 741 by C<associated_methods>, that is on the TODO list.
 742
 743 =back
 744
 745 =head2 Introspection
 746
 747 =over 4
 748
 749 =item B<meta>
 750
 751 This will return a B<Class::MOP::Class> instance which is related
 752 to this class.
 753
 754 It should also be noted that B<Class::MOP> will actually bootstrap
 755 this module by installing a number of attribute meta-objects into
 756 it's metaclass. This will allow this class to reap all the benifits
 757 of the MOP when subclassing it.
 758
 759 =back
 760
 761 =head1 AUTHORS
 762
 763 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 764
 765 =head1 COPYRIGHT AND LICENSE
 766
 767 Copyright 2006-2008 by Infinity Interactive, Inc.
 768
 769 L<http://www.iinteractive.com>
 770
 771 This library is free software; you can redistribute it and/or modify
 772 it under the same terms as Perl itself.
 773
 774 =cut
 775
 776