lib/CatalystX/ModelToControllerReflector.pm

   1 package CatalystX::ModelToControllerReflector;
   2 use Moose::Role;
   3 use namespace::clean -except => 'meta';
   4
   5 with 'CatalystX::DynamicComponent'
   6     => { alias => { _setup_dynamic_component => '_setup_dynamic_controller' } };
   7
   8 requires 'setup_components';
   9
  10 after 'setup_components' => sub { shift->_setup_dynamic_controllers(@_); };
  11
  12 sub _setup_dynamic_controllers {
  13     my ($app) = @_;
  14     my @model_names = grep { /::Model::/ } keys %{ $app->components };
  15
  16     foreach my $model_name (@model_names) {
  17         $app->_reflect_model_to_controller( $model_name, $app->components->{$model_name} );
  18     }
  19 }
  20
  21 sub _reflect_model_to_controller {
  22     my ( $app, $model_name, $model ) = @_;
  23
  24     my $class = blessed($app) || $app;
  25
  26     my $controller_name = $model_name;
  27     $controller_name =~ s/::Model::/::Controller::/;
  28
  29     my $suffix = $model_name;
  30     $suffix =~ s/^.*::Model:://;
  31
  32     my $controller = $app->_setup_dynamic_controller( $controller_name, {}, sub {
  33         shift->next::method(@_); # Just use the default COMPONENT method
  34     });
  35     my $meta = $controller->meta;
  36     $meta->make_mutable; # Dirty, I should build the class, add the methods, then
  37                          # last of all make it a component
  38     $meta->remove_method('COMPONENT');
  39     $meta->superclasses($app . '::ControllerBase');
  40
  41     my $methods = $model->meta->get_method_map;
  42     foreach my $method_name (keys %$methods) {
  43         $controller->meta->add_method(
  44             # Note need to pass model name, as the method actually comes from
  45             # the underlying model class, not the Catalyst shim class we autogenerated.
  46             $method_name => $app->generate_reflected_controller_action_method($suffix, $methods->{$method_name})
  47         );
  48     }
  49     $meta->make_immutable;
  50 }
  51
  52 sub generate_reflected_controller_action_method {
  53     my ( $app, $model, $method ) = @_;
  54     my $method_name = $method->name; # Is it worth passing the actual method object here?
  55     sub {
  56         my ($self, $c, @args) = @_;
  57         $c->res->header('X-From-Model', $model);
  58         $c->res->header('X-From-Model-Data', $c->model($model)->$method_name(@args));
  59         $c->res->body('OK');
  60     };
  61 }
  62
  63 1;
  64