lib/Class/Accessor/Grouped.pm

   1 package Class::Accessor::Grouped;
   2 use strict;
   3 use warnings;
   4 use Carp ();
   5 use Scalar::Util ();
   6 use Module::Runtime ();
   7
   8 BEGIN {
   9   # use M::R to work around the 5.8 require bugs
  10   if ($] < 5.009_005) {
  11     Module::Runtime::require_module('MRO::Compat');
  12   }
  13   else {
  14     require mro;
  15   }
  16 }
  17
  18 our $VERSION = '0.10006';
  19 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
  20
  21 # when changing minimum version don't forget to adjust Makefile.PL as well
  22 our $__minimum_xsa_version;
  23 BEGIN { $__minimum_xsa_version = '1.13' }
  24
  25 our $USE_XS;
  26 # the unless defined is here so that we can override the value
  27 # before require/use, *regardless* of the state of $ENV{CAG_USE_XS}
  28 $USE_XS = $ENV{CAG_USE_XS}
  29   unless defined $USE_XS;
  30
  31 BEGIN {
  32   package __CAG_ENV__;
  33
  34   die "Huh?! No minimum C::XSA version?!\n"
  35     unless $__minimum_xsa_version;
  36
  37   local $@;
  38   require constant;
  39
  40   # individual (one const at a time) imports so we are 5.6.2 compatible
  41   # if we can - why not ;)
  42   constant->import( NO_SUBNAME => eval {
  43     Module::Runtime::require_module('Sub::Name')
  44   } ? 0 : "$@" );
  45
  46   constant->import( NO_CXSA => ( !NO_SUBNAME() and eval {
  47     Module::Runtime::use_module('Class::XSAccessor' => $__minimum_xsa_version)
  48   } ) ? 0 : "$@" );
  49
  50   constant->import( BROKEN_GOTO => ($] < '5.008009') ? 1 : 0 );
  51
  52   constant->import( UNSTABLE_DOLLARAT => ($] < '5.013002') ? 1 : 0 );
  53
  54   constant->import( TRACK_UNDEFER_FAIL => (
  55     $INC{'Test/Builder.pm'} || $INC{'Test/Builder2.pm'}
  56       and
  57     $0 =~ m|^ x?t / .+ \.t $|x
  58   ) ? 1 : 0 );
  59 }
  60
  61 # Yes this method is undocumented
  62 # Yes it should be a private coderef like all the rest at the end of this file
  63 # No we can't do that (yet) because the DBIC-CDBI compat layer overrides it
  64 # %$*@!?&!&#*$!!!
  65 sub _mk_group_accessors {
  66   my($self, $maker, $group, @fields) = @_;
  67   my $class = Scalar::Util::blessed $self || $self;
  68
  69   no strict 'refs';
  70   no warnings 'redefine';
  71
  72   # So we don't have to do lots of lookups inside the loop.
  73   $maker = $self->can($maker) unless ref $maker;
  74
  75   for (@fields) {
  76
  77     my ($name, $field) = (ref $_) ? (@$_) : ($_, $_);
  78
  79     for (qw/DESTROY AUTOLOAD CLONE/) {
  80       Carp::carp("Having a data accessor named '$name' in '$class' is unwise.")
  81         if $name eq $_;
  82     }
  83
  84     my $alias = "_${name}_accessor";
  85
  86     for my $meth ($name, $alias) {
  87
  88       # the maker may elect to not return anything, meaning it already
  89       # installed the coderef for us (e.g. lack of Sub::Name)
  90       my $cref = $self->$maker($group, $field, $meth)
  91         or next;
  92
  93       my $fq_meth = "${class}::${meth}";
  94
  95       *$fq_meth = Sub::Name::subname($fq_meth, $cref);
  96         #unless defined &{$class."\:\:$field"}
  97     }
  98   }
  99 };
 100
 101 # coderef is setup at the end for clarity
 102 my $gen_accessor;
 103
 104 =head1 NAME
 105
 106 Class::Accessor::Grouped - Lets you build groups of accessors
 107
 108 =head1 SYNOPSIS
 109
 110  use base 'Class::Accessor::Grouped';
 111
 112  # make basic accessors for objects
 113  __PACKAGE__->mk_group_accessors(simple => qw(id name email));
 114
 115  # make accessor that works for objects and classes
 116  __PACKAGE__->mk_group_accessors(inherited => 'awesome_level');
 117
 118 =head1 DESCRIPTION
 119
 120 This class lets you build groups of accessors that will call different
 121 getters and setters.
 122
 123 =head1 METHODS
 124
 125 =head2 mk_group_accessors
 126
 127  __PACKAGE__->mk_group_accessors(simple => 'hair_length', [ hair_color => 'hc' ]);
 128
 129 =over 4
 130
 131 =item Arguments: $group, @fieldspec
 132
 133 Returns: none
 134
 135 =back
 136
 137 Creates a set of accessors in a given group.
 138
 139 $group is the name of the accessor group for the generated accessors; they
 140 will call get_$group($field) on get and set_$group($field, $value) on set.
 141
 142 If you want to mimic Class::Accessor's mk_accessors $group has to be 'simple'
 143 to tell Class::Accessor::Grouped to use its own get_simple and set_simple
 144 methods.
 145
 146 @fieldspec is a list of field/accessor names; if a fieldspec is a scalar
 147 this is used as both field and accessor name, if a listref it is expected to
 148 be of the form [ $accessor, $field ].
 149
 150 =cut
 151
 152 sub mk_group_accessors {
 153   my ($self, $group, @fields) = @_;
 154
 155   $self->_mk_group_accessors('make_group_accessor', $group, @fields);
 156   return;
 157 }
 158
 159 =head2 mk_group_ro_accessors
 160
 161  __PACKAGE__->mk_group_ro_accessors(simple => 'birthdate', [ social_security_number => 'ssn' ]);
 162
 163 =over 4
 164
 165 =item Arguments: $group, @fieldspec
 166
 167 Returns: none
 168
 169 =back
 170
 171 Creates a set of read only accessors in a given group. Identical to
 172 L</mk_group_accessors> but accessors will throw an error if passed a value
 173 rather than setting the value.
 174
 175 =cut
 176
 177 sub mk_group_ro_accessors {
 178   my($self, $group, @fields) = @_;
 179
 180   $self->_mk_group_accessors('make_group_ro_accessor', $group, @fields);
 181   return;
 182 }
 183
 184 =head2 mk_group_wo_accessors
 185
 186  __PACKAGE__->mk_group_wo_accessors(simple => 'lie', [ subject => 'subj' ]);
 187
 188 =over 4
 189
 190 =item Arguments: $group, @fieldspec
 191
 192 Returns: none
 193
 194 =back
 195
 196 Creates a set of write only accessors in a given group. Identical to
 197 L</mk_group_accessors> but accessors will throw an error if not passed a
 198 value rather than getting the value.
 199
 200 =cut
 201
 202 sub mk_group_wo_accessors {
 203   my($self, $group, @fields) = @_;
 204
 205   $self->_mk_group_accessors('make_group_wo_accessor', $group, @fields);
 206   return;
 207 }
 208
 209 =head2 get_simple
 210
 211 =over 4
 212
 213 =item Arguments: $field
 214
 215 Returns: $value
 216
 217 =back
 218
 219 Simple getter for hash-based objects which returns the value for the field
 220 name passed as an argument.
 221
 222 =cut
 223
 224 sub get_simple {
 225   return $_[0]->{$_[1]};
 226 }
 227
 228 =head2 set_simple
 229
 230 =over 4
 231
 232 =item Arguments: $field, $new_value
 233
 234 Returns: $new_value
 235
 236 =back
 237
 238 Simple setter for hash-based objects which sets and then returns the value
 239 for the field name passed as an argument.
 240
 241 =cut
 242
 243 sub set_simple {
 244   return $_[0]->{$_[1]} = $_[2];
 245 }
 246
 247
 248 =head2 get_inherited
 249
 250 =over 4
 251
 252 =item Arguments: $field
 253
 254 Returns: $value
 255
 256 =back
 257
 258 Simple getter for Classes and hash-based objects which returns the value for
 259 the field name passed as an argument. This behaves much like
 260 L<Class::Data::Accessor> where the field can be set in a base class,
 261 inherited and changed in subclasses, and inherited and changed for object
 262 instances.
 263
 264 =cut
 265
 266 sub get_inherited {
 267   my $class;
 268
 269   if ( defined( $class = Scalar::Util::blessed $_[0] ) ) {
 270     if (Scalar::Util::reftype $_[0] eq 'HASH') {
 271       return $_[0]->{$_[1]} if exists $_[0]->{$_[1]};
 272     }
 273     else {
 274       Carp::croak('Cannot get inherited value on an object instance that is not hash-based');
 275     }
 276   }
 277   else {
 278     $class = $_[0];
 279   }
 280
 281   no strict 'refs';
 282   no warnings 'uninitialized';
 283
 284   my $cag_slot = '::__cag_'. $_[1];
 285   return ${$class.$cag_slot} if defined(${$class.$cag_slot});
 286
 287   do { return ${$_.$cag_slot} if defined(${$_.$cag_slot}) }
 288     for $_[0]->get_super_paths;
 289
 290   return undef;
 291 }
 292
 293 =head2 set_inherited
 294
 295 =over 4
 296
 297 =item Arguments: $field, $new_value
 298
 299 Returns: $new_value
 300
 301 =back
 302
 303 Simple setter for Classes and hash-based objects which sets and then returns
 304 the value for the field name passed as an argument. When called on a hash-based
 305 object it will set the appropriate hash key value. When called on a class, it
 306 will set a class level variable.
 307
 308 B<Note:>: This method will die if you try to set an object variable on a non
 309 hash-based object.
 310
 311 =cut
 312
 313 sub set_inherited {
 314   if (defined Scalar::Util::blessed $_[0]) {
 315     if (Scalar::Util::reftype $_[0] eq 'HASH') {
 316       return $_[0]->{$_[1]} = $_[2];
 317     } else {
 318       Carp::croak('Cannot set inherited value on an object instance that is not hash-based');
 319     };
 320   } else {
 321     no strict 'refs';
 322
 323     return ${$_[0].'::__cag_'.$_[1]} = $_[2];
 324   };
 325 }
 326
 327 =head2 get_component_class
 328
 329 =over 4
 330
 331 =item Arguments: $field
 332
 333 Returns: $value
 334
 335 =back
 336
 337 Gets the value of the specified component class.
 338
 339  __PACKAGE__->mk_group_accessors('component_class' => 'result_class');
 340
 341  $self->result_class->method();
 342
 343  ## same as
 344  $self->get_component_class('result_class')->method();
 345
 346 =cut
 347
 348 sub get_component_class {
 349   return $_[0]->get_inherited($_[1]);
 350 };
 351
 352 =head2 set_component_class
 353
 354 =over 4
 355
 356 =item Arguments: $field, $class
 357
 358 Returns: $new_value
 359
 360 =back
 361
 362 Inherited accessor that automatically loads the specified class before setting
 363 it. This method will die if the specified class could not be loaded.
 364
 365  __PACKAGE__->mk_group_accessors('component_class' => 'result_class');
 366  __PACKAGE__->result_class('MyClass');
 367
 368  $self->result_class->method();
 369
 370 =cut
 371
 372 sub set_component_class {
 373   if (defined $_[2] and length $_[2]) {
 374     # disable warnings, and prevent $_ being eaten away by a behind-the-scenes
 375     # module loading
 376     local ($^W, $_);
 377
 378     if (__CAG_ENV__::UNSTABLE_DOLLARAT) {
 379       my $err;
 380       {
 381         local $@;
 382         eval { Module::Runtime::use_package_optimistically($_[2]) }
 383           or $err = $@;
 384       }
 385       Carp::croak("Could not load $_[1] '$_[2]': $err") if defined $err;
 386
 387     }
 388     else {
 389       eval { Module::Runtime::use_package_optimistically($_[2]) }
 390         or Carp::croak("Could not load $_[1] '$_[2]': $@");
 391     }
 392   };
 393
 394   return $_[0]->set_inherited($_[1], $_[2]);
 395 };
 396
 397 =head1 INTERNAL METHODS
 398
 399 These methods are documented for clarity, but are never meant to be called
 400 directly, and are not really meant for overriding either.
 401
 402 =head2 get_super_paths
 403
 404 Returns a list of 'parent' or 'super' class names that the current class
 405 inherited from. This is what drives the traversal done by L</get_inherited>.
 406
 407 =cut
 408
 409 sub get_super_paths {
 410   # get_linear_isa returns the class itself as the 1st element
 411   # use @_ as a pre-allocated scratch array
 412   (undef, @_) = @{mro::get_linear_isa( length( ref($_[0]) ) ? ref($_[0]) : $_[0] )};
 413   @_;
 414 };
 415
 416 =head2 make_group_accessor
 417
 418  __PACKAGE__->make_group_accessor('simple', 'hair_length', 'hair_length');
 419  __PACKAGE__->make_group_accessor('simple', 'hc', 'hair_color');
 420
 421 =over 4
 422
 423 =item Arguments: $group, $field, $accessor
 424
 425 Returns: \&accessor_coderef ?
 426
 427 =back
 428
 429 Called by mk_group_accessors for each entry in @fieldspec. Either returns
 430 a coderef which will be installed at C<&__PACKAGE__::$accessor>, or returns
 431 C<undef> if it elects to install the coderef on its own.
 432
 433 =cut
 434
 435 sub make_group_accessor { $gen_accessor->('rw', @_) }
 436
 437 =head2 make_group_ro_accessor
 438
 439  __PACKAGE__->make_group_ro_accessor('simple', 'birthdate', 'birthdate');
 440  __PACKAGE__->make_group_ro_accessor('simple', 'ssn', 'social_security_number');
 441
 442 =over 4
 443
 444 =item Arguments: $group, $field, $accessor
 445
 446 Returns: \&accessor_coderef ?
 447
 448 =back
 449
 450 Called by mk_group_ro_accessors for each entry in @fieldspec. Either returns
 451 a coderef which will be installed at C<&__PACKAGE__::$accessor>, or returns
 452 C<undef> if it elects to install the coderef on its own.
 453
 454 =cut
 455
 456 sub make_group_ro_accessor { $gen_accessor->('ro', @_) }
 457
 458 =head2 make_group_wo_accessor
 459
 460  __PACKAGE__->make_group_wo_accessor('simple', 'lie', 'lie');
 461  __PACKAGE__->make_group_wo_accessor('simple', 'subj', 'subject');
 462
 463 =over 4
 464
 465 =item Arguments: $group, $field, $accessor
 466
 467 Returns: \&accessor_coderef ?
 468
 469 =back
 470
 471 Called by mk_group_wo_accessors for each entry in @fieldspec. Either returns
 472 a coderef which will be installed at C<&__PACKAGE__::$accessor>, or returns
 473 C<undef> if it elects to install the coderef on its own.
 474
 475 =cut
 476
 477 sub make_group_wo_accessor { $gen_accessor->('wo', @_) }
 478
 479
 480 =head1 PERFORMANCE
 481
 482 To provide total flexibility L<Class::Accessor::Grouped> calls methods
 483 internally while performing get/set actions, which makes it noticeably
 484 slower than similar modules. To compensate, this module will automatically
 485 use the insanely fast L<Class::XSAccessor> to generate the C<simple>-group
 486 accessors if this module is available on your system.
 487
 488 =head2 Benchmark
 489
 490 This is the result of a set/get/set loop benchmark on perl 5.12.1 with
 491 thread support, showcasing most popular accessor builders: L<Moose>, L<Mouse>,
 492 L<Moo>, L<CAF|Class::Accessor::Fast>, L<CAF_XS|Class::Accessor::Fast::XS>,
 493 L<XSA|Class::XSAccessor>, and L<CAF_XSA|Class::XSAccessor::Compat>:
 494
 495            Rate  CAG moOse  CAF moUse  moo HANDMADE CAF_XS moUse_XS moo_XS CAF_XSA  XSA CAG_XS
 496  CAG      169/s   --  -21% -24%  -32% -32%     -34%   -59%     -63%   -67%    -67% -67%   -67%
 497  moOse    215/s  27%    --  -3%  -13% -13%     -15%   -48%     -53%   -58%    -58% -58%   -58%
 498  CAF      222/s  31%    3%   --  -10% -10%     -13%   -46%     -52%   -57%    -57% -57%   -57%
 499  moUse    248/s  46%   15%  11%    --  -0%      -3%   -40%     -46%   -52%    -52% -52%   -52%
 500  moo      248/s  46%   15%  11%    0%   --      -3%   -40%     -46%   -52%    -52% -52%   -52%
 501  HANDMADE 255/s  50%   18%  14%    3%   3%       --   -38%     -45%   -50%    -51% -51%   -51%
 502  CAF_XS   411/s 143%   91%  85%   66%  66%      61%     --     -11%   -20%    -20% -21%   -21%
 503  moUse_XS 461/s 172%  114% 107%   86%  86%      81%    12%       --   -10%    -11% -11%   -11%
 504  moo_XS   514/s 204%  139% 131%  107% 107%     102%    25%      12%     --     -0%  -1%    -1%
 505  CAF_XSA  516/s 205%  140% 132%  108% 108%     103%    26%      12%     0%      --  -0%    -0%
 506  XSA      519/s 206%  141% 133%  109% 109%     104%    26%      13%     1%      0%   --    -0%
 507  CAG_XS   519/s 206%  141% 133%  109% 109%     104%    26%      13%     1%      0%   0%     --
 508
 509 Benchmark program is available in the root of the
 510 L<repository|http://search.cpan.org/dist/Class-Accessor-Grouped/>:
 511
 512 =head2 Notes on Class::XSAccessor
 513
 514 You can force (or disable) the use of L<Class::XSAccessor> before creating a
 515 particular C<simple> accessor by either manipulating the global variable
 516 C<$Class::Accessor::Grouped::USE_XS> to true or false (preferably with
 517 L<localization|perlfunc/local>, or you can do so before runtime via the
 518 C<CAG_USE_XS> environment variable.
 519
 520 Since L<Class::XSAccessor> has no knowledge of L</get_simple> and
 521 L</set_simple> this module does its best to detect if you are overriding
 522 one of these methods and will fall back to using the perl version of the
 523 accessor in order to maintain consistency. However be aware that if you
 524 enable use of C<Class::XSAccessor> (automatically or explicitly), create
 525 an object, invoke a simple accessor on that object, and B<then> manipulate
 526 the symbol table to install a C<get/set_simple> override - you get to keep
 527 all the pieces.
 528
 529 =head1 AUTHORS
 530
 531 Matt S. Trout <mst@shadowcatsystems.co.uk>
 532
 533 Christopher H. Laco <claco@chrislaco.com>
 534
 535 =head1 CONTRIBUTORS
 536
 537 Caelum: Rafael Kitover <rkitover@cpan.org>
 538
 539 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
 540
 541 groditi: Guillermo Roditi <groditi@cpan.org>
 542
 543 Jason Plum <jason.plum@bmmsi.com>
 544
 545 ribasushi: Peter Rabbitson <ribasushi@cpan.org>
 546
 547
 548 =head1 COPYRIGHT & LICENSE
 549
 550 Copyright (c) 2006-2010 Matt S. Trout <mst@shadowcatsystems.co.uk>
 551
 552 This program is free software; you can redistribute it and/or modify
 553 it under the same terms as perl itself.
 554
 555 =cut
 556
 557 ########################################################################
 558 ########################################################################
 559 ########################################################################
 560 #
 561 # Here be many angry dragons
 562 # (all code is in private coderefs since everything inherits CAG)
 563 #
 564 ########################################################################
 565 ########################################################################
 566
 567 # Autodetect unless flag supplied
 568 my $xsa_autodetected;
 569 if (! defined $USE_XS) {
 570   $USE_XS = __CAG_ENV__::NO_CXSA ? 0 : 1;
 571   $xsa_autodetected++;
 572 }
 573
 574 my $maker_templates = {
 575   rw => {
 576     xs_call => 'accessors',
 577     pp_code => sub {
 578       my $set = "set_$_[0]";
 579       my $get = "get_$_[0]";
 580       my $field = $_[1];
 581       $field =~ s/'/\\'/g;
 582
 583       "
 584         \@_ != 1
 585           ? shift->$set('$field', \@_)
 586           : shift->$get('$field')
 587       "
 588     },
 589   },
 590   ro => {
 591     xs_call => 'getters',
 592     pp_code => sub {
 593       my $get = "get_$_[0]";
 594       my $field = $_[1];
 595       $field =~ s/'/\\'/g;
 596
 597       "
 598         \@_ == 1
 599           ? shift->$get('$field')
 600           : do {
 601             my \$caller = caller;
 602             my \$class = ref \$_[0] || \$_[0];
 603             Carp::croak(\"'\$caller' cannot alter the value of '$field' \".
 604                         \"(read-only attributes of class '\$class')\");
 605           }
 606       "
 607     },
 608   },
 609   wo => {
 610     xs_call => 'setters',
 611     pp_code => sub {
 612       my $set = "set_$_[0]";
 613       my $field = $_[1];
 614       $field =~ s/'/\\'/g;
 615
 616       "
 617         \@_ != 1
 618           ? shift->$set('$field', \@_)
 619           : do {
 620             my \$caller = caller;
 621             my \$class = ref \$_[0] || \$_[0];
 622             Carp::croak(\"'\$caller' cannot access the value of '$field' \".
 623                         \"(write-only attributes of class '\$class')\");
 624           }
 625       "
 626     },
 627   },
 628 };
 629
 630
 631 my ($accessor_maker_cache, $no_xsa_warned_classes);
 632
 633 # can't use pkg_gen to track this stuff, as it doesn't
 634 # detect superclass mucking
 635 my $original_simple_getter = __PACKAGE__->can ('get_simple');
 636 my $original_simple_setter = __PACKAGE__->can ('set_simple');
 637
 638 # Note!!! Unusual signature
 639 $gen_accessor = sub {
 640   my ($type, $class, $group, $field, $methname) = @_;
 641   if (my $c = Scalar::Util::blessed( $class )) {
 642     $class = $c;
 643   }
 644
 645   # When installing an XSA simple accessor, we need to make sure we are not
 646   # short-circuiting a (compile or runtime) get_simple/set_simple override.
 647   # What we do here is install a lazy first-access check, which will decide
 648   # the ultimate coderef being placed in the accessor slot
 649   #
 650   # Also note that the *original* class will always retain this shim, as
 651   # different branches inheriting from it may have different overrides.
 652   # Thus the final method (properly labeled and all) is installed in the
 653   # calling-package's namespace
 654   if ($USE_XS and $group eq 'simple') {
 655     die sprintf( "Class::XSAccessor requested but not available:\n%s\n", __CAG_ENV__::NO_CXSA )
 656       if __CAG_ENV__::NO_CXSA;
 657
 658     my ($expected_cref, $cached_implementation);
 659     my $ret = $expected_cref = sub {
 660       my $current_class = Scalar::Util::blessed( $_[0] ) || $_[0];
 661
 662       # $cached_implementation will be set only if the shim got
 663       # 'around'ed, in which case it is handy to avoid re-running
 664       # this block over and over again
 665       my $resolved_implementation = $cached_implementation->{$current_class} || do {
 666         if (
 667           ($current_class->can('get_simple')||0) == $original_simple_getter
 668             &&
 669           ($current_class->can('set_simple')||0) == $original_simple_setter
 670         ) {
 671           # nothing has changed, might as well use the XS crefs
 672           #
 673           # note that by the time this code executes, we already have
 674           # *objects* (since XSA works on 'simple' only by definition).
 675           # If someone is mucking with the symbol table *after* there
 676           # are some objects already - look! many, shiny pieces! :)
 677           #
 678           # The weird breeder thingy is because XSA does not have an
 679           # interface returning *just* a coderef, without installing it
 680           # anywhere :(
 681           Class::XSAccessor->import(
 682             replace => 1,
 683             class => '__CAG__XSA__BREEDER__',
 684             $maker_templates->{$type}{xs_call} => {
 685               $methname => $field,
 686             },
 687           );
 688           __CAG__XSA__BREEDER__->can($methname);
 689         }
 690         else {
 691           if (! $xsa_autodetected and ! $no_xsa_warned_classes->{$current_class}++) {
 692             # not using Carp since the line where this happens doesn't mean much
 693             warn 'Explicitly requested use of Class::XSAccessor disabled for objects of class '
 694               . "'$current_class' inheriting from '$class' due to an overriden get_simple and/or "
 695               . "set_simple\n";
 696           }
 697
 698           do {
 699             # that's faster than local
 700             $USE_XS = 0;
 701             my $c = $gen_accessor->($type, $class, 'simple', $field, $methname);
 702             $USE_XS = 1;
 703             $c;
 704           };
 705         }
 706       };
 707
 708       # if after this shim was created someone wrapped it with an 'around',
 709       # we can not blindly reinstall the method slot - we will destroy the
 710       # wrapper. Silently chain execution further...
 711       if ( !$expected_cref or $expected_cref != ($current_class->can($methname)||0) ) {
 712
 713         # there is no point in re-determining it on every subsequent call,
 714         # just store for future reference
 715         $cached_implementation->{$current_class} ||= $resolved_implementation;
 716
 717         # older perls segfault if the cref behind the goto throws
 718         # http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 719         return $resolved_implementation->(@_) if __CAG_ENV__::BROKEN_GOTO;
 720
 721         goto $resolved_implementation;
 722       }
 723
 724       if (__CAG_ENV__::TRACK_UNDEFER_FAIL) {
 725         my $deferred_calls_seen = do {
 726           no strict 'refs';
 727           \%{"${current_class}::__cag_deferred_xs_shim_invocations"}
 728         };
 729         my @cframe = caller(0);
 730         if (my $already_seen = $deferred_calls_seen->{$cframe[3]}) {
 731           Carp::carp (
 732             "Deferred version of method $cframe[3] invoked more than once (originally "
 733           . "invoked at $already_seen). This is a strong indication your code has "
 734           . 'cached the original ->can derived method coderef, and is using it instead '
 735           . 'of the proper method re-lookup, causing performance regressions'
 736           );
 737         }
 738         else {
 739           $deferred_calls_seen->{$cframe[3]} = "$cframe[1] line $cframe[2]";
 740         }
 741       }
 742
 743       # install the resolved implementation into the code slot so we do not
 744       # come here anymore (hopefully)
 745       # since XSAccessor was available - so is Sub::Name
 746       {
 747         no strict 'refs';
 748         no warnings 'redefine';
 749
 750         my $fq_name = "${current_class}::${methname}";
 751         *$fq_name = Sub::Name::subname($fq_name, $resolved_implementation);
 752
 753         # need to update what the shim expects too *in case* its
 754         # ->can was cached for some moronic reason
 755         $expected_cref = $resolved_implementation;
 756         Scalar::Util::weaken($expected_cref);
 757       }
 758
 759       # older perls segfault if the cref behind the goto throws
 760       # http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 761       return $resolved_implementation->(@_) if __CAG_ENV__::BROKEN_GOTO;
 762
 763       goto $resolved_implementation;
 764     };
 765
 766     Scalar::Util::weaken($expected_cref); # to break the self-reference
 767     $ret;
 768   }
 769
 770   # no Sub::Name - just install the coderefs directly (compiling every time)
 771   elsif (__CAG_ENV__::NO_SUBNAME) {
 772     my $src = $accessor_maker_cache->{source}{$type}{$group}{$field} ||=
 773       $maker_templates->{$type}{pp_code}->($group, $field);
 774
 775     no warnings 'redefine';
 776     local $@ if __CAG_ENV__::UNSTABLE_DOLLARAT;
 777     eval "sub ${class}::${methname} { $src }";
 778
 779     undef;  # so that no further attempt will be made to install anything
 780   }
 781
 782   # a coderef generator with a variable pad (returns a fresh cref on every invocation)
 783   else {
 784     ($accessor_maker_cache->{pp}{$type}{$group}{$field} ||= do {
 785       my $src = $accessor_maker_cache->{source}{$type}{$group}{$field} ||=
 786         $maker_templates->{$type}{pp_code}->($group, $field);
 787
 788       local $@ if __CAG_ENV__::UNSTABLE_DOLLARAT;
 789       eval "sub { my \$dummy; sub { \$dummy if 0; $src } }" or die $@;
 790     })->()
 791   }
 792 };
 793
 794 1;