lib/CatalystX/DynamicComponent/ModelToControllerReflector.pm

   1 package CatalystX::DynamicComponent::ModelToControllerReflector;
   2 use Moose::Role;
   3 use Moose::Util qw/does_role/;
   4 use List::MoreUtils qw/uniq/;
   5 use namespace::autoclean;
   6
   7 my $mangle_attributes_on_generated_methods = sub {
   8     my ($meta, $config) = @_;
   9     foreach my $name (keys %{ $config->{methods}}) {
  10         my $m = $meta->get_method($name);
  11         $meta->register_method_attributes($m->body, ['Local']);
  12     }
  13 };
  14
  15 with 'CatalystX::DynamicComponent' => {
  16     name => '_setup_dynamic_controller',
  17     pre_immutable_hook => $mangle_attributes_on_generated_methods,
  18 };
  19
  20 requires 'setup_components';
  21
  22 after 'setup_components' => sub { shift->_setup_dynamic_controllers(@_); };
  23
  24 sub _setup_dynamic_controllers {
  25     my ($app) = @_;
  26     my @model_names = grep { /::Model::/ } keys %{ $app->components };
  27
  28     foreach my $model_name (@model_names) {
  29         $app->_reflect_model_to_controller( $model_name, $app->components->{$model_name} );
  30     }
  31 }
  32
  33 sub _reflect_model_to_controller {
  34     my ( $app, $model_name, $model ) = @_;
  35
  36     my $class = blessed($app) || $app;
  37
  38     my $controller_name = $model_name;
  39     $controller_name =~ s/::Model::/::Controller::/;
  40
  41     my $suffix = $model_name;
  42     $suffix =~ s/^.*::Model:://;
  43
  44     my %controller_methods;
  45     # FIXME - Abstract this strategy crap out.
  46     my $model_methods = $model->meta->get_method_map;
  47     foreach my $method_name (keys %$model_methods) {
  48             next unless does_role($model_methods->{$method_name}, 'CatalystX::ControllerGeneratingModel::DispatchableMethod');
  49             # Note need to pass model name, as the method actually comes from
  50             # the underlying model class, not the Catalyst shim class we autogenerated.
  51             $controller_methods{$method_name} = $app->generate_reflected_controller_action_method($suffix, $model_methods->{$method_name})
  52     }
  53
  54     my $config_name = $controller_name;
  55     $config_name =~ s/^[^:]+:://;
  56
  57     # Shallow copy so we don't stuff method refs in config
  58     my $config = { %{$app->config->{$config_name}||{}} };
  59
  60     $config->{methods} = \%controller_methods;
  61     $app->_setup_dynamic_controller( $controller_name, $config );
  62 }
  63
  64 sub generate_reflected_controller_action_method {
  65     my ( $app, $model, $method ) = @_;
  66     my $method_name = $method->name; # Is it worth passing the actual method object here?
  67     sub {
  68         my ($self, $c, @args) = @_;
  69         $c->res->header('X-From-Model', $model);
  70         $c->res->header('X-From-Model-Data', $c->model($model)->$method_name(@args));
  71         $c->res->body('OK');
  72     };
  73 }
  74
  75 1;
  76
  77 __END__
  78
  79 =head1 NAME
  80
  81 CatalystX::DynamicComponent::ModelToControllerReflector - Generate Catalyst controllers automaticall from models and configuration.
  82
  83 =head1 SYNOPSIS
  84
  85 =head1 DESCRIPTION
  86
  87 =head1 LINKS
  88
  89 L<Catalyst>, L<MooseX::MethodAttributes>, L<CatalystX::ModelsFromConfig>.
  90
  91 =head1 BUGS
  92
  93 Probably plenty, test suite certainly isn't comprehensive.. Patches welcome.
  94
  95 =head1 AUTHOR
  96
  97 Tomas Doran (t0m) <bobtfish@bobtfish.net>
  98
  99 =head1 LICENSE
 100
 101 This code is copyright (c) 2009 Tomas Doran. This code is licensed on the same terms as perl
 102 itself.
 103
 104 =cut
 105