lib/CatalystX/ModelToControllerReflector.pm

   1 package CatalystX::ModelToControllerReflector;
   2 use Moose::Role;
   3 use Moose::Util qw/does_role/;
   4 use namespace::autoclean;
   5
   6 with 'CatalystX::DynamicComponent' => {
   7     name => '_setup_dynamic_controller',
   8     pre_immutable_hook => '_setup_dynamic_controller_meta',
   9 };
  10
  11 requires 'setup_components';
  12
  13 after 'setup_components' => sub { shift->_setup_dynamic_controllers(@_); };
  14
  15 sub _setup_dynamic_controllers {
  16     my ($app) = @_;
  17     my @model_names = grep { /::Model::/ } keys %{ $app->components };
  18
  19     foreach my $model_name (@model_names) {
  20         $app->_reflect_model_to_controller( $model_name, $app->components->{$model_name} );
  21     }
  22 }
  23
  24 sub _reflect_model_to_controller {
  25     my ( $app, $model_name, $model ) = @_;
  26
  27     my $class = blessed($app) || $app;
  28
  29     my $controller_name = $model_name;
  30     $controller_name =~ s/::Model::/::Controller::/;
  31
  32     my $suffix = $model_name;
  33     $suffix =~ s/^.*::Model:://;
  34
  35     my %controller_methods;
  36     my $model_methods = $model->meta->get_method_map;
  37     foreach my $method_name (keys %$model_methods) {
  38             next unless does_role($model_methods->{$method_name}, 'CatalystX::ControllerGeneratingModel::DispatchableMethod');
  39             # Note need to pass model name, as the method actually comes from
  40             # the underlying model class, not the Catalyst shim class we autogenerated.
  41             $controller_methods{$method_name} = $app->generate_reflected_controller_action_method($suffix, $model_methods->{$method_name})
  42     }
  43
  44     my $config_name = $controller_name;
  45     $config_name =~ s/^[^:]+:://;
  46     $app->_setup_dynamic_controller( $controller_name, $app->config->{$config_name}, \%controller_methods );
  47 }
  48
  49 sub _setup_dynamic_controller_meta {
  50     my ($app, $meta) = @_;
  51
  52     Moose::Util::apply_all_roles(
  53         $meta => 'CatalystX::ModelToControllerReflector::ControllerRole'
  54     );
  55 }
  56
  57 sub generate_reflected_controller_action_method {
  58     my ( $app, $model, $method ) = @_;
  59     my $method_name = $method->name; # Is it worth passing the actual method object here?
  60     sub {
  61         my ($self, $c, @args) = @_;
  62         $c->res->header('X-From-Model', $model);
  63         $c->res->header('X-From-Model-Data', $c->model($model)->$method_name(@args));
  64         $c->res->body('OK');
  65     };
  66 }
  67
  68 1;
  69