lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken blessed/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 __PACKAGE__->mk_accessors(
  34     qw/counter request response state action stack namespace stats/
  35 );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52
  53 __PACKAGE__->mk_classdata($_)
  54   for qw/components arguments dispatcher engine log dispatcher_class
  55   engine_class context_class request_class response_class stats_class
  56   setup_finished/;
  57
  58 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  59 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  60 __PACKAGE__->request_class('Catalyst::Request');
  61 __PACKAGE__->response_class('Catalyst::Response');
  62 __PACKAGE__->stats_class('Catalyst::Stats');
  63
  64 # Remember to update this in Catalyst::Runtime as well!
  65
  66 our $VERSION = '5.7014';
  67
  68 sub import {
  69     my ( $class, @arguments ) = @_;
  70
  71     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  72     # callers @ISA.
  73     return unless $class eq 'Catalyst';
  74
  75     my $caller = caller(0);
  76
  77     unless ( $caller->isa('Catalyst') ) {
  78         no strict 'refs';
  79         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  80     }
  81
  82     $caller->arguments( [@arguments] );
  83     $caller->setup_home;
  84 }
  85
  86 =head1 NAME
  87
  88 Catalyst - The Elegant MVC Web Application Framework
  89
  90 =head1 SYNOPSIS
  91
  92 See the L<Catalyst::Manual> distribution for comprehensive
  93 documentation and tutorials.
  94
  95     # Install Catalyst::Devel for helpers and other development tools
  96     # use the helper to create a new application
  97     catalyst.pl MyApp
  98
  99     # add models, views, controllers
 100     script/myapp_create.pl model MyDatabase DBIC::Schema create=dynamic dbi:SQLite:/path/to/db
 101     script/myapp_create.pl view MyTemplate TT
 102     script/myapp_create.pl controller Search
 103
 104     # built in testserver -- use -r to restart automatically on changes
 105     # --help to see all available options
 106     script/myapp_server.pl
 107
 108     # command line testing interface
 109     script/myapp_test.pl /yada
 110
 111     ### in lib/MyApp.pm
 112     use Catalyst qw/-Debug/; # include plugins here as well
 113
 114     ### In lib/MyApp/Controller/Root.pm (autocreated)
 115     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 116         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 117         $c->stash->{template} = 'foo.tt'; # set the template
 118         # lookup something from db -- stash vars are passed to TT
 119         $c->stash->{data} =
 120           $c->model('Database::Foo')->search( { country => $args[0] } );
 121         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 122             $c->forward( 'bar' ); # process another action
 123             # do something else after forward returns
 124         }
 125     }
 126
 127     # The foo.tt TT template can use the stash data from the database
 128     [% WHILE (item = data.next) %]
 129         [% item.foo %]
 130     [% END %]
 131
 132     # called for /bar/of/soap, /bar/of/soap/10, etc.
 133     sub bar : Path('/bar/of/soap') { ... }
 134
 135     # called for all actions, from the top-most controller downwards
 136     sub auto : Private {
 137         my ( $self, $c ) = @_;
 138         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 139             $c->res->redirect( '/login' ); # require login
 140             return 0; # abort request and go immediately to end()
 141         }
 142         return 1; # success; carry on to next action
 143     }
 144
 145     # called after all actions are finished
 146     sub end : Private {
 147         my ( $self, $c ) = @_;
 148         if ( scalar @{ $c->error } ) { ... } # handle errors
 149         return if $c->res->body; # already have a response
 150         $c->forward( 'MyApp::View::TT' ); # render template
 151     }
 152
 153     ### in MyApp/Controller/Foo.pm
 154     # called for /foo/bar
 155     sub bar : Local { ... }
 156
 157     # called for /blargle
 158     sub blargle : Global { ... }
 159
 160     # an index action matches /foo, but not /foo/1, etc.
 161     sub index : Private { ... }
 162
 163     ### in MyApp/Controller/Foo/Bar.pm
 164     # called for /foo/bar/baz
 165     sub baz : Local { ... }
 166
 167     # first Root auto is called, then Foo auto, then this
 168     sub auto : Private { ... }
 169
 170     # powerful regular expression paths are also possible
 171     sub details : Regex('^product/(\w+)/details$') {
 172         my ( $self, $c ) = @_;
 173         # extract the (\w+) from the URI
 174         my $product = $c->req->captures->[0];
 175     }
 176
 177 See L<Catalyst::Manual::Intro> for additional information.
 178
 179 =head1 DESCRIPTION
 180
 181 Catalyst is a modern framework for making web applications without the
 182 pain usually associated with this process. This document is a reference
 183 to the main Catalyst application. If you are a new user, we suggest you
 184 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 185
 186 See L<Catalyst::Manual> for more documentation.
 187
 188 Catalyst plugins can be loaded by naming them as arguments to the "use
 189 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 190 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 191 C<My::Module>.
 192
 193     use Catalyst qw/My::Module/;
 194
 195 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 196 fully qualify the name by using a unary plus:
 197
 198     use Catalyst qw/
 199         My::Module
 200         +Fully::Qualified::Plugin::Name
 201     /;
 202
 203 Special flags like C<-Debug> and C<-Engine> can also be specified as
 204 arguments when Catalyst is loaded:
 205
 206     use Catalyst qw/-Debug My::Module/;
 207
 208 The position of plugins and flags in the chain is important, because
 209 they are loaded in the order in which they appear.
 210
 211 The following flags are supported:
 212
 213 =head2 -Debug
 214
 215 Enables debug output. You can also force this setting from the system
 216 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 217 settings override the application, with <MYAPP>_DEBUG having the highest
 218 priority.
 219
 220 =head2 -Engine
 221
 222 Forces Catalyst to use a specific engine. Omit the
 223 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 224
 225     use Catalyst qw/-Engine=CGI/;
 226
 227 =head2 -Home
 228
 229 Forces Catalyst to use a specific home directory, e.g.:
 230
 231     use Catalyst qw[-Home=/usr/mst];
 232
 233 This can also be done in the shell environment by setting either the
 234 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 235 is replaced with the uppercased name of your application, any "::" in
 236 the name will be replaced with underscores, e.g. MyApp::Web should use
 237 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 238
 239 =head2 -Log
 240
 241 Specifies log level.
 242
 243 =head2 -Stats
 244
 245 Enables statistics collection and reporting. You can also force this setting
 246 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 247 environment settings override the application, with <MYAPP>_STATS having the
 248 highest priority.
 249
 250 e.g.
 251
 252    use Catalyst qw/-Stats=1/
 253
 254 =head1 METHODS
 255
 256 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 257
 258 =head2 $c->action
 259
 260 Returns a L<Catalyst::Action> object for the current action, which
 261 stringifies to the action name. See L<Catalyst::Action>.
 262
 263 =head2 $c->namespace
 264
 265 Returns the namespace of the current action, i.e., the URI prefix
 266 corresponding to the controller of the current action. For example:
 267
 268     # in Controller::Foo::Bar
 269     $c->namespace; # returns 'foo/bar';
 270
 271 =head2 $c->request
 272
 273 =head2 $c->req
 274
 275 Returns the current L<Catalyst::Request> object, giving access to
 276 information about the current client request (including parameters,
 277 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 278
 279 =head2 REQUEST FLOW HANDLING
 280
 281 =head2 $c->forward( $action [, \@arguments ] )
 282
 283 =head2 $c->forward( $class, $method, [, \@arguments ] )
 284
 285 Forwards processing to another action, by its private name. If you give a
 286 class name but no method, C<process()> is called. You may also optionally
 287 pass arguments in an arrayref. The action will receive the arguments in
 288 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 289 C<< $c->req->args >> will be restored to the previous values.
 290
 291 Any data C<return>ed from the action forwarded to, will be returned by the
 292 call to forward.
 293
 294     my $foodata = $c->forward('/foo');
 295     $c->forward('index');
 296     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 297     $c->forward('MyApp::View::TT');
 298
 299 Note that forward implies an C<<eval { }>> around the call (actually
 300 C<execute> does), thus de-fatalizing all 'dies' within the called
 301 action. If you want C<die> to propagate you need to do something like:
 302
 303     $c->forward('foo');
 304     die $c->error if $c->error;
 305
 306 Or make sure to always return true values from your actions and write
 307 your code like this:
 308
 309     $c->forward('foo') || return;
 310
 311 =cut
 312
 313 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 314
 315 =head2 $c->detach( $action [, \@arguments ] )
 316
 317 =head2 $c->detach( $class, $method, [, \@arguments ] )
 318
 319 =head2 $c->detach()
 320
 321 The same as C<forward>, but doesn't return to the previous action when
 322 processing is finished.
 323
 324 When called with no arguments it escapes the processing chain entirely.
 325
 326 =cut
 327
 328 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 329
 330 =head2 $c->response
 331
 332 =head2 $c->res
 333
 334 Returns the current L<Catalyst::Response> object, see there for details.
 335
 336 =head2 $c->stash
 337
 338 Returns a hashref to the stash, which may be used to store data and pass
 339 it between components during a request. You can also set hash keys by
 340 passing arguments. The stash is automatically sent to the view. The
 341 stash is cleared at the end of a request; it cannot be used for
 342 persistent storage (for this you must use a session; see
 343 L<Catalyst::Plugin::Session> for a complete system integrated with
 344 Catalyst).
 345
 346     $c->stash->{foo} = $bar;
 347     $c->stash( { moose => 'majestic', qux => 0 } );
 348     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 349
 350     # stash is automatically passed to the view for use in a template
 351     $c->forward( 'MyApp::View::TT' );
 352
 353 =cut
 354
 355 sub stash {
 356     my $c = shift;
 357     if (@_) {
 358         my $stash = @_ > 1 ? {@_} : $_[0];
 359         croak('stash takes a hash or hashref') unless ref $stash;
 360         foreach my $key ( keys %$stash ) {
 361             $c->{stash}->{$key} = $stash->{$key};
 362         }
 363     }
 364     return $c->{stash};
 365 }
 366
 367 =head2 $c->error
 368
 369 =head2 $c->error($error, ...)
 370
 371 =head2 $c->error($arrayref)
 372
 373 Returns an arrayref containing error messages.  If Catalyst encounters an
 374 error while processing a request, it stores the error in $c->error.  This
 375 method should only be used to store fatal error messages.
 376
 377     my @error = @{ $c->error };
 378
 379 Add a new error.
 380
 381     $c->error('Something bad happened');
 382
 383 =cut
 384
 385 sub error {
 386     my $c = shift;
 387     if ( $_[0] ) {
 388         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 389         croak @$error unless ref $c;
 390         push @{ $c->{error} }, @$error;
 391     }
 392     elsif ( defined $_[0] ) { $c->{error} = undef }
 393     return $c->{error} || [];
 394 }
 395
 396
 397 =head2 $c->state
 398
 399 Contains the return value of the last executed action.
 400
 401 =head2 $c->clear_errors
 402
 403 Clear errors.  You probably don't want to clear the errors unless you are
 404 implementing a custom error screen.
 405
 406 This is equivalent to running
 407
 408     $c->error(0);
 409
 410 =cut
 411
 412 sub clear_errors {
 413     my $c = shift;
 414     $c->error(0);
 415 }
 416
 417
 418 # search via regex
 419 sub _comp_search {
 420     my ( $c, @names ) = @_;
 421
 422     foreach my $name (@names) {
 423         foreach my $component ( keys %{ $c->components } ) {
 424             return $c->components->{$component} if $component =~ /$name/i;
 425         }
 426     }
 427
 428     return undef;
 429 }
 430
 431 # try explicit component names
 432 sub _comp_explicit {
 433     my ( $c, @names ) = @_;
 434
 435     foreach my $try (@names) {
 436         return $c->components->{$try} if ( exists $c->components->{$try} );
 437     }
 438
 439     return undef;
 440 }
 441
 442 # like component, but try just these prefixes before regex searching,
 443 #  and do not try to return "sort keys %{ $c->components }"
 444 sub _comp_prefixes {
 445     my ( $c, $name, @prefixes ) = @_;
 446
 447     my $appclass = ref $c || $c;
 448
 449     my @names = map { "${appclass}::${_}::${name}" } @prefixes;
 450
 451     my $comp = $c->_comp_explicit(@names);
 452     return $comp if defined($comp);
 453     $comp = $c->_comp_search($name);
 454     return $comp;
 455 }
 456
 457 # Find possible names for a prefix
 458
 459 sub _comp_names {
 460     my ( $c, @prefixes ) = @_;
 461
 462     my $appclass = ref $c || $c;
 463
 464     my @pre = map { "${appclass}::${_}::" } @prefixes;
 465
 466     my @names;
 467
 468     COMPONENT: foreach my $comp ($c->component) {
 469         foreach my $p (@pre) {
 470             if ($comp =~ s/^$p//) {
 471                 push(@names, $comp);
 472                 next COMPONENT;
 473             }
 474         }
 475     }
 476
 477     return @names;
 478 }
 479
 480 # Return a component if only one matches.
 481 sub _comp_singular {
 482     my ( $c, @prefixes ) = @_;
 483
 484     my $appclass = ref $c || $c;
 485
 486     my ( $comp, $rest ) =
 487       map { $c->_comp_search("^${appclass}::${_}::") } @prefixes;
 488     return $comp unless $rest;
 489 }
 490
 491 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 492 sub _filter_component {
 493     my ( $c, $comp, @args ) = @_;
 494     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 495         return $comp->ACCEPT_CONTEXT( $c, @args );
 496     }
 497     else { return $comp }
 498 }
 499
 500 =head2 COMPONENT ACCESSORS
 501
 502 =head2 $c->controller($name)
 503
 504 Gets a L<Catalyst::Controller> instance by name.
 505
 506     $c->controller('Foo')->do_stuff;
 507
 508 If the name is omitted, will return the controller for the dispatched
 509 action.
 510
 511 =cut
 512
 513 sub controller {
 514     my ( $c, $name, @args ) = @_;
 515     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Controller C/ ),
 516         @args )
 517       if ($name);
 518     return $c->component( $c->action->class );
 519 }
 520
 521 =head2 $c->model($name)
 522
 523 Gets a L<Catalyst::Model> instance by name.
 524
 525     $c->model('Foo')->do_stuff;
 526
 527 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 528
 529 If the name is omitted, it will look for
 530  - a model object in $c->stash{current_model_instance}, then
 531  - a model name in $c->stash->{current_model}, then
 532  - a config setting 'default_model', or
 533  - check if there is only one model, and return it if that's the case.
 534
 535 =cut
 536
 537 sub model {
 538     my ( $c, $name, @args ) = @_;
 539     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Model M/ ),
 540         @args )
 541       if $name;
 542     if (ref $c) {
 543         return $c->stash->{current_model_instance}
 544           if $c->stash->{current_model_instance};
 545         return $c->model( $c->stash->{current_model} )
 546           if $c->stash->{current_model};
 547     }
 548     return $c->model( $c->config->{default_model} )
 549       if $c->config->{default_model};
 550     return $c->_filter_component( $c->_comp_singular(qw/Model M/) );
 551
 552 }
 553
 554 =head2 $c->controllers
 555
 556 Returns the available names which can be passed to $c->controller
 557
 558 =cut
 559
 560 sub controllers {
 561     my ( $c ) = @_;
 562     return $c->_comp_names(qw/Controller C/);
 563 }
 564
 565
 566 =head2 $c->view($name)
 567
 568 Gets a L<Catalyst::View> instance by name.
 569
 570     $c->view('Foo')->do_stuff;
 571
 572 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 573
 574 If the name is omitted, it will look for
 575  - a view object in $c->stash{current_view_instance}, then
 576  - a view name in $c->stash->{current_view}, then
 577  - a config setting 'default_view', or
 578  - check if there is only one view, and return it if that's the case.
 579
 580 =cut
 581
 582 sub view {
 583     my ( $c, $name, @args ) = @_;
 584     return $c->_filter_component( $c->_comp_prefixes( $name, qw/View V/ ),
 585         @args )
 586       if $name;
 587     if (ref $c) {
 588         return $c->stash->{current_view_instance}
 589           if $c->stash->{current_view_instance};
 590         return $c->view( $c->stash->{current_view} )
 591           if $c->stash->{current_view};
 592     }
 593     return $c->view( $c->config->{default_view} )
 594       if $c->config->{default_view};
 595     return $c->_filter_component( $c->_comp_singular(qw/View V/) );
 596 }
 597
 598 =head2 $c->models
 599
 600 Returns the available names which can be passed to $c->model
 601
 602 =cut
 603
 604 sub models {
 605     my ( $c ) = @_;
 606     return $c->_comp_names(qw/Model M/);
 607 }
 608
 609
 610 =head2 $c->views
 611
 612 Returns the available names which can be passed to $c->view
 613
 614 =cut
 615
 616 sub views {
 617     my ( $c ) = @_;
 618     return $c->_comp_names(qw/View V/);
 619 }
 620
 621 =head2 $c->comp($name)
 622
 623 =head2 $c->component($name)
 624
 625 Gets a component object by name. This method is not recommended,
 626 unless you want to get a specific component by full
 627 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 628 should be used instead.
 629
 630 =cut
 631
 632 sub component {
 633     my $c = shift;
 634
 635     if (@_) {
 636
 637         my $name = shift;
 638
 639         my $appclass = ref $c || $c;
 640
 641         my @names = (
 642             $name, "${appclass}::${name}",
 643             map { "${appclass}::${_}::${name}" }
 644               qw/Model M Controller C View V/
 645         );
 646
 647         my $comp = $c->_comp_explicit(@names);
 648         return $c->_filter_component( $comp, @_ ) if defined($comp);
 649
 650         $comp = $c->_comp_search($name);
 651         return $c->_filter_component( $comp, @_ ) if defined($comp);
 652     }
 653
 654     return sort keys %{ $c->components };
 655 }
 656
 657
 658
 659 =head2 CLASS DATA AND HELPER CLASSES
 660
 661 =head2 $c->config
 662
 663 Returns or takes a hashref containing the application's configuration.
 664
 665     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 666
 667 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 668 like myapp.yml in your applications home directory. See
 669 L<Catalyst::Plugin::ConfigLoader>.
 670
 671     ---
 672     db: dsn:SQLite:foo.db
 673
 674
 675 =cut
 676
 677 sub config {
 678     my $c = shift;
 679
 680     $c->log->warn("Setting config after setup has been run is not a good idea.")
 681       if ( @_ and $c->setup_finished );
 682
 683     $c->NEXT::config(@_);
 684 }
 685
 686 =head2 $c->log
 687
 688 Returns the logging object instance. Unless it is already set, Catalyst
 689 sets this up with a L<Catalyst::Log> object. To use your own log class,
 690 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 691 C<< __PACKAGE__->setup >>.
 692
 693  __PACKAGE__->log( MyLogger->new );
 694  __PACKAGE__->setup;
 695
 696 And later:
 697
 698     $c->log->info( 'Now logging with my own logger!' );
 699
 700 Your log class should implement the methods described in
 701 L<Catalyst::Log>.
 702
 703
 704 =head2 $c->debug
 705
 706 Overload to enable debug messages (same as -Debug option).
 707
 708 Note that this is a static method, not an accessor and should be overloaded
 709 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 710
 711 =cut
 712
 713 sub debug { 0 }
 714
 715 =head2 $c->dispatcher
 716
 717 Returns the dispatcher instance. Stringifies to class name. See
 718 L<Catalyst::Dispatcher>.
 719
 720 =head2 $c->engine
 721
 722 Returns the engine instance. Stringifies to the class name. See
 723 L<Catalyst::Engine>.
 724
 725
 726 =head2 UTILITY METHODS
 727
 728 =head2 $c->path_to(@path)
 729
 730 Merges C<@path> with C<< $c->config->{home} >> and returns a
 731 L<Path::Class::Dir> object. Must be called after C<< MyApp->setup >>,
 732 which sets up C<< $c->config->{home} >>.
 733
 734 For example:
 735
 736     $c->path_to( 'db', 'sqlite.db' );
 737
 738 =cut
 739
 740 sub path_to {
 741     my ( $c, @path ) = @_;
 742     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 743     if ( -d $path ) { return $path }
 744     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 745 }
 746
 747 =head2 $c->plugin( $name, $class, @args )
 748
 749 Helper method for plugins. It creates a classdata accessor/mutator and
 750 loads and instantiates the given class.
 751
 752     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 753
 754     $c->prototype->define_javascript_functions;
 755
 756 =cut
 757
 758 sub plugin {
 759     my ( $class, $name, $plugin, @args ) = @_;
 760     $class->_register_plugin( $plugin, 1 );
 761
 762     eval { $plugin->import };
 763     $class->mk_classdata($name);
 764     my $obj;
 765     eval { $obj = $plugin->new(@args) };
 766
 767     if ($@) {
 768         Catalyst::Exception->throw( message =>
 769               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 770     }
 771
 772     $class->$name($obj);
 773     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 774       if $class->debug;
 775 }
 776
 777 =head2 MyApp->setup
 778
 779 Initializes the dispatcher and engine, loads any plugins, and loads the
 780 model, view, and controller components. You may also specify an array
 781 of plugins to load here, if you choose to not load them in the C<use
 782 Catalyst> line.
 783
 784     MyApp->setup;
 785     MyApp->setup( qw/-Debug/ );
 786
 787 =cut
 788
 789 sub setup {
 790     my ( $class, @arguments ) = @_;
 791
 792     $class->log->warn("Running setup twice is not a good idea.")
 793       if ( $class->setup_finished );
 794
 795     unless ( $class->isa('Catalyst') ) {
 796
 797         Catalyst::Exception->throw(
 798             message => qq/'$class' does not inherit from Catalyst/ );
 799     }
 800
 801     if ( $class->arguments ) {
 802         @arguments = ( @arguments, @{ $class->arguments } );
 803     }
 804
 805     # Process options
 806     my $flags = {};
 807
 808     foreach (@arguments) {
 809
 810         if (/^-Debug$/) {
 811             $flags->{log} =
 812               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 813         }
 814         elsif (/^-(\w+)=?(.*)$/) {
 815             $flags->{ lc $1 } = $2;
 816         }
 817         else {
 818             push @{ $flags->{plugins} }, $_;
 819         }
 820     }
 821
 822     $class->setup_home( delete $flags->{home} );
 823
 824     $class->setup_log( delete $flags->{log} );
 825     $class->setup_plugins( delete $flags->{plugins} );
 826     $class->setup_dispatcher( delete $flags->{dispatcher} );
 827     $class->setup_engine( delete $flags->{engine} );
 828     $class->setup_stats( delete $flags->{stats} );
 829
 830     for my $flag ( sort keys %{$flags} ) {
 831
 832         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 833             &$code( $class, delete $flags->{$flag} );
 834         }
 835         else {
 836             $class->log->warn(qq/Unknown flag "$flag"/);
 837         }
 838     }
 839
 840     eval { require Catalyst::Devel; };
 841     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 842         $class->log->warn(<<"EOF");
 843 You are running an old script!
 844
 845   Please update by running (this will overwrite existing files):
 846     catalyst.pl -force -scripts $class
 847
 848   or (this will not overwrite existing files):
 849     catalyst.pl -scripts $class
 850
 851 EOF
 852     }
 853
 854     if ( $class->debug ) {
 855         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 856
 857         if (@plugins) {
 858             my $t = Text::SimpleTable->new(74);
 859             $t->row($_) for @plugins;
 860             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 861         }
 862
 863         my $dispatcher = $class->dispatcher;
 864         my $engine     = $class->engine;
 865         my $home       = $class->config->{home};
 866
 867         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 868         $class->log->debug(qq/Loaded engine "$engine"/);
 869
 870         $home
 871           ? ( -d $home )
 872           ? $class->log->debug(qq/Found home "$home"/)
 873           : $class->log->debug(qq/Home "$home" doesn't exist/)
 874           : $class->log->debug(q/Couldn't find home/);
 875     }
 876
 877     # Call plugins setup
 878     {
 879         no warnings qw/redefine/;
 880         local *setup = sub { };
 881         $class->setup;
 882     }
 883
 884     # Initialize our data structure
 885     $class->components( {} );
 886
 887     $class->setup_components;
 888
 889     if ( $class->debug ) {
 890         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 891         for my $comp ( sort keys %{ $class->components } ) {
 892             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 893             $t->row( $comp, $type );
 894         }
 895         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 896           if ( keys %{ $class->components } );
 897     }
 898
 899     # Add our self to components, since we are also a component
 900     $class->components->{$class} = $class;
 901
 902     $class->setup_actions;
 903
 904     if ( $class->debug ) {
 905         my $name = $class->config->{name} || 'Application';
 906         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 907     }
 908     $class->log->_flush() if $class->log->can('_flush');
 909
 910     $class->setup_finished(1);
 911 }
 912
 913 =head2 $c->uri_for( $path, @args?, \%query_values? )
 914
 915 Merges path with C<< $c->request->base >> for absolute URIs and with
 916 C<< $c->namespace >> for relative URIs, then returns a normalized L<URI>
 917 object. If any args are passed, they are added at the end of the path.
 918 If the last argument to C<uri_for> is a hash reference, it is assumed to
 919 contain GET parameter key/value pairs, which will be appended to the URI
 920 in standard fashion.
 921
 922 Note that uri_for is destructive to the passed hashref.  Subsequent calls
 923 with the same hashref may have unintended results.
 924
 925 Instead of C<$path>, you can also optionally pass a C<$action> object
 926 which will be resolved to a path using
 927 C<< $c->dispatcher->uri_for_action >>; if the first element of
 928 C<@args> is an arrayref it is treated as a list of captures to be passed
 929 to C<uri_for_action>.
 930
 931 =cut
 932
 933 sub uri_for {
 934     my ( $c, $path, @args ) = @_;
 935
 936     if ( Scalar::Util::blessed($path) ) { # action object
 937         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 938                          ? shift(@args)
 939                          : [] );
 940         $path = $c->dispatcher->uri_for_action($path, $captures);
 941         return undef unless defined($path);
 942         $path = '/' if $path eq '';
 943     }
 944
 945     undef($path) if (defined $path && $path eq '');
 946
 947     my $params =
 948       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 949
 950     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
 951     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
 952
 953     unshift(@args, $path);
 954
 955     unless (defined $path && $path =~ s!^/!!) { # in-place strip
 956         my $namespace = $c->namespace;
 957         if (defined $path) { # cheesy hack to handle path '../foo'
 958            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
 959         }
 960         unshift(@args, $namespace || '');
 961     }
 962
 963     # join args with '/', or a blank string
 964     my $args = join('/', grep { defined($_) } @args);
 965     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
 966     $args =~ s!^/!!;
 967     my $base = $c->req->base;
 968     my $class = ref($base);
 969     $base =~ s{(?<!/)$}{/};
 970
 971     my $query = '';
 972
 973     if (my @keys = keys %$params) {
 974       # somewhat lifted from URI::_query's query_form
 975       $query = '?'.join('&', map {
 976           my $val = $params->{$_};
 977           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
 978           s/ /+/g;
 979           my $key = $_;
 980           $val = '' unless defined $val;
 981           (map {
 982               $_ = "$_";
 983               utf8::encode( $_ ) if utf8::is_utf8($_);
 984               # using the URI::Escape pattern here so utf8 chars survive
 985               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
 986               s/ /+/g;
 987               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
 988       } @keys);
 989     }
 990
 991     my $res = bless(\"${base}${args}${query}", $class);
 992     $res;
 993 }
 994
 995 =head2 $c->welcome_message
 996
 997 Returns the Catalyst welcome HTML page.
 998
 999 =cut
1000
1001 sub welcome_message {
1002     my $c      = shift;
1003     my $name   = $c->config->{name};
1004     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1005     my $prefix = Catalyst::Utils::appprefix( ref $c );
1006     $c->response->content_type('text/html; charset=utf-8');
1007     return <<"EOF";
1008 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1009     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1010 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1011     <head>
1012     <meta http-equiv="Content-Language" content="en" />
1013     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1014         <title>$name on Catalyst $VERSION</title>
1015         <style type="text/css">
1016             body {
1017                 color: #000;
1018                 background-color: #eee;
1019             }
1020             div#content {
1021                 width: 640px;
1022                 margin-left: auto;
1023                 margin-right: auto;
1024                 margin-top: 10px;
1025                 margin-bottom: 10px;
1026                 text-align: left;
1027                 background-color: #ccc;
1028                 border: 1px solid #aaa;
1029             }
1030             p, h1, h2 {
1031                 margin-left: 20px;
1032                 margin-right: 20px;
1033                 font-family: verdana, tahoma, sans-serif;
1034             }
1035             a {
1036                 font-family: verdana, tahoma, sans-serif;
1037             }
1038             :link, :visited {
1039                     text-decoration: none;
1040                     color: #b00;
1041                     border-bottom: 1px dotted #bbb;
1042             }
1043             :link:hover, :visited:hover {
1044                     color: #555;
1045             }
1046             div#topbar {
1047                 margin: 0px;
1048             }
1049             pre {
1050                 margin: 10px;
1051                 padding: 8px;
1052             }
1053             div#answers {
1054                 padding: 8px;
1055                 margin: 10px;
1056                 background-color: #fff;
1057                 border: 1px solid #aaa;
1058             }
1059             h1 {
1060                 font-size: 0.9em;
1061                 font-weight: normal;
1062                 text-align: center;
1063             }
1064             h2 {
1065                 font-size: 1.0em;
1066             }
1067             p {
1068                 font-size: 0.9em;
1069             }
1070             p img {
1071                 float: right;
1072                 margin-left: 10px;
1073             }
1074             span#appname {
1075                 font-weight: bold;
1076                 font-size: 1.6em;
1077             }
1078         </style>
1079     </head>
1080     <body>
1081         <div id="content">
1082             <div id="topbar">
1083                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1084                     $VERSION</h1>
1085              </div>
1086              <div id="answers">
1087                  <p>
1088                  <img src="$logo" alt="Catalyst Logo" />
1089                  </p>
1090                  <p>Welcome to the  world of Catalyst.
1091                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1092                     framework will make web development something you had
1093                     never expected it to be: Fun, rewarding, and quick.</p>
1094                  <h2>What to do now?</h2>
1095                  <p>That really depends  on what <b>you</b> want to do.
1096                     We do, however, provide you with a few starting points.</p>
1097                  <p>If you want to jump right into web development with Catalyst
1098                     you might want to start with a tutorial.</p>
1099 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1100 </pre>
1101 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1102 <pre>
1103 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1104 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1105 </code></pre>
1106                  <h2>What to do next?</h2>
1107                  <p>Next it's time to write an actual application. Use the
1108                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1109                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1110                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1111                     they can save you a lot of work.</p>
1112                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1113                     <p>Also, be sure to check out the vast and growing
1114                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1115                     you are likely to find what you need there.
1116                     </p>
1117
1118                  <h2>Need help?</h2>
1119                  <p>Catalyst has a very active community. Here are the main places to
1120                     get in touch with us.</p>
1121                  <ul>
1122                      <li>
1123                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1124                      </li>
1125                      <li>
1126                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1127                      </li>
1128                      <li>
1129                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1130                      </li>
1131                  </ul>
1132                  <h2>In conclusion</h2>
1133                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1134                     as we enjoyed making it. Please contact us if you have ideas
1135                     for improvement or other feedback.</p>
1136              </div>
1137          </div>
1138     </body>
1139 </html>
1140 EOF
1141 }
1142
1143 =head1 INTERNAL METHODS
1144
1145 These methods are not meant to be used by end users.
1146
1147 =head2 $c->components
1148
1149 Returns a hash of components.
1150
1151 =head2 $c->context_class
1152
1153 Returns or sets the context class.
1154
1155 =head2 $c->counter
1156
1157 Returns a hashref containing coderefs and execution counts (needed for
1158 deep recursion detection).
1159
1160 =head2 $c->depth
1161
1162 Returns the number of actions on the current internal execution stack.
1163
1164 =head2 $c->dispatch
1165
1166 Dispatches a request to actions.
1167
1168 =cut
1169
1170 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1171
1172 =head2 $c->dispatcher_class
1173
1174 Returns or sets the dispatcher class.
1175
1176 =head2 $c->dump_these
1177
1178 Returns a list of 2-element array references (name, structure) pairs
1179 that will be dumped on the error page in debug mode.
1180
1181 =cut
1182
1183 sub dump_these {
1184     my $c = shift;
1185     [ Request => $c->req ],
1186     [ Response => $c->res ],
1187     [ Stash => $c->stash ],
1188     [ Config => $c->config ];
1189 }
1190
1191 =head2 $c->engine_class
1192
1193 Returns or sets the engine class.
1194
1195 =head2 $c->execute( $class, $coderef )
1196
1197 Execute a coderef in given class and catch exceptions. Errors are available
1198 via $c->error.
1199
1200 =cut
1201
1202 sub execute {
1203     my ( $c, $class, $code ) = @_;
1204     $class = $c->component($class) || $class;
1205     $c->state(0);
1206
1207     if ( $c->depth >= $RECURSION ) {
1208         my $action = "$code";
1209         $action = "/$action" unless $action =~ /->/;
1210         my $error = qq/Deep recursion detected calling "$action"/;
1211         $c->log->error($error);
1212         $c->error($error);
1213         $c->state(0);
1214         return $c->state;
1215     }
1216
1217     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1218
1219     push( @{ $c->stack }, $code );
1220
1221     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1222
1223     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1224
1225     my $last = pop( @{ $c->stack } );
1226
1227     if ( my $error = $@ ) {
1228         if ( !ref($error) and $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1229         else {
1230             unless ( ref $error ) {
1231                 no warnings 'uninitialized';
1232                 chomp $error;
1233                 my $class = $last->class;
1234                 my $name  = $last->name;
1235                 $error = qq/Caught exception in $class->$name "$error"/;
1236             }
1237             $c->error($error);
1238             $c->state(0);
1239         }
1240     }
1241     return $c->state;
1242 }
1243
1244 sub _stats_start_execute {
1245     my ( $c, $code ) = @_;
1246
1247     return if ( ( $code->name =~ /^_.*/ )
1248         && ( !$c->config->{show_internal_actions} ) );
1249
1250     $c->counter->{"$code"}++;
1251
1252     my $action = "$code";
1253     $action = "/$action" unless $action =~ /->/;
1254
1255     # determine if the call was the result of a forward
1256     # this is done by walking up the call stack and looking for a calling
1257     # sub of Catalyst::forward before the eval
1258     my $callsub = q{};
1259     for my $index ( 2 .. 11 ) {
1260         last
1261         if ( ( caller($index) )[0] eq 'Catalyst'
1262             && ( caller($index) )[3] eq '(eval)' );
1263
1264         if ( ( caller($index) )[3] =~ /forward$/ ) {
1265             $callsub = ( caller($index) )[3];
1266             $action  = "-> $action";
1267             last;
1268         }
1269     }
1270
1271     my $uid = "$code" . $c->counter->{"$code"};
1272
1273     # is this a root-level call or a forwarded call?
1274     if ( $callsub =~ /forward$/ ) {
1275
1276         # forward, locate the caller
1277         if ( my $parent = $c->stack->[-1] ) {
1278             $c->stats->profile(
1279                 begin  => $action,
1280                 parent => "$parent" . $c->counter->{"$parent"},
1281                 uid    => $uid,
1282             );
1283         }
1284         else {
1285
1286             # forward with no caller may come from a plugin
1287             $c->stats->profile(
1288                 begin => $action,
1289                 uid   => $uid,
1290             );
1291         }
1292     }
1293     else {
1294
1295         # root-level call
1296         $c->stats->profile(
1297             begin => $action,
1298             uid   => $uid,
1299         );
1300     }
1301     return $action;
1302
1303 }
1304
1305 sub _stats_finish_execute {
1306     my ( $c, $info ) = @_;
1307     $c->stats->profile( end => $info );
1308 }
1309
1310 =head2 $c->_localize_fields( sub { }, \%keys );
1311
1312 =cut
1313
1314 sub _localize_fields {
1315     my ( $c, $localized, $code ) = ( @_ );
1316
1317     my $request = delete $localized->{request} || {};
1318     my $response = delete $localized->{response} || {};
1319
1320     local @{ $c }{ keys %$localized } = values %$localized;
1321     local @{ $c->request }{ keys %$request } = values %$request;
1322     local @{ $c->response }{ keys %$response } = values %$response;
1323
1324     $code->();
1325 }
1326
1327 =head2 $c->finalize
1328
1329 Finalizes the request.
1330
1331 =cut
1332
1333 sub finalize {
1334     my $c = shift;
1335
1336     for my $error ( @{ $c->error } ) {
1337         $c->log->error($error);
1338     }
1339
1340     # Allow engine to handle finalize flow (for POE)
1341     if ( $c->engine->can('finalize') ) {
1342         $c->engine->finalize($c);
1343     }
1344     else {
1345
1346         $c->finalize_uploads;
1347
1348         # Error
1349         if ( $#{ $c->error } >= 0 ) {
1350             $c->finalize_error;
1351         }
1352
1353         $c->finalize_headers;
1354
1355         # HEAD request
1356         if ( $c->request->method eq 'HEAD' ) {
1357             $c->response->body('');
1358         }
1359
1360         $c->finalize_body;
1361     }
1362
1363     if ($c->use_stats) {
1364         my $elapsed = sprintf '%f', $c->stats->elapsed;
1365         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1366         $c->log->info(
1367             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1368     }
1369
1370     return $c->response->status;
1371 }
1372
1373 =head2 $c->finalize_body
1374
1375 Finalizes body.
1376
1377 =cut
1378
1379 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1380
1381 =head2 $c->finalize_cookies
1382
1383 Finalizes cookies.
1384
1385 =cut
1386
1387 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1388
1389 =head2 $c->finalize_error
1390
1391 Finalizes error.
1392
1393 =cut
1394
1395 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1396
1397 =head2 $c->finalize_headers
1398
1399 Finalizes headers.
1400
1401 =cut
1402
1403 sub finalize_headers {
1404     my $c = shift;
1405
1406     # Check if we already finalized headers
1407     return if $c->response->{_finalized_headers};
1408
1409     # Handle redirects
1410     if ( my $location = $c->response->redirect ) {
1411         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1412         $c->response->header( Location => $location );
1413
1414         if ( !$c->response->body ) {
1415             # Add a default body if none is already present
1416             $c->response->body(
1417                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1418             );
1419         }
1420     }
1421
1422     # Content-Length
1423     if ( $c->response->body && !$c->response->content_length ) {
1424
1425         # get the length from a filehandle
1426         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1427         {
1428             my $stat = stat $c->response->body;
1429             if ( $stat && $stat->size > 0 ) {
1430                 $c->response->content_length( $stat->size );
1431             }
1432             else {
1433                 $c->log->warn('Serving filehandle without a content-length');
1434             }
1435         }
1436         else {
1437             # everything should be bytes at this point, but just in case
1438             $c->response->content_length( bytes::length( $c->response->body ) );
1439         }
1440     }
1441
1442     # Errors
1443     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1444         $c->response->headers->remove_header("Content-Length");
1445         $c->response->body('');
1446     }
1447
1448     $c->finalize_cookies;
1449
1450     $c->engine->finalize_headers( $c, @_ );
1451
1452     # Done
1453     $c->response->{_finalized_headers} = 1;
1454 }
1455
1456 =head2 $c->finalize_output
1457
1458 An alias for finalize_body.
1459
1460 =head2 $c->finalize_read
1461
1462 Finalizes the input after reading is complete.
1463
1464 =cut
1465
1466 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1467
1468 =head2 $c->finalize_uploads
1469
1470 Finalizes uploads. Cleans up any temporary files.
1471
1472 =cut
1473
1474 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1475
1476 =head2 $c->get_action( $action, $namespace )
1477
1478 Gets an action in a given namespace.
1479
1480 =cut
1481
1482 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1483
1484 =head2 $c->get_actions( $action, $namespace )
1485
1486 Gets all actions of a given name in a namespace and all parent
1487 namespaces.
1488
1489 =cut
1490
1491 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1492
1493 =head2 $c->handle_request( $class, @arguments )
1494
1495 Called to handle each HTTP request.
1496
1497 =cut
1498
1499 sub handle_request {
1500     my ( $class, @arguments ) = @_;
1501
1502     # Always expect worst case!
1503     my $status = -1;
1504     eval {
1505         if ($class->debug) {
1506             my $secs = time - $START || 1;
1507             my $av = sprintf '%.3f', $COUNT / $secs;
1508             my $time = localtime time;
1509             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1510         }
1511
1512         my $c = $class->prepare(@arguments);
1513         $c->dispatch;
1514         $status = $c->finalize;
1515     };
1516
1517     if ( my $error = $@ ) {
1518         chomp $error;
1519         $class->log->error(qq/Caught exception in engine "$error"/);
1520     }
1521
1522     $COUNT++;
1523     $class->log->_flush() if $class->log->can('_flush');
1524     return $status;
1525 }
1526
1527 =head2 $c->prepare( @arguments )
1528
1529 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1530 etc.).
1531
1532 =cut
1533
1534 sub prepare {
1535     my ( $class, @arguments ) = @_;
1536
1537     $class->context_class( ref $class || $class ) unless $class->context_class;
1538     my $c = $class->context_class->new(
1539         {
1540             counter => {},
1541             stack   => [],
1542             request => $class->request_class->new(
1543                 {
1544                     arguments        => [],
1545                     body_parameters  => {},
1546                     cookies          => {},
1547                     headers          => HTTP::Headers->new,
1548                     parameters       => {},
1549                     query_parameters => {},
1550                     secure           => 0,
1551                     captures         => [],
1552                     uploads          => {}
1553                 }
1554             ),
1555             response => $class->response_class->new(
1556                 {
1557                     body    => '',
1558                     cookies => {},
1559                     headers => HTTP::Headers->new(),
1560                     status  => 200
1561                 }
1562             ),
1563             stash => {},
1564             state => 0
1565         }
1566     );
1567
1568     $c->stats($class->stats_class->new)->enable($c->use_stats);
1569     if ( $c->debug ) {
1570         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1571     }
1572
1573     # For on-demand data
1574     $c->request->{_context}  = $c;
1575     $c->response->{_context} = $c;
1576     weaken( $c->request->{_context} );
1577     weaken( $c->response->{_context} );
1578
1579     # Allow engine to direct the prepare flow (for POE)
1580     if ( $c->engine->can('prepare') ) {
1581         $c->engine->prepare( $c, @arguments );
1582     }
1583     else {
1584         $c->prepare_request(@arguments);
1585         $c->prepare_headers;
1586         $c->prepare_connection;
1587         $c->prepare_query_parameters;
1588         $c->prepare_cookies;
1589         $c->prepare_path;
1590
1591         # Prepare the body for reading, either by prepare_body
1592         # or the user, if they are using $c->read
1593         $c->prepare_read;
1594
1595         # Parse the body unless the user wants it on-demand
1596         unless ( $c->config->{parse_on_demand} ) {
1597             $c->prepare_body;
1598         }
1599     }
1600
1601     my $method  = $c->req->method  || '';
1602     my $path    = $c->req->path;
1603     $path       = '/' unless length $path;
1604     my $address = $c->req->address || '';
1605
1606     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1607       if $c->debug;
1608
1609     $c->prepare_action;
1610
1611     return $c;
1612 }
1613
1614 =head2 $c->prepare_action
1615
1616 Prepares action. See L<Catalyst::Dispatcher>.
1617
1618 =cut
1619
1620 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1621
1622 =head2 $c->prepare_body
1623
1624 Prepares message body.
1625
1626 =cut
1627
1628 sub prepare_body {
1629     my $c = shift;
1630
1631     # Do we run for the first time?
1632     return if defined $c->request->{_body};
1633
1634     # Initialize on-demand data
1635     $c->engine->prepare_body( $c, @_ );
1636     $c->prepare_parameters;
1637     $c->prepare_uploads;
1638
1639     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1640         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1641         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1642             my $param = $c->req->body_parameters->{$key};
1643             my $value = defined($param) ? $param : '';
1644             $t->row( $key,
1645                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1646         }
1647         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1648     }
1649 }
1650
1651 =head2 $c->prepare_body_chunk( $chunk )
1652
1653 Prepares a chunk of data before sending it to L<HTTP::Body>.
1654
1655 See L<Catalyst::Engine>.
1656
1657 =cut
1658
1659 sub prepare_body_chunk {
1660     my $c = shift;
1661     $c->engine->prepare_body_chunk( $c, @_ );
1662 }
1663
1664 =head2 $c->prepare_body_parameters
1665
1666 Prepares body parameters.
1667
1668 =cut
1669
1670 sub prepare_body_parameters {
1671     my $c = shift;
1672     $c->engine->prepare_body_parameters( $c, @_ );
1673 }
1674
1675 =head2 $c->prepare_connection
1676
1677 Prepares connection.
1678
1679 =cut
1680
1681 sub prepare_connection {
1682     my $c = shift;
1683     $c->engine->prepare_connection( $c, @_ );
1684 }
1685
1686 =head2 $c->prepare_cookies
1687
1688 Prepares cookies.
1689
1690 =cut
1691
1692 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1693
1694 =head2 $c->prepare_headers
1695
1696 Prepares headers.
1697
1698 =cut
1699
1700 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1701
1702 =head2 $c->prepare_parameters
1703
1704 Prepares parameters.
1705
1706 =cut
1707
1708 sub prepare_parameters {
1709     my $c = shift;
1710     $c->prepare_body_parameters;
1711     $c->engine->prepare_parameters( $c, @_ );
1712 }
1713
1714 =head2 $c->prepare_path
1715
1716 Prepares path and base.
1717
1718 =cut
1719
1720 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1721
1722 =head2 $c->adjust_request_for_proxy
1723
1724 Adjusts the request to account for a frontend proxy.
1725
1726 =cut
1727
1728 sub adjust_request_for_proxy { my $c = shift; $c->engine->adjust_request_for_proxy( $c, @_ ) }
1729
1730 =head2 $c->prepare_query_parameters
1731
1732 Prepares query parameters.
1733
1734 =cut
1735
1736 sub prepare_query_parameters {
1737     my $c = shift;
1738
1739     $c->engine->prepare_query_parameters( $c, @_ );
1740
1741     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1742         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1743         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1744             my $param = $c->req->query_parameters->{$key};
1745             my $value = defined($param) ? $param : '';
1746             $t->row( $key,
1747                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1748         }
1749         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1750     }
1751 }
1752
1753 =head2 $c->prepare_read
1754
1755 Prepares the input for reading.
1756
1757 =cut
1758
1759 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1760
1761 =head2 $c->prepare_request
1762
1763 Prepares the engine request.
1764
1765 =cut
1766
1767 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1768
1769 =head2 $c->prepare_uploads
1770
1771 Prepares uploads.
1772
1773 =cut
1774
1775 sub prepare_uploads {
1776     my $c = shift;
1777
1778     $c->engine->prepare_uploads( $c, @_ );
1779
1780     if ( $c->debug && keys %{ $c->request->uploads } ) {
1781         my $t = Text::SimpleTable->new(
1782             [ 12, 'Parameter' ],
1783             [ 26, 'Filename' ],
1784             [ 18, 'Type' ],
1785             [ 9,  'Size' ]
1786         );
1787         for my $key ( sort keys %{ $c->request->uploads } ) {
1788             my $upload = $c->request->uploads->{$key};
1789             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1790                 $t->row( $key, $u->filename, $u->type, $u->size );
1791             }
1792         }
1793         $c->log->debug( "File Uploads are:\n" . $t->draw );
1794     }
1795 }
1796
1797 =head2 $c->prepare_write
1798
1799 Prepares the output for writing.
1800
1801 =cut
1802
1803 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1804
1805 =head2 $c->request_class
1806
1807 Returns or sets the request class.
1808
1809 =head2 $c->response_class
1810
1811 Returns or sets the response class.
1812
1813 =head2 $c->read( [$maxlength] )
1814
1815 Reads a chunk of data from the request body. This method is designed to
1816 be used in a while loop, reading C<$maxlength> bytes on every call.
1817 C<$maxlength> defaults to the size of the request if not specified.
1818
1819 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1820 directly.
1821
1822 Warning: If you use read(), Catalyst will not process the body,
1823 so you will not be able to access POST parameters or file uploads via
1824 $c->request.  You must handle all body parsing yourself.
1825
1826 =cut
1827
1828 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1829
1830 =head2 $c->run
1831
1832 Starts the engine.
1833
1834 =cut
1835
1836 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1837
1838 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1839
1840 Sets an action in a given namespace.
1841
1842 =cut
1843
1844 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1845
1846 =head2 $c->setup_actions($component)
1847
1848 Sets up actions for a component.
1849
1850 =cut
1851
1852 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1853
1854 =head2 $c->setup_components
1855
1856 Sets up components. Specify a C<setup_components> config option to pass
1857 additional options directly to L<Module::Pluggable>. To add additional
1858 search paths, specify a key named C<search_extra> as an array
1859 reference. Items in the array beginning with C<::> will have the
1860 application class name prepended to them.
1861
1862 =cut
1863
1864 sub setup_components {
1865     my $class = shift;
1866
1867     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1868     my $config  = $class->config->{ setup_components };
1869     my $extra   = delete $config->{ search_extra } || [];
1870
1871     push @paths, @$extra;
1872
1873     my $locator = Module::Pluggable::Object->new(
1874         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1875         %$config
1876     );
1877
1878     my @comps = sort { length $a <=> length $b } $locator->plugins;
1879     my %comps = map { $_ => 1 } @comps;
1880
1881     for my $component ( @comps ) {
1882
1883         # We pass ignore_loaded here so that overlay files for (e.g.)
1884         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
1885         # we know M::P::O found a file on disk so this is safe
1886
1887         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1888
1889         my $module  = $class->setup_component( $component );
1890         my %modules = (
1891             $component => $module,
1892             map {
1893                 $_ => $class->setup_component( $_ )
1894             } grep {
1895               not exists $comps{$_}
1896             } Devel::InnerPackage::list_packages( $component )
1897         );
1898
1899         for my $key ( keys %modules ) {
1900             $class->components->{ $key } = $modules{ $key };
1901         }
1902     }
1903 }
1904
1905 =head2 $c->setup_component
1906
1907 =cut
1908
1909 sub setup_component {
1910     my( $class, $component ) = @_;
1911
1912     unless ( $component->can( 'COMPONENT' ) ) {
1913         return $component;
1914     }
1915
1916     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1917     my $config = $class->config->{ $suffix } || {};
1918
1919     my $instance = eval { $component->COMPONENT( $class, $config ); };
1920
1921     if ( my $error = $@ ) {
1922         chomp $error;
1923         Catalyst::Exception->throw(
1924             message => qq/Couldn't instantiate component "$component", "$error"/
1925         );
1926     }
1927
1928     Catalyst::Exception->throw(
1929         message =>
1930         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1931     ) unless eval { $instance->can( 'can' ) };
1932
1933     return $instance;
1934 }
1935
1936 =head2 $c->setup_dispatcher
1937
1938 Sets up dispatcher.
1939
1940 =cut
1941
1942 sub setup_dispatcher {
1943     my ( $class, $dispatcher ) = @_;
1944
1945     if ($dispatcher) {
1946         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1947     }
1948
1949     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
1950         $dispatcher = 'Catalyst::Dispatcher::' . $env;
1951     }
1952
1953     unless ($dispatcher) {
1954         $dispatcher = $class->dispatcher_class;
1955     }
1956
1957     unless (Class::Inspector->loaded($dispatcher)) {
1958         require Class::Inspector->filename($dispatcher);
1959     }
1960
1961     # dispatcher instance
1962     $class->dispatcher( $dispatcher->new );
1963 }
1964
1965 =head2 $c->setup_engine
1966
1967 Sets up engine.
1968
1969 =cut
1970
1971 sub setup_engine {
1972     my ( $class, $engine ) = @_;
1973
1974     if ($engine) {
1975         $engine = 'Catalyst::Engine::' . $engine;
1976     }
1977
1978     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
1979         $engine = 'Catalyst::Engine::' . $env;
1980     }
1981
1982     if ( $ENV{MOD_PERL} ) {
1983
1984         # create the apache method
1985         {
1986             no strict 'refs';
1987             *{"$class\::apache"} = sub { shift->engine->apache };
1988         }
1989
1990         my ( $software, $version ) =
1991           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
1992
1993         $version =~ s/_//g;
1994         $version =~ s/(\.[^.]+)\./$1/g;
1995
1996         if ( $software eq 'mod_perl' ) {
1997
1998             if ( !$engine ) {
1999
2000                 if ( $version >= 1.99922 ) {
2001                     $engine = 'Catalyst::Engine::Apache2::MP20';
2002                 }
2003
2004                 elsif ( $version >= 1.9901 ) {
2005                     $engine = 'Catalyst::Engine::Apache2::MP19';
2006                 }
2007
2008                 elsif ( $version >= 1.24 ) {
2009                     $engine = 'Catalyst::Engine::Apache::MP13';
2010                 }
2011
2012                 else {
2013                     Catalyst::Exception->throw( message =>
2014                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2015                 }
2016
2017             }
2018
2019             # install the correct mod_perl handler
2020             if ( $version >= 1.9901 ) {
2021                 *handler = sub  : method {
2022                     shift->handle_request(@_);
2023                 };
2024             }
2025             else {
2026                 *handler = sub ($$) { shift->handle_request(@_) };
2027             }
2028
2029         }
2030
2031         elsif ( $software eq 'Zeus-Perl' ) {
2032             $engine = 'Catalyst::Engine::Zeus';
2033         }
2034
2035         else {
2036             Catalyst::Exception->throw(
2037                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2038         }
2039     }
2040
2041     unless ($engine) {
2042         $engine = $class->engine_class;
2043     }
2044
2045     unless (Class::Inspector->loaded($engine)) {
2046         require Class::Inspector->filename($engine);
2047     }
2048
2049     # check for old engines that are no longer compatible
2050     my $old_engine;
2051     if ( $engine->isa('Catalyst::Engine::Apache')
2052         && !Catalyst::Engine::Apache->VERSION )
2053     {
2054         $old_engine = 1;
2055     }
2056
2057     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2058         && Catalyst::Engine::Server->VERSION le '0.02' )
2059     {
2060         $old_engine = 1;
2061     }
2062
2063     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2064         && $engine->VERSION eq '0.01' )
2065     {
2066         $old_engine = 1;
2067     }
2068
2069     elsif ($engine->isa('Catalyst::Engine::Zeus')
2070         && $engine->VERSION eq '0.01' )
2071     {
2072         $old_engine = 1;
2073     }
2074
2075     if ($old_engine) {
2076         Catalyst::Exception->throw( message =>
2077               qq/Engine "$engine" is not supported by this version of Catalyst/
2078         );
2079     }
2080
2081     # engine instance
2082     $class->engine( $engine->new );
2083 }
2084
2085 =head2 $c->setup_home
2086
2087 Sets up the home directory.
2088
2089 =cut
2090
2091 sub setup_home {
2092     my ( $class, $home ) = @_;
2093
2094     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2095         $home = $env;
2096     }
2097
2098     unless ($home) {
2099         $home = Catalyst::Utils::home($class);
2100     }
2101
2102     if ($home) {
2103         $class->config->{home} ||= $home;
2104         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2105     }
2106 }
2107
2108 =head2 $c->setup_log
2109
2110 Sets up log.
2111
2112 =cut
2113
2114 sub setup_log {
2115     my ( $class, $debug ) = @_;
2116
2117     unless ( $class->log ) {
2118         $class->log( Catalyst::Log->new );
2119     }
2120
2121     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2122     if ( defined($env_debug) ? $env_debug : $debug ) {
2123         no strict 'refs';
2124         *{"$class\::debug"} = sub { 1 };
2125         $class->log->debug('Debug messages enabled');
2126     }
2127 }
2128
2129 =head2 $c->setup_plugins
2130
2131 Sets up plugins.
2132
2133 =cut
2134
2135 =head2 $c->setup_stats
2136
2137 Sets up timing statistics class.
2138
2139 =cut
2140
2141 sub setup_stats {
2142     my ( $class, $stats ) = @_;
2143
2144     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2145
2146     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2147     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2148         no strict 'refs';
2149         *{"$class\::use_stats"} = sub { 1 };
2150         $class->log->debug('Statistics enabled');
2151     }
2152 }
2153
2154
2155 =head2 $c->registered_plugins
2156
2157 Returns a sorted list of the plugins which have either been stated in the
2158 import list or which have been added via C<< MyApp->plugin(@args); >>.
2159
2160 If passed a given plugin name, it will report a boolean value indicating
2161 whether or not that plugin is loaded.  A fully qualified name is required if
2162 the plugin name does not begin with C<Catalyst::Plugin::>.
2163
2164  if ($c->registered_plugins('Some::Plugin')) {
2165      ...
2166  }
2167
2168 =cut
2169
2170 {
2171
2172     sub registered_plugins {
2173         my $proto = shift;
2174         return sort keys %{ $proto->_plugins } unless @_;
2175         my $plugin = shift;
2176         return 1 if exists $proto->_plugins->{$plugin};
2177         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2178     }
2179
2180     sub _register_plugin {
2181         my ( $proto, $plugin, $instant ) = @_;
2182         my $class = ref $proto || $proto;
2183
2184         # no ignore_loaded here, the plugin may already have been
2185         # defined in memory and we don't want to error on "no file" if so
2186
2187         Catalyst::Utils::ensure_class_loaded( $plugin );
2188
2189         $proto->_plugins->{$plugin} = 1;
2190         unless ($instant) {
2191             no strict 'refs';
2192             unshift @{"$class\::ISA"}, $plugin;
2193         }
2194         return $class;
2195     }
2196
2197     sub setup_plugins {
2198         my ( $class, $plugins ) = @_;
2199
2200         $class->_plugins( {} ) unless $class->_plugins;
2201         $plugins ||= [];
2202         for my $plugin ( reverse @$plugins ) {
2203
2204             unless ( $plugin =~ s/\A\+// ) {
2205                 $plugin = "Catalyst::Plugin::$plugin";
2206             }
2207
2208             $class->_register_plugin($plugin);
2209         }
2210     }
2211 }
2212
2213 =head2 $c->stack
2214
2215 Returns an arrayref of the internal execution stack (actions that are
2216 currently executing).
2217
2218 =head2 $c->stats_class
2219
2220 Returns or sets the stats (timing statistics) class.
2221
2222 =head2 $c->use_stats
2223
2224 Returns 1 when stats collection is enabled.  Stats collection is enabled
2225 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2226 environment variable is set.
2227
2228 Note that this is a static method, not an accessor and should be overloaded
2229 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2230
2231 =cut
2232
2233 sub use_stats { 0 }
2234
2235
2236 =head2 $c->write( $data )
2237
2238 Writes $data to the output stream. When using this method directly, you
2239 will need to manually set the C<Content-Length> header to the length of
2240 your output data, if known.
2241
2242 =cut
2243
2244 sub write {
2245     my $c = shift;
2246
2247     # Finalize headers if someone manually writes output
2248     $c->finalize_headers;
2249
2250     return $c->engine->write( $c, @_ );
2251 }
2252
2253 =head2 version
2254
2255 Returns the Catalyst version number. Mostly useful for "powered by"
2256 messages in template systems.
2257
2258 =cut
2259
2260 sub version { return $Catalyst::VERSION }
2261
2262 =head1 INTERNAL ACTIONS
2263
2264 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2265 C<_ACTION>, and C<_END>. These are by default not shown in the private
2266 action table, but you can make them visible with a config parameter.
2267
2268     MyApp->config->{show_internal_actions} = 1;
2269
2270 =head1 CASE SENSITIVITY
2271
2272 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2273 mapped to C</foo/bar>. You can activate case sensitivity with a config
2274 parameter.
2275
2276     MyApp->config->{case_sensitive} = 1;
2277
2278 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2279
2280 =head1 ON-DEMAND PARSER
2281
2282 The request body is usually parsed at the beginning of a request,
2283 but if you want to handle input yourself, you can enable on-demand
2284 parsing with a config parameter.
2285
2286     MyApp->config->{parse_on_demand} = 1;
2287
2288 =head1 PROXY SUPPORT
2289
2290 Many production servers operate using the common double-server approach,
2291 with a lightweight frontend web server passing requests to a larger
2292 backend server. An application running on the backend server must deal
2293 with two problems: the remote user always appears to be C<127.0.0.1> and
2294 the server's hostname will appear to be C<localhost> regardless of the
2295 virtual host that the user connected through.
2296
2297 Catalyst will automatically detect this situation when you are running
2298 the frontend and backend servers on the same machine. The following
2299 changes are made to the request.
2300
2301 =over 4
2302
2303 =item * X-Forwarded-For
2304
2305 The IP address in C<< $c->req->address >> is set to the user's real IP
2306 address, as read from the X-Forwarded-For header.
2307
2308 =item * X-Forwarded-Host
2309
2310 The host value for C<< $c->req->base >> and C<< $c->req->uri >> is set
2311 to the real host, as read from the X-Forwarded-Host header. The value
2312 of C<< $c->req->hostname >> is also adjusted accordingly.
2313
2314 =item * X-Forwarded-Port
2315
2316 The port value for C<< $c->req->base >> and C<< $c->req->uri >> is set
2317 to the real port, as read from the X-Forwarded-Port header.
2318
2319 =item * X-Forwarded-Path
2320
2321 If this is set, the value of the X-Forwarded-Path header is
2322 I<prepended> to the path value of C<< $c->req->base >> and C<<
2323 $c->req->uri >>.
2324
2325 =item * X-Forwarded-Is-SSL
2326
2327 If this is set, the scheme value of C<< $c->req->base >> and C<<
2328 $c->req->uri >> is set to "https". Additional, C<< $c->req->protocol
2329 >> is also set to "https", and C<< $c->req->secure >> is set to a true
2330 value.
2331
2332 =back
2333
2334 Obviously, your web server must support these headers for this to work.
2335
2336 In a more complex server farm environment where you may have your
2337 frontend proxy server(s) on different machines, you will need to set a
2338 configuration option to tell Catalyst to read the proxied data from the
2339 headers.
2340
2341     MyApp->config->{using_frontend_proxy} = 1;
2342
2343 If you do not wish to use the proxy support at all, you may set:
2344
2345     MyApp->config->{ignore_frontend_proxy} = 1;
2346
2347 =head1 THREAD SAFETY
2348
2349 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2350 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2351 believe the Catalyst core to be thread-safe.
2352
2353 If you plan to operate in a threaded environment, remember that all other
2354 modules you are using must also be thread-safe. Some modules, most notably
2355 L<DBD::SQLite>, are not thread-safe.
2356
2357 =head1 SUPPORT
2358
2359 IRC:
2360
2361     Join #catalyst on irc.perl.org.
2362
2363 Mailing Lists:
2364
2365     http://lists.rawmode.org/mailman/listinfo/catalyst
2366     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2367
2368 Web:
2369
2370     http://catalyst.perl.org
2371
2372 Wiki:
2373
2374     http://dev.catalyst.perl.org
2375
2376 =head1 SEE ALSO
2377
2378 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2379
2380 =head2 L<Catalyst::Manual> - The Catalyst Manual
2381
2382 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2383
2384 =head2 L<Catalyst::Engine> - Core engine
2385
2386 =head2 L<Catalyst::Log> - Log class.
2387
2388 =head2 L<Catalyst::Request> - Request object
2389
2390 =head2 L<Catalyst::Response> - Response object
2391
2392 =head2 L<Catalyst::Test> - The test suite.
2393
2394 =head1 CREDITS
2395
2396 Andy Grundman
2397
2398 Andy Wardley
2399
2400 Andreas Marienborg
2401
2402 Andrew Bramble
2403
2404 Andrew Ford
2405
2406 Andrew Ruthven
2407
2408 Arthur Bergman
2409
2410 Autrijus Tang
2411
2412 Brian Cassidy
2413
2414 Carl Franks
2415
2416 Christian Hansen
2417
2418 Christopher Hicks
2419
2420 Dan Sully
2421
2422 Danijel Milicevic
2423
2424 David Kamholz
2425
2426 David Naughton
2427
2428 Drew Taylor
2429
2430 Gary Ashton Jones
2431
2432 Geoff Richards
2433
2434 Jesse Sheidlower
2435
2436 Jesse Vincent
2437
2438 Jody Belka
2439
2440 Johan Lindstrom
2441
2442 Juan Camacho
2443
2444 Leon Brocard
2445
2446 Marcus Ramberg
2447
2448 Matt S Trout
2449
2450 Robert Sedlacek
2451
2452 Sam Vilain
2453
2454 Sascha Kiefer
2455
2456 Sebastian Willert
2457
2458 Tatsuhiko Miyagawa
2459
2460 Ulf Edvinsson
2461
2462 Yuval Kogman
2463
2464 =head1 AUTHOR
2465
2466 Sebastian Riedel, C<sri@oook.de>
2467
2468 =head1 LICENSE
2469
2470 This library is free software, you can redistribute it and/or modify it under
2471 the same terms as Perl itself.
2472
2473 =cut
2474
2475 1;