lib/CatalystX/DynamicComponent/ModelToControllerReflector.pm

   1 package CatalystX::DynamicComponent::ModelToControllerReflector;
   2 use Moose::Role;
   3 use Moose::Util qw/does_role/;
   4 use List::MoreUtils qw/uniq/;
   5 use Moose::Autobox;
   6 use namespace::autoclean;
   7
   8 my $mangle_attributes_on_generated_methods = sub {
   9     my ($meta, $config) = @_;
  10     foreach my $name (keys %{ $config->{methods}}) {
  11         my $m = $meta->get_method($name);
  12         $meta->register_method_attributes($m->body, ['Local']);
  13     }
  14 };
  15
  16 with 'CatalystX::DynamicComponent' => {
  17     name => '_setup_dynamic_controller',
  18     pre_immutable_hook => $mangle_attributes_on_generated_methods,
  19 };
  20
  21 requires 'setup_components';
  22
  23 after 'setup_components' => sub { shift->_setup_dynamic_controllers(@_); };
  24
  25 sub _setup_dynamic_controllers {
  26     my ($app) = @_;
  27
  28     my @model_names = grep { /::Model::/ } keys %{ $app->components };
  29     foreach my $model_name (@model_names) {
  30         $app->_reflect_model_to_controller( $model_name, $app->components->{$model_name} );
  31     }
  32 }
  33
  34 sub _reflect_model_to_controller {
  35     my ( $app, $model_name, $model ) = @_;
  36
  37     # Model passed in as MyApp::Model::Foo, strip MyApp
  38     $model_name =~ s/^[^:]+:://;
  39
  40     # Get Controller::Foo
  41     my $controller_name = $model_name;
  42     $controller_name =~ s/^Model::/Controller::/;
  43
  44     # Get Foo
  45     my $suffix = $model_name;
  46     $suffix =~ s/Model:://;
  47
  48     my %controller_methods;
  49     # FIXME - Abstract this strategy crap out.
  50     my $model_methods = $model->meta->get_method_map;
  51     my $interface_roles = [ uniq(($app->config->{$model_name}->{interface_roles}||=[])->flatten,
  52         ($app->config->{'CatalystX::DynamicComponent::ModelToControllerReflector'}->{interface_roles}||=[])->flatten) ];
  53
  54     for my $interface_role (@$interface_roles) {
  55             for my $required_method ($interface_role->meta->get_required_method_list) {
  56                     # Note need to pass model name, as the method actually comes from
  57                     # the underlying model class, not the Catalyst shim class we autogenerated.
  58                     $controller_methods{$required_method} =
  59                          $app->generate_reflected_controller_action_method($suffix, $model_methods->{$required_method})
  60             }
  61     }
  62
  63     # Shallow copy so we don't stuff method refs in config
  64     my $config = { %{$app->config->{$controller_name}||{}} };
  65
  66     $config->{methods} = \%controller_methods;
  67     $app->_setup_dynamic_controller( $controller_name, $config );
  68 }
  69
  70 sub generate_reflected_controller_action_method {
  71     my ( $app, $model, $method ) = @_;
  72     my $method_name = $method->name; # Is it worth passing the actual method object here?
  73     sub {
  74         my ($self, $c, @args) = @_;
  75         $c->res->header('X-From-Model', $model);
  76         my $response = $c->model($model)->$method_name($c->req->data);
  77         $c->res->header('X-From-Model-Data', $response);
  78         $c->res->body('OK');
  79         $c->stash->{response} = $response;
  80     };
  81 }
  82
  83 1;
  84
  85 __END__
  86
  87 =head1 NAME
  88
  89 CatalystX::DynamicComponent::ModelToControllerReflector - Generate Catalyst controllers automaticall from models and configuration.
  90
  91 =head1 SYNOPSIS
  92
  93 =head1 DESCRIPTION
  94
  95 =head1 LINKS
  96
  97 L<Catalyst>, L<MooseX::MethodAttributes>, L<CatalystX::ModelsFromConfig>.
  98
  99 =head1 BUGS
 100
 101 Probably plenty, test suite certainly isn't comprehensive.. Patches welcome.
 102
 103 =head1 AUTHOR
 104
 105 Tomas Doran (t0m) <bobtfish@bobtfish.net>
 106
 107 =head1 LICENSE
 108
 109 This code is copyright (c) 2009 Tomas Doran. This code is licensed on the same terms as perl
 110 itself.
 111
 112 =cut
 113