lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use Hash::Util qw/lock_hash/;
  31 use List::MoreUtils qw/uniq/;
  32 use attributes;
  33 use utf8;
  34 use Carp qw/croak carp shortmess/;
  35
  36 BEGIN { require 5.008004; }
  37
  38 has stack => (is => 'ro', default => sub { [] });
  39 has stash => (is => 'rw', default => sub { {} });
  40 has state => (is => 'rw', default => 0);
  41 has stats => (is => 'rw');
  42 has action => (is => 'rw');
  43 has counter => (is => 'rw', default => sub { {} });
  44 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  45 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  46 has namespace => (is => 'rw');
  47
  48 sub depth { scalar @{ shift->stack || [] }; }
  49 sub comp { shift->component(@_) }
  50
  51 sub req {
  52     my $self = shift; return $self->request(@_);
  53 }
  54 sub res {
  55     my $self = shift; return $self->response(@_);
  56 }
  57
  58 # For backwards compatibility
  59 sub finalize_output { shift->finalize_body(@_) };
  60
  61 # For statistics
  62 our $COUNT     = 1;
  63 our $START     = time;
  64 our $RECURSION = 1000;
  65 our $DETACH    = Catalyst::Exception::Detach->new;
  66 our $GO        = Catalyst::Exception::Go->new;
  67
  68 #I imagine that very few of these really need to be class variables. if any.
  69 #maybe we should just make them attributes with a default?
  70 __PACKAGE__->mk_classdata($_)
  71   for qw/container arguments dispatcher engine log dispatcher_class
  72   engine_class context_class request_class response_class stats_class
  73   setup_finished/;
  74
  75 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  76 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  77 __PACKAGE__->request_class('Catalyst::Request');
  78 __PACKAGE__->response_class('Catalyst::Response');
  79 __PACKAGE__->stats_class('Catalyst::Stats');
  80
  81 # Remember to update this in Catalyst::Runtime as well!
  82
  83 our $VERSION = '5.80032';
  84
  85 sub import {
  86     my ( $class, @arguments ) = @_;
  87
  88     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  89     # callers @ISA.
  90     return unless $class eq 'Catalyst';
  91
  92     my $caller = caller();
  93     return if $caller eq 'main';
  94
  95     my $meta = Moose::Meta::Class->initialize($caller);
  96
  97     unless ( $caller->isa('Catalyst') ) { # XXX - Remove!
  98         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Component'); # XXX - Remove!
  99         $meta->superclasses(@superclasses); # XXX - Remove!
 100     } # XXX - Remove!
 101
 102     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 103     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 104
 105     unless( $meta->has_method('meta') ){
 106         if ($Moose::VERSION >= 1.15) {
 107             $meta->_add_meta_method('meta');
 108         }
 109         else {
 110             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 111         }
 112     }
 113
 114     $caller->arguments( [@arguments] );
 115     $caller->setup_home;
 116 }
 117
 118 sub MODIFY_CODE_ATTRIBUTES {
 119     Catalyst::Exception->throw(
 120         "Catalyst applications (aka MyApp) cannot be controllers anymore. " .
 121         "That has been deprecated and removed. You should create a " .
 122         "controller class called Root.pm, and move relevant code to that class."
 123     );
 124 }
 125
 126
 127 sub _application { $_[0] }
 128
 129 =head1 NAME
 130
 131 Catalyst - The Elegant MVC Web Application Framework
 132
 133 =head1 SYNOPSIS
 134
 135 See the L<Catalyst::Manual> distribution for comprehensive
 136 documentation and tutorials.
 137
 138     # Install Catalyst::Devel for helpers and other development tools
 139     # use the helper to create a new application
 140     catalyst.pl MyApp
 141
 142     # add models, views, controllers
 143     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 144     script/myapp_create.pl view MyTemplate TT
 145     script/myapp_create.pl controller Search
 146
 147     # built in testserver -- use -r to restart automatically on changes
 148     # --help to see all available options
 149     script/myapp_server.pl
 150
 151     # command line testing interface
 152     script/myapp_test.pl /yada
 153
 154     ### in lib/MyApp.pm
 155     use Catalyst qw/-Debug/; # include plugins here as well
 156
 157     ### In lib/MyApp/Controller/Root.pm (autocreated)
 158     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 159         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 160         $c->stash->{template} = 'foo.tt'; # set the template
 161         # lookup something from db -- stash vars are passed to TT
 162         $c->stash->{data} =
 163           $c->model('Database::Foo')->search( { country => $args[0] } );
 164         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 165             $c->forward( 'bar' ); # process another action
 166             # do something else after forward returns
 167         }
 168     }
 169
 170     # The foo.tt TT template can use the stash data from the database
 171     [% WHILE (item = data.next) %]
 172         [% item.foo %]
 173     [% END %]
 174
 175     # called for /bar/of/soap, /bar/of/soap/10, etc.
 176     sub bar : Path('/bar/of/soap') { ... }
 177
 178     # called for all actions, from the top-most controller downwards
 179     sub auto : Private {
 180         my ( $self, $c ) = @_;
 181         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 182             $c->res->redirect( '/login' ); # require login
 183             return 0; # abort request and go immediately to end()
 184         }
 185         return 1; # success; carry on to next action
 186     }
 187
 188     # called after all actions are finished
 189     sub end : Private {
 190         my ( $self, $c ) = @_;
 191         if ( scalar @{ $c->error } ) { ... } # handle errors
 192         return if $c->res->body; # already have a response
 193         $c->forward( 'MyApp::View::TT' ); # render template
 194     }
 195
 196     ### in MyApp/Controller/Foo.pm
 197     # called for /foo/bar
 198     sub bar : Local { ... }
 199
 200     # called for /blargle
 201     sub blargle : Global { ... }
 202
 203     # an index action matches /foo, but not /foo/1, etc.
 204     sub index : Private { ... }
 205
 206     ### in MyApp/Controller/Foo/Bar.pm
 207     # called for /foo/bar/baz
 208     sub baz : Local { ... }
 209
 210     # first Root auto is called, then Foo auto, then this
 211     sub auto : Private { ... }
 212
 213     # powerful regular expression paths are also possible
 214     sub details : Regex('^product/(\w+)/details$') {
 215         my ( $self, $c ) = @_;
 216         # extract the (\w+) from the URI
 217         my $product = $c->req->captures->[0];
 218     }
 219
 220 See L<Catalyst::Manual::Intro> for additional information.
 221
 222 =head1 DESCRIPTION
 223
 224 Catalyst is a modern framework for making web applications without the
 225 pain usually associated with this process. This document is a reference
 226 to the main Catalyst application. If you are a new user, we suggest you
 227 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 228
 229 See L<Catalyst::Manual> for more documentation.
 230
 231 Catalyst plugins can be loaded by naming them as arguments to the "use
 232 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 233 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 234 C<My::Module>.
 235
 236     use Catalyst qw/My::Module/;
 237
 238 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 239 fully qualify the name by using a unary plus:
 240
 241     use Catalyst qw/
 242         My::Module
 243         +Fully::Qualified::Plugin::Name
 244     /;
 245
 246 Special flags like C<-Debug> and C<-Engine> can also be specified as
 247 arguments when Catalyst is loaded:
 248
 249     use Catalyst qw/-Debug My::Module/;
 250
 251 The position of plugins and flags in the chain is important, because
 252 they are loaded in the order in which they appear.
 253
 254 The following flags are supported:
 255
 256 =head2 -Debug
 257
 258 Enables debug output. You can also force this setting from the system
 259 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 260 settings override the application, with <MYAPP>_DEBUG having the highest
 261 priority.
 262
 263 This sets the log level to 'debug' and enables full debug output on the
 264 error screen. If you only want the latter, see L<< $c->debug >>.
 265
 266 =head2 -Engine
 267
 268 Forces Catalyst to use a specific engine. Omit the
 269 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 270
 271     use Catalyst qw/-Engine=CGI/;
 272
 273 =head2 -Home
 274
 275 Forces Catalyst to use a specific home directory, e.g.:
 276
 277     use Catalyst qw[-Home=/usr/mst];
 278
 279 This can also be done in the shell environment by setting either the
 280 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 281 is replaced with the uppercased name of your application, any "::" in
 282 the name will be replaced with underscores, e.g. MyApp::Web should use
 283 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 284
 285 If none of these are set, Catalyst will attempt to automatically detect the
 286 home directory. If you are working in a development envirnoment, Catalyst
 287 will try and find the directory containing either Makefile.PL, Build.PL or
 288 dist.ini. If the application has been installed into the system (i.e.
 289 you have done C<make install>), then Catalyst will use the path to your
 290 application module, without the .pm extension (ie, /foo/MyApp if your
 291 application was installed at /foo/MyApp.pm)
 292
 293 =head2 -Log
 294
 295     use Catalyst '-Log=warn,fatal,error';
 296
 297 Specifies a comma-delimited list of log levels.
 298
 299 =head2 -Stats
 300
 301 Enables statistics collection and reporting.
 302
 303    use Catalyst qw/-Stats=1/;
 304
 305 You can also force this setting from the system environment with CATALYST_STATS
 306 or <MYAPP>_STATS. The environment settings override the application, with
 307 <MYAPP>_STATS having the highest priority.
 308
 309 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 310
 311 =head1 METHODS
 312
 313 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 314
 315 =head2 $c->action
 316
 317 Returns a L<Catalyst::Action> object for the current action, which
 318 stringifies to the action name. See L<Catalyst::Action>.
 319
 320 =head2 $c->namespace
 321
 322 Returns the namespace of the current action, i.e., the URI prefix
 323 corresponding to the controller of the current action. For example:
 324
 325     # in Controller::Foo::Bar
 326     $c->namespace; # returns 'foo/bar';
 327
 328 =head2 $c->request
 329
 330 =head2 $c->req
 331
 332 Returns the current L<Catalyst::Request> object, giving access to
 333 information about the current client request (including parameters,
 334 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 335
 336 =head2 REQUEST FLOW HANDLING
 337
 338 =head2 $c->forward( $action [, \@arguments ] )
 339
 340 =head2 $c->forward( $class, $method, [, \@arguments ] )
 341
 342 Forwards processing to another action, by its private name. If you give a
 343 class name but no method, C<process()> is called. You may also optionally
 344 pass arguments in an arrayref. The action will receive the arguments in
 345 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 346 C<< $c->req->args >> will be restored to the previous values.
 347
 348 Any data C<return>ed from the action forwarded to, will be returned by the
 349 call to forward.
 350
 351     my $foodata = $c->forward('/foo');
 352     $c->forward('index');
 353     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 354     $c->forward('View::TT');
 355
 356 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 357 an C<< eval { } >> around the call (actually
 358 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 359 all 'dies' within the called action. If you want C<die> to propagate you
 360 need to do something like:
 361
 362     $c->forward('foo');
 363     die join "\n", @{ $c->error } if @{ $c->error };
 364
 365 Or make sure to always return true values from your actions and write
 366 your code like this:
 367
 368     $c->forward('foo') || return;
 369
 370 Another note is that C<< $c->forward >> always returns a scalar because it
 371 actually returns $c->state which operates in a scalar context.
 372 Thus, something like:
 373
 374     return @array;
 375
 376 in an action that is forwarded to is going to return a scalar,
 377 i.e. how many items are in that array, which is probably not what you want.
 378 If you need to return an array then return a reference to it,
 379 or stash it like so:
 380
 381     $c->stash->{array} = \@array;
 382
 383 and access it from the stash.
 384
 385 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 386
 387 =cut
 388
 389 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 390
 391 =head2 $c->detach( $action [, \@arguments ] )
 392
 393 =head2 $c->detach( $class, $method, [, \@arguments ] )
 394
 395 =head2 $c->detach()
 396
 397 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 398 doesn't return to the previous action when processing is finished.
 399
 400 When called with no arguments it escapes the processing chain entirely.
 401
 402 =cut
 403
 404 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 405
 406 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 407
 408 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 409
 410 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 411 but does a full dispatch, instead of just calling the new C<$action> /
 412 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 413 you go to are called, just like a new request.
 414
 415 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 416 This means, for example, that C<< $c->action >> methods such as
 417 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 418 L<reverse|Catalyst::Action/reverse> return information for the visited action
 419 when they are invoked within the visited action.  This is different from the
 420 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 421 continues to use the $c->action object from the caller action even when
 422 invoked from the callee.
 423
 424 C<< $c->stash >> is kept unchanged.
 425
 426 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 427 allows you to "wrap" another action, just as it would have been called by
 428 dispatching from a URL, while the analogous
 429 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 430 transfer control to another action as if it had been reached directly from a URL.
 431
 432 =cut
 433
 434 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 435
 436 =head2 $c->go( $action [, \@captures, \@arguments ] )
 437
 438 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 439
 440 The relationship between C<go> and
 441 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 442 the relationship between
 443 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 444 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 445 C<< $c->go >> will perform a full dispatch on the specified action or method,
 446 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 447 C<go> escapes the processing of the current request chain on completion, and
 448 does not return to its caller.
 449
 450 @arguments are arguments to the final destination of $action. @captures are
 451 arguments to the intermediate steps, if any, on the way to the final sub of
 452 $action.
 453
 454 =cut
 455
 456 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 457
 458 =head2 $c->response
 459
 460 =head2 $c->res
 461
 462 Returns the current L<Catalyst::Response> object, see there for details.
 463
 464 =head2 $c->stash
 465
 466 Returns a hashref to the stash, which may be used to store data and pass
 467 it between components during a request. You can also set hash keys by
 468 passing arguments. The stash is automatically sent to the view. The
 469 stash is cleared at the end of a request; it cannot be used for
 470 persistent storage (for this you must use a session; see
 471 L<Catalyst::Plugin::Session> for a complete system integrated with
 472 Catalyst).
 473
 474     $c->stash->{foo} = $bar;
 475     $c->stash( { moose => 'majestic', qux => 0 } );
 476     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 477
 478     # stash is automatically passed to the view for use in a template
 479     $c->forward( 'MyApp::View::TT' );
 480
 481 =cut
 482
 483 around stash => sub {
 484     my $orig = shift;
 485     my $c = shift;
 486     my $stash = $orig->($c);
 487     if (@_) {
 488         my $new_stash = @_ > 1 ? {@_} : $_[0];
 489         croak('stash takes a hash or hashref') unless ref $new_stash;
 490         foreach my $key ( keys %$new_stash ) {
 491           $stash->{$key} = $new_stash->{$key};
 492         }
 493     }
 494
 495     return $stash;
 496 };
 497
 498
 499 =head2 $c->error
 500
 501 =head2 $c->error($error, ...)
 502
 503 =head2 $c->error($arrayref)
 504
 505 Returns an arrayref containing error messages.  If Catalyst encounters an
 506 error while processing a request, it stores the error in $c->error.  This
 507 method should only be used to store fatal error messages.
 508
 509     my @error = @{ $c->error };
 510
 511 Add a new error.
 512
 513     $c->error('Something bad happened');
 514
 515 =cut
 516
 517 sub error {
 518     my $c = shift;
 519     if ( $_[0] ) {
 520         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 521         croak @$error unless ref $c;
 522         push @{ $c->{error} }, @$error;
 523     }
 524     elsif ( defined $_[0] ) { $c->{error} = undef }
 525     return $c->{error} || [];
 526 }
 527
 528
 529 =head2 $c->state
 530
 531 Contains the return value of the last executed action.
 532 Note that << $c->state >> operates in a scalar context which means that all
 533 values it returns are scalar.
 534
 535 =head2 $c->clear_errors
 536
 537 Clear errors.  You probably don't want to clear the errors unless you are
 538 implementing a custom error screen.
 539
 540 This is equivalent to running
 541
 542     $c->error(0);
 543
 544 =cut
 545
 546 sub clear_errors {
 547     my $c = shift;
 548     $c->error(0);
 549 }
 550
 551 =head2 COMPONENT ACCESSORS
 552
 553 =head2 $c->controller($name)
 554
 555 Gets a L<Catalyst::Controller> instance by name.
 556
 557     $c->controller('Foo')->do_stuff;
 558
 559 If the name is omitted, will return the controller for the dispatched
 560 action.
 561
 562 If you want to search for controllers, pass in a regexp as the argument.
 563
 564     # find all controllers that start with Foo
 565     my @foo_controllers = $c->controller(qr{^Foo});
 566
 567
 568 =cut
 569
 570 sub controller {
 571     my ( $c, $name, @args ) = @_;
 572
 573     $name ||= Catalyst::Utils::class2classshortsuffix( $c->action->class );
 574
 575     return $c->container->get_component_from_sub_container( 'controller', $name, $c, @args);
 576 }
 577
 578 =head2 $c->model($name)
 579
 580 Gets a L<Catalyst::Model> instance by name.
 581
 582     $c->model('Foo')->do_stuff;
 583
 584 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 585
 586 If the name is omitted, it will look for
 587  - a model object in $c->stash->{current_model_instance}, then
 588  - a model name in $c->stash->{current_model}, then
 589  - a config setting 'default_model', or
 590  - check if there is only one model, and return it if that's the case.
 591
 592 If you want to search for models, pass in a regexp as the argument.
 593
 594     # find all models that start with Foo
 595     my @foo_models = $c->model(qr{^Foo});
 596
 597 =cut
 598
 599 sub model {
 600     my ( $c, $name, @args ) = @_;
 601
 602     if (ref $c && !$name) {
 603         return $c->stash->{current_model_instance}
 604             if $c->stash->{current_model_instance};
 605
 606         $name = $c->stash->{current_model}
 607             if $c->stash->{current_model};
 608     }
 609
 610     return $c->container->get_component_from_sub_container( 'model', $name, $c, @args);
 611 }
 612
 613
 614 =head2 $c->view($name)
 615
 616 Gets a L<Catalyst::View> instance by name.
 617
 618     $c->view('Foo')->do_stuff;
 619
 620 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 621
 622 If the name is omitted, it will look for
 623  - a view object in $c->stash->{current_view_instance}, then
 624  - a view name in $c->stash->{current_view}, then
 625  - a config setting 'default_view', or
 626  - check if there is only one view, and return it if that's the case.
 627
 628 If you want to search for views, pass in a regexp as the argument.
 629
 630     # find all views that start with Foo
 631     my @foo_views = $c->view(qr{^Foo});
 632
 633 =cut
 634
 635 sub view {
 636     my ( $c, $name, @args ) = @_;
 637
 638     if (ref $c && !$name) {
 639         return $c->stash->{current_view_instance}
 640             if $c->stash->{current_view_instance};
 641
 642         $name = $c->stash->{current_view}
 643             if $c->stash->{current_view};
 644     }
 645
 646     return $c->container->get_component_from_sub_container( 'view', $name, $c, @args);
 647 }
 648
 649 =head2 $c->controllers
 650
 651 Returns the available names which can be passed to $c->controller
 652
 653 =cut
 654
 655 sub controllers {
 656     my ( $c ) = @_;
 657     return $c->container->get_sub_container('controller')->get_service_list;
 658 }
 659
 660 =head2 $c->models
 661
 662 Returns the available names which can be passed to $c->model
 663
 664 =cut
 665
 666 sub models {
 667     my ( $c ) = @_;
 668     return $c->container->get_sub_container('model')->get_service_list;
 669 }
 670
 671
 672 =head2 $c->views
 673
 674 Returns the available names which can be passed to $c->view
 675
 676 =cut
 677
 678 sub views {
 679     my ( $c ) = @_;
 680     return $c->container->get_sub_container('view')->get_service_list;
 681 }
 682
 683 =head2 $c->comp($name)
 684
 685 =head2 $c->component($name)
 686
 687 Gets a component object by name. This method is not recommended,
 688 unless you want to get a specific component by full
 689 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 690 should be used instead.
 691
 692 If C<$name> is a regexp, a list of components matched against the full
 693 component name will be returned.
 694
 695 =cut
 696
 697 sub component {
 698     my ( $c, $component, @args ) = @_;
 699
 700     unless ($component) {
 701         $c->log->warn('Calling $c->component with no args is deprecated and ');
 702         $c->log->warn('will be removed in a future release.');
 703         $c->log->warn('Use $c->component_list instead.');
 704         return $c->component_list;
 705     }
 706
 707     my ($type, $name) = _get_component_type_name($component);
 708
 709     return $c->container->get_component_from_sub_container(
 710         $type, $name, $c, @args
 711     ) if $type;
 712
 713     my @result = $c->container->find_component( $component, $c, @args );
 714
 715     # one last search for things like $c->comp(qr/::M::/)
 716     @result = $c->container->find_component_regexp(
 717         $c->components, $component, $c, @args
 718     ) if !@result and ref $component;
 719
 720     # list context for regexp searches
 721     return @result if ref $component;
 722
 723     # only one component (if it's found) for string searches
 724     return shift @result if @result;
 725
 726     if (ref $c eq $component) {
 727         $c->log->warn('You are calling $c->comp("MyApp"). This behaviour is');
 728         $c->log->warn('deprecated, and will be removed in a future release.');
 729         return $c;
 730     }
 731
 732     $c->log->warn("Looking for '$component', but nothing was found.");
 733
 734     # I would expect to return an empty list here, but that breaks back-compat
 735     $c->log->warn('Component not found, returning the list of existing');
 736     $c->log->warn('components. This behavior is deprecated and will be');
 737     $c->log->warn('removed in a future release. Use $c->component_list');
 738     $c->log->warn('instead.');
 739
 740     return $c->component_list;
 741 }
 742
 743 =head2 $c->component_list
 744
 745 Returns the sorted list of the component names of the application.
 746
 747 =cut
 748
 749 sub component_list { sort keys %{ shift->components } }
 750
 751 =head2 CLASS DATA AND HELPER CLASSES
 752
 753 =head2 $c->config
 754
 755 Returns or takes a hashref containing the application's configuration.
 756
 757     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 758
 759 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 760 like C<myapp.conf> in your applications home directory. See
 761 L<Catalyst::Plugin::ConfigLoader>.
 762
 763 =head3 Cascading configuration
 764
 765 The config method is present on all Catalyst components, and configuration
 766 will be merged when an application is started. Configuration loaded with
 767 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 768 followed by configuration in your top level C<MyApp> class. These two
 769 configurations are merged, and then configuration data whose hash key matches a
 770 component name is merged with configuration for that component.
 771
 772 The configuration for a component is then passed to the C<new> method when a
 773 component is constructed.
 774
 775 For example:
 776
 777     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 778     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 779
 780 will mean that C<MyApp::Model::Foo> receives the following data when
 781 constructed:
 782
 783     MyApp::Model::Foo->new({
 784         bar => 'baz',
 785         quux => 'frob',
 786         overrides => 'me',
 787     });
 788
 789 It's common practice to use a Moose attribute
 790 on the receiving component to access the config value.
 791
 792     package MyApp::Model::Foo;
 793
 794     use Moose;
 795
 796     # this attr will receive 'baz' at construction time
 797     has 'bar' => (
 798         is  => 'rw',
 799         isa => 'Str',
 800     );
 801
 802 You can then get the value 'baz' by calling $c->model('Foo')->bar
 803 (or $self->bar inside code in the model).
 804
 805 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 806 as a way of reading config within your code, as this B<will not> give you the
 807 correctly merged config back. You B<MUST> take the config values supplied to
 808 the constructor and use those instead.
 809
 810 =cut
 811
 812 around config => sub {
 813     my $orig = shift;
 814     my $c = shift;
 815
 816     croak('Setting config after setup has been run is not allowed.')
 817         if ( @_ and $c->setup_finished );
 818
 819     $c->$orig(@_);
 820 };
 821
 822 =head2 $c->log
 823
 824 Returns the logging object instance. Unless it is already set, Catalyst
 825 sets this up with a L<Catalyst::Log> object. To use your own log class,
 826 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 827 C<< __PACKAGE__->setup >>.
 828
 829  __PACKAGE__->log( MyLogger->new );
 830  __PACKAGE__->setup;
 831
 832 And later:
 833
 834     $c->log->info( 'Now logging with my own logger!' );
 835
 836 Your log class should implement the methods described in
 837 L<Catalyst::Log>.
 838
 839
 840 =head2 $c->debug
 841
 842 Returns 1 if debug mode is enabled, 0 otherwise.
 843
 844 You can enable debug mode in several ways:
 845
 846 =over
 847
 848 =item By calling myapp_server.pl with the -d flag
 849
 850 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 851
 852 =item The -Debug option in your MyApp.pm
 853
 854 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 855
 856 =back
 857
 858 The first three also set the log level to 'debug'.
 859
 860 Calling C<< $c->debug(1) >> has no effect.
 861
 862 =cut
 863
 864 sub debug { 0 }
 865
 866 =head2 $c->dispatcher
 867
 868 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 869
 870 =head2 $c->engine
 871
 872 Returns the engine instance. See L<Catalyst::Engine>.
 873
 874
 875 =head2 UTILITY METHODS
 876
 877 =head2 $c->path_to(@path)
 878
 879 Merges C<@path> with C<< $c->config->{home} >> and returns a
 880 L<Path::Class::Dir> object. Note you can usually use this object as
 881 a filename, but sometimes you will have to explicitly stringify it
 882 yourself by calling the C<< ->stringify >> method.
 883
 884 For example:
 885
 886     $c->path_to( 'db', 'sqlite.db' );
 887
 888 =cut
 889
 890 sub path_to {
 891     my ( $c, @path ) = @_;
 892     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 893     if ( -d $path ) { return $path }
 894     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 895 }
 896
 897 =head2 $c->plugin( $name, $class, @args )
 898
 899 Helper method for plugins. It creates a class data accessor/mutator and
 900 loads and instantiates the given class.
 901
 902     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 903
 904     $c->prototype->define_javascript_functions;
 905
 906 B<Note:> This method of adding plugins is deprecated. The ability
 907 to add plugins like this B<will be removed> in a Catalyst 5.81.
 908 Please do not use this functionality in new code.
 909
 910 =cut
 911
 912 sub plugin {
 913     my ( $class, $name, $plugin, @args ) = @_;
 914
 915     # See block comment in t/aggregate/unit_core_plugin.t
 916     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 917
 918     $class->_register_plugin( $plugin, 1 );
 919
 920     eval { $plugin->import };
 921     $class->mk_classdata($name);
 922     my $obj;
 923     eval { $obj = $plugin->new(@args) };
 924
 925     if ($@) {
 926         Catalyst::Exception->throw( message =>
 927               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 928     }
 929
 930     $class->$name($obj);
 931     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 932       if $class->debug;
 933 }
 934
 935 =head2 MyApp->setup
 936
 937 Initializes the dispatcher and engine, loads any plugins, and loads the
 938 model, view, and controller components. You may also specify an array
 939 of plugins to load here, if you choose to not load them in the C<use
 940 Catalyst> line.
 941
 942     MyApp->setup;
 943     MyApp->setup( qw/-Debug/ );
 944
 945 =cut
 946
 947 sub setup {
 948     my ( $class, @arguments ) = @_;
 949     croak('Running setup more than once')
 950         if ( $class->setup_finished );
 951
 952     unless ( $class->isa('Catalyst') ) {
 953
 954         Catalyst::Exception->throw(
 955             message => qq/'$class' does not inherit from Catalyst/ );
 956     }
 957
 958     if ( $class->arguments ) {
 959         @arguments = ( @arguments, @{ $class->arguments } );
 960     }
 961
 962     # Process options
 963     my $flags = {};
 964
 965     foreach (@arguments) {
 966
 967         if (/^-Debug$/) {
 968             $flags->{log} =
 969               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 970         }
 971         elsif (/^-(\w+)=?(.*)$/) {
 972             $flags->{ lc $1 } = $2;
 973         }
 974         else {
 975             push @{ $flags->{plugins} }, $_;
 976         }
 977     }
 978
 979     $class->setup_config();
 980     $class->setup_home( delete $flags->{home} );
 981
 982     $class->setup_log( delete $flags->{log} );
 983     $class->setup_plugins( delete $flags->{plugins} );
 984     $class->setup_dispatcher( delete $flags->{dispatcher} );
 985     $class->setup_engine( delete $flags->{engine} );
 986     $class->setup_stats( delete $flags->{stats} );
 987
 988     for my $flag ( sort keys %{$flags} ) {
 989
 990         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 991             &$code( $class, delete $flags->{$flag} );
 992         }
 993         else {
 994             $class->log->warn(qq/Unknown flag "$flag"/);
 995         }
 996     }
 997
 998     eval { require Catalyst::Devel; };
 999     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1000         $class->log->warn(<<"EOF");
1001 You are running an old script!
1002
1003   Please update by running (this will overwrite existing files):
1004     catalyst.pl -force -scripts $class
1005
1006   or (this will not overwrite existing files):
1007     catalyst.pl -scripts $class
1008
1009 EOF
1010     }
1011
1012     if ( $class->debug ) {
1013         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1014
1015         if (@plugins) {
1016             my $column_width = Catalyst::Utils::term_width() - 6;
1017             my $t = Text::SimpleTable->new($column_width);
1018             $t->row($_) for @plugins;
1019             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1020         }
1021
1022         my $dispatcher = $class->dispatcher;
1023         my $engine     = $class->engine;
1024         my $home       = $class->config->{home};
1025
1026         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1027         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1028
1029         $home
1030           ? ( -d $home )
1031           ? $class->log->debug(qq/Found home "$home"/)
1032           : $class->log->debug(qq/Home "$home" doesn't exist/)
1033           : $class->log->debug(q/Couldn't find home/);
1034     }
1035
1036     # Call plugins setup, this is stupid and evil.
1037     # Also screws C3 badly on 5.10, hack to avoid.
1038     {
1039         no warnings qw/redefine/;
1040         local *setup = sub { };
1041         $class->setup unless $Catalyst::__AM_RESTARTING;
1042     }
1043
1044     $class->setup_components;
1045
1046     if (
1047         $class->debug and
1048         my @comps_types = $class->container->get_components_types
1049     ) {
1050         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1051         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1052         $t->row( @$_ ) for @comps_types;
1053
1054         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" );
1055     }
1056
1057     $class->setup_actions;
1058
1059     if ( $class->debug ) {
1060         my $name = $class->config->{name} || 'Application';
1061         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1062     }
1063
1064     # Make sure that the application class becomes immutable at this point,
1065     B::Hooks::EndOfScope::on_scope_end {
1066         return if $@;
1067         my $meta = Class::MOP::get_metaclass_by_name($class);
1068         if (
1069             $meta->is_immutable
1070             && ! { $meta->immutable_options }->{replace_constructor}
1071             && (
1072                    $class->isa('Class::Accessor::Fast')
1073                 || $class->isa('Class::Accessor')
1074             )
1075         ) {
1076             warn "You made your application class ($class) immutable, "
1077                 . "but did not inline the\nconstructor. "
1078                 . "This will break catalyst, as your app \@ISA "
1079                 . "Class::Accessor(::Fast)?\nPlease pass "
1080                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1081         }
1082         $meta->make_immutable(
1083             replace_constructor => 1,
1084         ) unless $meta->is_immutable;
1085     };
1086
1087     if ($class->config->{case_sensitive}) {
1088         $class->log->warn($class . "->config->{case_sensitive} is set.");
1089         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1090     }
1091
1092     $class->setup_finalize;
1093     # Should be the last thing we do so that user things hooking
1094     # setup_finalize can log..
1095     $class->log->_flush() if $class->log->can('_flush');
1096     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1097 }
1098
1099 =head2 $app->setup_finalize
1100
1101 A hook to attach modifiers to. This method does not do anything except set the
1102 C<setup_finished> accessor.
1103
1104 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1105
1106 Example:
1107
1108     after setup_finalize => sub {
1109         my $app = shift;
1110
1111         ## do stuff here..
1112     };
1113
1114 =cut
1115
1116 sub setup_finalize {
1117     my ($class) = @_;
1118     $class->setup_finished(1);
1119 }
1120
1121 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1122
1123 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1124
1125 Constructs an absolute L<URI> object based on the application root, the
1126 provided path, and the additional arguments and query parameters provided.
1127 When used as a string, provides a textual URI.  If you need more flexibility
1128 than this (i.e. the option to provide relative URIs etc.) see
1129 L<Catalyst::Plugin::SmartURI>.
1130
1131 If no arguments are provided, the URI for the current action is returned.
1132 To return the current action and also provide @args, use
1133 C<< $c->uri_for( $c->action, @args ) >>.
1134
1135 If the first argument is a string, it is taken as a public URI path relative
1136 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1137 relative to the application root (if it does). It is then merged with
1138 C<< $c->request->base >>; any C<@args> are appended as additional path
1139 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1140
1141 If the first argument is a L<Catalyst::Action> it represents an action which
1142 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1143 optional C<\@captures> argument (an arrayref) allows passing the captured
1144 variables that are needed to fill in the paths of Chained and Regex actions;
1145 once the path is resolved, C<uri_for> continues as though a path was
1146 provided, appending any arguments or parameters and creating an absolute
1147 URI.
1148
1149 The captures for the current request can be found in
1150 C<< $c->request->captures >>, and actions can be resolved using
1151 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1152 path, use C<< $c->uri_for_action >> instead.
1153
1154   # Equivalent to $c->req->uri
1155   $c->uri_for($c->action, $c->req->captures,
1156       @{ $c->req->args }, $c->req->params);
1157
1158   # For the Foo action in the Bar controller
1159   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1160
1161   # Path to a static resource
1162   $c->uri_for('/static/images/logo.png');
1163
1164 =cut
1165
1166 sub uri_for {
1167     my ( $c, $path, @args ) = @_;
1168
1169     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1170         $path = $path->path_prefix;
1171         $path =~ s{/+\z}{};
1172         $path .= '/';
1173     }
1174
1175     undef($path) if (defined $path && $path eq '');
1176
1177     my $params =
1178       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1179
1180     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1181     foreach my $arg (@args) {
1182         utf8::encode($arg) if utf8::is_utf8($arg);
1183         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1184     }
1185
1186     if ( blessed($path) ) { # action object
1187         s|/|%2F|g for @args;
1188         my $captures = [ map { s|/|%2F|g; $_; }
1189                         ( scalar @args && ref $args[0] eq 'ARRAY'
1190                          ? @{ shift(@args) }
1191                          : ()) ];
1192
1193         foreach my $capture (@$captures) {
1194             utf8::encode($capture) if utf8::is_utf8($capture);
1195             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1196         }
1197
1198         my $action = $path;
1199         $path = $c->dispatcher->uri_for_action($action, $captures);
1200         if (not defined $path) {
1201             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1202                 if $c->debug;
1203             return undef;
1204         }
1205         $path = '/' if $path eq '';
1206     }
1207
1208     unshift(@args, $path);
1209
1210     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1211         my $namespace = $c->namespace;
1212         if (defined $path) { # cheesy hack to handle path '../foo'
1213            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1214         }
1215         unshift(@args, $namespace || '');
1216     }
1217
1218     # join args with '/', or a blank string
1219     my $args = join('/', grep { defined($_) } @args);
1220     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1221     $args =~ s!^/+!!;
1222     my $base = $c->req->base;
1223     my $class = ref($base);
1224     $base =~ s{(?<!/)$}{/};
1225
1226     my $query = '';
1227
1228     if (my @keys = keys %$params) {
1229       # somewhat lifted from URI::_query's query_form
1230       $query = '?'.join('&', map {
1231           my $val = $params->{$_};
1232           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1233           s/ /+/g;
1234           my $key = $_;
1235           $val = '' unless defined $val;
1236           (map {
1237               my $param = "$_";
1238               utf8::encode( $param ) if utf8::is_utf8($param);
1239               # using the URI::Escape pattern here so utf8 chars survive
1240               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1241               $param =~ s/ /+/g;
1242               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1243       } @keys);
1244     }
1245
1246     my $res = bless(\"${base}${args}${query}", $class);
1247     $res;
1248 }
1249
1250 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1251
1252 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1253
1254 =over
1255
1256 =item $path
1257
1258 A private path to the Catalyst action you want to create a URI for.
1259
1260 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1261 >> and passing the resulting C<$action> and the remaining arguments to C<<
1262 $c->uri_for >>.
1263
1264 You can also pass in a Catalyst::Action object, in which case it is passed to
1265 C<< $c->uri_for >>.
1266
1267 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1268
1269 For example, if the action looks like:
1270
1271  package MyApp::Controller::Users;
1272
1273  sub lst : Path('the-list') {}
1274
1275 You can use:
1276
1277  $c->uri_for_action('/users/lst')
1278
1279 and it will create the URI /users/the-list.
1280
1281 =back
1282
1283 =cut
1284
1285 sub uri_for_action {
1286     my ( $c, $path, @args ) = @_;
1287     my $action = blessed($path)
1288       ? $path
1289       : $c->dispatcher->get_action_by_path($path);
1290     unless (defined $action) {
1291       croak "Can't find action for path '$path'";
1292     }
1293     return $c->uri_for( $action, @args );
1294 }
1295
1296 =head2 $c->welcome_message
1297
1298 Returns the Catalyst welcome HTML page.
1299
1300 =cut
1301
1302 sub welcome_message {
1303     my $c      = shift;
1304     my $name   = $c->config->{name};
1305     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1306     my $prefix = Catalyst::Utils::appprefix( ref $c );
1307     $c->response->content_type('text/html; charset=utf-8');
1308     return <<"EOF";
1309 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1310     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1311 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1312     <head>
1313     <meta http-equiv="Content-Language" content="en" />
1314     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1315         <title>$name on Catalyst $VERSION</title>
1316         <style type="text/css">
1317             body {
1318                 color: #000;
1319                 background-color: #eee;
1320             }
1321             div#content {
1322                 width: 640px;
1323                 margin-left: auto;
1324                 margin-right: auto;
1325                 margin-top: 10px;
1326                 margin-bottom: 10px;
1327                 text-align: left;
1328                 background-color: #ccc;
1329                 border: 1px solid #aaa;
1330             }
1331             p, h1, h2 {
1332                 margin-left: 20px;
1333                 margin-right: 20px;
1334                 font-family: verdana, tahoma, sans-serif;
1335             }
1336             a {
1337                 font-family: verdana, tahoma, sans-serif;
1338             }
1339             :link, :visited {
1340                     text-decoration: none;
1341                     color: #b00;
1342                     border-bottom: 1px dotted #bbb;
1343             }
1344             :link:hover, :visited:hover {
1345                     color: #555;
1346             }
1347             div#topbar {
1348                 margin: 0px;
1349             }
1350             pre {
1351                 margin: 10px;
1352                 padding: 8px;
1353             }
1354             div#answers {
1355                 padding: 8px;
1356                 margin: 10px;
1357                 background-color: #fff;
1358                 border: 1px solid #aaa;
1359             }
1360             h1 {
1361                 font-size: 0.9em;
1362                 font-weight: normal;
1363                 text-align: center;
1364             }
1365             h2 {
1366                 font-size: 1.0em;
1367             }
1368             p {
1369                 font-size: 0.9em;
1370             }
1371             p img {
1372                 float: right;
1373                 margin-left: 10px;
1374             }
1375             span#appname {
1376                 font-weight: bold;
1377                 font-size: 1.6em;
1378             }
1379         </style>
1380     </head>
1381     <body>
1382         <div id="content">
1383             <div id="topbar">
1384                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1385                     $VERSION</h1>
1386              </div>
1387              <div id="answers">
1388                  <p>
1389                  <img src="$logo" alt="Catalyst Logo" />
1390                  </p>
1391                  <p>Welcome to the  world of Catalyst.
1392                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1393                     framework will make web development something you had
1394                     never expected it to be: Fun, rewarding, and quick.</p>
1395                  <h2>What to do now?</h2>
1396                  <p>That really depends  on what <b>you</b> want to do.
1397                     We do, however, provide you with a few starting points.</p>
1398                  <p>If you want to jump right into web development with Catalyst
1399                     you might want to start with a tutorial.</p>
1400 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1401 </pre>
1402 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1403 <pre>
1404 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1405 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1406 </code></pre>
1407                  <h2>What to do next?</h2>
1408                  <p>Next it's time to write an actual application. Use the
1409                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1410                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1411                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1412                     they can save you a lot of work.</p>
1413                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1414                     <p>Also, be sure to check out the vast and growing
1415                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1416                     you are likely to find what you need there.
1417                     </p>
1418
1419                  <h2>Need help?</h2>
1420                  <p>Catalyst has a very active community. Here are the main places to
1421                     get in touch with us.</p>
1422                  <ul>
1423                      <li>
1424                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1425                      </li>
1426                      <li>
1427                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1428                      </li>
1429                      <li>
1430                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1431                      </li>
1432                  </ul>
1433                  <h2>In conclusion</h2>
1434                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1435                     as we enjoyed making it. Please contact us if you have ideas
1436                     for improvement or other feedback.</p>
1437              </div>
1438          </div>
1439     </body>
1440 </html>
1441 EOF
1442 }
1443
1444 =head1 INTERNAL METHODS
1445
1446 These methods are not meant to be used by end users.
1447
1448 =head2 $c->components
1449
1450 Returns a hash of components.
1451
1452 =cut
1453
1454 sub components {
1455     my ( $class, $comps ) = @_;
1456
1457     # FIXME: should this ugly kludge exist?
1458     $class->setup_config unless defined $class->container;
1459
1460     my $containers;
1461     $containers->{$_} = $class->container->get_sub_container($_)
1462         for qw(model view controller);
1463
1464     if ( $comps ) {
1465         for my $component ( keys %$comps ) {
1466             my ($type, $name) = _get_component_type_name($component);
1467
1468             $containers->{$type}->add_service(
1469                 Catalyst::IOC::BlockInjection->new(
1470                     name  => $name,
1471                     block => sub { $class->setup_component($component) },
1472                 )
1473             );
1474         }
1475     }
1476
1477     my %components;
1478     for my $container (keys %$containers) {
1479         my @service_list = $containers->{$container}->get_service_list;
1480         for my $component (@service_list) {
1481             my $comp = $containers->{$container}->resolve(
1482                 service => $component
1483             );
1484             my $comp_name = ref $comp || $comp;
1485             $components{$comp_name} = $comp;
1486         }
1487     }
1488
1489     return lock_hash %components;
1490 }
1491
1492 =head2 $c->context_class
1493
1494 Returns or sets the context class.
1495
1496 =head2 $c->counter
1497
1498 Returns a hashref containing coderefs and execution counts (needed for
1499 deep recursion detection).
1500
1501 =head2 $c->depth
1502
1503 Returns the number of actions on the current internal execution stack.
1504
1505 =head2 $c->dispatch
1506
1507 Dispatches a request to actions.
1508
1509 =cut
1510
1511 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1512
1513 =head2 $c->dispatcher_class
1514
1515 Returns or sets the dispatcher class.
1516
1517 =head2 $c->dump_these
1518
1519 Returns a list of 2-element array references (name, structure) pairs
1520 that will be dumped on the error page in debug mode.
1521
1522 =cut
1523
1524 sub dump_these {
1525     my $c = shift;
1526     [ Request => $c->req ],
1527     [ Response => $c->res ],
1528     [ Stash => $c->stash ],
1529     [ Config => $c->config ];
1530 }
1531
1532 =head2 $c->engine_class
1533
1534 Returns or sets the engine class.
1535
1536 =head2 $c->execute( $class, $coderef )
1537
1538 Execute a coderef in given class and catch exceptions. Errors are available
1539 via $c->error.
1540
1541 =cut
1542
1543 sub execute {
1544     my ( $c, $class, $code ) = @_;
1545     $class = $c->component($class) || $class;
1546     $c->state(0);
1547
1548     if ( $c->depth >= $RECURSION ) {
1549         my $action = $code->reverse();
1550         $action = "/$action" unless $action =~ /->/;
1551         my $error = qq/Deep recursion detected calling "${action}"/;
1552         $c->log->error($error);
1553         $c->error($error);
1554         $c->state(0);
1555         return $c->state;
1556     }
1557
1558     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1559
1560     push( @{ $c->stack }, $code );
1561
1562     no warnings 'recursion';
1563     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1564     #      I have no idea how, ergo $ret (which appears to fix the issue)
1565     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1566
1567     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1568
1569     my $last = pop( @{ $c->stack } );
1570
1571     if ( my $error = $@ ) {
1572         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1573             $error->rethrow if $c->depth > 1;
1574         }
1575         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1576             $error->rethrow if $c->depth > 0;
1577         }
1578         else {
1579             unless ( ref $error ) {
1580                 no warnings 'uninitialized';
1581                 chomp $error;
1582                 my $class = $last->class;
1583                 my $name  = $last->name;
1584                 $error = qq/Caught exception in $class->$name "$error"/;
1585             }
1586             $c->error($error);
1587         }
1588         $c->state(0);
1589     }
1590     return $c->state;
1591 }
1592
1593 sub _stats_start_execute {
1594     my ( $c, $code ) = @_;
1595     my $appclass = ref($c) || $c;
1596     return if ( ( $code->name =~ /^_.*/ )
1597         && ( !$appclass->config->{show_internal_actions} ) );
1598
1599     my $action_name = $code->reverse();
1600     $c->counter->{$action_name}++;
1601
1602     my $action = $action_name;
1603     $action = "/$action" unless $action =~ /->/;
1604
1605     # determine if the call was the result of a forward
1606     # this is done by walking up the call stack and looking for a calling
1607     # sub of Catalyst::forward before the eval
1608     my $callsub = q{};
1609     for my $index ( 2 .. 11 ) {
1610         last
1611         if ( ( caller($index) )[0] eq 'Catalyst'
1612             && ( caller($index) )[3] eq '(eval)' );
1613
1614         if ( ( caller($index) )[3] =~ /forward$/ ) {
1615             $callsub = ( caller($index) )[3];
1616             $action  = "-> $action";
1617             last;
1618         }
1619     }
1620
1621     my $uid = $action_name . $c->counter->{$action_name};
1622
1623     # is this a root-level call or a forwarded call?
1624     if ( $callsub =~ /forward$/ ) {
1625         my $parent = $c->stack->[-1];
1626
1627         # forward, locate the caller
1628         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1629             $c->stats->profile(
1630                 begin  => $action,
1631                 parent => "$parent" . $c->counter->{"$parent"},
1632                 uid    => $uid,
1633             );
1634         }
1635         else {
1636
1637             # forward with no caller may come from a plugin
1638             $c->stats->profile(
1639                 begin => $action,
1640                 uid   => $uid,
1641             );
1642         }
1643     }
1644     else {
1645
1646         # root-level call
1647         $c->stats->profile(
1648             begin => $action,
1649             uid   => $uid,
1650         );
1651     }
1652     return $action;
1653
1654 }
1655
1656 sub _stats_finish_execute {
1657     my ( $c, $info ) = @_;
1658     $c->stats->profile( end => $info );
1659 }
1660
1661 =head2 $c->finalize
1662
1663 Finalizes the request.
1664
1665 =cut
1666
1667 sub finalize {
1668     my $c = shift;
1669
1670     for my $error ( @{ $c->error } ) {
1671         $c->log->error($error);
1672     }
1673
1674     # Allow engine to handle finalize flow (for POE)
1675     my $engine = $c->engine;
1676     if ( my $code = $engine->can('finalize') ) {
1677         $engine->$code($c);
1678     }
1679     else {
1680
1681         $c->finalize_uploads;
1682
1683         # Error
1684         if ( $#{ $c->error } >= 0 ) {
1685             $c->finalize_error;
1686         }
1687
1688         $c->finalize_headers;
1689
1690         # HEAD request
1691         if ( $c->request->method eq 'HEAD' ) {
1692             $c->response->body('');
1693         }
1694
1695         $c->finalize_body;
1696     }
1697
1698     $c->log_response;
1699
1700     if ($c->use_stats) {
1701         my $elapsed = sprintf '%f', $c->stats->elapsed;
1702         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1703         $c->log->info(
1704             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1705     }
1706
1707     return $c->response->status;
1708 }
1709
1710 =head2 $c->finalize_body
1711
1712 Finalizes body.
1713
1714 =cut
1715
1716 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1717
1718 =head2 $c->finalize_cookies
1719
1720 Finalizes cookies.
1721
1722 =cut
1723
1724 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1725
1726 =head2 $c->finalize_error
1727
1728 Finalizes error.
1729
1730 =cut
1731
1732 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1733
1734 =head2 $c->finalize_headers
1735
1736 Finalizes headers.
1737
1738 =cut
1739
1740 sub finalize_headers {
1741     my $c = shift;
1742
1743     my $response = $c->response; #accessor calls can add up?
1744
1745     # Check if we already finalized headers
1746     return if $response->finalized_headers;
1747
1748     # Handle redirects
1749     if ( my $location = $response->redirect ) {
1750         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1751         $response->header( Location => $location );
1752
1753         if ( !$response->has_body ) {
1754             # Add a default body if none is already present
1755             $response->body(
1756                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1757             );
1758         }
1759     }
1760
1761     # Content-Length
1762     if ( defined $response->body && length $response->body && !$response->content_length ) {
1763
1764         # get the length from a filehandle
1765         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1766         {
1767             my $stat = stat $response->body;
1768             if ( $stat && $stat->size > 0 ) {
1769                 $response->content_length( $stat->size );
1770             }
1771             else {
1772                 $c->log->warn('Serving filehandle without a content-length');
1773             }
1774         }
1775         else {
1776             # everything should be bytes at this point, but just in case
1777             $response->content_length( length( $response->body ) );
1778         }
1779     }
1780
1781     # Errors
1782     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1783         $response->headers->remove_header("Content-Length");
1784         $response->body('');
1785     }
1786
1787     $c->finalize_cookies;
1788
1789     $c->engine->finalize_headers( $c, @_ );
1790
1791     # Done
1792     $response->finalized_headers(1);
1793 }
1794
1795 =head2 $c->finalize_output
1796
1797 An alias for finalize_body.
1798
1799 =head2 $c->finalize_read
1800
1801 Finalizes the input after reading is complete.
1802
1803 =cut
1804
1805 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1806
1807 =head2 $c->finalize_uploads
1808
1809 Finalizes uploads. Cleans up any temporary files.
1810
1811 =cut
1812
1813 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1814
1815 =head2 $c->get_action( $action, $namespace )
1816
1817 Gets an action in a given namespace.
1818
1819 =cut
1820
1821 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1822
1823 =head2 $c->get_actions( $action, $namespace )
1824
1825 Gets all actions of a given name in a namespace and all parent
1826 namespaces.
1827
1828 =cut
1829
1830 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1831
1832 =head2 $app->handle_request( @arguments )
1833
1834 Called to handle each HTTP request.
1835
1836 =cut
1837
1838 sub handle_request {
1839     my ( $class, @arguments ) = @_;
1840
1841     # Always expect worst case!
1842     my $status = -1;
1843     eval {
1844         if ($class->debug) {
1845             my $secs = time - $START || 1;
1846             my $av = sprintf '%.3f', $COUNT / $secs;
1847             my $time = localtime time;
1848             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1849         }
1850
1851         my $c = $class->prepare(@arguments);
1852         $c->dispatch;
1853         $status = $c->finalize;
1854     };
1855
1856     if ( my $error = $@ ) {
1857         chomp $error;
1858         $class->log->error(qq/Caught exception in engine "$error"/);
1859     }
1860
1861     $COUNT++;
1862
1863     if(my $coderef = $class->log->can('_flush')){
1864         $class->log->$coderef();
1865     }
1866     return $status;
1867 }
1868
1869 =head2 $c->prepare( @arguments )
1870
1871 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1872 etc.).
1873
1874 =cut
1875
1876 sub prepare {
1877     my ( $class, @arguments ) = @_;
1878
1879     # XXX
1880     # After the app/ctxt split, this should become an attribute based on something passed
1881     # into the application.
1882     $class->context_class( ref $class || $class ) unless $class->context_class;
1883
1884     my $c = $class->context_class->new({});
1885
1886     # For on-demand data
1887     $c->request->_context($c);
1888     $c->response->_context($c);
1889
1890     #surely this is not the most efficient way to do things...
1891     $c->stats($class->stats_class->new)->enable($c->use_stats);
1892     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1893         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1894     }
1895
1896     #XXX reuse coderef from can
1897     # Allow engine to direct the prepare flow (for POE)
1898     if ( $c->engine->can('prepare') ) {
1899         $c->engine->prepare( $c, @arguments );
1900     }
1901     else {
1902         $c->prepare_request(@arguments);
1903         $c->prepare_connection;
1904         $c->prepare_query_parameters;
1905         $c->prepare_headers;
1906         $c->prepare_cookies;
1907         $c->prepare_path;
1908
1909         # Prepare the body for reading, either by prepare_body
1910         # or the user, if they are using $c->read
1911         $c->prepare_read;
1912
1913         # Parse the body unless the user wants it on-demand
1914         unless ( ref($c)->config->{parse_on_demand} ) {
1915             $c->prepare_body;
1916         }
1917     }
1918
1919     my $method  = $c->req->method  || '';
1920     my $path    = $c->req->path;
1921     $path       = '/' unless length $path;
1922     my $address = $c->req->address || '';
1923
1924     $c->log_request;
1925
1926     $c->prepare_action;
1927
1928     return $c;
1929 }
1930
1931 =head2 $c->prepare_action
1932
1933 Prepares action. See L<Catalyst::Dispatcher>.
1934
1935 =cut
1936
1937 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1938
1939 =head2 $c->prepare_body
1940
1941 Prepares message body.
1942
1943 =cut
1944
1945 sub prepare_body {
1946     my $c = shift;
1947
1948     return if $c->request->_has_body;
1949
1950     # Initialize on-demand data
1951     $c->engine->prepare_body( $c, @_ );
1952     $c->prepare_parameters;
1953     $c->prepare_uploads;
1954 }
1955
1956 =head2 $c->prepare_body_chunk( $chunk )
1957
1958 Prepares a chunk of data before sending it to L<HTTP::Body>.
1959
1960 See L<Catalyst::Engine>.
1961
1962 =cut
1963
1964 sub prepare_body_chunk {
1965     my $c = shift;
1966     $c->engine->prepare_body_chunk( $c, @_ );
1967 }
1968
1969 =head2 $c->prepare_body_parameters
1970
1971 Prepares body parameters.
1972
1973 =cut
1974
1975 sub prepare_body_parameters {
1976     my $c = shift;
1977     $c->engine->prepare_body_parameters( $c, @_ );
1978 }
1979
1980 =head2 $c->prepare_connection
1981
1982 Prepares connection.
1983
1984 =cut
1985
1986 sub prepare_connection {
1987     my $c = shift;
1988     $c->engine->prepare_connection( $c, @_ );
1989 }
1990
1991 =head2 $c->prepare_cookies
1992
1993 Prepares cookies.
1994
1995 =cut
1996
1997 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1998
1999 =head2 $c->prepare_headers
2000
2001 Prepares headers.
2002
2003 =cut
2004
2005 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2006
2007 =head2 $c->prepare_parameters
2008
2009 Prepares parameters.
2010
2011 =cut
2012
2013 sub prepare_parameters {
2014     my $c = shift;
2015     $c->prepare_body_parameters;
2016     $c->engine->prepare_parameters( $c, @_ );
2017 }
2018
2019 =head2 $c->prepare_path
2020
2021 Prepares path and base.
2022
2023 =cut
2024
2025 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2026
2027 =head2 $c->prepare_query_parameters
2028
2029 Prepares query parameters.
2030
2031 =cut
2032
2033 sub prepare_query_parameters {
2034     my $c = shift;
2035
2036     $c->engine->prepare_query_parameters( $c, @_ );
2037 }
2038
2039 =head2 $c->log_request
2040
2041 Writes information about the request to the debug logs.  This includes:
2042
2043 =over 4
2044
2045 =item * Request method, path, and remote IP address
2046
2047 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2048
2049 =item * Request parameters
2050
2051 =item * File uploads
2052
2053 =back
2054
2055 =cut
2056
2057 sub log_request {
2058     my $c = shift;
2059
2060     return unless $c->debug;
2061
2062     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2063     my $request = $dump->[1];
2064
2065     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2066     $method ||= '';
2067     $path = '/' unless length $path;
2068     $address ||= '';
2069     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2070
2071     $c->log_request_headers($request->headers);
2072
2073     if ( my $keywords = $request->query_keywords ) {
2074         $c->log->debug("Query keywords are: $keywords");
2075     }
2076
2077     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2078
2079     $c->log_request_uploads($request);
2080 }
2081
2082 =head2 $c->log_response
2083
2084 Writes information about the response to the debug logs by calling
2085 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2086
2087 =cut
2088
2089 sub log_response {
2090     my $c = shift;
2091
2092     return unless $c->debug;
2093
2094     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2095     my $response = $dump->[1];
2096
2097     $c->log_response_status_line($response);
2098     $c->log_response_headers($response->headers);
2099 }
2100
2101 =head2 $c->log_response_status_line($response)
2102
2103 Writes one line of information about the response to the debug logs.  This includes:
2104
2105 =over 4
2106
2107 =item * Response status code
2108
2109 =item * Content-Type header (if present)
2110
2111 =item * Content-Length header (if present)
2112
2113 =back
2114
2115 =cut
2116
2117 sub log_response_status_line {
2118     my ($c, $response) = @_;
2119
2120     $c->log->debug(
2121         sprintf(
2122             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2123             $response->status                            || 'unknown',
2124             $response->headers->header('Content-Type')   || 'unknown',
2125             $response->headers->header('Content-Length') || 'unknown'
2126         )
2127     );
2128 }
2129
2130 =head2 $c->log_response_headers($headers);
2131
2132 Hook method which can be wrapped by plugins to log the responseheaders.
2133 No-op in the default implementation.
2134
2135 =cut
2136
2137 sub log_response_headers {}
2138
2139 =head2 $c->log_request_parameters( query => {}, body => {} )
2140
2141 Logs request parameters to debug logs
2142
2143 =cut
2144
2145 sub log_request_parameters {
2146     my $c          = shift;
2147     my %all_params = @_;
2148
2149     return unless $c->debug;
2150
2151     my $column_width = Catalyst::Utils::term_width() - 44;
2152     foreach my $type (qw(query body)) {
2153         my $params = $all_params{$type};
2154         next if ! keys %$params;
2155         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2156         for my $key ( sort keys %$params ) {
2157             my $param = $params->{$key};
2158             my $value = defined($param) ? $param : '';
2159             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2160         }
2161         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2162     }
2163 }
2164
2165 =head2 $c->log_request_uploads
2166
2167 Logs file uploads included in the request to the debug logs.
2168 The parameter name, filename, file type, and file size are all included in
2169 the debug logs.
2170
2171 =cut
2172
2173 sub log_request_uploads {
2174     my $c = shift;
2175     my $request = shift;
2176     return unless $c->debug;
2177     my $uploads = $request->uploads;
2178     if ( keys %$uploads ) {
2179         my $t = Text::SimpleTable->new(
2180             [ 12, 'Parameter' ],
2181             [ 26, 'Filename' ],
2182             [ 18, 'Type' ],
2183             [ 9,  'Size' ]
2184         );
2185         for my $key ( sort keys %$uploads ) {
2186             my $upload = $uploads->{$key};
2187             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2188                 $t->row( $key, $u->filename, $u->type, $u->size );
2189             }
2190         }
2191         $c->log->debug( "File Uploads are:\n" . $t->draw );
2192     }
2193 }
2194
2195 =head2 $c->log_request_headers($headers);
2196
2197 Hook method which can be wrapped by plugins to log the request headers.
2198 No-op in the default implementation.
2199
2200 =cut
2201
2202 sub log_request_headers {}
2203
2204 =head2 $c->log_headers($type => $headers)
2205
2206 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2207
2208 =cut
2209
2210 sub log_headers {
2211     my $c       = shift;
2212     my $type    = shift;
2213     my $headers = shift;    # an HTTP::Headers instance
2214
2215     return unless $c->debug;
2216
2217     my $column_width = Catalyst::Utils::term_width() - 28;
2218     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2219     $headers->scan(
2220         sub {
2221             my ( $name, $value ) = @_;
2222             $t->row( $name, $value );
2223         }
2224     );
2225     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2226 }
2227
2228
2229 =head2 $c->prepare_read
2230
2231 Prepares the input for reading.
2232
2233 =cut
2234
2235 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2236
2237 =head2 $c->prepare_request
2238
2239 Prepares the engine request.
2240
2241 =cut
2242
2243 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2244
2245 =head2 $c->prepare_uploads
2246
2247 Prepares uploads.
2248
2249 =cut
2250
2251 sub prepare_uploads {
2252     my $c = shift;
2253
2254     $c->engine->prepare_uploads( $c, @_ );
2255 }
2256
2257 =head2 $c->prepare_write
2258
2259 Prepares the output for writing.
2260
2261 =cut
2262
2263 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2264
2265 =head2 $c->request_class
2266
2267 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2268
2269 =head2 $c->response_class
2270
2271 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2272
2273 =head2 $c->read( [$maxlength] )
2274
2275 Reads a chunk of data from the request body. This method is designed to
2276 be used in a while loop, reading C<$maxlength> bytes on every call.
2277 C<$maxlength> defaults to the size of the request if not specified.
2278
2279 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2280 directly.
2281
2282 Warning: If you use read(), Catalyst will not process the body,
2283 so you will not be able to access POST parameters or file uploads via
2284 $c->request.  You must handle all body parsing yourself.
2285
2286 =cut
2287
2288 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2289
2290 =head2 $c->run
2291
2292 Starts the engine.
2293
2294 =cut
2295
2296 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2297
2298 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2299
2300 Sets an action in a given namespace.
2301
2302 =cut
2303
2304 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2305
2306 =head2 $c->setup_actions($component)
2307
2308 Sets up actions for a component.
2309
2310 =cut
2311
2312 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2313
2314 =head2 $c->setup_config
2315
2316 =cut
2317
2318 sub setup_config {
2319     my $class = shift;
2320
2321     my %args = %{ $class->config || {} };
2322
2323     my @container_classes = ( "${class}::Container", 'Catalyst::IOC::Container');
2324     unshift @container_classes, delete $args{container_class} if exists $args{container_class};
2325
2326     my $container_class = Class::MOP::load_first_existing_class(@container_classes);
2327
2328     my $container = $container_class->new( %args, name => "$class" );
2329     $class->container($container);
2330
2331     my $config = $container->resolve(service => 'config');
2332     $class->config($config);
2333     $class->finalize_config; # back-compat
2334 }
2335
2336 =head2 $c->finalize_config
2337
2338 =cut
2339
2340 sub finalize_config { }
2341
2342 =head2 $c->setup_components
2343
2344 This method is called internally to set up the application's components.
2345
2346 It finds modules by calling the L<locate_components> method, expands them to
2347 package names with the L<expand_component_module> method, and then installs
2348 each component into the application.
2349
2350 The C<setup_components> config option is passed to both of the above methods.
2351
2352 Installation of each component is performed by the L<setup_component> method,
2353 below.
2354
2355 =cut
2356
2357 sub setup_components {
2358     my $class = shift;
2359
2360     my $config  = $class->config->{ setup_components };
2361
2362     Catalyst::Exception->throw(
2363         qq{You are using search_extra config option. That option is\n} .
2364         qq{deprecated, please refer to the documentation for\n} .
2365         qq{other ways of achieving the same results.\n}
2366     ) if delete $config->{ search_extra };
2367
2368     my @comps = $class->locate_components($config);
2369     my %comps = map { $_ => 1 } @comps;
2370
2371     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2372     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2373         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2374     ) if $deprecatedcatalyst_component_names;
2375
2376     for my $component ( @comps ) {
2377
2378         # We pass ignore_loaded here so that overlay files for (e.g.)
2379         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2380         # we know M::P::O found a file on disk so this is safe
2381
2382         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2383     }
2384
2385     my $containers;
2386     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
2387
2388     for my $component (@comps) {
2389         my $instance = $class->setup_component($component);
2390         if ( my ($type, $name) = _get_component_type_name($component) ) {
2391             $containers->{$type}->add_service(Catalyst::IOC::BlockInjection->new( name => $name, block => sub { return $instance } ));
2392         }
2393         my @expanded_components = $instance->can('expand_modules')
2394             ? $instance->expand_modules( $component, $config )
2395             : $class->expand_component_module( $component, $config );
2396         for my $component (@expanded_components) {
2397             next if $comps{$component};
2398
2399             $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @expanded_components;
2400             $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2401                 qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2402             ) if $deprecatedcatalyst_component_names;
2403
2404             if (my ($type, $name) = _get_component_type_name($component)) {
2405                 $containers->{$type}->add_service(Catalyst::IOC::BlockInjection->new( name => $name, block => sub { return $class->setup_component($component) } ));
2406             }
2407         }
2408     }
2409
2410     $containers->{model}->make_single_default;
2411     $containers->{view}->make_single_default;
2412 }
2413
2414 # FIXME: should this sub exist?
2415 # should it be moved to Catalyst::Utils,
2416 # or replaced by something already existing there?
2417 sub _get_component_type_name {
2418     my ( $component ) = @_;
2419
2420     my @parts = split /::/, $component;
2421
2422     while (my $type = shift @parts) {
2423         return ('controller', join '::', @parts)
2424             if $type =~ /^(c|controller)$/i;
2425
2426         return ('model', join '::', @parts)
2427             if $type =~ /^(m|model)$/i;
2428
2429         return ('view', join '::', @parts)
2430             if $type =~ /^(v|view)$/i;
2431     }
2432
2433     return (undef, $component);
2434 }
2435
2436 =head2 $c->locate_components( $setup_component_config )
2437
2438 This method is meant to provide a list of component modules that should be
2439 setup for the application.  By default, it will use L<Module::Pluggable>.
2440
2441 Specify a C<setup_components> config option to pass additional options directly
2442 to L<Module::Pluggable>.
2443
2444 =cut
2445
2446 sub locate_components {
2447     my $class  = shift;
2448     my $config = shift;
2449
2450     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2451
2452     my $locator = Module::Pluggable::Object->new(
2453         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2454         %$config
2455     );
2456
2457     # XXX think about ditching this sort entirely
2458     my @comps = sort { length $a <=> length $b } $locator->plugins;
2459
2460     return @comps;
2461 }
2462
2463 =head2 $c->expand_component_module( $component, $setup_component_config )
2464
2465 Components found by C<locate_components> will be passed to this method, which
2466 is expected to return a list of component (package) names to be set up.
2467
2468 =cut
2469
2470 sub expand_component_module {
2471     my ($class, $module) = @_;
2472     return Devel::InnerPackage::list_packages( $module );
2473 }
2474
2475 =head2 $c->setup_component
2476
2477 =cut
2478
2479 ## FIXME - Why the hell do we try calling the ->COMPONENT method twice, this is madness!?!
2480 sub setup_component {
2481     my( $class, $component ) = @_;
2482
2483     unless ( $component->can( 'COMPONENT' ) ) {
2484         return $component;
2485     }
2486
2487     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2488     my $config = $class->config->{ $suffix } || {};
2489     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2490     # methods also pass it. local to avoid pointlessly shitting in config
2491     # for the debug screen, as $component is already the key name.
2492     local $config->{catalyst_component_name} = $component;
2493
2494     my $instance = eval { $component->COMPONENT( $class, $config ); };
2495
2496     if ( my $error = $@ ) {
2497         chomp $error;
2498         Catalyst::Exception->throw(
2499             message => qq/Couldn't instantiate component "$component", "$error"/
2500         );
2501     }
2502     elsif (!blessed $instance) {
2503         my $metaclass = Moose::Util::find_meta($component);
2504         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2505         my $component_method_from = $method_meta->associated_metaclass->name;
2506         my $value = defined($instance) ? $instance : 'undef';
2507         Catalyst::Exception->throw(
2508             message =>
2509             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2510         );
2511     }
2512
2513     return $instance;
2514 }
2515
2516 =head2 $c->setup_dispatcher
2517
2518 Sets up dispatcher.
2519
2520 =cut
2521
2522 sub setup_dispatcher {
2523     my ( $class, $dispatcher ) = @_;
2524
2525     if ($dispatcher) {
2526         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2527     }
2528
2529     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2530         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2531     }
2532
2533     unless ($dispatcher) {
2534         $dispatcher = $class->dispatcher_class;
2535     }
2536
2537     Class::MOP::load_class($dispatcher);
2538
2539     # dispatcher instance
2540     $class->dispatcher( $dispatcher->new );
2541 }
2542
2543 =head2 $c->setup_engine
2544
2545 Sets up engine.
2546
2547 =cut
2548
2549 sub setup_engine {
2550     my ( $class, $engine ) = @_;
2551
2552     if ($engine) {
2553         $engine = 'Catalyst::Engine::' . $engine;
2554     }
2555
2556     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2557         $engine = 'Catalyst::Engine::' . $env;
2558     }
2559
2560     if ( $ENV{MOD_PERL} ) {
2561         my $meta = Class::MOP::get_metaclass_by_name($class);
2562
2563         # create the apache method
2564         $meta->add_method('apache' => sub { shift->engine->apache });
2565
2566         my ( $software, $version ) =
2567           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2568
2569         $version =~ s/_//g;
2570         $version =~ s/(\.[^.]+)\./$1/g;
2571
2572         if ( $software eq 'mod_perl' ) {
2573
2574             if ( !$engine ) {
2575
2576                 if ( $version >= 1.99922 ) {
2577                     $engine = 'Catalyst::Engine::Apache2::MP20';
2578                 }
2579
2580                 elsif ( $version >= 1.9901 ) {
2581                     $engine = 'Catalyst::Engine::Apache2::MP19';
2582                 }
2583
2584                 elsif ( $version >= 1.24 ) {
2585                     $engine = 'Catalyst::Engine::Apache::MP13';
2586                 }
2587
2588                 else {
2589                     Catalyst::Exception->throw( message =>
2590                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2591                 }
2592
2593             }
2594
2595             # install the correct mod_perl handler
2596             if ( $version >= 1.9901 ) {
2597                 *handler = sub  : method {
2598                     shift->handle_request(@_);
2599                 };
2600             }
2601             else {
2602                 *handler = sub ($$) { shift->handle_request(@_) };
2603             }
2604
2605         }
2606
2607         elsif ( $software eq 'Zeus-Perl' ) {
2608             $engine = 'Catalyst::Engine::Zeus';
2609         }
2610
2611         else {
2612             Catalyst::Exception->throw(
2613                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2614         }
2615     }
2616
2617     unless ($engine) {
2618         $engine = $class->engine_class;
2619     }
2620
2621     Class::MOP::load_class($engine);
2622
2623     # check for old engines that are no longer compatible
2624     my $old_engine;
2625     if ( $engine->isa('Catalyst::Engine::Apache')
2626         && !Catalyst::Engine::Apache->VERSION )
2627     {
2628         $old_engine = 1;
2629     }
2630
2631     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2632         && Catalyst::Engine::Server->VERSION le '0.02' )
2633     {
2634         $old_engine = 1;
2635     }
2636
2637     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2638         && $engine->VERSION eq '0.01' )
2639     {
2640         $old_engine = 1;
2641     }
2642
2643     elsif ($engine->isa('Catalyst::Engine::Zeus')
2644         && $engine->VERSION eq '0.01' )
2645     {
2646         $old_engine = 1;
2647     }
2648
2649     if ($old_engine) {
2650         Catalyst::Exception->throw( message =>
2651               qq/Engine "$engine" is not supported by this version of Catalyst/
2652         );
2653     }
2654
2655     # engine instance
2656     $class->engine( $engine->new );
2657 }
2658
2659 =head2 $c->setup_home
2660
2661 Sets up the home directory.
2662
2663 =cut
2664
2665 sub setup_home {
2666     my ( $class, $home ) = @_;
2667
2668     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2669         $home = $env;
2670     }
2671
2672     $home ||= Catalyst::Utils::home($class);
2673
2674     if ($home) {
2675         #I remember recently being scolded for assigning config values like this
2676         $class->config->{home} ||= $home;
2677         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2678     }
2679 }
2680
2681 =head2 $c->setup_log
2682
2683 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2684 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2685 log to.
2686
2687 This method also installs a C<debug> method that returns a true value into the
2688 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2689 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2690
2691 Note that if the log has already been setup, by either a previous call to
2692 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2693 that this method won't actually set up the log object.
2694
2695 =cut
2696
2697 sub setup_log {
2698     my ( $class, $levels ) = @_;
2699
2700     $levels ||= '';
2701     $levels =~ s/^\s+//;
2702     $levels =~ s/\s+$//;
2703     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2704
2705     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2706     if ( defined $env_debug ) {
2707         $levels{debug} = 1 if $env_debug; # Ugly!
2708         delete($levels{debug}) unless $env_debug;
2709     }
2710
2711     unless ( $class->log ) {
2712         $class->log( Catalyst::Log->new(keys %levels) );
2713     }
2714
2715     if ( $levels{debug} ) {
2716         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2717         $class->log->debug('Debug messages enabled');
2718     }
2719 }
2720
2721 =head2 $c->setup_plugins
2722
2723 Sets up plugins.
2724
2725 =cut
2726
2727 =head2 $c->setup_stats
2728
2729 Sets up timing statistics class.
2730
2731 =cut
2732
2733 sub setup_stats {
2734     my ( $class, $stats ) = @_;
2735
2736     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2737
2738     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2739     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2740         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2741         $class->log->debug('Statistics enabled');
2742     }
2743 }
2744
2745
2746 =head2 $c->registered_plugins
2747
2748 Returns a sorted list of the plugins which have either been stated in the
2749 import list or which have been added via C<< MyApp->plugin(@args); >>.
2750
2751 If passed a given plugin name, it will report a boolean value indicating
2752 whether or not that plugin is loaded.  A fully qualified name is required if
2753 the plugin name does not begin with C<Catalyst::Plugin::>.
2754
2755  if ($c->registered_plugins('Some::Plugin')) {
2756      ...
2757  }
2758
2759 =cut
2760
2761 {
2762
2763     sub registered_plugins {
2764         my $proto = shift;
2765         return sort keys %{ $proto->_plugins } unless @_;
2766         my $plugin = shift;
2767         return 1 if exists $proto->_plugins->{$plugin};
2768         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2769     }
2770
2771     sub _register_plugin {
2772         my ( $proto, $plugin, $instant ) = @_;
2773         my $class = ref $proto || $proto;
2774
2775         Class::MOP::load_class( $plugin );
2776         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2777             if $plugin->isa( 'Catalyst::Component' );
2778         $proto->_plugins->{$plugin} = 1;
2779         unless ($instant) {
2780             my $meta = Class::MOP::get_metaclass_by_name($class);
2781             $meta->superclasses($plugin, $meta->superclasses);
2782         }
2783         return $class;
2784     }
2785
2786     sub setup_plugins {
2787         my ( $class, $plugins ) = @_;
2788
2789         $class->_plugins( {} ) unless $class->_plugins;
2790         $plugins = Data::OptList::mkopt($plugins || []);
2791
2792         my @plugins = map {
2793             [ Catalyst::Utils::resolve_namespace(
2794                   $class . '::Plugin',
2795                   'Catalyst::Plugin', $_->[0]
2796               ),
2797               $_->[1],
2798             ]
2799          } @{ $plugins };
2800
2801         for my $plugin ( reverse @plugins ) {
2802             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2803             my $meta = find_meta($plugin->[0]);
2804             next if $meta && $meta->isa('Moose::Meta::Role');
2805
2806             $class->_register_plugin($plugin->[0]);
2807         }
2808
2809         my @roles =
2810             map  { $_->[0]->name, $_->[1] }
2811             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2812             map  { [find_meta($_->[0]), $_->[1]] }
2813             @plugins;
2814
2815         Moose::Util::apply_all_roles(
2816             $class => @roles
2817         ) if @roles;
2818     }
2819 }
2820
2821 =head2 $c->stack
2822
2823 Returns an arrayref of the internal execution stack (actions that are
2824 currently executing).
2825
2826 =head2 $c->stats
2827
2828 Returns the current timing statistics object. By default Catalyst uses
2829 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2830 L<< stats_class|/"$c->stats_class" >>.
2831
2832 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2833 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2834 profile explicitly, although MyApp.pm still won't profile nor output anything
2835 by itself.
2836
2837 =head2 $c->stats_class
2838
2839 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2840
2841 =head2 $c->use_stats
2842
2843 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2844
2845 Note that this is a static method, not an accessor and should be overridden
2846 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2847
2848 =cut
2849
2850 sub use_stats { 0 }
2851
2852
2853 =head2 $c->write( $data )
2854
2855 Writes $data to the output stream. When using this method directly, you
2856 will need to manually set the C<Content-Length> header to the length of
2857 your output data, if known.
2858
2859 =cut
2860
2861 sub write {
2862     my $c = shift;
2863
2864     # Finalize headers if someone manually writes output
2865     $c->finalize_headers;
2866
2867     return $c->engine->write( $c, @_ );
2868 }
2869
2870 =head2 version
2871
2872 Returns the Catalyst version number. Mostly useful for "powered by"
2873 messages in template systems.
2874
2875 =cut
2876
2877 sub version { return $Catalyst::VERSION }
2878
2879 =head1 CONFIGURATION
2880
2881 There are a number of 'base' config variables which can be set:
2882
2883 =over
2884
2885 =item *
2886
2887 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2888
2889 =item *
2890
2891 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2892
2893 =item *
2894
2895 C<home> - The application home directory. In an uninstalled application,
2896 this is the top level application directory. In an installed application,
2897 this will be the directory containing C<< MyApp.pm >>.
2898
2899 =item *
2900
2901 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2902
2903 =item *
2904
2905 C<name> - The name of the application in debug messages and the debug and
2906 welcome screens
2907
2908 =item *
2909
2910 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2911 until it is accessed. This allows you to (for example) check authentication (and reject
2912 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2913
2914 =item *
2915
2916 C<root> - The root directory for templates. Usually this is just a
2917 subdirectory of the home directory, but you can set it to change the
2918 templates to a different directory.
2919
2920 =item *
2921
2922 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2923 to be shown in hit debug tables in the test server.
2924
2925 =item *
2926
2927 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
2928 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
2929 for more information.
2930
2931 =item *
2932
2933 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2934
2935 =back
2936
2937 =head1 INTERNAL ACTIONS
2938
2939 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2940 C<_ACTION>, and C<_END>. These are by default not shown in the private
2941 action table, but you can make them visible with a config parameter.
2942
2943     MyApp->config(show_internal_actions => 1);
2944
2945 =head1 ON-DEMAND PARSER
2946
2947 The request body is usually parsed at the beginning of a request,
2948 but if you want to handle input yourself, you can enable on-demand
2949 parsing with a config parameter.
2950
2951     MyApp->config(parse_on_demand => 1);
2952
2953 =head1 PROXY SUPPORT
2954
2955 Many production servers operate using the common double-server approach,
2956 with a lightweight frontend web server passing requests to a larger
2957 backend server. An application running on the backend server must deal
2958 with two problems: the remote user always appears to be C<127.0.0.1> and
2959 the server's hostname will appear to be C<localhost> regardless of the
2960 virtual host that the user connected through.
2961
2962 Catalyst will automatically detect this situation when you are running
2963 the frontend and backend servers on the same machine. The following
2964 changes are made to the request.
2965
2966     $c->req->address is set to the user's real IP address, as read from
2967     the HTTP X-Forwarded-For header.
2968
2969     The host value for $c->req->base and $c->req->uri is set to the real
2970     host, as read from the HTTP X-Forwarded-Host header.
2971
2972 Additionally, you may be running your backend application on an insecure
2973 connection (port 80) while your frontend proxy is running under SSL.  If there
2974 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2975 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2976 be created properly.
2977
2978 In the case of passing in:
2979
2980     X-Forwarded-Port: 443
2981
2982 All calls to C<uri_for> will result in an https link, as is expected.
2983
2984 Obviously, your web server must support these headers for this to work.
2985
2986 In a more complex server farm environment where you may have your
2987 frontend proxy server(s) on different machines, you will need to set a
2988 configuration option to tell Catalyst to read the proxied data from the
2989 headers.
2990
2991     MyApp->config(using_frontend_proxy => 1);
2992
2993 If you do not wish to use the proxy support at all, you may set:
2994
2995     MyApp->config(ignore_frontend_proxy => 1);
2996
2997 =head1 THREAD SAFETY
2998
2999 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3000 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3001 believe the Catalyst core to be thread-safe.
3002
3003 If you plan to operate in a threaded environment, remember that all other
3004 modules you are using must also be thread-safe. Some modules, most notably
3005 L<DBD::SQLite>, are not thread-safe.
3006
3007 =head1 SUPPORT
3008
3009 IRC:
3010
3011     Join #catalyst on irc.perl.org.
3012
3013 Mailing Lists:
3014
3015     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3016     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3017
3018 Web:
3019
3020     http://catalyst.perl.org
3021
3022 Wiki:
3023
3024     http://dev.catalyst.perl.org
3025
3026 =head1 SEE ALSO
3027
3028 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3029
3030 =head2 L<Catalyst::Manual> - The Catalyst Manual
3031
3032 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3033
3034 =head2 L<Catalyst::Engine> - Core engine
3035
3036 =head2 L<Catalyst::Log> - Log class.
3037
3038 =head2 L<Catalyst::Request> - Request object
3039
3040 =head2 L<Catalyst::Response> - Response object
3041
3042 =head2 L<Catalyst::Test> - The test suite.
3043
3044 =head1 PROJECT FOUNDER
3045
3046 sri: Sebastian Riedel <sri@cpan.org>
3047
3048 =head1 CONTRIBUTORS
3049
3050 abw: Andy Wardley
3051
3052 acme: Leon Brocard <leon@astray.com>
3053
3054 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3055
3056 Andrew Bramble
3057
3058 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3059
3060 Andrew Ruthven
3061
3062 André Walker
3063
3064 andyg: Andy Grundman <andy@hybridized.org>
3065
3066 audreyt: Audrey Tang
3067
3068 bricas: Brian Cassidy <bricas@cpan.org>
3069
3070 Caelum: Rafael Kitover <rkitover@io.com>
3071
3072 chansen: Christian Hansen
3073
3074 chicks: Christopher Hicks
3075
3076 Chisel Wright C<pause@herlpacker.co.uk>
3077
3078 Danijel Milicevic C<me@danijel.de>
3079
3080 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3081
3082 David Naughton, C<naughton@umn.edu>
3083
3084 David E. Wheeler
3085
3086 dhoss: Devin Austin <dhoss@cpan.org>
3087
3088 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3089
3090 Drew Taylor
3091
3092 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3093
3094 esskar: Sascha Kiefer
3095
3096 fireartist: Carl Franks <cfranks@cpan.org>
3097
3098 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3099
3100 gabb: Danijel Milicevic
3101
3102 Gary Ashton Jones
3103
3104 Gavin Henry C<ghenry@perl.me.uk>
3105
3106 Geoff Richards
3107
3108 groditi: Guillermo Roditi <groditi@gmail.com>
3109
3110 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3111
3112 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3113
3114 jcamacho: Juan Camacho
3115
3116 jester: Jesse Sheidlower C<jester@panix.com>
3117
3118 jhannah: Jay Hannah <jay@jays.net>
3119
3120 Jody Belka
3121
3122 Johan Lindstrom
3123
3124 jon: Jon Schutz <jjschutz@cpan.org>
3125
3126 Jonathan Rockway C<< <jrockway@cpan.org> >>
3127
3128 Kieren Diment C<kd@totaldatasolution.com>
3129
3130 konobi: Scott McWhirter <konobi@cpan.org>
3131
3132 marcus: Marcus Ramberg <mramberg@cpan.org>
3133
3134 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3135
3136 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3137
3138 mugwump: Sam Vilain
3139
3140 naughton: David Naughton
3141
3142 ningu: David Kamholz <dkamholz@cpan.org>
3143
3144 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3145
3146 numa: Dan Sully <daniel@cpan.org>
3147
3148 obra: Jesse Vincent
3149
3150 Octavian Rasnita
3151
3152 omega: Andreas Marienborg
3153
3154 Oleg Kostyuk <cub.uanic@gmail.com>
3155
3156 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3157
3158 rafl: Florian Ragwitz <rafl@debian.org>
3159
3160 random: Roland Lammel <lammel@cpan.org>
3161
3162 Robert Sedlacek C<< <rs@474.at> >>
3163
3164 SpiceMan: Marcel Montes
3165
3166 sky: Arthur Bergman
3167
3168 szbalint: Balint Szilakszi <szbalint@cpan.org>
3169
3170 t0m: Tomas Doran <bobtfish@bobtfish.net>
3171
3172 Ulf Edvinsson
3173
3174 Viljo Marrandi C<vilts@yahoo.com>
3175
3176 Will Hawes C<info@whawes.co.uk>
3177
3178 willert: Sebastian Willert <willert@cpan.org>
3179
3180 wreis: Wallace Reis <wallace@reis.org.br>
3181
3182 Yuval Kogman, C<nothingmuch@woobling.org>
3183
3184 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3185
3186 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3187
3188 =head1 COPYRIGHT
3189
3190 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3191
3192 =head1 LICENSE
3193
3194 This library is free software. You can redistribute it and/or modify it under
3195 the same terms as Perl itself.
3196
3197 =cut
3198
3199 no Moose;
3200
3201 __PACKAGE__->meta->make_immutable;
3202
3203 1;