lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/Catalyst::View/;
   7 use Data::Dump 'dump';
   8 use Template;
   9 use Template::Timer;
  10 use MRO::Compat;
  11
  12 our $VERSION = '0.30';
  13
  14 __PACKAGE__->mk_accessors('template');
  15 __PACKAGE__->mk_accessors('include_path');
  16
  17 *paths = \&include_path;
  18
  19 =head1 NAME
  20
  21 Catalyst::View::TT - Template View Class
  22
  23 =head1 SYNOPSIS
  24
  25 # use the helper to create your View
  26     myapp_create.pl view TT TT
  27
  28 # configure in lib/MyApp.pm (Could be set from configfile instead)
  29
  30     MyApp->config(
  31         name     => 'MyApp',
  32         root     => MyApp->path_to('root'),
  33         'View::TT' => {
  34             # any TT configurations items go here
  35             INCLUDE_PATH => [
  36               MyApp->path_to( 'root', 'src' ),
  37               MyApp->path_to( 'root', 'lib' ),
  38             ],
  39             TEMPLATE_EXTENSION => '.tt',
  40             CATALYST_VAR => 'c',
  41             TIMER        => 0,
  42             # Not set by default
  43             PRE_PROCESS        => 'config/main',
  44             WRAPPER            => 'site/wrapper',
  45         },
  46     );
  47
  48 # render view from lib/MyApp.pm or lib/MyApp::Controller::SomeController.pm
  49
  50     sub message : Global {
  51         my ( $self, $c ) = @_;
  52         $c->stash->{template} = 'message.tt2';
  53         $c->stash->{message}  = 'Hello World!';
  54         $c->forward( $c->view('TT') );
  55     }
  56
  57 # access variables from template
  58
  59     The message is: [% message %].
  60
  61     # example when CATALYST_VAR is set to 'Catalyst'
  62     Context is [% Catalyst %]
  63     The base is [% Catalyst.req.base %]
  64     The name is [% Catalyst.config.name %]
  65
  66     # example when CATALYST_VAR isn't set
  67     Context is [% c %]
  68     The base is [% base %]
  69     The name is [% name %]
  70
  71 =cut
  72
  73 sub _coerce_paths {
  74     my ( $paths, $dlim ) = shift;
  75     return () if ( !$paths );
  76     return @{$paths} if ( ref $paths eq 'ARRAY' );
  77
  78     # tweak delim to ignore C:/
  79     unless ( defined $dlim ) {
  80         $dlim = ( $^O eq 'MSWin32' ) ? ':(?!\\/)' : ':';
  81     }
  82     return split( /$dlim/, $paths );
  83 }
  84
  85 sub new {
  86     my ( $class, $c, $arguments ) = @_;
  87     my $config = {
  88         EVAL_PERL          => 0,
  89         TEMPLATE_EXTENSION => '',
  90         %{ $class->config },
  91         %{$arguments},
  92     };
  93     if ( ! (ref $config->{INCLUDE_PATH} eq 'ARRAY') ) {
  94         my $delim = $config->{DELIMITER};
  95         my @include_path
  96             = _coerce_paths( $config->{INCLUDE_PATH}, $delim );
  97         if ( !@include_path ) {
  98             my $root = $c->config->{root};
  99             my $base = Path::Class::dir( $root, 'base' );
 100             @include_path = ( "$root", "$base" );
 101         }
 102         $config->{INCLUDE_PATH} = \@include_path;
 103     }
 104
 105     # if we're debugging and/or the TIMER option is set, then we install
 106     # Template::Timer as a custom CONTEXT object, but only if we haven't
 107     # already got a custom CONTEXT defined
 108
 109     if ( $config->{TIMER} ) {
 110         if ( $config->{CONTEXT} ) {
 111             $c->log->error(
 112                 'Cannot use Template::Timer - a TT CONTEXT is already defined'
 113             );
 114         }
 115         else {
 116             $config->{CONTEXT} = Template::Timer->new(%$config);
 117         }
 118     }
 119
 120     if ( $c->debug && $config->{DUMP_CONFIG} ) {
 121         $c->log->debug( "TT Config: ", dump($config) );
 122     }
 123
 124     my $self = $class->next::method(
 125         $c, { %$config },
 126     );
 127
 128     # Set base include paths. Local'd in render if needed
 129     $self->include_path($config->{INCLUDE_PATH});
 130
 131     $self->config($config);
 132
 133     # Creation of template outside of call to new so that we can pass [ $self ]
 134     # as INCLUDE_PATH config item, which then gets ->paths() called to get list
 135     # of include paths to search for templates.
 136
 137     # Use a weakend copy of self so we dont have loops preventing GC from working
 138     my $copy = $self;
 139     Scalar::Util::weaken($copy);
 140     $config->{INCLUDE_PATH} = [ sub { $copy->paths } ];
 141
 142     if ( $config->{PROVIDERS} ) {
 143         my @providers = ();
 144         if ( ref($config->{PROVIDERS}) eq 'ARRAY') {
 145             foreach my $p (@{$config->{PROVIDERS}}) {
 146                 my $pname = $p->{name};
 147                 my $prov = 'Template::Provider';
 148                 if($pname eq '_file_')
 149                 {
 150                     $p->{args} = { %$config };
 151                 }
 152                 else
 153                 {
 154                     if($pname =~ s/^\+//) {
 155                         $prov = $pname;
 156                     }
 157                     else
 158                     {
 159                         $prov .= "::$pname";
 160                     }
 161                     # We copy the args people want from the config
 162                     # to the args
 163                     $p->{args} ||= {};
 164                     if ($p->{copy_config}) {
 165                         map  { $p->{args}->{$_} = $config->{$_}  }
 166                                    grep { exists $config->{$_} }
 167                                    @{ $p->{copy_config} };
 168                     }
 169                 }
 170                 eval "require $prov";
 171                 if(!$@) {
 172                     push @providers, "$prov"->new($p->{args});
 173                 }
 174                 else
 175                 {
 176                     $c->log->warn("Can't load $prov, ($@)");
 177                 }
 178             }
 179         }
 180         delete $config->{PROVIDERS};
 181         if(@providers) {
 182             $config->{LOAD_TEMPLATES} = \@providers;
 183         }
 184     }
 185
 186     $self->{template} =
 187         Template->new($config) || do {
 188             my $error = Template->error();
 189             $c->log->error($error);
 190             $c->error($error);
 191             return undef;
 192         };
 193
 194
 195     return $self;
 196 }
 197
 198 sub process {
 199     my ( $self, $c ) = @_;
 200
 201     my $template = $c->stash->{template}
 202       ||  $c->action . $self->config->{TEMPLATE_EXTENSION};
 203
 204     unless (defined $template) {
 205         $c->log->debug('No template specified for rendering') if $c->debug;
 206         return 0;
 207     }
 208
 209     my $output = $self->render($c, $template);
 210
 211     if (UNIVERSAL::isa($output, 'Template::Exception')) {
 212         my $error = qq/Couldn't render template "$output"/;
 213         $c->log->error($error);
 214         $c->error($error);
 215         return 0;
 216     }
 217
 218     unless ( $c->response->content_type ) {
 219         $c->response->content_type('text/html; charset=utf-8');
 220     }
 221
 222     $c->response->body($output);
 223
 224     return 1;
 225 }
 226
 227 sub render {
 228     my ($self, $c, $template, $args) = @_;
 229
 230     $c->log->debug(qq/Rendering template "$template"/) if $c->debug;
 231
 232     my $output;
 233     my $vars = {
 234         (ref $args eq 'HASH' ? %$args : %{ $c->stash() }),
 235         $self->template_vars($c)
 236     };
 237
 238     local $self->{include_path} =
 239         [ @{ $vars->{additional_template_paths} }, @{ $self->{include_path} } ]
 240         if ref $vars->{additional_template_paths};
 241
 242     unless ($self->template->process( $template, $vars, \$output ) ) {
 243         return $self->template->error;
 244     } else {
 245         return $output;
 246     }
 247 }
 248
 249 sub template_vars {
 250     my ( $self, $c ) = @_;
 251
 252     my $cvar = $self->config->{CATALYST_VAR};
 253
 254     defined $cvar
 255       ? ( $cvar => $c )
 256       : (
 257         c    => $c,
 258         base => $c->req->base,
 259         name => $c->config->{name}
 260       )
 261 }
 262
 263
 264 1;
 265
 266 __END__
 267
 268 =head1 DESCRIPTION
 269
 270 This is the Catalyst view class for the L<Template Toolkit|Template>.
 271 Your application should defined a view class which is a subclass of
 272 this module.  The easiest way to achieve this is using the
 273 F<myapp_create.pl> script (where F<myapp> should be replaced with
 274 whatever your application is called).  This script is created as part
 275 of the Catalyst setup.
 276
 277     $ script/myapp_create.pl view TT TT
 278
 279 This creates a MyApp::View::TT.pm module in the F<lib> directory (again,
 280 replacing C<MyApp> with the name of your application) which looks
 281 something like this:
 282
 283     package FooBar::View::TT;
 284
 285     use strict;
 286     use warnings;
 287
 288     use base 'Catalyst::View::TT';
 289
 290     __PACKAGE__->config->{DEBUG} = 'all';
 291
 292 Now you can modify your action handlers in the main application and/or
 293 controllers to forward to your view class.  You might choose to do this
 294 in the end() method, for example, to automatically forward all actions
 295 to the TT view class.
 296
 297     # In MyApp or MyApp::Controller::SomeController
 298
 299     sub end : Private {
 300         my( $self, $c ) = @_;
 301         $c->forward( $c->view('TT') );
 302     }
 303
 304 =head2 CONFIGURATION
 305
 306 There are a three different ways to configure your view class.  The
 307 first way is to call the C<config()> method in the view subclass.  This
 308 happens when the module is first loaded.
 309
 310     package MyApp::View::TT;
 311
 312     use strict;
 313     use base 'Catalyst::View::TT';
 314
 315     MyApp::View::TT->config({
 316         INCLUDE_PATH => [
 317             MyApp->path_to( 'root', 'templates', 'lib' ),
 318             MyApp->path_to( 'root', 'templates', 'src' ),
 319         ],
 320         PRE_PROCESS  => 'config/main',
 321         WRAPPER      => 'site/wrapper',
 322     });
 323
 324 The second way is to define a C<new()> method in your view subclass.
 325 This performs the configuration when the view object is created,
 326 shortly after being loaded.  Remember to delegate to the base class
 327 C<new()> method (via C<$self-E<gt>next::method()> in the example below) after
 328 performing any configuration.
 329
 330     sub new {
 331         my $self = shift;
 332         $self->config({
 333             INCLUDE_PATH => [
 334                 MyApp->path_to( 'root', 'templates', 'lib' ),
 335                 MyApp->path_to( 'root', 'templates', 'src' ),
 336             ],
 337             PRE_PROCESS  => 'config/main',
 338             WRAPPER      => 'site/wrapper',
 339         });
 340         return $self->next::method(@_);
 341     }
 342
 343 The final, and perhaps most direct way, is to define a class
 344 item in your main application configuration, again by calling the
 345 uniquitous C<config()> method.  The items in the class hash are
 346 added to those already defined by the above two methods.  This happens
 347 in the base class new() method (which is one reason why you must
 348 remember to call it via C<MRO::Compat> if you redefine the C<new()>
 349 method in a subclass).
 350
 351     package MyApp;
 352
 353     use strict;
 354     use Catalyst;
 355
 356     MyApp->config({
 357         name     => 'MyApp',
 358         root     => MyApp->path_to('root'),
 359         'View::TT' => {
 360             INCLUDE_PATH => [
 361                 MyApp->path_to( 'root', 'templates', 'lib' ),
 362                 MyApp->path_to( 'root', 'templates', 'src' ),
 363             ],
 364             PRE_PROCESS  => 'config/main',
 365             WRAPPER      => 'site/wrapper',
 366         },
 367     });
 368
 369 Note that any configuration items defined by one of the earlier
 370 methods will be overwritten by items of the same name provided by the
 371 latter methods.
 372
 373 =head2 DYNAMIC INCLUDE_PATH
 374
 375 Sometimes it is desirable to modify INCLUDE_PATH for your templates at run time.
 376
 377 Additional paths can be added to the start of INCLUDE_PATH via the stash as
 378 follows:
 379
 380     $c->stash->{additional_template_paths} =
 381         [$c->config->{root} . '/test_include_path'];
 382
 383 If you need to add paths to the end of INCLUDE_PATH, there is also an
 384 include_path() accessor available:
 385
 386     push( @{ $c->view('TT')->include_path }, qw/path/ );
 387
 388 Note that if you use include_path() to add extra paths to INCLUDE_PATH, you
 389 MUST check for duplicate paths. Without such checking, the above code will add
 390 "path" to INCLUDE_PATH at every request, causing a memory leak.
 391
 392 A safer approach is to use include_path() to overwrite the array of paths
 393 rather than adding to it. This eliminates both the need to perform duplicate
 394 checking and the chance of a memory leak:
 395
 396     @{ $c->view('TT')->include_path } = qw/path another_path/;
 397
 398 If you are calling C<render> directly then you can specify dynamic paths by
 399 having a C<additional_template_paths> key with a value of additonal directories
 400 to search. See L<CAPTURING TEMPLATE OUTPUT> for an example showing this.
 401
 402 =head2 RENDERING VIEWS
 403
 404 The view plugin renders the template specified in the C<template>
 405 item in the stash.
 406
 407     sub message : Global {
 408         my ( $self, $c ) = @_;
 409         $c->stash->{template} = 'message.tt2';
 410         $c->forward( $c->view('TT') );
 411     }
 412
 413 If a stash item isn't defined, then it instead uses the
 414 stringification of the action dispatched to (as defined by $c->action)
 415 in the above example, this would be C<message>, but because the default
 416 is to append '.tt', it would load C<root/message.tt>.
 417
 418 The items defined in the stash are passed to the Template Toolkit for
 419 use as template variables.
 420
 421     sub default : Private {
 422         my ( $self, $c ) = @_;
 423         $c->stash->{template} = 'message.tt2';
 424         $c->stash->{message}  = 'Hello World!';
 425         $c->forward( $c->view('TT') );
 426     }
 427
 428 A number of other template variables are also added:
 429
 430     c      A reference to the context object, $c
 431     base   The URL base, from $c->req->base()
 432     name   The application name, from $c->config->{ name }
 433
 434 These can be accessed from the template in the usual way:
 435
 436 <message.tt2>:
 437
 438     The message is: [% message %]
 439     The base is [% base %]
 440     The name is [% name %]
 441
 442
 443 The output generated by the template is stored in C<< $c->response->body >>.
 444
 445 =head2 CAPTURING TEMPLATE OUTPUT
 446
 447 If you wish to use the output of a template for some other purpose than
 448 displaying in the response, e.g. for sending an email, this is possible using
 449 L<Catalyst::Plugin::Email> and the L<render> method:
 450
 451   sub send_email : Local {
 452     my ($self, $c) = @_;
 453
 454     $c->email(
 455       header => [
 456         To      => 'me@localhost',
 457         Subject => 'A TT Email',
 458       ],
 459       body => $c->view('TT')->render($c, 'email.tt', {
 460         additional_template_paths => [ $c->config->{root} . '/email_templates'],
 461         email_tmpl_param1 => 'foo'
 462         }
 463       ),
 464     );
 465   # Redirect or display a message
 466   }
 467
 468 =head2 TEMPLATE PROFILING
 469
 470 See L<C<TIMER>> property of the L<config> method.
 471
 472 =head2 METHODS
 473
 474 =head2 new
 475
 476 The constructor for the TT view. Sets up the template provider,
 477 and reads the application config.
 478
 479 =head2 process
 480
 481 Renders the template specified in C<< $c->stash->{template} >> or
 482 C<< $c->action >> (the private name of the matched action.  Calls L<render> to
 483 perform actual rendering. Output is stored in C<< $c->response->body >>.
 484
 485 =head2 render($c, $template, \%args)
 486
 487 Renders the given template and returns output, or a L<Template::Exception>
 488 object upon error.
 489
 490 The template variables are set to C<%$args> if $args is a hashref, or
 491 $C<< $c->stash >> otherwise. In either case the variables are augmented with
 492 C<base> set to C< << $c->req->base >>, C<c> to C<$c> and C<name> to
 493 C<< $c->config->{name} >>. Alternately, the C<CATALYST_VAR> configuration item
 494 can be defined to specify the name of a template variable through which the
 495 context reference (C<$c>) can be accessed. In this case, the C<c>, C<base> and
 496 C<name> variables are omitted.
 497
 498 C<$template> can be anything that Template::process understands how to
 499 process, including the name of a template file or a reference to a test string.
 500 See L<Template::process|Template/process> for a full list of supported formats.
 501
 502 =head2 template_vars
 503
 504 Returns a list of keys/values to be used as the catalyst variables in the
 505 template.
 506
 507 =head2 config
 508
 509 This method allows your view subclass to pass additional settings to
 510 the TT configuration hash, or to set the options as below:
 511
 512 =head2 paths
 513
 514 The list of paths TT will look for templates in.
 515
 516 =head2 C<CATALYST_VAR>
 517
 518 Allows you to change the name of the Catalyst context object. If set, it will also
 519 remove the base and name aliases, so you will have access them through <context>.
 520
 521 For example:
 522
 523     MyApp->config({
 524         name     => 'MyApp',
 525         root     => MyApp->path_to('root'),
 526         'View::TT' => {
 527             CATALYST_VAR => 'Catalyst',
 528         },
 529     });
 530
 531 F<message.tt2>:
 532
 533     The base is [% Catalyst.req.base %]
 534     The name is [% Catalyst.config.name %]
 535
 536 =head2 C<TIMER>
 537
 538 If you have configured Catalyst for debug output, and turned on the TIMER setting,
 539 C<Catalyst::View::TT> will enable profiling of template processing
 540 (using L<Template::Timer>). This will embed HTML comments in the
 541 output from your templates, such as:
 542
 543     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
 544     <!-- TIMER START: include mainmenu/cssindex.tt -->
 545     <!-- TIMER START: process mainmenu/cssindex.tt -->
 546     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
 547     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
 548
 549     ....
 550
 551     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
 552
 553
 554 =head2 C<TEMPLATE_EXTENSION>
 555
 556 a sufix to add when looking for templates bases on the C<match> method in L<Catalyst::Request>.
 557
 558 For example:
 559
 560   package MyApp::Controller::Test;
 561   sub test : Local { .. }
 562
 563 Would by default look for a template in <root>/test/test. If you set TEMPLATE_EXTENSION to '.tt', it will look for
 564 <root>/test/test.tt.
 565
 566 =head2 C<PROVIDERS>
 567
 568 Allows you to specify the template providers that TT will use.
 569
 570     MyApp->config({
 571         name     => 'MyApp',
 572         root     => MyApp->path_to('root'),
 573         'View::TT' => {
 574             PROVIDERS => [
 575                 {
 576                     name    => 'DBI',
 577                     args    => {
 578                         DBI_DSN => 'dbi:DB2:books',
 579                         DBI_USER=> 'foo'
 580                     }
 581                 }, {
 582                     name    => '_file_',
 583                     args    => {}
 584                 }
 585             ]
 586         },
 587     });
 588
 589 The 'name' key should correspond to the class name of the provider you
 590 want to use.  The _file_ name is a special case that represents the default
 591 TT file-based provider.  By default the name is will be prefixed with
 592 'Template::Provider::'.  You can fully qualify the name by using a unary
 593 plus:
 594
 595     name => '+MyApp::Provider::Foo'
 596
 597 You can also specify the 'copy_config' key as an arrayref, to copy those keys
 598 from the general config, into the config for the provider:
 599
 600     DEFAULT_ENCODING    => 'utf-8',
 601     PROVIDERS => [
 602         {
 603             name    => 'Encoding',
 604             copy_config => [qw(DEFAULT_ENCODING INCLUDE_PATH)]
 605         }
 606     ]
 607
 608 This can prove useful when you want to use the additional_template_paths hack
 609 in your own provider, or if you need to use Template::Provider::Encoding
 610
 611 =head2 HELPERS
 612
 613 The L<Catalyst::Helper::View::TT> and
 614 L<Catalyst::Helper::View::TTSite> helper modules are provided to create
 615 your view module.  There are invoked by the F<myapp_create.pl> script:
 616
 617     $ script/myapp_create.pl view TT TT
 618
 619     $ script/myapp_create.pl view TT TTSite
 620
 621 The L<Catalyst::Helper::View::TT> module creates a basic TT view
 622 module.  The L<Catalyst::Helper::View::TTSite> module goes a little
 623 further.  It also creates a default set of templates to get you
 624 started.  It also configures the view module to locate the templates
 625 automatically.
 626
 627 =head1 SEE ALSO
 628
 629 L<Catalyst>, L<Catalyst::Helper::View::TT>,
 630 L<Catalyst::Helper::View::TTSite>, L<Template::Manual>
 631
 632 =head1 AUTHORS
 633
 634 Sebastian Riedel, C<sri@cpan.org>
 635
 636 Marcus Ramberg, C<mramberg@cpan.org>
 637
 638 Jesse Sheidlower, C<jester@panix.com>
 639
 640 Andy Wardley, C<abw@cpan.org>
 641
 642 =head1 COPYRIGHT
 643
 644 This program is free software, you can redistribute it and/or modify it
 645 under the same terms as Perl itself.
 646
 647 =cut